Падручнік паказвае, як выкарыстоўваць функцыю TEXTJOIN для аб'яднання тэксту ў Excel з практычнымі прыкладамі.

Да нядаўняга часу было два распаўсюджаных метаду аб'яднання змесціва вочак у Excel: канкатэнацыя аператар і функцыя CONCATENATE. З увядзеннем TEXTJOIN здаецца, што з'явілася больш магутная альтэрнатыва, якая дазваляе злучаць тэкст больш гнутка, уключаючы любы раздзяляльнік паміж імі. Але на самой справе гэта значна больш!

Функцыя Excel TEXTJOIN

TEXTJOIN у Excel аб'ядноўвае тэкставыя радкі з некалькіх ячэек або дыяпазонаў і аддзяляе камбінаваныя значэнні любым раздзяляльнікам што вы ўказваеце. Яна можа ігнараваць або ўключаць у вынік пустыя ячэйкі.

Функцыя даступная ў Excel для Office 365, Excel 2021 і Excel 2019.

Сінтаксіс функцыі TEXTJOIN наступны :

Where:

• Delimiter (абавязкова) - гэта раздзяляльнік паміж кожным тэкставым значэннем што вы аб'ядноўваеце. Звычайна ён падаецца як тэкставы радок, заключаны ў двукоссе, або спасылка на ячэйку, якая змяшчае тэкставы радок. Лік, уведзены ў якасці раздзяляльніка, разглядаецца як тэкст.
• Ignore_empty (абавязкова) - вызначае, ігнараваць пустыя вочкі ці не:
  • TRUE - ігнараваць любыя пустыя вочкі.
  • ХЛУСНЯ - уключыць пустыя вочкі ў выніковы радок.
• Тэкст1 (абавязкова) - першае значэнне для далучэння. Можа быць прадстаўлены як тэкставы радок, спасылка на ячэйку, якая змяшчае радок, або масіў радкоў, напрыклад дыяпазон ячэек.
• Тэкст2 , … (неабавязкова) - дадатковыя тэкставыя значэнні быць злучанымі разам. Дапускаецца максімум 252 тэкставых аргументаў, уключаючы тэкст1 .

У якасці прыкладу аб'яднаем часткі адраса з ячэек B2, C2 і D2 разам у адну ячэйку, падзяліўшы значэнні з коскай і прабелам:

З дапамогай функцыі CONCATENATE вам трэба было б вызначаць кожную ячэйку асобна і ставіць раздзяляльнік (", ") пасля кожнай спасылкі, што можа быць надакучлівым пры аб'яднанні змесціва многіх ячэек:

=CONCATENATE(A2, ", ", B2, ", ", C2)

З дапамогай Excel TEXTJOIN вы вызначаеце раздзяляльнік толькі адзін раз у першым аргументе і даяце дыяпазон ячэек для трэцяга аргумента:

=TEXTJOIN(", ", TRUE, A2:C2)

TEXTJOIN у Excel - 6 рэчаў, якія трэба памятаць

Каб эфектыўна выкарыстоўваць TEXTJOIN у вашых працоўных аркушах, трэба звярнуць увагу на некалькі важных момантаў:

1. TEXTJOIN - гэта новы функцыя, якая даступна толькі ў Excel 2019 - Excel 365. У больш ранніх версіях Excel выкарыстоўвайце функцыю CONCATENATE або "&" замест аператара.
2. У новых версіях Excel вы таксама можаце выкарыстоўваць функцыю CONCAT для аб'яднання значэнняў з асобных ячэек і дыяпазонаў, але без опцый для раздзяляльнікаў або пустых вочак.
3. Любы нумар. да TEXTJOIN для раздзяляльніка або тэксту аргументы пераўтвараюцца ў тэкст.
4. Калі раздзяляльнік не ўказаны або з'яўляецца пустым радком (""), тэкставыя значэнні аб'ядноўваюцца без раздзяляльнікаў.
5. Функцыя можа апрацоўваць да 252 тэкставых аргументаў.
6. Выніковы радок можа змяшчаць максімум 32 767 сімвалаў, што з'яўляецца абмежаваннем ячэйкі ў Excel. Калі гэты ліміт перавышаны, формула TEXTJOIN вяртае #VALUE! памылка.

Як аб'яднаць тэкст у Excel - прыклады формул

Каб лепш зразумець усе перавагі TEXTJOIN, давайце паглядзім, як выкарыстоўваць гэтую функцыю ў рэальных сітуацыях .

Пераўтварыце слупок у спіс, падзелены коскамі

Калі вы жадаеце аб'яднаць вертыкальны спіс, падзяляючы значэнні коскай, кропкай з коскай або любым іншым раздзяляльнікам, TEXTJOIN - гэта правільная функцыя для выкарыстання.

У гэтым прыкладзе мы аб'яднаем перамогі і паразы кожнай каманды з табліцы ніжэй. Гэта можна зрабіць з дапамогай наступных формул, якія адрозніваюцца толькі дыяпазонам ячэек, якія злучаюцца.

Для каманды 1:

=TEXTJOIN(",", FALSE, B2:B6)

Для каманды 2:

=TEXTJOIN(",", FALSE, C2:C6)

І гэтак далей.

Ва ўсіх формулах выкарыстоўваюцца наступныя аргументы:

• Раздзяляльнік - a коска (",").
• Ignore_empty усталявана ў FALSE, каб уключыць пустыя вочкі, таму што нам трэба паказаць, у якія гульні не гулялі.

Як У выніку вы атрымаеце чатыры спісы, падзеленыя коскамі, якія прадстаўляюць перамогі і паразы кожнай каманды ў кампактнай форме:

Злучайце ячэйкі з рознымі раздзяляльнікамі

У сітуацыі, калі вам трэба падзяліць аб'яднаныя значэнні рознымі раздзяляльнікамі, вы можаце ўвесці некалькі раздзяляльнікаў у выглядзе канстанты масіва або ўвесці кожны раздзяляльнік у асобную ячэйку і выкарыстоўвайце спасылку на дыяпазон для аргумента раздзяляльнік .

Выкажам здагадку, што вы хочаце аб'яднаць вочкі, якія змяшчаюць розныя часткі імёнаў, і атрымаць вынік у наступным фармаце: Прозвішча , Імя Імя па бацьку .

Як бачыце, прозвішча і імя падзеленыя коскай і прабелам (", "), а імя і імя па бацьку - прабелам (" ") толькі. Такім чынам, мы ўключаем гэтыя два раздзяляльнікі ў канстанту масіва {", "," "} і атрымліваем наступную формулу:

=TEXTJOIN({", "," "}, TRUE, A2:C2)

Дзе A2:C2 - гэта часткі імя, якія трэба аб'яднаць.

У якасці альтэрнатывы вы можаце ўвесці падзельнікі без двукоссяў у некаторых пустых клетках (скажам, коска і прабел у F3 і прабел у G3) і выкарыстоўваць дыяпазон $F$3:$G$3 (звярніце ўвагу абсалютныя спасылкі на ячэйкі) для аргумента падзельнік :

=TEXTJOIN($F$3:$G$3, TRUE, A2:C2)

Выкарыстоўваючы гэты агульны падыход, вы можаце аб'ядноўваць змесціва ячэйкі ў розных формах.

Напрыклад, калі вы хочаце атрымаць вынік у фармаце Імя Ініцыял па бацьку Прозвішча , выкарыстоўвайце функцыю LEFT, каб атрымаць першы сімвал (ініцыял) з клеткі C2. Што тычыцца падзельнікаў, мы ставім прабел (" ") паміж імем і ініцыялам па бацьку; акропка і прабел (". ") паміж пачаткам і прозвішчам:

=TEXTJOIN({" ",". "}, TRUE, B2, LEFT(C2,1), A2)

Злучыць тэкст і даты ў Excel

У канкрэтным выпадку, калі вы аб'ядноўваеце тэксту і дат, увядзенне дат непасрэдна ў формулу TEXTJOIN не будзе працаваць. Як вы, магчыма, памятаеце, Excel захоўвае даты як парадкавыя нумары, таму ваша формула верне лік, які прадстаўляе дату, як паказана на скрыншоце ніжэй:

=TEXTJOIN(" ", TRUE, A2:B2)

Каб выправіць гэта, вам трэба пераўтварыць дату ў тэкставы радок, перш чым далучыцца да яго. І тут спатрэбіцца функцыя ТЭКСТ з патрэбным кодам фармату (у нашым выпадку "мм/дд/гггг"):

=TEXTJOIN(" ", TRUE, A2, TEXT(B2, "mm/dd/yyyy"))

Аб'яднаць тэкст з разрывамі радкоў

Калі вы жадаеце аб'яднаць тэкст у Excel так, каб кожнае значэнне пачыналася з новага радка, выкарыстоўвайце CHAR(10) у якасці раздзяляльніка (дзе 10 - сімвал перакладу радка).

Напрыклад, каб аб'яднаць тэкст з ячэйкі A2 і B2, якія падзяляюць значэнні разрывам радка, гэта формула для выкарыстання:

=TEXTJOIN(CHAR(10), TRUE, A2:B2)

Савет. Каб вынік адлюстроўваўся ў некалькіх радках, як паказана на скрыншоце вышэй, пераканайцеся, што функцыя абцякання тэкстам уключана.

TEXTJOIN IF для аб'яднання тэксту з умовамі

Дзякуючы магчымасці Excel TEXTJOIN апрацоўваць масівы радкоў, яго таксама можна выкарыстоўваць для ўмоўнага аб'яднання змесціва дзвюх ці больш вочак. Каб зрабіць гэта, выкарыстоўвайце функцыю КАЛІ для ацэнкі дыяпазону ячэек і вяртання масіва значэнняў, якія адпавядаюць умове аргумента тэкст1 TEXTJOIN.

Выкажам здагадку, што вы хочаце атрымаць спіс членаў Каманды 1 з табліцы, паказанай на скрыншоце ніжэй. Каб дасягнуць гэтага, укладзіце наступны аператар IF у аргумент text1 :

IF($B$2:$B$9=1, $A$2:$A$9, "")

На простай англійскай мове прыведзеная вышэй формула кажа: калі слупок B роўны 1, вярніце значэнне са слупка А ў тым жа радку; у адваротным выпадку вяртае пусты радок.

Поўная формула для Каманды 1 прымае такую ​​форму:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=1, $A$2:$A$9, ""))

Аналагічным чынам вы можаце атрымаць падзелены коскамі спіс членаў Каманды 2:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=2, $A$2:$A$9, ""))

Заўвага. Дзякуючы функцыі дынамічных масіваў, даступнай у Excel 365 і 2021, гэта працуе як звычайная формула, паказаная на скрыншоце вышэй. У Excel 2019 вы павінны ўвесці яго як традыцыйную формулу масіва, націснуўшы спалучэнне клавіш Ctrl + Shift + Enter.

Пошук і вяртанне некалькіх супадзенняў у спісе, раздзеленым коскамі

Як вы, напэўна, ведаеце, Функцыя Excel VLOOKUP можа вяртаць толькі першае знойдзенае супадзенне. Але што, калі вам трэба атрымаць усе супадзенні для пэўнага ідэнтыфікатара, SKU ці чагосьці іншага?

Каб вывесці вынікі ў асобныя ячэйкі, выкарыстоўвайце адну з формул, апісаных у раздзеле "Як зрабіць VLOOKUP некалькі значэнняў у Excel".

Каб знайсці і вярнуць усе супадаючыя значэнні ў адной ячэйцы ў выглядзе спісу праз коскі, выкарыстоўвайце формулу TEXTJOIN IF.

Каб убачыць, як гэта працуе на практыцы, давайце атрымаем спіс прадукты, набытыя дадзеным прадаўцом з узорнай табліцыніжэй. Гэта можна лёгка зрабіць з дапамогай наступнай формулы:

=TEXTJOIN(", ", TRUE, IF($A$2:$A$12=D2, $B$2:$B$12, ""))

Дзе A2:A12 — імёны прадаўцоў, B2:B12 — прадукты, а D2 — прадавец, які вас цікавіць.

Прыведзеная вышэй формула ідзе да E2 і прыносіць усе супадзенні для мэтавага прадаўца ў D2 (Адам). Дзякуючы разумнаму выкарыстанню адносных (для мэтавага прадаўца) і абсалютных (для імёнаў прадаўцоў і прадуктаў) спасылак на ячэйкі, формула правільна капіюецца ў прыведзеныя ніжэй ячэйкі і добра працуе таксама для двух іншых прадаўцоў:

Нататка. Як і ў папярэднім прыкладзе, гэта працуе як звычайная формула ў Excel 365 і 2021 і як формула CSE (Ctrl + Shift + Enter) у Excel 2019.

Логіка формулы дакладна такая ж, як і ў папярэдні прыклад:

Аператар IF параўноўвае кожнае імя ў A2:A12 з мэтавым імем у D2 (у нашым выпадку Адам):

IF($A$2:$A$12=D2, $B$2:$B$12, "")

Калі лагічны тэст ацэньвае у TRUE (г.зн. імя ў D2 супадае з імем у слупку A), формула вяртае прадукт са слупка B; інакш вяртаецца пусты радок (""). Вынікам IF з'яўляецца наступны масіў:

{"";"";"Bananas";"Apples";"";"";"";"Oranges";"";"Lemons";""}

Масіў пераходзіць да функцыі TEXTJOIN як аргумент text1 . І таму, што TEXTJOIN настроены на аддзяленне значэнняў коскай і прабелам (", "), мы атрымаем гэты радок у якасці канчатковага выніку:

Бананы, яблыкі, апельсіны, лімоны

Excel TEXTJOIN не працуе

Калі ваша формула TEXTJOIN прыводзіць да памылкі, хутчэй за ўсё,быць адным з наступнага:

• #NAME? памылка ўзнікае, калі TEXTJOIN выкарыстоўваецца ў старой версіі Excel, дзе гэтая функцыя не падтрымліваецца (да 2019 г.), або калі назва функцыі напісана з памылкай.
• #ЗНАЧЭННЕ! памылка ўзнікае, калі выніковы радок перавышае 32 767 сімвалаў.
• #ЗНАЧЭННЕ! памылка таксама можа адбыцца, калі Excel не распазнае падзельнік як тэкст, напрыклад, калі вы ўводзіце нейкі недрукаваны сімвал, напрыклад CHAR(0).

Вось як выкарыстоўваць функцыю TEXTJOIN у Excel. Я дзякую вам за чытанне і спадзяюся ўбачыць вас у нашым блогу на наступным тыдні!

Даступныя спампоўкі

Прыклады формул Excel TEXTJOIN