ප්‍රායෝගික උදාහරණ සමඟින් Excel හි පෙළ ඒකාබද්ධ කිරීමට TEXTJOIN ශ්‍රිතය භාවිතා කරන ආකාරය නිබන්ධනය පෙන්වයි.

මෑත කාලය වන තුරු, Excel හි සෛල අන්තර්ගතයන් ඒකාබද්ධ කිරීමට ප්‍රචලිත ක්‍රම දෙකක් තිබුණි: concatenation ක්රියාකරු සහ CONCATENATE කාර්යය. TEXTJOIN හඳුන්වාදීමත් සමඟ, එය අතර ඇති ඕනෑම පරිසීමකයක් ඇතුළුව වඩාත් නම්‍යශීලී ආකාරයකින් පෙළ සම්බන්ධ කිරීමට ඔබට හැකියාව ලබා දෙන වඩාත් ප්‍රබල විකල්පයක් දර්ශනය වී ඇති බව පෙනේ. නමුත් ඇත්ත වශයෙන්ම, එයට තවත් බොහෝ දේ ඇත!

Excel TEXTJOIN ශ්‍රිතය

TEXTJOIN in Excel බහු සෛල හෝ පරාසයන්ගෙන් පෙළ තන්තු ඒකාබද්ධ කරන අතර ඕනෑම පරිසීමකයක් සමඟ ඒකාබද්ධ අගයන් වෙන් කරයි. ඔබ සඳහන් කරන බව. එය ප්‍රතිඵලයේ හිස් කොටු නොසලකා හැරීමට හෝ ඇතුළත් කිරීමට හැකිය.

Function එක Office 365, Excel 2021, සහ Excel 2019 සඳහා Excel හි ඇත.

TEXTJOIN ශ්‍රිතයේ වාක්‍ය ඛණ්ඩය පහත පරිදි වේ. :

කොතැනද:

• ඩිලිමිටරය (අවශ්‍ය) - එක් එක් පෙළ අගය අතර බෙදුම්කරු වේ ඔබ ඒකාබද්ධ කරන බව. සාමාන්‍යයෙන්, එය ද්විත්ව උද්ධෘත වලින් කොටා ඇති පෙළ තන්තුවක් ලෙස හෝ පෙළ තන්තුවක් අඩංගු කොටුවකට යොමු කිරීමක් ලෙස සපයනු ලැබේ. පරිසීමකයක් ලෙස සපයා ඇති අංකයක් පෙළ ලෙස සලකනු ලැබේ.
• Ignore_empty (අවශ්‍යයි) - හිස් කොටු නොසලකා හරිනවාද නැද්ද යන්න තීරණය කරයි:
  • සත්‍ය - ඕනෑම හිස් සෛල නොසලකා හරින්න.
  • FALSE - ලැබෙන තන්තුවට හිස් කොටු ඇතුළත් කරන්න.
• Text1 (අවශ්‍යයි) - සම්බන්ධ වීමට පළමු අගය. පෙළ තන්තුවක්, තන්තුවක් අඩංගු කොටුවකට යොමුවක් හෝ සෛල පරාසයක් වැනි තන්තු මාලාවක් ලෙස සැපයිය හැකිය.
• Text2 , … (විකල්ප) - අමතර පෙළ අගයන් එකට එකතු විය යුතුය. text1 ඇතුළුව, උපරිම පෙළ විස්තාරක 252කට ඉඩ දෙනු ලැබේ.

උදාහරණයක් ලෙස, අපි B2, C2 සහ D2 සෛල වලින් ලිපින කොටස් එක් කොටුවකට එකතු කර අගයන් වෙන් කරමු. කොමාවක් සහ ඉඩක් සහිතව:

CONCATENATE ශ්‍රිතය සමඟින්, ඔබට එක් එක් කොටුව තනි තනිව සඳහන් කිරීමට අවශ්‍ය වන අතර එක් එක් යොමුවකට පසුව පරිසීමකයක් (", ") තැබීමට අවශ්‍ය වේ, එය බොහෝ දේවල අන්තර්ගතය ඒකාබද්ධ කිරීමේදී කරදරකාරී විය හැක. cell:

=CONCATENATE(A2, ", ", B2, ", ", C2)

Excel TEXTJOIN සමඟින්, ඔබ පළමු තර්කයේ එක් වරක් පරිසීමකය සඳහන් කර, තුන්වන තර්කය සඳහා සෛල පරාසයක් සපයන්න:

=TEXTJOIN(", ", TRUE, A2:C2)

Excel හි TEXTJOIN - මතක තබා ගත යුතු කරුණු 6ක්

ඔබේ වැඩ පත්‍රිකාවල TEXTJOIN ඵලදායී ලෙස භාවිත කිරීමට, අවධානය යොමු කළ යුතු වැදගත් කරුණු කිහිපයක් තිබේ:

1. TEXTJOIN අලුත් එකක් ශ්‍රිතය, ලබා ගත හැක්කේ Excel 2019 - Excel 365 හි පමණි. පෙර Excel අනුවාද වල, කරුණාකර CONCATENATE ශ්‍රිතය හෝ "&" භාවිතා කරන්න ඒ වෙනුවට ක්‍රියාකරු.
2. එක්සෙල් නම් නව අනුවාදවලදී, ඔබට වෙන් වෙන් කොටු සහ පරාස වලින් අගයන් සංකලනය කිරීමට CONCAT ශ්‍රිතය භාවිතා කළ හැක, නමුත් සීමා කිරීම් හෝ හිස් කොටු සඳහා විකල්ප නොමැත.
3. ඕනෑම අංකයක් සපයා ඇත. සීමාංකය හෝ පෙළ සඳහා TEXTJOIN වෙතතර්කයන් පෙළ බවට පරිවර්තනය වේ.
4. සීමකය නිශ්චිතව දක්වා නොමැති නම් හෝ හිස් තන්තුවක් ("") නම්, පෙළ අගයන් කිසිදු පරිසීමකයකින් තොරව සංයුක්ත වේ.
5. ශ්‍රිතයට හැකිය පෙළ විස්තාරක 252 ක් දක්වා හසුරුවන්න.
6. ප්‍රතිඵලයක් ලෙස ලැබෙන තන්තුවෙහි උපරිම අක්ෂර 32,767ක් අඩංගු විය හැක, එය Excel හි සෛල සීමාව වේ. මෙම සීමාව ඉක්මවා ගියහොත්, TEXTJOIN සූත්‍රයක් #VALUE ලබා දෙයි! දෝෂයකි.

Excel හි පෙළ සම්බන්ධ කරන්නේ කෙසේද - සූත්‍ර උදාහරණ

TEXTJOIN හි සියලුම වාසි හොඳින් අවබෝධ කර ගැනීමට, සැබෑ ජීවිතයේ අවස්ථා වලදී කාර්යය භාවිතා කරන්නේ කෙසේදැයි බලමු .

තීරුව කොමාවෙන් වෙන් කළ ලැයිස්තුවට පරිවර්තනය කරන්න

ඔබ කොමාවකින්, අර්ධ කොමාවකින් හෝ වෙනත් ඕනෑම පරිසීමකයකින් අගයන් වෙන් කරන සිරස් ලැයිස්තුවක් සංසන්දනය කිරීමට බලාපොරොත්තු වන විට, TEXTJOIN භාවිතා කිරීමට නිවැරදි ශ්‍රිතය වේ.

මෙම උදාහරණය සඳහා, අපි පහත වගුවෙන් එක් එක් කණ්ඩායමේ ජයග්‍රහණ සහ පරාජයන් ඒකාබද්ධ කරන්නෙමු. මෙය පහත සූත්‍ර සමඟ සිදු කළ හැකි අතර, ඒවා සම්බන්ධ වී ඇති සෛල පරාසයේ පමණක් වෙනස් වේ.

1 කණ්ඩායම සඳහා:

=TEXTJOIN(",", FALSE, B2:B6)

කණ්ඩායම 2 සඳහා:

=TEXTJOIN(",", FALSE, C2:C6)

සහ එසේ ය.

සියලු සූත්‍රවල පහත තර්ක භාවිතා වේ:

• සීමකය - a කොමාව (",").
• Ignore_empty හිස් කොටු ඇතුළත් කිරීමට FALSE ලෙස සකසා ඇත මන්ද අපට ක්‍රීඩා නොකළ ක්‍රීඩා පෙන්විය යුතුය.

ලෙස ප්‍රතිඵලයක් වශයෙන්, ඔබට එක් එක් කණ්ඩායමේ ජයග්‍රහණ සහ පරාජයන් සංයුක්ත ආකාරයෙන් නියෝජනය කරන කොමාවෙන් වෙන් කළ ලැයිස්තු හතරක් ලැබෙනු ඇත:

විවිධ පරිසීමක සමඟ සෛල එක් කරන්න

ඔබට විවිධ පරිසීමක සමඟ ඒකාබද්ධ අගයන් වෙන් කිරීමට අවශ්‍ය වූ විට, ඔබට අරා නියතයක් ලෙස පරිසීමක කිහිපයක් සැපයිය හැකිය, නැතහොත් එක් එක් පරිසීමකය වෙනම කොටුවකට ඇතුළත් කළ හැකිය. සහ ඩිලිමිටරය තර්කය සඳහා පරාස යොමුවක් භාවිතා කරන්න.

ඔබට විවිධ නම් කොටස් අඩංගු කොටු එකතු කර ප්‍රතිඵලය මෙම ආකෘතියෙන් ලබා ගැනීමට අවශ්‍ය යැයි සිතමු: අවසාන නම , පළමු නම මැද නම .

ඔබට පෙනෙන පරිදි, අවසාන නම සහ මුල් නම කොමාවකින් සහ ඉඩකින් (", ") වෙන් කර ඇති අතර මුල් නම සහ මැද නම අවකාශයකින් වෙන් කරනු ලැබේ. (" ") පමනි. එබැවින්, අපි මෙම පරිසීමක දෙක අරාව නියතයක ඇතුළත් කර පහත සූත්‍රය ලබා ගනිමු:

=TEXTJOIN({", "," "}, TRUE, A2:C2)

A2:C2 යනු ඒකාබද්ධ කළ යුතු නාම කොටස් වේ.

විකල්පයක් ලෙස, ඔබට සමහර හිස් කොටු තුළ උද්ධෘත ලකුණු නොමැතිව සීමා කිරීම් ටයිප් කළ හැකිය (කියන්න, F3 හි කොමාවක් සහ ඉඩක් සහ G3 හි ඉඩක්) සහ $F$3:$G$3 පරාසය භාවිතා කරන්න (කරුණාකර මතක තබා ගන්න නිරපේක්ෂ සෛල යොමු) සීමාංකය තර්කය:

=TEXTJOIN($F$3:$G$3, TRUE, A2:C2)

මෙම සාමාන්‍ය ප්‍රවේශය භාවිතා කිරීමෙන්, ඔබට විවිධ ආකාරවලින් සෛල අන්තර්ගතය ඒකාබද්ධ කළ හැකිය.

උදාහරණයක් ලෙස, ඔබට පළමු නම මැද මුල අවසාන නම ආකෘතියෙන් ප්‍රතිඵලය අවශ්‍ය නම්, පළමු අක්ෂරය (මුල් කොටස) උකහා ගැනීමට LEFT ශ්‍රිතය භාවිතා කරන්න. C2 කොටුවෙන්. පරිසීමක සඳහා, අපි පළමු නම සහ මැද මුලකුරු අතර ඉඩක් ("") තබමු; ඒආරම්භක සහ අවසාන නම අතර කාල සීමාව සහ ඉඩක් (". ") පෙළ සහ දින, TEXTJOIN සූත්‍රයකට සෘජුවම දින සැපයීම ක්‍රියා නොකරයි. ඔබට මතක ඇති පරිදි, Excel දිනයන් අනුක්‍රමික අංක ලෙස ගබඩා කරයි, එබැවින් ඔබගේ සූත්‍රය පහත තිර රුවෙහි පෙන්වා ඇති පරිදි දිනය නියෝජනය කරන අංකයක් ලබා දෙනු ඇත:

=TEXTJOIN(" ", TRUE, A2:B2)

මෙය නිවැරදි කිරීමට, ඔබ පරිවර්තනය කළ යුතුය එයට සම්බන්ධ වීමට පෙර පෙළ පෙළකට දිනය. තවද මෙහිදී අවශ්‍ය ආකෘති කේතය සහිත TEXT ශ්‍රිතය (අපගේ නඩුවේ "mm/dd/yyyy") ප්‍රයෝජනවත් වේ:

=TEXTJOIN(" ", TRUE, A2, TEXT(B2, "mm/dd/yyyy"))

පේළි බිඳීම් සමඟ පෙළ ඒකාබද්ධ කරන්න

එක් එක් අගය නව පේළියකින් ආරම්භ වන පරිදි එක්සෙල් හි පෙළ ඒකාබද්ධ කිරීමට ඔබ කැමති නම්, පරිසීමකය ලෙස CHAR(10) භාවිතා කරන්න (10 යනු රේඛීය පෝෂක අක්ෂරයකි).

උදාහරණයක් ලෙස, වෙතින් පෙළ ඒකාබද්ධ කිරීමට සෛල A2 සහ B2 රේඛා බිඳීමකින් අගයන් වෙන් කරයි, මෙය භාවිතා කළ යුතු සූත්‍රයයි:

=TEXTJOIN(CHAR(10), TRUE, A2:B2)

ඉඟිය. ඉහත තිර රුවෙහි පෙන්වා ඇති පරිදි ප්‍රතිඵලය පේළි කිහිපයකින් දර්ශනය වීමට, Wrap text විශේෂාංගය ක්‍රියාත්මක කර ඇති බව සහතික කර ගන්න.

TEXTJOIN IF කොන්දේසි සමඟ පෙළ ඒකාබද්ධ කිරීමට

Excel TEXTJOIN තන්තු අරා හැසිරවීමට ඇති හැකියාව හේතුවෙන්, එය සෛල දෙකක හෝ වැඩි ගණනක අන්තර්ගතය කොන්දේසි සහිතව ඒකාබද්ධ කිරීමට ද භාවිතා කළ හැක. එය සිදු කිරීම සඳහා, සෛල පරාසයක් ඇගයීමට IF ශ්‍රිතය භාවිතා කර කොන්දේසිය සපුරාලන අගයන් අරාවක් text1 තර්කයට ආපසු ලබා දෙන්න.TEXTJOIN.

පහත තිර රුවෙහි පෙන්වා ඇති වගුවෙන්, ඔබට කණ්ඩායම් 1 සාමාජිකයන්ගේ ලැයිස්තුවක් ලබාගැනීමට අවශ්‍ය යැයි සිතන්න. මෙය සාක්ෂාත් කර ගැනීම සඳහා, පහත දැක්වෙන IF ප්‍රකාශය text1 තර්කය තුළට ඇතුල් කරන්න:

IF($B$2:$B$9=1, $A$2:$A$9, "")

පැහැදිලි ඉංග්‍රීසියෙන්, ඉහත සූත්‍රය පවසන්නේ: B තීරුව 1 ට සමාන නම්, a ආපසු දෙන්න එකම පේළියේ A තීරුවේ සිට අගය; එසේ නොමැතිනම් හිස් තන්තුවක් ආපසු ලබා දෙන්න.

කණ්ඩායම 1 සඳහා සම්පූර්ණ සූත්‍රය මෙම හැඩය ගනී:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=1, $A$2:$A$9, ""))

සමාන ආකාරයකින්, ඔබට ලබා ගත හැක කණ්ඩායම 2:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=2, $A$2:$A$9, ""))

සටහනෙහි සාමාජිකයින්ගේ කොමාවෙන් වෙන්වූ ලැයිස්තුව. Excel 365 සහ 2021 හි ඇති Dynamic Arrays විශේෂාංගය හේතුවෙන්, මෙය ඉහත තිර පිටුවේ පෙන්වා ඇති සාමාන්‍ය සූත්‍රයක් ලෙස ක්‍රියා කරයි. Excel 2019 හි, ඔබ එය Ctrl + Shift + Enter කෙටිමඟ එබීමෙන් සාම්ප්‍රදායික අරා සූත්‍රයක් ලෙස ඇතුළත් කළ යුතුය.

කොමාවෙන් වෙන් කළ ලැයිස්තුවේ බහුවිධ ගැලපීම් සොයා බලා ආපසු දෙන්න

ඔබ බොහෝ විට දන්නා පරිදි, Excel VLOOKUP ශ්‍රිතයට ලබා දිය හැක්කේ මුලින්ම සොයාගත් ගැළපීම පමණි. නමුත් ඔබට නිශ්චිත හැඳුනුම්පතක්, SKU හෝ වෙනත් දෙයක් සඳහා සියලු ගැලපීම් ලබා ගැනීමට අවශ්‍ය නම් කුමක් කළ යුතුද?

වෙනම සෛල තුළ ප්‍රතිඵල ප්‍රතිදානය කිරීමට, Excel හි බහුවිධ අගයන් VLOOKUP කරන්නේ කෙසේද යන්නෙහි විස්තර කර ඇති සූත්‍රවලින් එකක් භාවිතා කරන්න.

කොමාවෙන් වෙන් කළ ලැයිස්තුවක් ලෙස තනි කොටුවක ඇති සියලුම ගැළපෙන අගයන් බැලීමට සහ ආපසු ලබා දීමට, TEXTJOIN IF සූත්‍රය භාවිතා කරන්න.

එය ප්‍රායෝගිකව ක්‍රියා කරන ආකාරය බැලීමට, අපි ලැයිස්තුවක් ලබා ගනිමු නියැදි වගුවෙන් ලබා දී ඇති විකුණුම්කරුවෙකු විසින් මිලදී ගත් නිෂ්පාදනපහත. මෙය පහත සූත්‍රය සමඟින් පහසුවෙන් කළ හැක:

=TEXTJOIN(", ", TRUE, IF($A$2:$A$12=D2, $B$2:$B$12, ""))

A2:A12 විකුණුම්කරුවන්ගේ නම්, B2:B12 නිෂ්පාදන වන අතර D2 යනු උනන්දුව දක්වන විකුණුම්කරු වේ.

>ඉහත සූත්‍රය E2 වෙත ගොස් D2 (Adam) හි ඉලක්ක විකුණුම්කරු සඳහා සියලුම ගැලපීම් ගෙන එයි. සාපේක්ෂ (ඉලක්ක විකුණුම්කරු සඳහා) සහ නිරපේක්ෂ (විකුණුම්කරුගේ නම් සහ නිෂ්පාදන සඳහා) සෛල යොමුවල දක්ෂ භාවිතය හේතුවෙන්, සූත්‍රය පහත සෛල වෙත නිවැරදිව පිටපත් කර අනෙක් විකුණුම්කරුවන් දෙදෙනා සඳහාද හොඳින් ක්‍රියා කරයි:

සටහන. පෙර උදාහරණයේදී මෙන්, මෙය Excel 365 සහ 2021 හි සාමාන්‍ය සූත්‍රයක් ලෙසත්, Excel 2019 හි CSE සූත්‍රයක් (Ctrl + Shift + Enter ) ලෙසත් ක්‍රියා කරයි.

සූත්‍රයේ තර්කනය හරියටම සමාන වේ. පෙර උදාහරණය:

IF ප්‍රකාශය A2:A12 හි එක් එක් නම D2 හි ඉලක්ක නාමයට එරෙහිව සංසන්දනය කරයි (අපගේ නඩුවේ Adam):

IF($A$2:$A$12=D2, $B$2:$B$12, "")

තර්කානුකූල පරීක්ෂණය ඇගයීමට ලක් කරන්නේ නම් TRUE වෙත (එනම් D2 හි නම A තීරුවේ නමට ගැලපේ), සූත්‍රය B තීරුවෙන් නිෂ්පාදනයක් ලබා දෙයි; එසේ නොමැතිනම් හිස් තන්තුවක් ("") ආපසු එවනු ලැබේ. IF හි ප්‍රතිඵලය පහත අරාව වේ:

{"";"";"Bananas";"Apples";"";"";"";"Oranges";"";"Lemons";""}

අරාව text1 තර්කය ලෙස TEXTJOIN ශ්‍රිතය වෙත යයි. තවද TEXTJOIN අගයන් කොමාවකින් සහ ඉඩකින් (", ") වෙන් කිරීමට වින්‍යාස කර ඇති නිසා, අවසාන ප්‍රතිඵලය ලෙස අපට මෙම තන්තුව ලැබේ:

කෙසෙල්, ඇපල්, දොඩම්, ලෙමන්

Excel TEXTJOIN ක්‍රියා නොකරයි

ඔබේ TEXTJOIN සූත්‍රය දෝෂයක් ඇති වූ විට, එය බොහෝ දුරට ඉඩ ඇතපහත ඒවායින් එකක් වීමට:

• #NAME? මෙම ශ්‍රිතයට සහය නොදක්වන (2019ට පෙර) Excel හි පැරණි අනුවාදයක TEXTJOIN භාවිතා කරන විට හෝ ශ්‍රිතයේ නම වැරදි ලෙස අක්ෂර වින්‍යාස කර ඇති විට දෝෂයක් ඇතිවේ.
• #VALUE! ප්‍රතිඵලයක් ලෙස ලැබෙන තන්තුව අක්ෂර 32,767 ඉක්මවන්නේ නම් දෝෂයක් ඇතිවේ.
• #VALUE! Excel විසින් පරිසීමකය පෙළ ලෙස හඳුනා නොගන්නේ නම්, දෝශයක් ඇති විය හැක, උදාහරණයක් ලෙස ඔබ CHAR(0) වැනි මුද්‍රණය කළ නොහැකි අක්ෂර කිහිපයක් සපයා ඇත්නම්.

ඒ තමයි Excel හි TEXTJOIN ශ්‍රිතය භාවිතා කරන ආකාරය. කියවීමට මම ඔබට ස්තූතිවන්ත වන අතර ලබන සතියේ අපගේ බ්ලොගයේ ඔබව දැකීමට බලාපොරොත්තු වෙමි!

ලබාගත හැකි බාගැනීම්

Excel TEXTJOIN සූත්‍ර උදාහරණ