Vodič pokazuje kako koristiti funkciju TEXTJOIN za spajanje teksta u Excelu s praktičnim primjerima.

Do nedavno, postojale su dvije preovlađujuće metode za spajanje sadržaja ćelije u Excelu: spajanje operator i funkcija CONCATENATE. Sa uvođenjem TEXTJOIN-a, čini se da se pojavila moćnija alternativa, koja vam omogućava da spojite tekst na fleksibilniji način uključujući bilo koji graničnik između. Ali u stvari, tu je mnogo više!

Excel funkcija TEXTJOIN

TEXTJOIN u Excelu spaja tekstualne nizove iz više ćelija ili raspona i odvaja kombinovane vrijednosti bilo kojim graničnikom koje navedete. Može zanemariti ili uključiti prazne ćelije u rezultat.

Funkcija je dostupna u Excelu za Office 365, Excel 2021 i Excel 2019.

Sintaksa funkcije TEXTJOIN je sljedeća :

Gdje:

• Razgranič (obavezno) - je separator između svake tekstualne vrijednosti koje kombinujete. Obično se isporučuje kao tekstualni niz zatvoren u dvostrukim navodnicima ili referenca na ćeliju koja sadrži tekstualni niz. Broj naveden kao graničnik se tretira kao tekst.
• Ignore_empty (obavezno) - Određuje hoće li se zanemariti prazne ćelije ili ne:
  • TRUE - zanemari sve prazne ćelije.
  • FALSE - uključi prazne ćelije u rezultirajući niz.
• Tekst1 (obavezno) - prva vrijednost za pridruživanje. Može se dostaviti kao tekstualni niz, referenca na ćeliju koja sadrži niz, ili niz nizova kao što je raspon ćelija.
• Tekst2 , … (opcionalno) - dodatne tekstualne vrijednosti da budu spojeni zajedno. Dozvoljena su maksimalno 252 tekstualna argumenta, uključujući tekst1 .

Na primjer, kombinirajmo dijelove adrese iz ćelija B2, C2 i D2 zajedno u jednu ćeliju, odvajajući vrijednosti sa zarezom i razmakom:

Sa funkcijom CONCATENATE, trebali biste navesti svaku ćeliju pojedinačno i staviti graničnik (", ") nakon svake reference, što bi moglo smetati pri spajanju sadržaja mnogih ćelije:

=CONCATENATE(A2, ", ", B2, ", ", C2)

S Excel TEXTJOIN, vi specificirate graničnik samo jednom u prvom argumentu i dajete raspon ćelija za treći argument:

=TEXTJOIN(", ", TRUE, A2:C2)

TEXTJOIN u Excelu - 6 stvari koje treba zapamtiti

Da biste efikasno koristili TEXTJOIN u svojim radnim listovima, treba obratiti pažnju na nekoliko važnih tačaka:

1. TEXTJOIN je nova funkciju, koja je dostupna samo u programu Excel 2019 - Excel 365. U ranijim verzijama Excela, koristite funkciju CONCATENATE ili "&" umjesto operatora.
2. U novim verzijama ako je Excel, također možete koristiti funkciju CONCAT za spajanje vrijednosti iz zasebnih ćelija i raspona, ali bez opcija za graničnike ili prazne ćelije.
3. Bilo koji broj naveden na TEXTJOIN za razdjelnik ili tekst argumenti se pretvaraju u tekst.
4. Ako delimiter nije specificiran ili je prazan niz (""), tekstualne vrijednosti se spajaju bez ikakvog graničnika.
5. Funkcija može obrađuju do 252 tekstualna argumenta.
6. Rezultirajući niz može sadržavati najviše 32.767 znakova, što je ograničenje ćelije u Excelu. Ako je ovo ograničenje prekoračeno, formula TEXTJOIN vraća #VALUE! greška.

Kako spojiti tekst u Excel - primjeri formule

Da bismo bolje razumjeli sve prednosti TEXTJOIN-a, pogledajmo kako koristiti funkciju u stvarnim scenarijima .

Pretvorite kolonu u listu razdvojenu zarezima

Kada želite spojiti vertikalnu listu odvajajući vrijednosti zarezom, tačkom zarezom ili bilo kojim drugim graničnikom, TEXTJOIN je prava funkcija za korištenje.

Za ovaj primjer, spojit ćemo pobjede i poraze svakog tima iz tabele ispod. To se može učiniti sa sljedećim formulama, koje se razlikuju samo u rasponu ćelija koje se spajaju.

Za tim 1:

=TEXTJOIN(",", FALSE, B2:B6)

Za tim 2:

=TEXTJOIN(",", FALSE, C2:C6)

I tako dalje.

U svim formulama se koriste sljedeći argumenti:

• Razgranič - a zarez (",").
• Ignore_empty je postavljeno na FALSE da uključi prazne ćelije jer moramo pokazati koje igre nisu igrane.

Kao rezultat ćete dobiti četiri liste razdvojene zarezima koje u kompaktnom obliku predstavljaju pobjede i poraze svakog tima:

Spoji ćelije s različitim graničnicima

U situaciji kada trebate odvojiti kombinirane vrijednosti različitim graničnicima, možete ili dati nekoliko graničnika kao konstantu niza ili unijeti svaki graničnik u posebnu ćeliju i koristite referencu raspona za argument delimiter .

Pretpostavimo da želite spojiti ćelije koje sadrže različite dijelove imena i dobiti rezultat u ovom formatu: Prezime , Ime Srednje ime .

Kao što vidite, prezime i ime su odvojeni zarezom i razmakom (", "), dok su ime i srednje ime razmakom (" ") samo. Dakle, uključujemo ova dva graničnika u konstantu niza {", "," "} i dobijamo sledeću formulu:

=TEXTJOIN({", "," "}, TRUE, A2:C2)

Gde su A2:C2 delovi imena koji se kombinuju.

Alternativno, možete upisati graničnike bez navodnika u neke prazne ćelije (recimo, zarez i razmak u F3 i razmak u G3) i koristiti raspon $F$3:$G$3 (imajte na umu apsolutne reference ćelije) za argument delimiter :

=TEXTJOIN($F$3:$G$3, TRUE, A2:C2)

Koristeći ovaj opći pristup, možete spojiti sadržaj ćelije u različitim oblicima.

Na primjer, ako želite rezultat u formatu Ime Srednji početni Prezime , tada koristite funkciju LIJEVO da izdvojite prvi znak (inicijal) iz ćelije C2. Što se tiče graničnika, stavljamo razmak (" ") između imena i srednjeg inicijala; atačka i razmak (". ") između početnog i prezimena:

=TEXTJOIN({" ",". "}, TRUE, B2, LEFT(C2,1), A2)

Spoji tekst i datume u Excelu

U posebnom slučaju kada spajate teksta i datuma, dostavljanje datuma direktno u formulu TEXTJOIN neće raditi. Kao što se možda sjećate, Excel pohranjuje datume kao serijske brojeve, tako da će vaša formula vratiti broj koji predstavlja datum kao što je prikazano na slici ispod:

=TEXTJOIN(" ", TRUE, A2:B2)

Da biste ovo popravili, morate konvertirati datum u tekstualni niz prije nego što mu se pridruži. I ovdje je zgodna funkcija TEXT sa željenim kodom formata ("mm/dd/yyyy" u našem slučaju):

=TEXTJOIN(" ", TRUE, A2, TEXT(B2, "mm/dd/yyyy"))

Spoji tekst s prijelomima reda

Ako želite spojiti tekst u Excelu tako da svaka vrijednost počinje u novom redu, koristite CHAR(10) kao graničnik (gdje je 10 znak za uvlačenje u red).

Na primjer, da biste kombinirali tekst iz ćelije A2 i B2 koje odvajaju vrijednosti prijelomom reda, ovo je formula za korištenje:

=TEXTJOIN(CHAR(10), TRUE, A2:B2)

Savjet. Da bi se rezultat prikazao u više redova kao što je prikazano na slici iznad, provjerite je li uključena funkcija Prelamanje teksta.

TEXTJOIN IF za spajanje teksta sa uslovima

Zbog sposobnosti programa Excel TEXTJOIN da rukuje nizovima nizova, može se koristiti i za uslovno spajanje sadržaja dve ili više ćelija. Da biste to učinili, koristite funkciju IF za procjenu raspona ćelija i vratite niz vrijednosti koje ispunjavaju uvjet u argument text1 argumentaTEXTJOIN.

Iz tabele prikazane na slici ispod, pretpostavimo da želite da preuzmete listu članova Tima 1 . Da biste to postigli, ugniježite sljedeću IF naredbu u argument text1 :

IF($B$2:$B$9=1, $A$2:$A$9, "")

Na jednostavnom engleskom, gornja formula kaže: Ako je stupac B jednak 1, vratite vrijednost iz kolone A u istom redu; inače vrati prazan niz.

Kompletna formula za Tim 1 ima ovaj oblik:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=1, $A$2:$A$9, ""))

Na sličan način možete dobiti Zarezima odvojena lista članova Tima 2:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=2, $A$2:$A$9, ""))

Napomena. Zbog funkcije dinamičkih nizova koja je dostupna u Excel 365 i 2021, ovo funkcionira kao obična formula, prikazana na slici iznad. U Excel 2019, morate je unijeti kao tradicionalnu formulu niza pritiskom na prečicu Ctrl + Shift + Enter.

Potražite i vratite više podudaranja u listi odvojenoj zarezima

Kao što vjerojatno znate, Excel funkcija VLOOKUP može vratiti samo prvo pronađeno podudaranje. Ali šta ako trebate dobiti sva podudaranja za određeni ID, SKU ili nešto drugo?

Da biste rezultate izbacili u odvojene ćelije, koristite jednu od formula opisanih u Kako izvršiti VLOOKUP više vrijednosti u Excelu.

Da biste potražili i vratili sve odgovarajuće vrijednosti u jednoj ćeliji kao listu razdvojenu zarezima, koristite formulu TEXTJOIN IF.

Da vidite kako to funkcionira u praksi, dohvatimo listu proizvodi koje je kupio određeni prodavac iz tabele uzorakaispod. To se lako može učiniti sljedećom formulom:

=TEXTJOIN(", ", TRUE, IF($A$2:$A$12=D2, $B$2:$B$12, ""))

Gdje su A2:A12 imena prodavača, B2:B12 su proizvodi, a D2 je prodavač od interesa.

Gorenja formula ide na E2 i donosi sva poklapanja za ciljnog prodavca u D2 (Adam). Zbog pametne upotrebe relativnih (za ciljanog prodavača) i apsolutnih (za imena prodavača i proizvoda) referenci ćelija, formula se ispravno kopira u donje ćelije i dobro funkcionira i za druga dva prodavača:

Bilješka. Kao i u prethodnom primjeru, ovo funkcionira kao obična formula u Excelu 365 i 2021, te kao CSE formula (Ctrl + Shift + Enter ) u Excelu 2019.

Logika formule je potpuno ista kao u prethodni primjer:

IF izraz uspoređuje svako ime u A2:A12 sa ciljnim imenom u D2 (Adam u našem slučaju):

IF($A$2:$A$12=D2, $B$2:$B$12, "")

Ako logički test procjenjuje na TRUE (tj. ime u D2 odgovara imenu u koloni A), formula vraća proizvod iz kolone B; inače se vraća prazan niz (""). Rezultat IF je sljedeći niz:

{"";"";"Bananas";"Apples";"";"";"";"Oranges";"";"Lemons";""}

Niz ide na funkciju TEXTJOIN kao argument text1 . A pošto je TEXTJOIN konfiguriran da odvaja vrijednosti zarezom i razmakom (", "), dobijamo ovaj niz kao konačni rezultat:

Banane, Apples, Oranges, Lemons

Excel TEXTJOIN ne radi

Kada vaša formula TEXTJOIN rezultira greškom, najvjerovatnijebiti jedno od sljedećeg:

• #NAME? greška se javlja kada se TEXTJOIN koristi u starijoj verziji Excela gdje ova funkcija nije podržana (prije 2019.) ili kada je ime funkcije pogrešno napisano.
• #VALUE! greška se javlja ako rezultirajući niz premašuje 32.767 znakova.
• #VALUE! greška se može pojaviti i ako Excel ne prepozna graničnik kao tekst, na primjer ako unesete neki znak koji se ne može ispisati kao što je CHAR(0).

Tako se koristi funkcija TEXTJOIN u Excelu. Zahvaljujem vam što čitate i nadam se da se vidimo na našem blogu sljedeće sedmice!

Dostupna preuzimanja

Primjeri formule TEXTJOIN u Excelu