Tutorialak TEXTJOIN funtzioa Excel-en testua batzeko nola erabili erakusten du adibide praktikoekin.

Duela gutxi arte, bi metodo nagusi zeuden Excel-en gelaxken edukia batzeko: kateamendua. operadorea eta KATENATU funtzioa. TEXTJOIN sartzearekin batera, badirudi alternatiba indartsuago bat agertu dela, eta horri esker testua modu malguago batean elkartzea ahalbidetzen du, tarteko edozein mugatzaile barne. Baina egia esan, askoz gehiago dago!

Excel TEXTJOIN funtzioa

TEXTJOIN Excel-en gelaxka edo barruti anitzetako testu-kateak batzen ditu eta balio konbinatuak edozein mugatzailerekin bereizten ditu. zehazten duzuna. Emaitzetan gelaxka hutsak baztertu edo sartu ditzake.

Funtzioa Office 365, Excel 2021 eta Excel 2019rako Excel-en eskuragarri dago.

TEXTJOIN funtzioaren sintaxia honakoa da. :

Non:

• Mugatzailea (beharrezkoa) - testu-balio bakoitzaren arteko bereizlea da konbinatzen duzula. Normalean, komatxo bikoitz artean sartutako testu-kate gisa edo testu-kate bat duen gelaxka baten erreferentzia gisa ematen da. Mugatzaile gisa emandako zenbaki bat testu gisa tratatzen da.
• Ignore_empty (beharrezkoa) - Gelaxka hutsak baztertu ala ez zehazten du:
  • EGIA - ez ikusi gelaxka hutsik.
  • FALSE - sartu gelaxka hutsak ondoriozko katean.
• Testua1 (beharrezkoa) - batzeko lehen balioa. Testu-kate gisa, kate bat duen gelaxka baten erreferentzia gisa edo kate-matrize gisa eman daiteke, hala nola gelaxka sorta bat.
• Testua2 , … (aukerakoa) - testu-balio gehigarriak elkarrekin batzeko. Gehienez 252 testu-argumentu onartzen dira, testua1 barne.

Adibide gisa, konbina ditzagun B2, C2 eta D2 gelaxketako helbide-zatiak gelaxka batean, balioak bereiziz. koma eta zuriune batekin:

KATENATU funtzioarekin, gelaxka bakoitza banan-banan zehaztu beharko zenuke eta erreferentzia bakoitzaren ondoren mugatzaile bat (", ") jarri beharko zenuke, askoren edukiak bateratzean trabagarria izan daitekeena. gelaxkak:

=CONCATENATE(A2, ", ", B2, ", ", C2)

Excel TEXTJOIN-ekin, mugatzailea behin bakarrik zehazten duzu lehen argumentuan, eta hirugarren argumenturako gelaxka sorta bat hornitzen duzu:

=TEXTJOIN(", ", TRUE, A2:C2)

TEXTJOIN Excel-en - Gogoratu beharreko 6 gauza

Zure lan-orrietan TEXTJOIN modu eraginkorrean erabiltzeko, kontuan hartu beharreko puntu garrantzitsu batzuk daude:

1. TEXTJOIN berria da. funtzioa, Excel 2019 - Excel 365-en soilik erabilgarri. Aurreko Excel bertsioetan, erabili CONCATENATE funtzioa edo "&" operadorearen ordez.
2. Excel bada bertsio berrietan, CONCAT funtzioa ere erabil dezakezu gelaxka eta barrutietako balioak kateatzeko, baina mugatzaileetarako edo gelaxka hutsetarako aukerarik gabe.
3. Edozein zenbaki ematen da. TEXTJOIN-era mugatzailea edo testua rakoargumentuak testu bihurtzen dira.
4. mugatzailea zehazten ez bada edo kate huts bat ("") bada, testu-balioak inongo mugatzailerik gabe kateatzen dira.
5. Funtzioak egin dezake. 252 testu-argumentu kudeatu gehienez.
6. Ondoriozko kateak 32.767 karaktere izan ditzake gehienez, hau da, Excel-en gelaxka-muga. Muga hori gainditzen bada, TEXTJOIN formula batek #BALOIA itzultzen du! errorea.

Nola batu testua Excel-en - formula adibideak

TEXTJOIN-en abantaila guztiak hobeto ulertzeko, ikus dezagun nola erabili funtzioa bizitza errealeko eszenatokietan. .

Bihurtu zutabea komaz bereizitako zerrendara

Zerrenda bertikal bat kateatu nahi duzunean, balioak koma, puntu eta koma edo beste edozein mugatzailez bereiziz, TEXTJOIN da erabili beharreko funtzio egokia.

Adibide honetarako, talde bakoitzaren garaipenak eta galerak kateatu egingo ditugu beheko taulan. Hau formula hauekin egin daiteke, elkartzen diren gelaxken barrutian soilik desberdinak direnak.

1. taldearentzat:

=TEXTJOIN(",", FALSE, B2:B6)

2.taldearentzat:

=TEXTJOIN(",", FALSE, C2:C6)

Eta abar.

Formula guztietan, argumentu hauek erabiltzen dira:

• Mugatzailea - a koma (",").
• Ignore_empty FALSE gisa ezarrita dago gelaxka hutsak sartzeko, zein jokotan jokatu ez diren erakutsi behar dugulako.

Denez. emaitza, komaz bereizitako lau zerrenda lortuko dituzu talde bakoitzaren garaipenak eta galerak adierazten dituztenak forma trinkoan:

Lotu gelaxkak mugatzaile ezberdinekin

Balio konbinatuak mugatzaile ezberdinekin bereizi behar dituzunean, hainbat mugatzaile eman ditzakezu matrize konstante gisa edo mugatzaile bakoitza gelaxka batean sartu. eta erabili barruti-erreferentzia bat mugatzailea argumenturako.

Izen-atal desberdinak dituzten gelaxkak elkartu eta emaitza formatu honetan lortu nahi duzula suposatuz: Abizena , Izena Bigarren izena .

Ikus dezakezun bezala, Abizena eta Izena koma batekin eta zuriune batekin (", ") bereizten dira, eta Izena eta Bigarren izena zuriune batekin. (" ") soilik. Beraz, bi mugatzaile hauek {", "," "} matrizeko konstante batean sartzen ditugu eta formula hau lortzen dugu:

=TEXTJOIN({", "," "}, TRUE, A2:C2)

Non A2:C2 diren konbinatu beharreko izen-zatiak.

Bestela, mugatzaileak idatz ditzakezu komatxorik gabe gelaxka huts batzuetan (esaterako, koma eta zuriune bat F3n eta zuriune bat G3n) eta $F$3:$G$3 barrutia erabil dezakezu (kontuan izan. gelaxken erreferentzia absolutuak) mugatzailea argumenturako:

=TEXTJOIN($F$3:$G$3, TRUE, A2:C2)

Ikuspegi orokor hau erabiliz, gelaxka-edukia hainbat formatan batu dezakezu.

Adibidez, emaitza Izena Erdiko hasiera Abizena formatuan nahi baduzu, erabili LEFT funtzioa lehenengo karakterea (hasierakoa) ateratzeko. C2 zelulatik. Mugatzaileei dagokienez, zuriune bat (" ") jarri dugu Lehen izenaren eta Erdiko hasieraren artean; apuntua eta zuriune bat ("". ") Hasierako eta Abizenaren artean:

=TEXTJOIN({" ",". "}, TRUE, B2, LEFT(C2,1), A2)

Lotu testua eta datak Excel-en

Batzen ari zaren kasu zehatz batean testua eta datak, TEXTJOIN formula bati datak zuzenean emateak ez du funtzionatuko. Gogoratuko duzunez, Excel-ek datak serie-zenbaki gisa gordetzen ditu, beraz, zure formulak data adierazten duen zenbaki bat itzuliko du beheko pantaila-argazkian erakusten den moduan:

=TEXTJOIN(" ", TRUE, A2:B2)

Hau konpontzeko, bihurtu behar duzu data testu-kate batean sartu aurretik. Eta hemen nahi den formatu kodea duen TESTU-funtzioa ("mm/dd/yyyy" gure kasuan) ondo datorkigu:

=TEXTJOIN(" ", TRUE, A2, TEXT(B2, "mm/dd/yyyy"))

Bateatu testua lerro-jauziekin

Excel-en testua batu nahi baduzu, balio bakoitza lerro berri batean hasteko, erabili CHAR(10) mugatzaile gisa (non 10 lerro-jarrera karakterea den).

Adibidez, testua konbinatzeko. A2 eta B2 gelaxkak lerro-jauzi baten bidez balioak bereiziz, hau da erabili beharreko formula:

=TEXTJOIN(CHAR(10), TRUE, A2:B2)

Aholkua. Emaitza goiko pantaila-argazkian erakusten den bezala hainbat lerrotan bistaratzeko, ziurtatu Testua biltzeko funtzioa aktibatuta dagoela.

TEXTJOIN IF testua baldintzekin bateratzeko

Excel TEXTJOIN-ek kate-matrizeak kudeatzeko duen gaitasuna dela eta, bi gelaxka edo gehiagoren edukia baldintzapean bateratzeko ere erabil daiteke. Hori egiteko, erabili IF funtzioa gelaxka sorta bat ebaluatzeko eta baldintza betetzen duten balio-matrizea itzultzeko testua1 argumentura.TEXTJOIN.

Beheko pantaila-argazkian agertzen den taulatik, demagun 1. taldea kideen zerrenda berreskuratu nahi duzula. Hori lortzeko, habiaratu IF adierazpena testua1 argumentuan:

IF($B$2:$B$9=1, $A$2:$A$9, "")

Ingeles hutsez, goiko formulak dio: B zutabea 1 berdina bada, itzuli a. errenkada bereko A zutabeko balioa; bestela, kate huts bat itzuli.

1.taldea ren formula osoak forma hau hartzen du:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=1, $A$2:$A$9, ""))

Antzeko modu batean, lor dezakezu Talde 2ko kideen komaz bereizita:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=2, $A$2:$A$9, ""))

Oharra. Excel 365 eta 2021-en eskuragarri dagoen Dynamic Arrays funtzioa dela eta, honek formula arrunt gisa funtzionatzen du, goiko pantaila-argazkian erakusten dena. Excel 2019-n, matrize-formula tradizional gisa sartu behar duzu Ctrl + Shift + Sartu lasterbidea sakatuz.

Bilatu eta itzuli hainbat bat-etortze komaz bereizitako zerrendan

Ziurrenik dakizuenez, Excel VLOOKUP funtzioak aurkitutako lehen bat etortzea soilik itzul dezake. Baina zer gertatzen da ID, SKU edo beste zerbaitetarako partida guztiak lortu behar badituzu?

Emaitzak gelaxka bereizietan ateratzeko, erabili Excel-en hainbat balio VLOOKUP atalean deskribatutako formuletako bat.

Zalula bakarrean bat datozen balio guztiak komaz bereizitako zerrenda gisa bilatzeko eta itzultzeko, erabili TEXTJOIN IF formula.

Praktikan nola funtzionatzen duen ikusteko, berreskura dezagun zerrenda bat. saltzaile jakin batek lagin-taulatik erositako produktuakbehean. Hau erraz egin daiteke formula honekin:

=TEXTJOIN(", ", TRUE, IF($A$2:$A$12=D2, $B$2:$B$12, ""))

Non A2:A12 saltzaile-izenak diren, B2:B12 produktuak diren eta D2 interesgarri den saltzailea.

Goiko formula E2-ra doa eta helburu-saltzailearen partida guztiak ekartzen ditu D2-n (Adam). Erlatibozko (helburuko saltzailearentzat) eta absolutuetako (saltzaileen izenetarako eta produktuetarako) gelaxka-erreferentzien erabilera adimentsua dela eta, formula ondo kopiatzen da beheko gelaxketan eta ondo funtzionatzen du beste bi saltzaileentzat ere:

Ohar. Aurreko adibidean bezala, honek Excel 365 eta 2021-en formula arrunt gisa funtzionatzen du, eta CSE formula gisa (Ktrl + Shift + Sartu ) Excel 2019-n.

Formularen logika berdina da. aurreko adibidea:

IF adierazpenak A2:A12-ko izen bakoitza D2-ko xede-izenarekin alderatzen du (Adam gure kasuan):

IF($A$2:$A$12=D2, $B$2:$B$12, "")

Proba logikoak ebaluatzen badu EGIA (hau da, D2-ko izena A zutabeko izenarekin bat dator), formulak B zutabeko produktu bat itzultzen du; bestela ("") kate huts bat itzultzen da. IF-ren emaitza honako array hau da:

{"";"";"Bananas";"Apples";"";"";"";"Oranges";"";"Lemons";""}

Matrizea TEXTJOIN funtziora doa testua1 argumentu gisa. Eta TEXTJOIN balioak koma eta zuriune batekin (", ") bereizteko konfiguratuta dagoenez, kate hau lortuko dugu azken emaitza gisa:

Platanoak, Sagarrak, Laranjak, Limoiak

Excel TEXTJOIN ez da funtzionatzen

Zure TEXTJOIN formulak errore bat sortzen duenean, litekeena dahauetako bat izatea:

• #IZENA? errorea gertatzen da TEXTJOIN funtzio hau onartzen ez den Excel-en bertsio zaharrago batean erabiltzen denean (2019 aurrekoa) edo funtzioaren izena gaizki idatzita dagoenean.
• #VALUE! errorea gertatzen da ondoriozko kateak 32.767 karaktere baino gehiago baditu.
• #VALUE! errorea ere gerta daiteke Excel-ek mugatzailea testu gisa ezagutzen ez badu, adibidez CHAR(0) bezalako karaktere inprimagarriak ematen badituzu.

Horrela erabili TEXTJOIN funtzioa Excel-en. Eskerrik asko irakurtzeagatik eta datorren astean gure blogean ikustea espero dut!

Deskarga erabilgarri

Excel TEXTJOIN formula adibideak