გაკვეთილი გვიჩვენებს, თუ როგორ გამოვიყენოთ TEXTJOIN ფუნქცია Excel-ში ტექსტის პრაქტიკულ მაგალითებთან შერწყმის მიზნით.

ბოლო დრომდე, Excel-ში უჯრედის შიგთავსის გაერთიანების ორი გავრცელებული მეთოდი იყო: შეერთება. ოპერატორი და CONCATENATE ფუნქცია. TEXTJOIN-ის დანერგვით, როგორც ჩანს, გაჩნდა უფრო ძლიერი ალტერნატივა, რომელიც საშუალებას გაძლევთ შეუერთდეთ ტექსტს უფრო მოქნილი გზით, მათ შორის ნებისმიერი დელიმიტერის ჩათვლით. მაგრამ სინამდვილეში, მასში ბევრად მეტია!

Excel TEXTJOIN ფუნქცია

TEXTJOIN Excel-ში აერთიანებს ტექსტის სტრიქონებს მრავალი უჯრედიდან ან დიაპაზონიდან და გამოყოფს კომბინირებულ მნიშვნელობებს ნებისმიერი გამიჯვნის საშუალებით. რომ დააკონკრეტეთ. მას შეუძლია იგნორირება ან შედეგში შეიცავდეს ცარიელი უჯრედები.

ფუნქცია ხელმისაწვდომია Excel-ში Office 365, Excel 2021 და Excel 2019-ისთვის.

TEXTJOIN ფუნქციის სინტაქსი ასეთია. :

სად:

• განმსაზღვრელი (საჭიროა) - არის გამყოფი თითოეულ ტექსტურ მნიშვნელობას შორის რომ აერთიანებთ. ჩვეულებრივ, იგი მოწოდებულია როგორც ტექსტის სტრიქონი, რომელიც ჩასმულია ორმაგ ბრჭყალებში ან მითითებით უჯრედზე, რომელიც შეიცავს ტექსტურ სტრიქონს. გამყოფად მიწოდებული რიცხვი განიხილება როგორც ტექსტი.
• იგნორირება_ცარიელი (საჭირო) - განსაზღვრავს ცარიელი უჯრედების იგნორირებას თუ არა:
  • TRUE - ნებისმიერი ცარიელი უჯრედის იგნორირება.
  • FALSE - შეიტანეთ ცარიელი უჯრედები მიღებულ სტრიქონში.
• Text1 (აუცილებელია) - შეერთების პირველი მნიშვნელობა. შეიძლება იყოს მიწოდებული ტექსტის სტრიქონის სახით, მითითება უჯრედზე, რომელიც შეიცავს სტრიქონს, ან სტრიქონების მასივს, როგორიცაა უჯრედების დიაპაზონი.
• Text2 , … (სურვილისამებრ) - ტექსტის დამატებითი მნიშვნელობები ერთად შეერთება. დასაშვებია მაქსიმუმ 252 ტექსტური არგუმენტი, მათ შორის text1 .

მაგალითად, მოდით გავაერთიანოთ მისამართების ნაწილები B2, C2 და D2 უჯრედებიდან ერთად ერთ უჯრედში და გამოვყოთ მნიშვნელობები. მძიმით და ინტერვალით:

CONCATENATE ფუნქციით, თქვენ უნდა მიუთითოთ თითოეული უჯრედი ინდივიდუალურად და დააყენოთ დელიმიტერი (", ") ყოველი მითითების შემდეგ, რაც შეიძლება შემაწუხებელი იყოს მრავალი შიგთავსის გაერთიანებისას. უჯრედები:

=CONCATENATE(A2, ", ", B2, ", ", C2)

Excel TEXTJOIN-ით, პირველ არგუმენტში მხოლოდ ერთხელ აზუსტებთ დელიმიტერს და აწვდით უჯრედების დიაპაზონს მესამე არგუმენტისთვის:

=TEXTJOIN(", ", TRUE, A2:C2)

TEXTJOIN Excel-ში - 6 რამ, რაც უნდა გახსოვდეთ

TEXTJOIN ეფექტურად გამოსაყენებლად თქვენს სამუშაო ფურცლებში, არის რამდენიმე მნიშვნელოვანი პუნქტი, რომელიც უნდა გაითვალისწინოთ:

1. TEXTJOIN არის ახალი ფუნქცია, რომელიც ხელმისაწვდომია მხოლოდ Excel 2019-ში - Excel 365. Excel-ის ადრინდელ ვერსიებში, გთხოვთ, გამოიყენოთ CONCATENATE ფუნქცია ან "&" ოპერატორის ნაცვლად.
2. Excel-ის ახალ ვერსიებში, თქვენ ასევე შეგიძლიათ გამოიყენოთ CONCAT ფუნქცია ცალკეული უჯრედებიდან და დიაპაზონებიდან მნიშვნელობების შესაერთებლად, მაგრამ დელიმიტერების ან ცარიელი უჯრედების ვარიანტების გარეშე.
3. მოწოდებულია ნებისმიერი ნომერი. TEXTJOIN-ზე განმსაზღვრელი ან ტექსტი არგუმენტები გარდაიქმნება ტექსტად.
4. თუ განმსაზღვრელი არ არის მითითებული ან არის ცარიელი სტრიქონი (""), ტექსტის მნიშვნელობები შეერთდება ყოველგვარი დელიმიტერის გარეშე.
5. ფუნქციას შეუძლია ამუშავებს 252-მდე ტექსტურ არგუმენტს.
6. მიღებული სტრიქონი შეიძლება შეიცავდეს მაქსიმუმ 32767 სიმბოლოს, რაც არის უჯრედის ლიმიტი Excel-ში. თუ ეს ლიმიტი გადააჭარბებს, TEXTJOIN ფორმულა უბრუნებს #VALUE-ს! შეცდომა.

როგორ გავაერთიანოთ ტექსტი Excel-ში - ფორმულის მაგალითები

TEXTJOIN-ის ყველა უპირატესობის უკეთ გასაგებად, მოდით შევხედოთ, თუ როგორ გამოვიყენოთ ფუნქცია რეალურ სცენარებში .

სვეტის კონვერტაცია მძიმით გამოყოფილი სიაში

როცა თქვენ ცდილობთ ვერტიკალური სიის შეერთებას, რომელიც გამოყოფს მნიშვნელობებს მძიმით, მძიმით ან სხვა განმასხვავებელი ნიშნით, TEXTJOIN არის სწორი ფუნქცია.

ამ მაგალითისთვის, ჩვენ გავაერთიანებთ თითოეული გუნდის მოგებებსა და წაგებას ქვემოთ მოცემული ცხრილიდან. ეს შეიძლება გაკეთდეს შემდეგი ფორმულებით, რომლებიც განსხვავდება მხოლოდ შეერთებული უჯრედების დიაპაზონში.

გუნდისთვის 1:

=TEXTJOIN(",", FALSE, B2:B6)

გუნდისთვის 2:

=TEXTJOIN(",", FALSE, C2:C6)

და ასე შემდეგ.

ყველა ფორმულაში გამოყენებულია შემდეგი არგუმენტები:

• განმსაზღვრელი - a მძიმით (",").
• იგნორირება_ცარიელის დაყენებულია FALSE-ზე, რათა შეიცავდეს ცარიელ უჯრედებს, რადგან ჩვენ უნდა ვაჩვენოთ რომელი თამაშები არ ითამაშა.

როგორც შედეგად, თქვენ მიიღებთ მძიმით გამოყოფილ ოთხ სიას, რომლებიც წარმოადგენს თითოეული გუნდის მოგებასა და წაგებას კომპაქტურ ფორმაში:

უჯრედების შეერთება სხვადასხვა დელიმიტერებით

იმ სიტუაციაში, როდესაც გჭირდება კომბინირებული მნიშვნელობების გამოყოფა სხვადასხვა დელიმიტერებით, შეგიძლიათ ან მიაწოდოთ რამდენიმე დელიმიტერი, როგორც მასივის მუდმივი, ან შეიყვანოთ თითოეული დელიმიტერი ცალკე უჯრედში და გამოიყენეთ დიაპაზონის მითითება განმსაზღვრელი არგუმენტისთვის.

ვთქვათ, რომ გსურთ შეუერთოთ უჯრედები, რომლებიც შეიცავს სხვადასხვა სახელის ნაწილებს და მიიღოთ შედეგი ამ ფორმატში: გვარი , სახელი შუა სახელი .

როგორც ხედავთ, გვარი და სახელი გამოყოფილია მძიმით და ინტერვალით (", "), ხოლო სახელი და შუა სახელი ინტერვალით. მხოლოდ (""). ასე რომ, ჩვენ ჩავრთავთ ამ ორ დელიმიტერს მასივის მუდმივში {", "," "} და მივიღებთ შემდეგ ფორმულას:

=TEXTJOIN({", "," "}, TRUE, A2:C2)

სადაც A2:C2 არის სახელების ნაწილები, რომლებიც უნდა გაერთიანდეს.

ალტერნატიულად, შეგიძლიათ აკრიფოთ გამყოფები ბრჭყალების გარეშე ზოგიერთ ცარიელ უჯრედებში (მაგალითად, მძიმით და სივრცეში F3-ში და სივრცეში G3-ში) და გამოიყენოთ დიაპაზონი $F$3:$G$3 (გთხოვთ გაითვალისწინოთ უჯრედების აბსოლუტური მითითებები) განმსაზღვრელი არგუმენტისთვის:

=TEXTJOIN($F$3:$G$3, TRUE, A2:C2)

ამ ზოგადი მიდგომის გამოყენებით, შეგიძლიათ უჯრედის შიგთავსის გაერთიანება სხვადასხვა ფორმით.

მაგალითად, თუ გსურთ შედეგი სახელი შუა საწყისი გვარი ფორმატში, მაშინ გამოიყენეთ LEFT ფუნქცია პირველი სიმბოლოს ამოსაღებად (საწყისი) C2 უჯრედიდან. რაც შეეხება დელიმიტერებს, ჩვენ ვდებთ ინტერვალს (" ") სახელსა და შუა ინიციალს შორის; აწერტილი და ინტერვალი (". ") საწყისსა და გვარს შორის:

=TEXTJOIN({" ",". "}, TRUE, B2, LEFT(C2,1), A2)

შეაერთეთ ტექსტი და თარიღები Excel-ში

კონკრეტულ შემთხვევაში, როდესაც თქვენ გაერთიანებთ ტექსტი და თარიღები, თარიღების მიწოდება პირდაპირ TEXTJOIN ფორმულაში არ იმუშავებს. როგორც გახსოვთ, Excel ინახავს თარიღებს, როგორც სერიულ ნომრებს, ასე რომ, თქვენი ფორმულა დააბრუნებს თარიღს, როგორც ნაჩვენებია ქვემოთ მოცემულ ეკრანის სურათზე:

=TEXTJOIN(" ", TRUE, A2:B2)

ამის გამოსასწორებლად, თქვენ უნდა გადაიყვანოთ თარიღი ტექსტის სტრიქონში შეერთებამდე. და აქ TEXT ფუნქცია სასურველი ფორმატის კოდით (ჩვენს შემთხვევაში "მმ/დდ/წწ") გამოდგება:

=TEXTJOIN(" ", TRUE, A2, TEXT(B2, "mm/dd/yyyy"))

ტექსტის შერწყმა ხაზების წყვეტებთან

თუ გსურთ ტექსტის შერწყმა Excel-ში ისე, რომ თითოეული მნიშვნელობა იწყება ახალი სტრიქონიდან, გამოიყენეთ CHAR(10) როგორც დელიმიტერი (სადაც 10 არის ხაზის სიმბოლო).

მაგალითად, ტექსტის გაერთიანება უჯრედები A2 და B2, რომლებიც გამოყოფენ მნიშვნელობებს ხაზის წყვეტით, ეს არის გამოსაყენებელი ფორმულა:

=TEXTJOIN(CHAR(10), TRUE, A2:B2)

რჩევა. იმისათვის, რომ შედეგი გამოჩნდეს რამდენიმე სტრიქონში, როგორც ეს ნაჩვენებია ზემოთ მოცემულ ეკრანის სურათზე, დარწმუნდით, რომ ჩართულია ტექსტის გადახვევის ფუნქცია.

TEXTJOIN IF ტექსტის შერწყმა პირობებთან

Excel-ის TEXTJOIN-ის უნარის გამო, ამუშავებს სტრიქონების მასივებს, ის ასევე შეიძლება გამოყენებულ იქნას ორი ან მეტი უჯრედის შიგთავსის პირობითად გაერთიანებისთვის. ამის შესასრულებლად გამოიყენეთ IF ფუნქცია უჯრედების დიაპაზონის შესაფასებლად და დააბრუნეთ მნიშვნელობების მასივი, რომელიც აკმაყოფილებს პირობას text1 არგუმენტში.TEXTJOIN.

ქვემოთ სკრინშოტზე ნაჩვენები ცხრილიდან, დავუშვათ, რომ გსურთ მიიღოთ გუნდი 1 წევრების სია. ამის მისაღწევად, ჩასვით შემდეგი IF განცხადება text1 არგუმენტში:

IF($B$2:$B$9=1, $A$2:$A$9, "")

მარტივი ინგლისურით, ზემოთ ფორმულა ამბობს: თუ სვეტი B უდრის 1-ს, დააბრუნეთ მნიშვნელობა A სვეტიდან იმავე მწკრივში; წინააღმდეგ შემთხვევაში დააბრუნეთ ცარიელი სტრიქონი.

სრული ფორმულა გუნდი 1 იღებს ამ ფორმას:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=1, $A$2:$A$9, ""))

მსგავსი წესით, შეგიძლიათ მიიღოთ გუნდის 2-ის წევრების მძიმით გამოყოფილი სია:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=2, $A$2:$A$9, ""))

შენიშვნა. დინამიური მასივების ფუნქციის გამო, რომელიც ხელმისაწვდომია Excel 365-სა და 2021-ში, ეს მუშაობს როგორც ჩვეულებრივი ფორმულა, რომელიც ნაჩვენებია ზემოთ მოცემულ ეკრანის სურათზე. Excel 2019-ში, თქვენ უნდა შეიყვანოთ ის, როგორც ტრადიციული მასივის ფორმულა Ctrl + Shift + Enter მალსახმობის დაჭერით.

მოძებნეთ და დააბრუნეთ მრავალი შესატყვისი მძიმით გამოყოფილი სიაში

როგორც ალბათ იცით, Excel VLOOKUP ფუნქციას შეუძლია დააბრუნოს მხოლოდ პირველი ნაპოვნი მატჩი. მაგრამ რა მოხდება, თუ თქვენ გჭირდებათ ყველა მატჩის მიღება კონკრეტული ID-სთვის, SKU-სთვის ან სხვა რამისთვის?

შედეგების ცალკეულ უჯრედებში გამოსატანად გამოიყენეთ ერთ-ერთი ფორმულა, რომელიც აღწერილია Excel-ში მრავალჯერადი მნიშვნელობების ამოღების მიზნით.

იმისათვის, რომ მოიძიოთ და დააბრუნოთ ყველა შესატყვისი მნიშვნელობა ერთ უჯრედში მძიმით გამოყოფილი სიის სახით, გამოიყენეთ TEXTJOIN IF ფორმულა.

იმისთვის, რომ ნახოთ, როგორ მუშაობს ის პრაქტიკაში, ავიღოთ სია მოცემული გამყიდველის მიერ შეძენილი პროდუქტები ნიმუშის ცხრილიდანქვევით. ეს მარტივად შეიძლება გაკეთდეს შემდეგი ფორმულით:

=TEXTJOIN(", ", TRUE, IF($A$2:$A$12=D2, $B$2:$B$12, ""))

სადაც A2:A12 არის გამყიდველის სახელები, B2:B12 არის პროდუქტები და D2 არის დაინტერესებული გამყიდველი.

ზემოხსენებული ფორმულა მიდის E2-ზე და მოაქვს ყველა მატჩი სამიზნე გამყიდველისთვის D2-ში (ადამ). ფარდობითი (სამიზნე გამყიდველისთვის) და აბსოლუტური (გამყიდველის სახელებისა და პროდუქტებისთვის) უჯრედების მითითებების ჭკვიანური გამოყენების გამო, ფორმულა სწორად კოპირდება ქვემოთ მოცემულ უჯრედებზე და კარგად მუშაობს დანარჩენი ორი გამყიდველისთვისაც:

Შენიშვნა. როგორც წინა მაგალითში, ეს მუშაობს როგორც ჩვეულებრივი ფორმულა Excel 365-ში და 2021-ში და როგორც CSE ფორმულა (Ctrl + Shift + Enter ) Excel 2019-ში.

ფორმულის ლოგიკა ზუსტად იგივეა, რაც წინა მაგალითი:

IF განცხადება ადარებს თითოეულ სახელს A2:A12-ში სამიზნე სახელთან D2-ში (ჩვენს შემთხვევაში Adam):

IF($A$2:$A$12=D2, $B$2:$B$12, "")

თუ ლოგიკური ტესტი აფასებს TRUE-მდე (ანუ D2-ის სახელი ემთხვევა A სვეტის სახელს), ფორმულა აბრუნებს პროდუქტს B სვეტიდან; წინააღმდეგ შემთხვევაში ცარიელი სტრიქონი ("") დაბრუნდება. IF-ის შედეგი არის შემდეგი მასივი:

{"";"";"Bananas";"Apples";"";"";"";"Oranges";"";"Lemons";""}

მაივი გადადის TEXTJOIN ფუნქციაზე, როგორც text1 არგუმენტი. და რადგან TEXTJOIN კონფიგურირებულია მნიშვნელობების გამოყოფისთვის მძიმით და ინტერვალით (", "), საბოლოო შედეგს მივიღებთ ამ სტრიქონს:

ბანანი, ვაშლი, ფორთოხალი, ლიმონი

Excel TEXTJOIN არ მუშაობს

როდესაც თქვენი TEXTJOIN ფორმულა იწვევს შეცდომას, დიდი ალბათობითიყოს ერთ-ერთი შემდეგი:

• #NAME? შეცდომა ჩნდება, როდესაც TEXTJOIN გამოიყენება Excel-ის ძველ ვერსიაში, სადაც ეს ფუნქცია არ არის მხარდაჭერილი (2019 წლამდე) ან როდესაც ფუნქციის სახელი არასწორად არის დაწერილი.
• #VALUE! შეცდომა ჩნდება, თუ მიღებული სტრიქონი აღემატება 32767 სიმბოლოს.
• #VALUE! შეცდომა შეიძლება ასევე მოხდეს, თუ Excel არ ცნობს დელიმიტერს ტექსტად, მაგალითად, თუ თქვენ მიაწოდეთ რაიმე დაუბეჭდავი სიმბოლო, როგორიცაა CHAR(0).

ასე გამოვიყენოთ TEXTJOIN ფუნქცია Excel-ში. მადლობას გიხდით, რომ კითხულობთ და იმედი მაქვს, მომავალ კვირას გნახავთ ჩვენს ბლოგზე!

ხელმისაწვდომი ჩამოტვირთვები

Excel TEXTJOIN ფორმულის მაგალითები