Ipinapakita ng tutorial kung paano gamitin ang TEXTJOIN function upang pagsamahin ang text sa Excel sa mga praktikal na halimbawa.

Hanggang kamakailan lamang, mayroong dalawang laganap na paraan upang pagsamahin ang mga nilalaman ng cell sa Excel: ang concatenation operator at CONCATENATE function. Sa pagpapakilala ng TEXTJOIN, tila isang mas makapangyarihang alternatibo ang lumitaw, na nagbibigay-daan sa iyong sumali sa text sa isang mas flexible na paraan kasama ang anumang delimiter sa pagitan. Ngunit sa totoo lang, marami pang iba dito!

Excel TEXTJOIN function

Ang TEXTJOIN sa Excel ay pinagsasama-sama ang mga string ng text mula sa maraming mga cell o mga hanay at pinaghihiwalay ang pinagsamang mga halaga sa anumang delimiter na iyong tinukoy. Maaari nitong balewalain o isama ang mga walang laman na cell sa resulta.

Available ang function sa Excel para sa Office 365, Excel 2021, at Excel 2019.

Ang syntax ng TEXTJOIN function ay ang mga sumusunod :

Where:

• Delimiter (kinakailangan) - ay isang separator sa pagitan ng bawat text value na pagsasamahin mo. Karaniwan, ito ay ibinibigay bilang isang text string na nakapaloob sa double quotes o isang reference sa isang cell na naglalaman ng isang text string. Ang isang numerong ibinigay bilang delimiter ay itinuturing bilang text.
• Ignore_empty (kinakailangan) - Tinutukoy kung babalewalain ang mga walang laman na cell o hindi:
  • TRUE - huwag pansinin ang anumang mga blangkong cell.
  • FALSE - isama ang mga walang laman na cell sa resultang string.
• Text1 (kinakailangan) - unang halaga upang sumali. Maaaring ibigay bilang isang text string, isang reference sa isang cell na naglalaman ng isang string, o array ng mga string tulad ng isang hanay ng mga cell.
• Text2 , … (opsyonal) - karagdagang mga halaga ng teksto upang pagsamahin. Pinahihintulutan ang maximum na 252 text argument, kasama ang text1 .

Bilang halimbawa, pagsamahin natin ang mga bahagi ng address mula sa mga cell B2, C2 at D2 sa isang cell, na naghihiwalay sa mga value na may kuwit at puwang:

Gamit ang CONCATENATE function, kailangan mong tukuyin ang bawat cell nang paisa-isa at maglagay ng delimiter (", ") pagkatapos ng bawat reference, na maaaring nakakainis kapag pinagsama ang mga nilalaman ng marami mga cell:

=CONCATENATE(A2, ", ", B2, ", ", C2)

Sa Excel TEXTJOIN, tinukoy mo ang delimiter nang isang beses lang sa unang argumento, at nagbibigay ng hanay ng mga cell para sa ikatlong argumento:

=TEXTJOIN(", ", TRUE, A2:C2)

TEXTJOIN sa Excel - 6 na bagay na dapat tandaan

Upang epektibong magamit ang TEXTJOIN sa iyong mga worksheet, may ilang mahahalagang punto na dapat pansinin:

1. Ang TEXTJOIN ay isang bago function, na available lang sa Excel 2019 - Excel 365. Sa mga naunang bersyon ng Excel, pakigamit ang CONCATENATE function o ang "&" operator sa halip.
2. Sa mga bagong bersyon kung Excel, maaari mo ring gamitin ang CONCAT function upang pagsama-samahin ang mga halaga mula sa magkahiwalay na mga cell at hanay, ngunit walang mga pagpipilian para sa mga delimiter o walang laman na mga cell.
3. Anumang numero na ibinigay sa TEXTJOIN para sa delimiter o text ang mga argumento ay na-convert sa text.
4. Kung ang delimiter ay hindi tinukoy o isang walang laman na string (""), ang mga value ng text ay pinagsasama-sama nang walang anumang delimiter.
5. Ang function ay maaaring humawak ng hanggang 252 text argument.
6. Ang resultang string ay maaaring maglaman ng maximum na 32,767 character, na siyang limitasyon ng cell sa Excel. Kung lumampas ang limitasyong ito, ibabalik ng formula ng TEXTJOIN ang #VALUE! error.

Paano sumali sa text sa Excel - mga halimbawa ng formula

Upang mas maunawaan ang lahat ng mga pakinabang ng TEXTJOIN, tingnan natin kung paano gamitin ang function sa totoong buhay na mga sitwasyon .

I-convert ang column sa comma separated list

Kapag naghahanap ka upang pagsamahin ang isang patayong listahan na naghihiwalay sa mga value sa pamamagitan ng kuwit, tuldok-kuwit o anumang iba pang delimiter, TEXTJOIN ang tamang function na gagamitin.

Para sa halimbawang ito, pagsasama-samahin namin ang mga panalo at pagkatalo ng bawat koponan mula sa talahanayan sa ibaba. Magagawa ito sa mga sumusunod na formula, na naiiba lamang sa hanay ng mga cell na pinagsama.

Para sa Team 1:

=TEXTJOIN(",", FALSE, B2:B6)

Para sa Team 2:

=TEXTJOIN(",", FALSE, C2:C6)

At iba pa.

Sa lahat ng formula, ginagamit ang mga sumusunod na argumento:

• Delimiter - a kuwit (",").
• Ignore_empty ay nakatakda sa FALSE upang isama ang mga walang laman na cell dahil kailangan nating ipakita kung aling mga laro ang hindi nilaro.

Bilang ang resulta, makakakuha ka ng apat na listahang pinaghihiwalay ng kuwit na kumakatawan sa mga panalo at pagkatalo ng bawat koponan sa isang compact form:

Sumali sa mga cell na may iba't ibang delimiter

Sa isang sitwasyon kung kailan kailangan mong paghiwalayin ang pinagsamang mga halaga sa iba't ibang mga delimiter, maaari kang magbigay ng ilang delimiter bilang array constant o ipasok ang bawat delimiter sa isang hiwalay na cell at gumamit ng range reference para sa argumentong delimiter .

Ipagpalagay na gusto mong sumali sa mga cell na naglalaman ng iba't ibang bahagi ng pangalan at makuha ang resulta sa format na ito: Apelyido , Unang pangalan Gitnang pangalan .

Tulad ng nakikita mo, ang Apelyido at Unang pangalan ay pinaghihiwalay ng kuwit at puwang (", ") habang ang Pangalan at Gitnang pangalan ay pinaghihiwalay ng isang puwang (" ") lang. Kaya, isinama namin ang dalawang delimiter na ito sa array constant na {", "," "} at makuha ang sumusunod na formula:

=TEXTJOIN({", "," "}, TRUE, A2:C2)

Kung saan A2:C2 ang mga bahagi ng pangalan na pagsasamahin.

Bilang kahalili, maaari mong i-type ang mga delimiter nang walang mga panipi sa ilang mga cell na walang laman (sabihin, isang kuwit at isang puwang sa F3 at isang puwang sa G3) at gamitin ang hanay na $F$3:$G$3 (mangyaring isipin ang absolute cell references) para sa delimiter argument:

=TEXTJOIN($F$3:$G$3, TRUE, A2:C2)

Sa pamamagitan ng paggamit ng pangkalahatang diskarteng ito, maaari mong pagsamahin ang mga nilalaman ng cell sa iba't ibang anyo.

Halimbawa, kung gusto mo ang resulta sa format na Unang pangalan Middle initial Apelyido , pagkatapos ay gamitin ang LEFT function para kunin ang unang character (ang inisyal) mula sa cell C2. Tulad ng para sa mga delimiter, naglalagay kami ng puwang (" ") sa pagitan ng Unang pangalan at ng Gitnang inisyal; atuldok at isang puwang (". ") sa pagitan ng Inisyal at ng Apelyido:

=TEXTJOIN({" ",". "}, TRUE, B2, LEFT(C2,1), A2)

Sumali sa text at mga petsa sa Excel

Sa isang partikular na kaso kapag pinagsasama mo text at mga petsa, ang pagbibigay ng mga petsa nang direkta sa isang TEXTJOIN formula ay hindi gagana. Gaya ng natatandaan mo, ang Excel ay nag-iimbak ng mga petsa bilang mga serial number, kaya ang iyong formula ay magbabalik ng numerong kumakatawan sa petsa tulad ng ipinapakita sa screenshot sa ibaba:

=TEXTJOIN(" ", TRUE, A2:B2)

Upang ayusin ito, kailangan mong mag-convert ang petsa sa isang text string bago ito sumali. At dito ang TEXT function na may gustong format code ("mm/dd/yyyy" sa aming kaso) ay madaling gamitin:

=TEXTJOIN(" ", TRUE, A2, TEXT(B2, "mm/dd/yyyy"))

Pagsamahin ang text sa mga line break

Kung gusto mong pagsamahin ang text sa Excel para magsimula ang bawat value sa isang bagong linya, gamitin ang CHAR(10) bilang delimiter (kung saan ang 10 ay isang linefeed na character).

Halimbawa, para pagsamahin ang text mula sa cell A2 at B2 na naghihiwalay sa mga value sa pamamagitan ng isang line break, ito ang formula na gagamitin:

=TEXTJOIN(CHAR(10), TRUE, A2:B2)

Tip. Para ipakita ang resulta sa maraming linya tulad ng ipinapakita sa screenshot sa itaas, tiyaking naka-on ang feature na Wrap text.

TEXTJOIN IF para pagsamahin ang text sa mga kundisyon

Dahil sa kakayahan ng Excel TEXTJOIN na pangasiwaan ang mga arrays ng mga string, maaari rin itong gamitin para may kondisyong pagsamahin ang mga nilalaman ng dalawa o higit pang mga cell. Upang magawa ito, gamitin ang IF function upang suriin ang isang hanay ng mga cell at ibalik ang isang hanay ng mga halaga na tumutugon sa kundisyon sa text1 argument ngTEXTJOIN.

Mula sa talahanayang ipinapakita sa screenshot sa ibaba, ipagpalagay na gusto mong kumuha ng listahan ng Team 1 na miyembro. Para makamit ito, ilagay ang sumusunod na IF statement sa text1 argument:

IF($B$2:$B$9=1, $A$2:$A$9, "")

Sa simpleng English, ang formula sa itaas ay nagsasabing: Kung ang column B ay katumbas ng 1, ibalik ang isang halaga mula sa column A sa parehong row; kung hindi, magbabalik ng walang laman na string.

Ang kumpletong formula para sa Team 1 ay ganito ang hugis:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=1, $A$2:$A$9, ""))

Sa katulad na paraan, maaari kang makakuha ng listahan na pinaghihiwalay ng kuwit ng mga miyembro ng Koponan 2:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=2, $A$2:$A$9, ""))

Tandaan. Dahil sa feature na Dynamic Arrays na available sa Excel 365 at 2021, gumagana ito bilang isang regular na formula, na ipinapakita sa screenshot sa itaas. Sa Excel 2019, dapat mo itong ilagay bilang tradisyonal na array formula sa pamamagitan ng pagpindot sa Ctrl + Shift + Enter shortcut.

Maghanap at magbalik ng maraming tugma sa listahang pinaghihiwalay ng kuwit

Tulad ng malamang na alam mo, ang Maibabalik lang ng Excel VLOOKUP function ang unang nahanap na tugma. Ngunit paano kung kailangan mong makuha ang lahat ng tugma para sa isang partikular na ID, SKU, o iba pa?

Upang ilabas ang mga resulta sa magkakahiwalay na mga cell, gamitin ang isa sa mga formula na inilarawan sa Paano mag-VLOOKUP ng maraming value sa Excel.

Upang hanapin at ibalik ang lahat ng tumutugmang value sa isang cell bilang isang listahan na pinaghihiwalay ng kuwit, gamitin ang formula na TEXTJOIN IF.

Upang makita kung paano ito gumagana sa pagsasanay, kunin natin ang isang listahan ng mga produktong binili ng isang ibinigay na nagbebenta mula sa sample tablesa ibaba. Madali itong magawa gamit ang sumusunod na formula:

=TEXTJOIN(", ", TRUE, IF($A$2:$A$12=D2, $B$2:$B$12, ""))

Kung saan ang A2:A12 ay mga pangalan ng nagbebenta, ang B2:B12 ay mga produkto, at ang D2 ay ang nagbebenta ng interes.

Napupunta ang formula sa itaas sa E2 at dinadala ang lahat ng tugma para sa target na nagbebenta sa D2 (Adam). Dahil sa matalinong paggamit ng mga kamag-anak (para sa target na nagbebenta) at ganap (para sa mga pangalan at produkto ng nagbebenta) na mga sanggunian sa cell, ang formula ay nakopya nang tama sa mga cell sa ibaba at gumagana nang maayos para sa iba pang dalawang nagbebenta:

Tandaan. Tulad ng nakaraang halimbawa, ito ay gumagana bilang isang regular na formula sa Excel 365 at 2021, at bilang isang CSE formula (Ctrl + Shift + Enter ) sa Excel 2019.

Ang lohika ng formula ay eksaktong kapareho ng sa nakaraang halimbawa:

Inihahambing ng IF statement ang bawat pangalan sa A2:A12 laban sa target na pangalan sa D2 (Adam sa aming kaso):

IF($A$2:$A$12=D2, $B$2:$B$12, "")

Kung susuriin ng lohikal na pagsubok sa TRUE (i.e. ang pangalan sa D2 ay tumutugma sa pangalan sa column A), ang formula ay nagbabalik ng isang produkto mula sa column B; kung hindi, isang walang laman na string ("") ang ibinalik. Ang resulta ng IF ay ang sumusunod na array:

{"";"";"Bananas";"Apples";"";"";"";"Oranges";"";"Lemons";""}

Ang array ay papunta sa TEXTJOIN function bilang text1 argument. At dahil naka-configure ang TEXTJOIN upang paghiwalayin ang mga value gamit ang kuwit at puwang (", "), nakukuha namin ang string na ito bilang huling resulta:

Mga Saging, Mansanas, Oranges, Lemon

Excel Hindi gumagana ang TEXTJOIN

Kapag nagresulta sa error ang iyong formula sa TEXTJOIN, malamang naupang maging isa sa mga sumusunod:

• #NAME? nangyayari ang error kapag ginamit ang TEXTJOIN sa mas lumang bersyon ng Excel kung saan hindi sinusuportahan ang function na ito (pre-2019) o kapag mali ang spelling ng pangalan ng function.
• #VALUE! nangyayari ang error kung ang resultang string ay lumampas sa 32,767 character.
• #VALUE! maaaring mangyari din ang error kung hindi nakilala ng Excel ang delimiter bilang text, halimbawa kung nagbibigay ka ng ilang hindi napi-print na character gaya ng CHAR(0).

Ganyan gamitin ang TEXTJOIN function sa Excel. Salamat sa pagbabasa at umaasa akong makita ka sa aming blog sa susunod na linggo!

Mga available na download

Mga halimbawa ng formula ng Excel TEXTJOIN