Mafunzo yanaonyesha jinsi ya kutumia kitendakazi cha TEXTJOIN ili kuunganisha maandishi katika Excel na mifano ya vitendo.

Hadi hivi majuzi, kulikuwa na mbinu mbili zilizoenea za kuunganisha yaliyomo kwenye kisanduku katika Excel: muunganisho opereta na kitendakazi cha CONCATENATE. Kwa utangulizi wa TEXTJOIN, inaonekana kama njia mbadala yenye nguvu zaidi imeonekana, ambayo hukuwezesha kuunganisha maandishi kwa njia rahisi zaidi ikijumuisha kikomo chochote katikati. Lakini kwa kweli, kuna mengi zaidi!

Kitendaji cha Excel TEXTJOIN

TEXTJOIN katika Excel huunganisha mifuatano ya maandishi kutoka kwa visanduku vingi au safu na kutenganisha thamani zilizounganishwa na kikomo chochote. kwamba unabainisha. Inaweza kupuuza au kujumuisha seli tupu katika matokeo.

Chaguo za kukokotoa zinapatikana katika Excel kwa Office 365, Excel 2021, na Excel 2019.

Sintaksia ya chaguo za kukokotoa za TEXTJOIN ni kama ifuatavyo. :

Ambapo:

• Delimiter (inahitajika) - ni kitenganishi kati ya kila thamani ya maandishi kwamba unachanganya. Kwa kawaida, hutolewa kama mfuatano wa maandishi ulioambatanishwa katika manukuu mara mbili au rejeleo la kisanduku kilicho na mfuatano wa maandishi. Nambari iliyotolewa kama kikomo inachukuliwa kuwa maandishi.
• Puuza_tupu (inahitajika) - Huamua iwapo itapuuza visanduku tupu au la:
  • TRUE - puuza visanduku vyovyote.
  • FALSE - jumuisha visanduku tupu katika mfuatano unaotokana.
• Nakala1 (inahitajika) - thamani ya kwanza ya kujiunga. Inaweza kutolewa kama mfuatano wa maandishi, rejeleo la kisanduku kilicho na mfuatano, au safu ya mifuatano kama vile safu ya visanduku.
• Nakala2 , … (si lazima) - thamani za ziada za maandishi. kuunganishwa pamoja. Upeo wa hoja za maandishi 252 zinaruhusiwa, ikiwa ni pamoja na text1 .

Kwa mfano, hebu tuunganishe sehemu za anwani kutoka seli B2, C2 na D2 pamoja hadi kisanduku kimoja, tukitenganisha thamani. yenye koma na nafasi:

Na kitendakazi cha CONCATENATE, utahitaji kubainisha kila kisanduku kivyake na kuweka kikomo (", ") baada ya kila marejeleo, jambo ambalo linaweza kusumbua wakati wa kuunganisha yaliyomo kwenye nyingi. seli:

=CONCATENATE(A2, ", ", B2, ", ", C2)

Ukiwa na Excel TEXTJOIN, unabainisha kitenganishi mara moja tu katika hoja ya kwanza, na kutoa safu ya visanduku kwa hoja ya tatu:

=TEXTJOIN(", ", TRUE, A2:C2)

TEXTJOIN katika Excel - mambo 6 ya kukumbuka

Ili kutumia TEXTJOIN ipasavyo katika laha zako za kazi, kuna mambo machache muhimu ya kuzingatia:

1. TEXTJOIN ni mpya. kitendakazi, ambacho kinapatikana tu katika Excel 2019 - Excel 365. Katika matoleo ya awali ya Excel, tafadhali tumia kitendakazi cha CONCATENATE au "&" opereta badala yake.
2. Katika matoleo mapya kama Excel, unaweza pia kutumia kitendakazi cha CONCAT kubatilisha thamani kutoka seli tofauti na safu, lakini bila chaguo za vikomo au visanduku tupu.
3. Nambari yoyote iliyotolewa. kwa TEXTJOIN kwa delimiter au text hoja hubadilishwa kuwa maandishi.
4. Ikiwa kitenganishi hakijabainishwa au ni mfuatano tupu (""), thamani za maandishi huunganishwa bila kikomo chochote.
5. Kitendakazi kinaweza kukokotoa. shughulikia hadi hoja za maandishi 252.
6. Mfuatano unaotokana unaweza kuwa na upeo wa vibambo 32,767, ambacho ndicho kikomo cha kisanduku katika Excel. Ikiwa kikomo hiki kitapitwa, fomula ya TEXTJOIN italeta #VALUE! kosa.

Jinsi ya kuunganisha maandishi katika Excel - mifano ya fomula

Ili kuelewa vyema manufaa yote ya TEXTJOIN, hebu tuangalie jinsi ya kutumia chaguo hili la kukokotoa katika hali halisi. .

Geuza safu wima kuwa orodha iliyotenganishwa kwa koma

Unapotafuta kuambatanisha orodha wima inayotenganisha thamani kwa koma, nusu koloni au kikomo kingine chochote, TEXTJOIN ndiyo chaguo sahihi la kukokotoa kutumia.

Kwa mfano huu, tutakuwa tukilinganisha ushindi na hasara za kila timu kutoka kwenye jedwali lililo hapa chini. Hili linaweza kufanywa kwa kutumia fomula zifuatazo, ambazo hutofautiana tu katika safu ya visanduku vilivyounganishwa.

Kwa Timu 1:

=TEXTJOIN(",", FALSE, B2:B6)

Kwa Timu 2:

=TEXTJOIN(",", FALSE, C2:C6)

Na kadhalika.

Katika fomula zote, hoja zifuatazo zimetumika:

• Delimiter - a koma (",").
• Puuza_tupu imewekwa kuwa FALSE ili kujumuisha visanduku tupu kwa sababu tunahitaji kuonyesha ni michezo gani ambayo haikuchezwa.

Kama matokeo, utapata orodha nne zilizotenganishwa kwa koma ambazo zinawakilisha ushindi na hasara za kila timu katika fomu fupi:

Jiunge na visanduku vilivyo na vikomo tofauti

Katika hali ambayo unahitaji kutenganisha thamani zilizounganishwa na vikomo tofauti, unaweza kusambaza vikomo kadhaa kama safu thabiti au kuingiza kila kikomo katika kisanduku tofauti. na utumie marejeleo ya masafa kwa hoja ya delimiter .

Tuseme unataka kuunganisha visanduku vilivyo na sehemu tofauti za majina na kupata matokeo katika umbizo hili: Jina la mwisho , Jina la Kwanza Jina la Kati .

Kama unavyoona, Jina la Mwisho na Jina la Kwanza zimetenganishwa kwa koma na nafasi (", ") huku Jina la Kwanza na Jina la Kati kwa nafasi. ("") pekee. Kwa hivyo, tunajumuisha vitenganishi hivi viwili katika safu thabiti {", "," "} na kupata fomula ifuatayo:

=TEXTJOIN({", "," "}, TRUE, A2:C2)

Ambapo A2:C2 ndizo sehemu za majina zitakazounganishwa.

Vinginevyo, unaweza kuandika vikomo bila alama za nukuu katika visanduku vingine tupu (sema, koma na nafasi katika F3 na nafasi katika G3) na utumie masafa $F$3:$G$3 (tafadhali kumbuka. marejeleo kamili ya seli) kwa hoja ya kitenganishi :

=TEXTJOIN($F$3:$G$3, TRUE, A2:C2)

Kwa kutumia mbinu hii ya jumla, unaweza kuunganisha maudhui ya seli katika miundo mbalimbali.

Kwa mfano, ikiwa unataka matokeo katika umbizo la Jina la Kwanza Asili ya kati Jina la mwisho , basi tumia kitendakazi cha KUSHOTO kutoa herufi ya kwanza (ya kwanza) kutoka kwa seli C2. Kuhusu vitenganishi, tunaweka nafasi (" ") kati ya Jina la Kwanza na la awali la Kati; akipindi na nafasi (". ") kati ya Jina la Kwanza na la Mwisho:

=TEXTJOIN({" ",". "}, TRUE, B2, LEFT(C2,1), A2)

Jiunge na maandishi na tarehe katika Excel

Katika hali mahususi unapounganisha maandishi na tarehe, kutoa tarehe moja kwa moja kwa fomula ya TEXTJOIN haitafanya kazi. Kama unavyoweza kukumbuka, Excel huhifadhi tarehe kama nambari za mfululizo, kwa hivyo fomula yako itarudisha nambari inayowakilisha tarehe kama inavyoonyeshwa kwenye picha ya skrini hapa chini:

=TEXTJOIN(" ", TRUE, A2:B2)

Ili kurekebisha hili, unahitaji kubadilisha. tarehe katika mfuatano wa maandishi kabla ya kuiunganisha. Na hapa kitendakazi cha TEXT na msimbo wa umbizo unaotakikana ("mm/dd/yyyy" kwa upande wetu) huja kwa manufaa:

=TEXTJOIN(" ", TRUE, A2, TEXT(B2, "mm/dd/yyyy"))

Unganisha maandishi na vikatika mistari

Iwapo ungependa kuunganisha maandishi katika Excel ili kila thamani ianze katika mstari mpya, tumia CHAR(10) kama kikomo (ambapo 10 ni herufi ya kulisha laini).

Kwa mfano, kuchanganya maandishi kutoka seli A2 na B2 zikitenganisha thamani kwa kukatika kwa mstari, hii ndiyo fomula ya kutumia:

=TEXTJOIN(CHAR(10), TRUE, A2:B2)

Kidokezo. Ili matokeo yaonekane katika mistari mingi kama inavyoonyeshwa kwenye picha ya skrini iliyo hapo juu, hakikisha kuwa kipengele cha maandishi ya Wrap kimewashwa.

TEXTJOIN IF ili kuunganisha maandishi na masharti

Kwa sababu ya uwezo wa Excel TEXTJOIN kushughulikia safu za mifuatano, inaweza pia kutumika kuunganisha kwa masharti maudhui ya seli mbili au zaidi. Ili kuifanya, tumia chaguo la kukokotoa la IF kutathmini safu ya visanduku na kurudisha safu ya thamani zinazokidhi masharti kwa maandishi1 hoja ya.TEXTJOIN.

Kutoka kwa jedwali lililoonyeshwa kwenye picha ya skrini iliyo hapa chini, chukulia ungependa kuepua orodha ya washiriki Timu 1 . Ili kufanikisha hili, weka kauli ifuatayo ya IF kwenye maandishi1 hoja:

IF($B$2:$B$9=1, $A$2:$A$9, "")

Kwa Kiingereza safi, fomula iliyo hapo juu inasema: Ikiwa safu wima B ni sawa na 1, rudisha a thamani kutoka kwa safu A katika safu sawa; vinginevyo rudisha mfuatano tupu.

Mfumo kamili ya Timu 1 inachukua umbo hili:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=1, $A$2:$A$9, ""))

Kwa namna sawa, unaweza kupata orodha iliyotenganishwa kwa koma ya wanachama wa Timu 2:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=2, $A$2:$A$9, ""))

Kumbuka. Kwa sababu ya kipengele cha Mikusanyiko Inayobadilika inayopatikana katika Excel 365 na 2021, hii inafanya kazi kama fomula ya kawaida, iliyoonyeshwa kwenye picha ya skrini iliyo hapo juu. Katika Excel 2019, ni lazima uiweke kama fomula ya mkusanyiko wa kitamaduni kwa kubofya Ctrl + Shift + Enter njia ya mkato.

Tafuta na urudishe zinazolingana katika orodha iliyotenganishwa kwa koma

Kama unavyojua, Chaguo za kukokotoa za Excel VLOOKUP zinaweza tu kurudisha ulinganifu wa kwanza uliopatikana. Lakini vipi ikiwa unahitaji kupata mechi zote za kitambulisho mahususi, SKU, au kitu kingine?

Ili kutoa matokeo katika visanduku tofauti, tumia mojawapo ya fomula zilizofafanuliwa katika Jinsi ya VLOOKUP thamani nyingi katika Excel.

Ili kutafuta na kurejesha thamani zote zinazolingana katika kisanduku kimoja kama orodha iliyotenganishwa kwa koma, tumia fomula ya TEXTJOIN IF.

Ili kuona jinsi inavyofanya kazi, hebu tupate orodha ya bidhaa zilizonunuliwa na muuzaji fulani kutoka kwa jedwali la sampulichini. Hili linaweza kufanywa kwa urahisi kwa kutumia fomula ifuatayo:

=TEXTJOIN(", ", TRUE, IF($A$2:$A$12=D2, $B$2:$B$12, ""))

Ambapo A2:A12 ni majina ya wauzaji, B2:B12 ni bidhaa, na D2 ndiye muuzaji wa faida.

Fomula iliyo hapo juu inaenda kwa E2 na kuleta mechi zote za muuzaji lengwa katika D2 (Adam). Kwa sababu ya utumiaji wa busara wa jamaa (kwa muuzaji lengwa) na marejeleo kamili ya seli (kwa majina na bidhaa za muuzaji), fomula inanakili kwa usahihi kwenye visanduku vilivyo hapa chini na hufanya kazi vizuri kwa wauzaji wengine wawili pia:

Kumbuka. Kama ilivyo kwa mfano uliopita, hii inafanya kazi kama fomula ya kawaida katika Excel 365 na 2021, na kama fomula ya CSE (Ctrl + Shift + Enter ) katika Excel 2019.

Mantiki ya fomula ni sawa kabisa na katika mfano uliopita:

Taarifa ya IF inalinganisha kila jina katika A2:A12 dhidi ya jina lengwa katika D2 (Adam kwa upande wetu):

IF($A$2:$A$12=D2, $B$2:$B$12, "")

Ikiwa jaribio la kimantiki litatathmini hadi TRUE (yaani, jina katika D2 linalingana na jina katika safu wima A), fomula hurejesha bidhaa kutoka safu B; vinginevyo kamba tupu ("") inarudishwa. Matokeo ya IF ni safu ifuatayo:

{"";"";"Bananas";"Apples";"";"";"";"Oranges";"";"Lemons";""}

Mkusanyiko huenda kwa chaguo za kukokotoa TEXTJOIN kama maandishi1 hoja. Na kwa sababu TEXTJOIN imesanidiwa ili kutenganisha thamani kwa koma na nafasi (", "), tunapata mfuatano huu kama tokeo la mwisho:

Ndizi, Tufaha, Machungwa, Ndimu

Excel TEXTJOIN haifanyi kazi

Fomula yako ya TEXTJOIN inaposababisha hitilafu, kuna uwezekano mkubwakuwa mmoja wa wafuatao:

• #JINA? hitilafu hutokea wakati TEXTJOIN inapotumiwa katika toleo la zamani la Excel ambapo chaguo hili la kukokotoa halitumiki (kabla ya 2019) au wakati jina la chaguo la kukokotoa limeandikwa kimakosa.
• #VALUE! hitilafu hutokea ikiwa mfuatano unaotokana unazidi vibambo 32,767.
• #VALUE! hitilafu pia inaweza kutokea ikiwa Excel haitambui kikomo kama maandishi, kwa mfano ikiwa utatoa herufi zisizoweza kuchapishwa kama vile CHAR(0).

Hiyo ndivyo jinsi ya kutumia chaguo la kukokotoa la TEXTJOIN katika Excel. Ninakushukuru kwa kusoma na kutumaini kukuona kwenye blogu yetu wiki ijayo!

Vipakuliwa vinavyopatikana

Mifano ya fomula ya Excel TEXTJOIN