Mae'r tiwtorial yn dangos sut i ddefnyddio'r ffwythiant TEXTJOIN i gyfuno testun yn Excel ag enghreifftiau ymarferol.

Tan yn ddiweddar, roedd dau ddull cyffredin i gyfuno cynnwys cell yn Excel: y concatenation gweithredwr a swyddogaeth CONCATENATE. Gyda chyflwyniad TEXTJOIN, mae'n ymddangos bod dewis arall mwy pwerus wedi ymddangos, sy'n eich galluogi i ymuno â thestun mewn modd mwy hyblyg gan gynnwys unrhyw amffinydd rhyngddynt. Ond a dweud y gwir, mae llawer mwy iddo!

Excel TEXTJOIN function

TEXTJOIN in Excel yn uno llinynnau testun o gelloedd neu ystodau lluosog ac yn gwahanu'r gwerthoedd cyfun ag unrhyw amffinydd eich bod yn nodi. Gall naill ai anwybyddu neu gynnwys celloedd gwag yn y canlyniad.

Mae'r ffwythiant ar gael yn Excel ar gyfer Office 365, Excel 2021, ac Excel 2019.

Mae cystrawen ffwythiant TEXTJOIN fel a ganlyn :

Ble:

• Amffinydd (gofynnol) - yn wahanydd rhwng pob gwerth testun eich bod yn cyfuno. Fel arfer, fe'i cyflenwir fel llinyn testun wedi'i amgáu mewn dyfynbrisiau dwbl neu gyfeiriad at gell sy'n cynnwys llinyn testun. Mae rhif a gyflenwir fel amffinydd yn cael ei drin fel testun.
• Anwybyddu_gwag (gofynnol) - Yn penderfynu a ddylid anwybyddu celloedd gwag ai peidio:
  • CYWIR - anwybyddwch unrhyw gelloedd gwag.
  • GAU - cynnwys celloedd gwag yn y llinyn canlyniadol.
• Text1 (gofynnol) - gwerth cyntaf i ymuno. Gellir ei gyflenwi fel llinyn testun, cyfeiriad at gell sy'n cynnwys llinyn, neu amrywiaeth o linynnau megis ystod o gelloedd.
• Text2 , … (dewisol) - gwerthoedd testun ychwanegol i'w huno. Caniateir uchafswm o 252 o argiau testun, gan gynnwys testun1 .

Fel enghraifft, gadewch i ni gyfuno rhannau cyfeiriad o gelloedd B2, C2 a D2 gyda'i gilydd yn un gell, gan wahanu'r gwerthoedd gyda choma a bwlch:

Gyda'r ffwythiant CONCATENATE, byddai angen i chi nodi pob cell yn unigol a rhoi amffinydd (", ") ar ôl pob cyfeiriad, a allai fod yn drafferthus wrth gyfuno cynnwys llawer celloedd:

=CONCATENATE(A2, ", ", B2, ", ", C2)

Gydag Excel TEXTJOIN, rydych yn nodi'r amffinydd unwaith yn unig yn y ddadl gyntaf, ac yn cyflenwi ystod o gelloedd ar gyfer y drydedd arg:

=TEXTJOIN(", ", TRUE, A2:C2) <12

TEXTJOIN yn Excel - 6 pheth i'w cofio

I ddefnyddio TEXTJOIN yn effeithiol yn eich taflenni gwaith, mae rhai pwyntiau pwysig i'w hystyried:

1. Mae TEXTJOIN yn newydd swyddogaeth, sydd ar gael yn Excel 2019 - Excel 365 yn unig. Mewn fersiynau Excel cynharach, defnyddiwch y swyddogaeth CONCATENATE neu'r "&" gweithredwr yn lle hynny.
2. Mewn fersiynau newydd os Excel, gallwch hefyd ddefnyddio'r ffwythiant CONCAT i gydgatenu gwerthoedd o gelloedd ac ystodau ar wahân, ond heb unrhyw opsiynau ar gyfer amffinyddion na chelloedd gwag.
3. Unrhyw rif a gyflenwir i TEXTJOIN am y amffinydd neu testun argeuon yn cael eu trosi i destun.
4. Os nad yw amffinydd wedi ei nodi neu yn llinyn gwag (""), mae gwerthoedd testun yn cael eu cydgadwynu heb unrhyw amffinydd.
5. Gall y ffwythiant trin hyd at 252 o ddadleuon testun.
6. Gall y llinyn canlyniadol gynnwys uchafswm o 32,767 nod, sef y terfyn cell yn Excel. Os eir y tu hwnt i'r terfyn hwn, mae fformiwla TEXTJOIN yn dychwelyd y #VALUE! gwall.

Sut i ymuno â thestun yn Excel - enghreifftiau fformiwla

Er mwyn deall holl fanteision TEXTJOIN yn well, gadewch i ni edrych ar sut i ddefnyddio'r ffwythiant mewn sefyllfaoedd go iawn .

Trosi colofn i restr wedi'i gwahanu gan goma

Pan fyddwch yn edrych i gydgadwynu rhestr fertigol sy'n gwahanu'r gwerthoedd â choma, hanner colon neu unrhyw amffinydd arall, TEXTJOIN yw'r ffwythiant cywir i'w ddefnyddio.

Ar gyfer yr enghraifft hon, byddwn yn cyfuno buddugoliaethau a cholledion pob tîm o’r tabl isod. Gellir gwneud hyn gyda'r fformiwlâu canlynol, sy'n wahanol yn unig yn yr ystod o gelloedd sy'n cael eu huno.

Ar gyfer Tîm 1:

=TEXTJOIN(",", FALSE, B2:B6)

Ar gyfer Tîm 2:<3

=TEXTJOIN(",", FALSE, C2:C6)

Ac yn y blaen.

Yn yr holl fformiwlâu, defnyddir y dadleuon canlynol:

• Amffinydd - a coma (",").
• Anwybyddu_gwag wedi'i osod i ANGHYWIR i gynnwys celloedd gwag oherwydd mae angen i ni ddangos pa gemau na chafodd eu chwarae.

Fel y O ganlyniad, byddwch yn cael pedair rhestr wedi'u gwahanu gan goma sy'n cynrychioli buddugoliaethau a cholledion pob tîm ar ffurf gryno:

Ymuno â chelloedd â gwahanol amffinyddion

Mewn sefyllfa pan fydd angen i chi wahanu'r gwerthoedd cyfunol â gwahanol amffinyddion, gallwch naill ai gyflenwi sawl amffinydd fel cysonyn arae neu fewnbynnu pob amffinydd mewn cell ar wahân a defnyddiwch gyfeirnod amrediad ar gyfer y ddadl amffinydd .

A chymryd eich bod am ymuno â chelloedd sy'n cynnwys gwahanol rannau enw a chael y canlyniad yn y fformat hwn: Enw olaf , Enw cyntaf Enw canol .

Fel y gwelwch, mae'r Cyfenw a'r Enw Cyntaf yn cael eu gwahanu gan goma a bwlch (", ") tra bod yr enw cyntaf a'r enw canol gan fwlch ("") yn unig. Felly, rydym yn cynnwys y ddau amffinydd hyn mewn cysonyn arae {", "," "} ac yn cael y fformiwla ganlynol:

=TEXTJOIN({", "," "}, TRUE, A2:C2)

Lle A2:C2 yw'r rhannau enw i'w cyfuno.

Fel arall, gallwch deipio'r amffinyddion heb ddyfynodau mewn rhai celloedd gwag (dyweder, coma a bwlch yn F3 a bwlch yn G3) a defnyddio'r ystod $F$3:$G$3 (cofiwch y cyfeiriadau cell absoliwt) ar gyfer y ddadl amffinydd :

=TEXTJOIN($F$3:$G$3, TRUE, A2:C2)

Drwy ddefnyddio'r dull cyffredinol hwn, gallwch gyfuno cynnwys cell mewn gwahanol ffurfiau.

Er enghraifft, os ydych chi eisiau'r canlyniad yn y fformat Enw cyntaf Cychwynnol canol Enw olaf , yna defnyddiwch y ffwythiant CHWITH i echdynnu'r nod cyntaf (y blaenlythrennol) o gell C2. Ynglŷn â'r amffinyddion, rydyn ni'n rhoi bwlch (" ") rhwng yr enw Cyntaf a'r llythrennau blaen Canol; acyfnod a bwlch (".") rhwng y blaenlythrennau a'r enw olaf:

=TEXTJOIN({" ",". "}, TRUE, B2, LEFT(C2,1), A2)

Ymunwch â thestun a dyddiadau yn Excel

Mewn achos penodol pan fyddwch yn uno testun a dyddiadau, ni fydd cyflenwi dyddiadau yn uniongyrchol i fformiwla TEXTJOIN yn gweithio. Fel y cofiwch efallai, mae Excel yn storio dyddiadau fel rhifau cyfresol, felly bydd eich fformiwla yn dychwelyd rhif sy'n cynrychioli'r dyddiad a ddangosir yn y sgrinlun isod:

=TEXTJOIN(" ", TRUE, A2:B2)

I drwsio hyn, mae angen i chi drosi y dyddiad yn llinyn testun cyn ymuno ag ef. Ac yma mae'r swyddogaeth TESTUN gyda'r cod fformat dymunol ("mm/dd/bbbb" yn ein hachos ni) yn ddefnyddiol:

=TEXTJOIN(" ", TRUE, A2, TEXT(B2, "mm/dd/yyyy"))

Uno testun gyda thoriadau llinell

Os hoffech gyfuno testun yn Excel fel bod pob gwerth yn dechrau mewn llinell newydd, defnyddiwch CHAR(10) fel amffinydd (lle mae 10 yn nod porthiant llinell).

Er enghraifft, i gyfuno testun o celloedd A2 a B2 yn gwahanu'r gwerthoedd gan doriad llinell, dyma'r fformiwla i'w defnyddio:

=TEXTJOIN(CHAR(10), TRUE, A2:B2)

Awgrym. Er mwyn i'r canlyniad gael ei arddangos mewn llinellau lluosog fel y dangosir yn y llun uchod, gwnewch yn siŵr bod y nodwedd Wrap text wedi'i throi ymlaen.

TEXTJOIN IF i gyfuno testun ag amodau

Oherwydd gallu Excel TEXTJOIN i drin araeau o linynnau, gellir ei ddefnyddio hefyd i uno cynnwys dwy gell neu fwy yn amodol. I'w wneud, defnyddiwch y ffwythiant IF i werthuso ystod o gelloedd a dychwelyd amrywiaeth o werthoedd sy'n bodloni'r amod i'r arg text1 oTEXTJOIN.

O'r tabl a ddangosir yn y ciplun isod, mae'n debyg eich bod am adalw rhestr o aelodau Tîm 1 . I gyflawni hyn, nythu'r datganiad IF canlynol yn y ddadl text1 :

IF($B$2:$B$9=1, $A$2:$A$9, "")

Mewn Saesneg clir, mae'r fformiwla uchod yn dweud: Os yw colofn B yn hafal i 1, dychwelwch a gwerth o golofn A yn yr un rhes; fel arall dychwelwch linyn gwag.

Mae'r fformiwla gyflawn ar gyfer Tîm 1 yn cymryd y siâp hwn:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=1, $A$2:$A$9, ""))

Mewn modd tebyg, gallwch gael a rhestr wedi'i gwahanu gan goma o aelodau Tîm 2:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=2, $A$2:$A$9, ""))

Nodyn. Oherwydd y nodwedd Araeau Dynamig sydd ar gael yn Excel 365 a 2021, mae hyn yn gweithio fel fformiwla reolaidd, a ddangosir yn y sgrin lun uchod. Yn Excel 2019, rhaid i chi ei nodi fel fformiwla arae draddodiadol trwy wasgu'r llwybr byr Ctrl + Shift + Enter.

Edrychwch a dychwelwch nifer o gemau cyfatebol yn y rhestr wedi'i gwahanu gan goma

Fel y gwyddoch fwy na thebyg, mae'r Gall swyddogaeth Excel VLOOKUP ond dychwelyd yr ornest gyntaf a ganfuwyd. Ond beth os oes angen i chi gael yr holl gemau ar gyfer ID penodol, SKU, neu rywbeth arall?

I allbynnu'r canlyniadau mewn celloedd ar wahân, defnyddiwch un o'r fformiwlâu a ddisgrifir yn Sut i VLOOKUP gwerthoedd lluosog yn Excel.

I edrych i fyny a dychwelyd yr holl werthoedd cyfatebol mewn un gell fel rhestr wedi'i gwahanu gan goma, defnyddiwch fformiwla TEXTJOIN IF.

I weld sut mae'n gweithio'n ymarferol, gadewch i ni adfer rhestr o cynhyrchion a brynwyd gan werthwr penodol o'r tabl samplisod. Gellir gwneud hyn yn hawdd gyda'r fformiwla ganlynol:

=TEXTJOIN(", ", TRUE, IF($A$2:$A$12=D2, $B$2:$B$12, ""))

Lle mae A2:A12 yn enwau gwerthwyr, mae B2:B12 yn gynhyrchion, a D2 yw'r gwerthwr o ddiddordeb.

Mae'r fformiwla uchod yn mynd i E2 ac yn dod â'r holl gemau ar gyfer y gwerthwr targed yn D2 (Adam). Oherwydd y defnydd clyfar o gyfeiriadau celloedd cymharol (ar gyfer y gwerthwr targed) ac absoliwt (ar gyfer enwau'r gwerthwr a'r cynhyrchion), mae'r fformiwla'n copïo'n gywir i'r celloedd isod ac yn gweithio'n braf i'r ddau werthwr arall hefyd:

Nodyn. Fel gyda'r enghraifft flaenorol, mae hwn yn gweithio fel fformiwla reolaidd yn Excel 365 a 2021, ac fel fformiwla CSE ( Ctrl + Shift + Enter ) yn Excel 2019.

Mae rhesymeg y fformiwla yn union yr un fath ag yn y enghraifft flaenorol:

Mae datganiad IF yn cymharu pob enw yn A2:A12 yn erbyn yr enw targed yn D2 (Adam yn ein hachos ni):

IF($A$2:$A$12=D2, $B$2:$B$12, "")

Os yw'r prawf rhesymegol yn gwerthuso i TRUE (h.y. mae'r enw yn D2 yn cyfateb i'r enw yng ngholofn A), mae'r fformiwla yn dychwelyd cynnyrch o golofn B; fel arall dychwelir llinyn gwag (""). Canlyniad IF yw'r arae canlynol:

{"";"";"Bananas";"Apples";"";"";"";"Oranges";"";"Lemons";""}

Mae'r arae yn mynd i ffwythiant TEXTJOIN fel yr arg text1 . Ac oherwydd bod TEXTJOIN wedi'i ffurfweddu i wahanu'r gwerthoedd gyda choma a bwlch (", "), rydyn ni'n cael y llinyn hwn fel y canlyniad terfynol:

Bananas, Afalau, Orennau, Lemonau

Excel TEXTJOIN ddim yn gweithio

Pan fydd eich fformiwla TEXTJOIN yn arwain at wall, mae'n fwyaf tebygoli fod yn un o'r canlynol:

• #NAME? mae gwall yn digwydd pan ddefnyddir TEXTJOIN mewn fersiwn hŷn o Excel lle na chefnogir y swyddogaeth hon (cyn 2019) neu pan fydd enw'r ffwythiant wedi'i gamsillafu.
• #VALUE! mae gwall yn digwydd os yw'r llinyn canlyniadol yn fwy na 32,767 nod.
• #VALUE! gall gwall ddigwydd hefyd os nad yw Excel yn adnabod y amffinydd fel testun, er enghraifft os ydych chi'n cyflenwi rhyw nod na ellir ei argraffu megis CHAR(0).

Dyna sut i ddefnyddio'r ffwythiant TEXTJOIN yn Excel. Diolch i chi am ddarllen a gobeithio eich gweld ar ein blog wythnos nesaf!

Ar gael i'w lawrlwytho

Enghreifftiau fformiwla Excel TEXTJOIN