ट्यूटोरियल दिखाता है कि व्यावहारिक उदाहरणों के साथ एक्सेल में टेक्स्ट मर्ज करने के लिए टेक्स्टजॉइन फ़ंक्शन का उपयोग कैसे करें। ऑपरेटर और CONCATENATE फ़ंक्शन। TEXTJOIN की शुरुआत के साथ, ऐसा लगता है कि एक अधिक शक्तिशाली विकल्प सामने आया है, जो आपको बीच में किसी भी सीमांकक सहित अधिक लचीले तरीके से पाठ में शामिल होने में सक्षम बनाता है। लेकिन वास्तव में, इसमें और भी बहुत कुछ है!

Excel TEXTJOIN फ़ंक्शन

Excel में TEXTJOIN कई सेल या रेंज से टेक्स्ट स्ट्रिंग्स को मर्ज करता है और किसी भी सीमांकक के साथ संयुक्त मानों को अलग करता है कि आप निर्दिष्ट करें। यह परिणाम में खाली कोशिकाओं को या तो अनदेखा कर सकता है या शामिल कर सकता है।

फ़ंक्शन Excel में Office 365, Excel 2021 और Excel 2019 के लिए उपलब्ध है।

TEXTJOIN फ़ंक्शन का सिंटैक्स इस प्रकार है :

कहाँ:

• Delimiter (आवश्यक) - प्रत्येक पाठ मान के बीच एक विभाजक है कि आप गठबंधन करें। आम तौर पर, इसे डबल कोट्स में संलग्न टेक्स्ट स्ट्रिंग या टेक्स्ट स्ट्रिंग वाले सेल के संदर्भ के रूप में आपूर्ति की जाती है। सीमांकक के रूप में प्रदान की गई संख्या को टेक्स्ट माना जाता है।
• Ignore_empty (आवश्यक) - यह निर्धारित करता है कि रिक्त कक्षों को अनदेखा करना है या नहीं:
  • TRUE - किसी भी रिक्त कक्षों को अनदेखा करें।
  • FALSE - परिणामी स्ट्रिंग में खाली सेल शामिल करें।
• Text1 (आवश्यक) - जुड़ने के लिए पहला मान। एक टेक्स्ट स्ट्रिंग के रूप में आपूर्ति की जा सकती है, एक स्ट्रिंग वाले सेल का संदर्भ, या स्ट्रिंग्स की सरणी जैसे सेल की एक श्रृंखला।
• टेक्स्ट 2 , ... (वैकल्पिक) - अतिरिक्त टेक्स्ट मान एक साथ जुड़ना। text1 सहित अधिकतम 252 टेक्स्ट तर्कों की अनुमति है।

उदाहरण के तौर पर, चलिए सेल B2, C2 और D2 से पता भागों को एक साथ एक सेल में जोड़ते हैं, मानों को अलग करते हैं। एक अल्पविराम और एक स्थान के साथ:

कनेक्टनेट फ़ंक्शन के साथ, आपको प्रत्येक सेल को अलग-अलग निर्दिष्ट करना होगा और प्रत्येक संदर्भ के बाद एक सीमांकक (", ") लगाना होगा, जो कई की सामग्री को मर्ज करते समय परेशान हो सकता है सेल:

=CONCATENATE(A2, ", ", B2, ", ", C2)

Excel TEXTJOIN के साथ, आप पहले आर्ग्युमेंट में केवल एक बार डिलिमिटर निर्दिष्ट करते हैं, और तीसरे आर्गुमेंट के लिए सेल की एक श्रृंखला प्रदान करते हैं:

=TEXTJOIN(", ", TRUE, A2:C2) <12

Excel में TEXTJOIN - याद रखने वाली 6 बातें

आपके वर्कशीट में TEXTJOIN का प्रभावी ढंग से उपयोग करने के लिए, ध्यान देने योग्य कुछ महत्वपूर्ण बिंदु हैं:

1. TEXTJOIN एक नया है फ़ंक्शन, जो केवल Excel 2019 - Excel 365 में उपलब्ध है। Excel के पुराने संस्करणों में, कृपया CONCATENATE फ़ंक्शन या "&" का उपयोग करें इसके बजाय ऑपरेटर।
2. एक्सेल के नए संस्करणों में, आप अलग-अलग सेल और रेंज से मूल्यों को जोड़ने के लिए CONCAT फ़ंक्शन का भी उपयोग कर सकते हैं, लेकिन सीमांकक या खाली सेल के लिए कोई विकल्प नहीं है।
3. कोई भी संख्या प्रदान की गई सीमांकक या पाठ के लिए TEXTJOIN करने के लिएतर्कों को पाठ में बदल दिया जाता है।
4. यदि परिसीमक निर्दिष्ट नहीं है या एक खाली स्ट्रिंग ("") है, तो पाठ मान बिना किसी सीमांकक के समाप्‍त हो जाते हैं।
5. फ़ंक्शन कर सकता है अधिकतम 252 टेक्स्ट तर्क संभालें।
6. परिणामी स्ट्रिंग में अधिकतम 32,767 वर्ण हो सकते हैं, जो एक्सेल में सेल की सीमा है। यदि यह सीमा पार हो जाती है, तो TEXTJOIN सूत्र #VALUE! त्रुटि।

Excel में टेक्स्ट कैसे जुड़ें - सूत्र उदाहरण

टेक्स्टजॉइन के सभी लाभों को बेहतर ढंग से समझने के लिए, आइए देखें कि वास्तविक जीवन परिदृश्यों में फ़ंक्शन का उपयोग कैसे करें .

कॉलम को अल्पविराम से अलग की गई सूची में बदलें

जब आप अल्पविराम, अर्धविराम या किसी अन्य सीमांकक द्वारा मानों को अलग करने वाली लंबवत सूची को जोड़ना चाहते हैं, तो TEXTJOIN उपयोग करने के लिए सही कार्य है।

इस उदाहरण के लिए, हम नीचे दी गई तालिका से प्रत्येक टीम की जीत और हार को जोड़ेंगे। यह निम्नलिखित सूत्रों के साथ किया जा सकता है, जो केवल जुड़ने वाली कोशिकाओं की श्रेणी में भिन्न होते हैं।

टीम 1 के लिए:

=TEXTJOIN(",", FALSE, B2:B6)

टीम 2 के लिए:

=TEXTJOIN(",", FALSE, C2:C6)

और इसी तरह।

सभी सूत्रों में, निम्नलिखित तर्कों का उपयोग किया जाता है:

• सीमांकक - a कॉमा (",").
• Ignore_empty को खाली सेल शामिल करने के लिए FALSE पर सेट किया गया है क्योंकि हमें यह दिखाने की आवश्यकता है कि कौन से गेम नहीं खेले गए थे।

जैसा कि परिणामस्वरूप, आपको चार अल्पविराम से अलग की गई सूचियाँ मिलेंगी जो कॉम्पैक्ट रूप में प्रत्येक टीम की जीत और हार का प्रतिनिधित्व करती हैं:

विभिन्न परिसीमकों वाले कक्षों को जोड़ें

ऐसी स्थिति में जब आपको विभिन्न परिसीमकों के साथ संयुक्त मानों को अलग करने की आवश्यकता हो, तो आप या तो एक सरणी स्थिरांक के रूप में कई परिसीमकों की आपूर्ति कर सकते हैं या प्रत्येक सीमांकक को एक अलग कक्ष में इनपुट कर सकते हैं और सीमांकक तर्क के लिए एक श्रेणी संदर्भ का उपयोग करें।

मान लें कि आप अलग-अलग नाम वाले सेल में शामिल होना चाहते हैं और इस प्रारूप में परिणाम प्राप्त करना चाहते हैं: अंतिम नाम , प्रथम नाम मध्य नाम ।

जैसा कि आप देख सकते हैं, अंतिम नाम और प्रथम नाम अल्पविराम और एक रिक्ति (", ") द्वारा अलग किए जाते हैं जबकि प्रथम नाम और मध्य नाम एक रिक्ति द्वारा अलग किए जाते हैं (" ") केवल। इसलिए, हम इन दो परिसीमकों को एक सरणी स्थिरांक {", "," "} में शामिल करते हैं और निम्नलिखित सूत्र प्राप्त करते हैं:

=TEXTJOIN({", "," "}, TRUE, A2:C2)

कहाँ A2:C2 संयुक्त किए जाने वाले नाम भाग हैं।

वैकल्पिक रूप से, आप कुछ रिक्त कक्षों में उद्धरण चिह्नों के बिना सीमांकक टाइप कर सकते हैं (जैसे, F3 में एक अल्पविराम और एक स्थान और G3 में एक स्थान) और $F$3:$G$3 श्रेणी का उपयोग करें (कृपया ध्यान दें निरपेक्ष सेल संदर्भ) सीमांकक तर्क के लिए:

=TEXTJOIN($F$3:$G$3, TRUE, A2:C2)

इस सामान्य दृष्टिकोण का उपयोग करके, आप विभिन्न रूपों में सेल सामग्री को मर्ज कर सकते हैं।

उदाहरण के लिए, यदि आप परिणाम प्रथम नाम मध्य प्रारंभिक अंतिम नाम प्रारूप में चाहते हैं, तो पहले वर्ण (प्रारंभिक) को निकालने के लिए LEFT फ़ंक्शन का उपयोग करें सेल C2 से। सीमांकक के लिए, हम पहले नाम और मध्य प्रारंभिक के बीच एक स्थान (" ") रखते हैं; एकप्रारंभिक और अंतिम नाम के बीच की अवधि और एक स्थान ("।"):

=TEXTJOIN({" ",". "}, TRUE, B2, LEFT(C2,1), A2)

Excel में पाठ और तिथियों को जोड़ें

एक विशिष्ट मामले में जब आप विलय कर रहे हों पाठ और दिनांक, सीधे TEXTJOIN सूत्र को दिनांक प्रदान करने से काम नहीं चलेगा। जैसा कि आपको याद होगा, एक्सेल तारीखों को सीरियल नंबर के रूप में स्टोर करता है, इसलिए आपका फॉर्मूला नीचे दिए गए स्क्रीनशॉट में दिखाए गए अनुसार तारीख का प्रतिनिधित्व करने वाला एक नंबर लौटाएगा:

=TEXTJOIN(" ", TRUE, A2:B2)

इसे ठीक करने के लिए, आपको कनवर्ट करने की आवश्यकता है इसमें शामिल होने से पहले एक टेक्स्ट स्ट्रिंग में दिनांक। और यहाँ वांछित प्रारूप कोड (हमारे मामले में "mm/dd/yyyy") के साथ TEXT फ़ंक्शन काम आता है:

=TEXTJOIN(" ", TRUE, A2, TEXT(B2, "mm/dd/yyyy"))

लाइन ब्रेक के साथ टेक्स्ट मर्ज करें

यदि आप एक्सेल में टेक्स्ट को मर्ज करना चाहते हैं ताकि प्रत्येक मान एक नई पंक्ति में शुरू हो, तो CHAR(10) को सीमांकक के रूप में उपयोग करें (जहां 10 एक लाइनफीड वर्ण है)।

उदाहरण के लिए, टेक्स्ट को संयोजित करने के लिए कक्ष A2 और B2 एक पंक्ति विराम द्वारा मानों को अलग करते हैं, यह उपयोग करने का सूत्र है:

=TEXTJOIN(CHAR(10), TRUE, A2:B2)

युक्ति। ऊपर दिए गए स्क्रीनशॉट में दिखाए गए परिणाम को कई पंक्तियों में प्रदर्शित करने के लिए, सुनिश्चित करें कि रैप टेक्स्ट सुविधा चालू है।

TEXTJOIN IF को शर्तों के साथ टेक्स्ट मर्ज करना है

एक्सेल TEXTJOIN की स्ट्रिंग्स की सरणी को संभालने की क्षमता के कारण, इसका उपयोग सशर्त रूप से दो या अधिक सेल की सामग्री को मर्ज करने के लिए भी किया जा सकता है। ऐसा करने के लिए, सेल की एक श्रेणी का मूल्यांकन करने के लिए IF फ़ंक्शन का उपयोग करें और text1 के तर्क की शर्त को पूरा करने वाले मानों की एक सरणी वापस करें।TEXTJOIN।

नीचे स्क्रीनशॉट में दिखाई गई तालिका से, मान लीजिए कि आप टीम 1 सदस्यों की सूची प्राप्त करना चाहते हैं। इसे प्राप्त करने के लिए, निम्नलिखित IF स्टेटमेंट को text1 तर्क में नेस्ट करें:

IF($B$2:$B$9=1, $A$2:$A$9, "")

सामान्य अंग्रेजी में, उपरोक्त सूत्र कहता है: यदि कॉलम B 1 के बराबर है, तो रिटर्न a एक ही पंक्ति में स्तंभ A से मान; अन्यथा एक खाली स्ट्रिंग वापस करें।

टीम 1 के लिए पूर्ण सूत्र इस आकार को लेता है:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=1, $A$2:$A$9, ""))

इसी तरह, आप एक प्राप्त कर सकते हैं टीम 2:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=2, $A$2:$A$9, ""))

के सदस्यों की अल्पविराम से अलग की गई सूची नोट। एक्सेल 365 और 2021 में उपलब्ध डायनेमिक एरेज़ फीचर के कारण, यह एक नियमित सूत्र के रूप में काम करता है, जैसा कि ऊपर स्क्रीनशॉट में दिखाया गया है। एक्सेल 2019 में, आपको इसे Ctrl + Shift + Enter शॉर्टकट दबाकर एक पारंपरिक सरणी सूत्र के रूप में दर्ज करना होगा। एक्सेल VLOOKUP फ़ंक्शन केवल पहला पाया गया मिलान लौटा सकता है। लेकिन क्या होगा यदि आपको किसी विशिष्ट आईडी, एसकेयू, या कुछ और के लिए सभी मिलान प्राप्त करने की आवश्यकता है?

परिणामों को अलग-अलग सेल में आउटपुट करने के लिए, Excel में एकाधिक मानों को VLOOKUP कैसे करें में वर्णित सूत्रों में से किसी एक का उपयोग करें।

अल्पविराम से अलग की गई सूची के रूप में एकल सेल में सभी मेल खाने वाले मानों को देखने और वापस करने के लिए, TEXTJOIN IF सूत्र का उपयोग करें। किसी दिए गए विक्रेता द्वारा नमूना तालिका से खरीदे गए उत्पादनीचे। यह निम्नलिखित सूत्र के साथ आसानी से किया जा सकता है:

=TEXTJOIN(", ", TRUE, IF($A$2:$A$12=D2, $B$2:$B$12, ""))

जहां A2:A12 विक्रेता के नाम हैं, B2:B12 उत्पाद हैं, और D2 ब्याज का विक्रेता है।

उपरोक्त सूत्र E2 में जाता है और D2 (एडम) में लक्षित विक्रेता के लिए सभी मैच लाता है। रिश्तेदार (लक्षित विक्रेता के लिए) और पूर्ण (विक्रेता के नाम और उत्पादों के लिए) सेल संदर्भों के चतुर उपयोग के कारण, सूत्र सही ढंग से नीचे की कोशिकाओं में कॉपी हो जाता है और अन्य दो विक्रेताओं के लिए भी अच्छी तरह से काम करता है:

टिप्पणी। पिछले उदाहरण की तरह, यह Excel 365 और 2021 में एक नियमित सूत्र के रूप में और Excel 2019 में CSE सूत्र (Ctrl + Shift + Enter ) के रूप में काम करता है।

सूत्र का तर्क ठीक वैसा ही है जैसा कि इसमें है पिछला उदाहरण:

IF कथन A2:A12 में प्रत्येक नाम की तुलना D2 में लक्ष्य नाम से करता है (हमारे मामले में एडम):

IF($A$2:$A$12=D2, $B$2:$B$12, "")

यदि तार्किक परीक्षण मूल्यांकन करता है TRUE (यानी D2 में नाम कॉलम A में नाम से मेल खाता है), सूत्र कॉलम B से उत्पाद लौटाता है; अन्यथा एक खाली स्ट्रिंग ("") वापस आ जाती है। IF का परिणाम निम्नलिखित सरणी है:

{"";"";"Bananas";"Apples";"";"";"";"Oranges";"";"Lemons";""}

सरणी TEXTJOIN फ़ंक्शन में text1 तर्क के रूप में जाती है। और क्योंकि TEXTJOIN को अल्पविराम और एक स्थान (", ") के साथ मानों को अलग करने के लिए कॉन्फ़िगर किया गया है, हमें यह स्ट्रिंग अंतिम परिणाम के रूप में मिलती है:

केले, सेब, संतरे, नींबू

Excel TEXTJOIN काम नहीं कर रहा है

जब आपके TEXTJOIN फॉर्मूले में कोई त्रुटि होती है, तो इसकी सबसे अधिक संभावना हैनिम्न में से एक होने के लिए:

• #NAME? त्रुटि तब होती है जब TEXTJOIN का उपयोग Excel के पुराने संस्करण में किया जाता है जहां यह फ़ंक्शन समर्थित नहीं है (2019 से पहले) या जब फ़ंक्शन का नाम गलत लिखा गया हो।
• #VALUE! त्रुटि तब होती है जब परिणामी स्ट्रिंग 32,767 वर्णों से अधिक हो जाती है।
• #VALUE! त्रुटि तब भी हो सकती है जब एक्सेल सीमांकक को पाठ के रूप में नहीं पहचानता है, उदाहरण के लिए यदि आप कुछ गैर-मुद्रण योग्य वर्ण जैसे CHAR(0) प्रदान करते हैं।

एक्सेल में टेक्स्टजॉइन फ़ंक्शन का उपयोग कैसे करें पढ़ने के लिए मैं आपको धन्यवाद देता हूं और आशा करता हूं कि अगले सप्ताह आप हमारे ब्लॉग पर मिलेंगे!

उपलब्ध डाउनलोड

Excel TEXTJOIN सूत्र उदाहरण