Преглед садржаја
Упутство показује како да користите функцију ТЕКСТЈОИН за спајање текста у Екцел-у са практичним примерима.
До недавно су постојале две преовлађујуће методе за спајање садржаја ћелије у Екцел-у: конкатенација оператор и функција ЦОНЦАТЕНАТЕ. Са увођењем ТЕКСТЈОИН-а, чини се да се појавила моћнија алтернатива, која вам омогућава да спојите текст на флексибилнији начин, укључујући било који граничник између. Али у ствари, има много више од тога!
Екцел функција ТЕКСТЈОИН
ТЕКСТЈОИН у Екцел-у спаја текстуалне низове из више ћелија или опсега и раздваја комбиноване вредности било којим граничником које наведете. Може да игнорише или укључи празне ћелије у резултат.
Функција је доступна у Екцел-у за Оффице 365, Екцел 2021 и Екцел 2019.
Синтакса функције ТЕКСТЈОИН је следећа :
ТЕКСТЈОИН(делимитер, игноре_емпти, тект1, [тект2], …)Где:
- Разгранич (обавезно) - је сепаратор између сваке текстуалне вредности које комбинујеш. Обично се испоручује као текстуални низ затворен у двоструким наводницима или референца на ћелију која садржи текстуални низ. Број наведен као граничник се третира као текст.
- Игноре_емпти (обавезно) - Одређује да ли да се игноришу празне ћелије или не:
- ТРУЕ - игнорише све празне ћелије.
- ФАЛСЕ - укључи празне ћелије у резултујући низ.
- Текст1 (обавезно) - прва вредност за придруживање. Може се доставити као текстуални низ, референца на ћелију која садржи стринг или низ стрингова као што је опсег ћелија.
- Текст2 , … (опционо) - додатне текстуалне вредности да се споје заједно. Дозвољена су највише 252 текстуална аргумента, укључујући текст1 .
На пример, хајде да комбинујемо делове адресе из ћелија Б2, Ц2 и Д2 заједно у једну ћелију, раздвајајући вредности са зарезом и размаком:
Код функције ЦОНЦАТЕНАТЕ, требало би да наведете сваку ћелију појединачно и да ставите граничник (", ") после сваке референце, што би могло да смета при спајању садржаја многих ћелије:
=CONCATENATE(A2, ", ", B2, ", ", C2)
Код Екцел ТЕКСТЈОИН, само једном наведете граничник у првом аргументу и доставите опсег ћелија за трећи аргумент:
=TEXTJOIN(", ", TRUE, A2:C2) 
ТЕКСТЈОИН у Екцел-у – 6 ствари које треба запамтити
Да бисте ефикасно користили ТЕКСТЈОИН у својим радним листовима, треба обратити пажњу на неколико важних тачака:
- ТЕКСТЈОИН је нова функцију, која је доступна само у програму Екцел 2019 – Екцел 365. У ранијим верзијама програма Екцел, користите функцију ЦОНЦАТЕНАТЕ или „&амп;“ уместо оператора.
- У новим верзијама ако је Екцел, такође можете да користите функцију ЦОНЦАТ да повежете вредности из засебних ћелија и опсега, али без опција за граничнике или празне ћелије.
- Било који број наведен на ТЕКСТЈОИН за разгранич или текст аргументи се конвертују у текст.
- Ако делимитер није наведен или је празан стринг (""), текстуалне вредности се спајају без икаквог граничника.
- Функција може рукују до 252 текстуална аргумента.
- Резултирајући стринг може да садржи највише 32.767 знакова, што је ограничење ћелије у Екцел-у. Ако је ово ограничење прекорачено, формула ТЕКСТЈОИН враћа #ВАЛУЕ! грешка.
Како спојити текст у Екцел-у – примери формуле
Да бисмо боље разумели све предности ТЕКСТЈОИН-а, хајде да погледамо како да користите функцију у стварним сценаријима .
Конвертујте колону у листу раздвојену зарезима
Када желите да повежете вертикалну листу одвајајући вредности зарезом, тачком и зарезом или било којим другим граничником, ТЕКСТЈОИН је права функција за коришћење.
За овај пример, спојићемо победе и поразе сваког тима из табеле испод. Ово се може урадити помоћу следећих формула, које се разликују само по опсегу ћелија које се спајају.
За тим 1:
=TEXTJOIN(",", FALSE, B2:B6)
За тим 2:
=TEXTJOIN(",", FALSE, C2:C6)
И тако даље.
У свим формулама се користе следећи аргументи:
- Разгранич - а зарез (",").
- Игноре_емпти је подешен на ФАЛСЕ да укључи празне ћелије јер морамо да покажемо које игре нису игране.
Као као резултат, добићете четири листе раздвојене зарезима које представљају победе и поразе сваког тима у компактном облику: 
Споји ћелије са различитим граничницима
У ситуацији када треба да одвојите комбиноване вредности различитим граничницима, можете или да унесете неколико граничника као константу низа или да унесете сваки граничник у посебну ћелију и користите референцу опсега за аргумент делимитер .
Претпоставимо да желите да спојите ћелије које садрже различите делове имена и добијете резултат у овом формату: Презиме , Име Средње име .
Као што видите, презиме и име су одвојени зарезом и размаком (", "), док су име и средње име размаком само (" "). Дакле, ми укључујемо ова два граничника у константу низа {", "," "} и добијамо следећу формулу:
=TEXTJOIN({", "," "}, TRUE, A2:C2)
Где су А2:Ц2 делови имена који се комбинују.
Алтернативно, можете да откуцате граничнике без наводника у неке празне ћелије (рецимо, зарез и размак у Ф3 и размак у Г3) и да користите опсег $Ф$3:$Г$3 (имајте на уму апсолутне референце ћелије) за аргумент делимитер :
=TEXTJOIN($F$3:$G$3, TRUE, A2:C2) 
Користећи овај општи приступ, можете спојити садржај ћелије у различитим облицима.
На пример, ако желите резултат у формату Име Средњи почетни Презиме , онда користите функцију ЛЕФТ да издвојите први знак (иницијал) из ћелије Ц2. Што се тиче граничника, стављамо размак (" ") између имена и средњег слова; атачка и размак (". ") између почетног и презимена:
=TEXTJOIN({" ",". "}, TRUE, B2, LEFT(C2,1), A2) 
Уједините текст и датуме у Екцел-у
У одређеном случају када спајате текста и датума, достављање датума директно у формулу ТЕКСТЈОИН неће радити. Као што се можда сећате, Екцел чува датуме као серијске бројеве, тако да ће ваша формула вратити број који представља датум као што је приказано на слици испод:
=TEXTJOIN(" ", TRUE, A2:B2) 
Да бисте ово поправили, морате да конвертујете датум у текстуални низ пре него што му се придружи. И овде је згодна функција ТЕКСТ са кодом жељеног формата („мм/дд/гггг“ у нашем случају):
=TEXTJOIN(" ", TRUE, A2, TEXT(B2, "mm/dd/yyyy")) 
Споји текст са преломима редова
Ако желите да спојите текст у Екцел-у тако да свака вредност почиње у новом реду, користите ЦХАР(10) као граничник (где је 10 знак за увод у ред).
На пример, да бисте комбиновали текст из ћелије А2 и Б2 које одвајају вредности преломом реда, ово је формула коју треба користити:
=TEXTJOIN(CHAR(10), TRUE, A2:B2) 
Савет. Да би се резултат приказао у више редова као што је приказано на слици изнад, уверите се да је укључена функција Преламање текста.
ТЕКСТЈОИН ИФ за спајање текста са условима
Због способности програма Екцел ТЕКСТЈОИН да рукује низовима стрингова, може се користити и за условно спајање садржаја две или више ћелија. Да бисте то урадили, користите функцију ИФ да процените опсег ћелија и вратите низ вредности које испуњавају услов у аргумент тект1 ТЕКСТЈОИН.
Из табеле приказане на слици испод, претпоставимо да желите да преузмете листу чланова Тима 1 . Да бисте то постигли, угнездите следећу ИФ изјаву у аргумент тект1 :
IF($B$2:$B$9=1, $A$2:$A$9, "")
На једноставном енглеском, горња формула каже: Ако је колона Б једнака 1, вратите а вредност из колоне А у истом реду; у супротном врати празан стринг.
Комплетна формула за Тим 1 има овај облик:
=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=1, $A$2:$A$9, ""))
На сличан начин можете добити Листа чланова Тима 2 раздвојених зарезима:
=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=2, $A$2:$A$9, "")) 
Напомена. Због функције динамичких низова која је доступна у Екцел 365 и 2021, ово функционише као обична формула, приказана на слици изнад. У Екцел 2019, морате је унети као традиционалну формулу низа притиском на пречицу Цтрл + Схифт + Ентер.
Потражите и вратите више подударања у листи раздвојених зарезима
Као што вероватно знате, Екцел функција ВЛООКУП може да врати само прво пронађено подударање. Али шта ако треба да добијете сва подударања за одређени ИД, СКУ или нешто друго?
Да бисте објавили резултате у одвојеним ћелијама, користите једну од формула описаних у Како да ВЛООКУП више вредности у Екцел-у.
Да бисте потражили и вратили све одговарајуће вредности у једној ћелији као листу раздвојену зарезима, користите формулу ТЕКСТЈОИН ИФ.
Да бисте видели како то функционише у пракси, хајде да преузмемо листу производи које је купио дати продавац из табеле узоракаиспод. Ово се лако може урадити следећом формулом:
=TEXTJOIN(", ", TRUE, IF($A$2:$A$12=D2, $B$2:$B$12, ""))
Где су А2:А12 имена продавца, Б2:Б12 су производи, а Д2 је продавац од интереса.
Горе наведена формула иде на Е2 и доноси све утакмице за циљног продавца у Д2 (Адам). Због паметне употребе релативних (за циљног продавца) и апсолутних (за имена продавца и производе) референци на ћелије, формула се исправно копира у ћелије испод и добро функционише и за друга два продавца: 
Белешка. Као и са претходним примером, ово функционише као обична формула у Екцел 365 и 2021, и као ЦСЕ формула (Цтрл + Схифт + Ентер ) у Екцел 2019.
Логика формуле је потпуно иста као у претходни пример:
ИФ израз упоређује свако име у А2:А12 са циљним именом у Д2 (Адам у нашем случају):
IF($A$2:$A$12=D2, $B$2:$B$12, "")
Ако логички тест процењује на ТРУЕ (тј. име у Д2 одговара имену у колони А), формула враћа производ из колоне Б; у супротном се враћа празан стринг (""). Резултат ИФ је следећи низ:
{"";"";"Bananas";"Apples";"";"";"";"Oranges";"";"Lemons";""}
Низ иде у функцију ТЕКСТЈОИН као аргумент тект1 . А пошто је ТЕКСТЈОИН конфигурисан да одваја вредности зарезом и размаком (", "), добијамо овај низ као коначни резултат:
Банане, Апплес, Орангес, Лемонс
Екцел ТЕКСТЈОИН не ради
Када ваша ТЕКСТЈОИН формула резултира грешком, највероватниједа буде једно од следећег:
- #НАМЕ? грешка се јавља када се ТЕКСТЈОИН користи у старијој верзији Екцел-а где ова функција није подржана (пре 2019.) или када је име функције погрешно написано.
- #ВАЛУЕ! грешка се јавља ако резултујући стринг премашује 32.767 знакова.
- #ВАЛУЕ! грешка се такође може појавити ако Екцел не препозна граничник као текст, на пример ако унесете неки знак који се не може штампати као што је ЦХАР(0).
Тако се користи функција ТЕКСТЈОИН у Екцел-у. Захваљујем вам што сте читали и надам се да се видимо на нашем блогу следеће недеље!
Доступна преузимања
Примери формуле ТЕКСТЈОИН у Екцел-у
