La lernilo montras kiel uzi la funkcion TEXTJOIN por kunfandi tekston en Excel kun praktikaj ekzemploj.

Ĝis antaŭ nelonge, ekzistis du ĝeneralaj metodoj por kunfandi ĉelenhavojn en Excel: la kunkatego funkciigisto kaj CONCATENATE-funkcio. Kun la enkonduko de TEXTJOIN, ŝajnas, ke pli potenca alternativo aperis, kiu ebligas vin kunigi tekston en pli fleksebla maniero inkluzive de iu ajn limigo intere. Sed vere, estas multe pli al ĝi!

Excel TEXTJOIN-funkcio

TEXTJOIN en Excel kunfandas tekstajn ĉenojn de pluraj ĉeloj aŭ intervaloj kaj apartigas la kombinitajn valorojn per iu ajn limigilo. ke vi specifas. Ĝi povas aŭ ignori aŭ inkluzivi malplenajn ĉelojn en la rezulto.

La funkcio estas disponebla en Excel por Office 365, Excel 2021, kaj Excel 2019.

La sintakso de la funkcio TEXTJOIN estas jena :

Kie:

• Limigilo (postulata) - estas apartigilo inter ĉiu tekstvaloro ke vi kombinas. Kutime, ĝi estas liverita kiel teksta ĉeno enfermita inter citiloj aŭ referenco al ĉelo enhavanta tekstoĉenon. Numero provizita kiel limigilo estas traktata kiel teksto.
• Ignori_malplenan (postulata) - Determinas ĉu ignori malplenajn ĉelojn aŭ ne:
  • VERA - ignoru iujn malplenajn ĉelojn.
  • FALSA - inkluzivu malplenajn ĉelojn en la rezulta ĉeno.
• Teksto1 (bezonata) - unua valoro aliĝi. Povas esti liverita kiel teksta ĉeno, referenco al ĉelo enhavanta ĉenon, aŭ tabelo da ĉenoj kiel gamo da ĉeloj.
• Teksto2 , … (laŭvola) - kromaj tekstovaloroj esti kunigitaj. Maksimume 252 tekstaj argumentoj estas permesitaj, inkluzive de teksto1 .

Ekzemple, ni kombinu adrespartojn de ĉeloj B2, C2 kaj D2 kune en unu ĉelon, apartigante la valorojn. kun komo kaj spaco:

Kun la funkcio CONCATENATE, vi bezonus specifi ĉiun ĉelon individue kaj meti limigilon (", ") post ĉiu referenco, kio povus esti ĝena dum kunfandado de la enhavo de multaj ĉeloj:

=CONCATENATE(A2, ", ", B2, ", ", C2)

Kun Excel TEXTJOIN, vi specifas la limigilon nur unufoje en la unua argumento, kaj provizas gamon da ĉeloj por la tria argumento:

=TEXTJOIN(", ", TRUE, A2:C2)

TEXTJOIN en Excel - 6 memorindaj aferoj

Por efike uzi TEXTJOIN en viaj laborfolioj, estas kelkaj gravaj punktoj pri kiuj atentu:

1. TEXTJOIN estas nova funkcio, kiu disponeblas nur en Excel 2019 - Excel 365. En pli fruaj Excel-versioj, bonvolu uzi la funkcion CONCATENATE aŭ la "&" operatoro anstataŭe.
2. En novaj versioj se Excel, vi ankaŭ povas uzi la CONCAT-funkcion por kunligi valorojn de apartaj ĉeloj kaj intervaloj, sed sen opcioj por limigiloj aŭ malplenaj ĉeloj.
3. Ajna nombro provizita. al TEXTJOIN por la limigilo aŭ teksto argumentoj estas konvertitaj al teksto.
4. Se limigilo ne estas specifita aŭ estas malplena ĉeno (""), tekstvaloroj estas kunligitaj sen ia limigilo.
5. La funkcio povas pritrakti ĝis 252 tekstajn argumentojn.
6. La rezulta ĉeno povas enhavi maksimume 32 767 signojn, kio estas la ĉellimo en Excel. Se ĉi tiu limo estas superita, TEXTJOIN-formulo liveras la #VALORO! eraro.

Kiel kunigi tekston en Excel - formulaj ekzemploj

Por pli bone kompreni ĉiujn avantaĝojn de TEXTJOIN, ni rigardu kiel uzi la funkcion en realaj scenaroj. .

Konverti kolumnon al komo-disigita listo

Kiam vi celas kunligi vertikalan liston apartigantan la valorojn per komo, punktokomo aŭ ajna alia limigo, TEXTJOIN estas la ĝusta funkcio por uzi.

Por ĉi tiu ekzemplo, ni kunmetos venkojn kaj perdojn de ĉiu teamo el la suba tabelo. Ĉi tio povas esti farita per la sekvaj formuloj, kiuj diferencas nur en la gamo de ĉeloj kunigitaj.

Por Teamo 1:

=TEXTJOIN(",", FALSE, B2:B6)

Por Teamo 2:

=TEXTJOIN(",", FALSE, C2:C6)

Kaj tiel plu.

En ĉiuj formuloj estas uzataj jenaj argumentoj:

• Limigilo - a komo (",").
• Ignore_empty estas agordita al FALSO por inkluzivi malplenajn ĉelojn ĉar ni devas montri kiuj ludoj ne estis luditaj.

Kiel la rezulto, vi ricevos kvar komojn disigitajn listojn, kiuj reprezentas venkojn kaj perdojn de ĉiu teamo en kompakta formo:

Kunigi ĉelojn kun malsamaj limigiloj

En situacio, kiam vi bezonas apartigi la kombinitajn valorojn per malsamaj limigiloj, vi povas aŭ provizi plurajn limigilojn kiel tabelkonstanto aŭ enigi ĉiun limigilon en aparta ĉelo. kaj uzu intervalreferencon por la argumento limigilo .

Supoze, ke vi volas kunigi ĉelojn enhavantajn malsamajn nompartojn kaj ricevi la rezulton en ĉi tiu formato: Familinomo , Familinomo kaj Meznomo .

Kiel vi povas vidi, la Familia nomo kaj Antaŭnomo estas apartigitaj per komo kaj spaco (", ") dum la Antaŭnomo kaj Meznomo per spaco (" ") nur. Do, ni inkluzivas ĉi tiujn du limigilojn en tabelkonstanto {", "," "} kaj ricevas la jenan formulon:

=TEXTJOIN({", "," "}, TRUE, A2:C2)

Kie A2:C2 estas la nompartoj kombinotaj.

Alternative, vi povas tajpi la limigilojn sen citiloj en iuj malplenaj ĉeloj (ekzemple, komo kaj spaco en F3 kaj spaco en G3) kaj uzi la intervalon $F$3:$G$3 (bonvolu atenti la absolutaj ĉelaj referencoj) por la argumento limigilo :

=TEXTJOIN($F$3:$G$3, TRUE, A2:C2)

Uzante ĉi tiun ĝeneralan aliron, vi povas kunfandi ĉelenhavojn en diversaj formoj.

Ekzemple, se vi volas la rezulton en la formato Antnomo Meza komenca Familinomo , tiam uzu la funkcion LEFT por ĉerpi la unuan signon (la komencan) de ĉelo C2. Koncerne la limigilojn, ni metas spacon (" ") inter la Antaŭnomo kaj la Meza inicialo; apunkto kaj spaco ("". ") inter la Komenca kaj la Familia nomo:

=TEXTJOIN({" ",". "}, TRUE, B2, LEFT(C2,1), A2)

Kunigu tekston kaj datojn en Excel

En specifa kazo kiam vi kunfandas teksto kaj datoj, liverado de datoj rekte al TEXTJOIN-formulo ne funkcios. Kiel vi eble memoras, Excel konservas datojn kiel seriajn numerojn, do via formulo redonos nombron reprezentantan la daton kiel montrite en la ekrankopio sube:

=TEXTJOIN(" ", TRUE, A2:B2)

Por ripari tion, vi devas konverti la dato en tekstan ĉenon antaŭ ol kunigi ĝin. Kaj ĉi tie la TEKSTO-funkcio kun la dezirata formatkodo ("mm/dd/jjyy" en nia kazo) utilas:

=TEXTJOIN(" ", TRUE, A2, TEXT(B2, "mm/dd/yyyy"))

Kunfandi tekston kun liniorompoj

Se vi ŝatus kunfandi tekston en Excel, por ke ĉiu valoro komenciĝu en nova linio, uzu CHAR(10) kiel limigilon (kie 10 estas linipaŝa signo).

Ekzemple, por kombini tekston de ĉeloj A2 kaj B2 disigante la valorojn per linio-rompo, jen la formulo por uzi:

=TEXTJOIN(CHAR(10), TRUE, A2:B2)

Konsilo. Por ke la rezulto aperu en pluraj linioj kiel montrite en la supra ekrankopio, certigu, ke la funkcio Envolvi tekston estas ŝaltita.

TEXTJOIN IF por kunfandi tekston kun kondiĉoj

Pro la kapablo de Excel TEXTJOIN pritrakti tabelojn de ĉenoj, ĝi ankaŭ povas esti uzata por kondiĉe kunfandi la enhavon de du aŭ pli da ĉeloj. Por fari ĝin, uzu la IF-funkcion por taksi gamon da ĉeloj kaj redoni tabelon da valoroj, kiuj plenumas la kondiĉon al la argumento text1 deTEXTJOIN.

El la tabelo montrita en la ekrankopio malsupre, supozu, ke vi volas preni liston de membroj de Teamo 1 . Por atingi ĉi tion, nestu la sekvan IF-deklaron en la argumenton text1 :

IF($B$2:$B$9=1, $A$2:$A$9, "")

En simpla angla, la supra formulo diras: Se kolumno B egalas 1, redonu a. valoro de kolumno A en la sama vico; alie redonu malplenan ĉenon.

La kompleta formulo por Teamo 1 prenas ĉi tiun formon:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=1, $A$2:$A$9, ""))

Simile, vi povas akiri komo-disigita listo de la membroj de Teamo 2:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=2, $A$2:$A$9, ""))

Noto. Pro la funkcio Dynamic Arrays disponebla en Excel 365 kaj 2021, ĉi tio funkcias kiel regula formulo, montrita en la supra ekrankopio. En Excel 2019, vi devas enigi ĝin kiel tradician tabelan formulon premante la ŝparvojon Ctrl + Shift + Enigu.

Serĉu kaj redonu plurajn kongruojn en komo-disigita listo

Kiel vi verŝajne scias, la Excel VLOOKUP-funkcio povas nur redoni la unuan trovitan kongruon. Sed kio se vi bezonas akiri ĉiujn kongruojn por specifa identigilo, SKU aŭ io alia?

Por eligi la rezultojn en apartaj ĉeloj, uzu unu el la formuloj priskribitaj en Kiel VLOOKUP plurajn valorojn en Excel.

Por serĉi kaj redoni ĉiujn kongruajn valorojn en ununura ĉelo kiel liston per komo apartigita, uzu la formulon TEXTJOIN IF.

Por vidi kiel ĝi funkcias praktike, ni prenu liston de produktoj aĉetitaj de donita vendisto de la specimena tabelomalsupre. Ĉi tio povas esti facile farita per la jena formulo:

=TEXTJOIN(", ", TRUE, IF($A$2:$A$12=D2, $B$2:$B$12, ""))

Kie A2:A12 estas vendistaj nomoj, B2:B12 estas produktoj, kaj D2 estas la interesa vendanto.

La supra formulo iras al E2 kaj alportas ĉiujn matĉojn por la celvendisto en D2 (Adam). Pro la lerta uzo de relativaj (por la celvendisto) kaj absolutaj (por la vendistaj nomoj kaj produktoj) ĉelaj referencoj, la formulo ĝuste kopias al la subaj ĉeloj kaj bone funkcias ankaŭ por la aliaj du vendistoj:

Notu. Kiel ĉe la antaŭa ekzemplo, ĉi tio funkcias kiel regula formulo en Excel 365 kaj 2021, kaj kiel CSE-formulo (Ctrl + Shift + Enigu ) en Excel 2019.

La logiko de la formulo estas ĝuste la sama kiel en la antaŭa ekzemplo:

La deklaro IF komparas ĉiun nomon en A2:A12 kontraŭ la celnomo en D2 (Adam en nia kazo):

IF($A$2:$A$12=D2, $B$2:$B$12, "")

Se la logika testo taksas al VERA (t.e. la nomo en D2 kongruas kun la nomo en kolumno A), la formulo resendas produkton de kolumno B; alie malplena ĉeno ("") estas resendita. La rezulto de SE estas la sekva tabelo:

{"";"";"Bananas";"Apples";"";"";"";"Oranges";"";"Lemons";""}

La tabelo iras al la funkcio TEXTJOIN kiel la argumento teksto1 . Kaj ĉar TEXTJOIN estas agordita por apartigi la valorojn per komo kaj spaco (", "), ni ricevas ĉi tiun ĉenon kiel la fina rezulto:

Bananoj, Pomoj, Oranĝoj, Citronoj

Excel TEXTJOIN ne funkcias

Kiam via TEXTJOIN-formulo rezultigas eraron, estas plej verŝajneesti unu el la jenaj:

• #NOMO? eraro okazas kiam TEXTJOIN estas uzata en pli malnova versio de Excel kie ĉi tiu funkcio ne estas subtenata (antaŭ 2019) aŭ kiam la nomo de la funkcio estas misliterumita.
• #VALUE! eraro okazas se la rezulta ĉeno superas 32 767 signojn.
• #VALUE! eraro ankaŭ povas okazi se Excel ne rekonas la limigilon kiel tekston, ekzemple se vi provizas iun neprinteblan signon kiel CHAR(0).

Tiel estas kiel uzi la funkcion TEXTJOIN en Excel. Mi dankas vin pro legado kaj esperas vidi vin en nia blogo venontsemajne!

Haveblaj elŝutoj

Excel TEXTJOIN formulekzemploj