Google E-Tablolar'da kelime ve karakter sayısı nadir durumlarda kullanılsa da, yine de bazılarımızın menüde görmeyi beklediği bir işlevdir. Ancak Google Dokümanlar'ın aksine, Google E-Tablolar'da bunu yapan LEN işlevidir.

E-tablolarda karakter saymanın birçok farklı yolu olsa da, bugünkü blog yazımızda LEN fonksiyonunu ele alacağız, çünkü bu fonksiyonun tablolardaki temel amacı saymaktır :) Ancak, tek başına neredeyse hiç kullanılmaz. Aşağıda Google E-Tablolar LEN'i nasıl doğru kullanacağınızı öğrenecek ve e-tablolarda karakter hesaplamak için en çok aranan formülleri bulacaksınız.

Google E-Tablolar LEN işlevi - kullanım ve sözdizimi

Google E-Tablolar'daki LEN fonksiyonunun ana ve tek amacı dize uzunluğunu elde etmektir. O kadar basittir ki sadece 1 argüman gerektirir:

• metnin kendisini çift tırnak içinde alabilir:

  =LEN("Yggdrasil")

• veya ilgilenilen metni içeren bir hücreye başvuru:

  =LEN(A2)

Elektronik tablolarda fonksiyonun kullanımında herhangi bir özellik olup olmadığını görelim.

Google E-Tablolar'da karakter sayısı

En basit işlemle başlayacağım: Google E-Tablolar'da karakter sayımını en yaygın şekilde, LEN işlevini kullanarak metnin bulunduğu hücreye referans vererek yapın.

Formülü B2'ye giriyorum ve her satırdaki karakterleri saymak için tüm sütuna kopyalıyorum:

=LEN(A2)

Not: LEN işlevi tüm karakterleri hesaplar: harfler, sayılar, boşluklar, noktalama işaretleri, vb.

Benzer bir şekilde tüm hücre aralığı için karakter sayımı yapabileceğinizi düşünebilirsiniz, bunun gibi: LEN(A2:A6) Ancak, ne kadar tuhaf olsa da, işler bu şekilde yürümüyor.

Birden fazla hücredeki karakterleri toplamak için, LEN'inizi SUMPRODUCT - girilen aralıklardaki sayıları toplayan işlev - içine sarmalısınız. Benim durumumda, aralık LEN işlevi tarafından döndürülür:

=SUMPRODUCT(LEN(A2:A6))

Elbette, bunun yerine SUM işlevini kullanabilirsiniz. Ancak Google E-Tablolar'daki SUM, diğer işlevlerden gelen dizileri işlemez. Çalışmasını sağlamak için başka bir işlev eklemeniz gerekir - ArrayFormula:

=ArrayFormula(SUM(LEN(A2:A6)))

Google E-Tablolar'da boşluksuz karakterleri sayma

Yukarıda belirttiğim gibi, Google E-Tablolar LEN işlevi boşluklar da dahil olmak üzere gördüğü her karakteri sayar.

Peki ya yanlışlıkla eklenen fazladan boşluklar varsa ve sonuç için bunları dikkate almak istemiyorsanız?

Bu gibi durumlar için Google E-Tablolar'da TRIM işlevi vardır. Bu işlev metinde önde, sonda ve arada tekrarlanan boşluklar olup olmadığını kontrol eder. TRIM işlevi LEN ile eşleştirildiğinde, LEN tüm bu tuhaf boşlukları saymaz.

İşte bir örnek: A sütununa farklı konumlarda boşluklar ekledim. Gördüğünüz gibi, Google E-Tablolar LEN kendi başına hepsini sayıyor:

=LEN(A2)

Ancak TRIM'i entegre ettiğiniz anda, tüm ekstra boşluklar yok sayılır:

=LEN(TRIM(A2))

Daha da ileri gidebilir ve formülünüzün kelimeler arasındaki tek boşlukları bile göz ardı etmesini sağlayabilirsiniz. SUBSTITUTE işlevi size yardımcı olacaktır. Temel amacı bir karakteri diğeriyle değiştirmek olsa da, boşlukları tamamen azaltmasını sağlamak için bir hile vardır:

• text_to_search çalıştığınız aralıktır: A sütunu veya A2 Tam olarak.
• search_for çift tırnak içinde bir boşluk karakteri olmalıdır: " "
• replace_with Boşlukları yok sayacaksanız, bunları tam anlamıyla hiçbir şeyle (boş dize) değiştirmeniz gerekir: ""
• occurence_number normalde değiştirilecek örneği belirtmek için kullanılır. Ancak tüm boşluklar olmadan karakterlerin nasıl sayılacağını açıkladığım için, isteğe bağlı olduğu için bu argümanı atlamanızı öneririm.

Şimdi tüm bunları Google Sheets LEN'de bir araya getirmeye çalışın ve hiçbir boşluğun dikkate alınmadığını göreceksiniz:

=LEN(SUBSTITUTE(A2, " ", ""))

Google E-Tablolar: belirli karakterleri sayma

Belirli karakterleri, harfleri veya sayıları saymanız gerektiğinde aynı Google E-Tablolar LEN ve SUBSTITUTE ikilisi kullanılır.

Örneklerimde, 's' harfinin kaç kez geçtiğini bulacağım ve bu sefer hazır bir formülle başlayacağım:

=LEN(A2)-LEN(SUBSTITUTE(A2, "s", ""))

Nasıl çalıştığını anlamak için parçalara ayıralım:

1. SUBSTITUTE(A2, "s", "") A2 içinde 's' harfini arar ve tüm geçtiği yerleri "nothing" veya boş dize ("") ile değiştirir.
2. LEN(SUBSTITUTE(A2, "s", "") A2'deki 's' hariç tüm karakterlerin sayısını hesaplar.
3. LEN(A2) A2'deki tüm karakterleri sayar.
4. Son olarak, birini diğerinden çıkarırsınız.

Sonuç farkı, hücrede kaç tane 's' olduğunu gösterir:

Not: A2'de 3 's' görürken B1'in neden sadece 1 's' olduğunu söylediğini merak edebilirsiniz.

Sorun şu ki, SUBSTITUTE işlevi büyük/küçük harfe duyarlıdır. Ondan tüm 's' örneklerini küçük harfle almasını istedim ve öyle de yaptı.

Metin harflerini yok sayması ve hem küçük hem de büyük harfleri işlemesi için bir Google E-Tablolar işlevini daha yardıma çağırmanız gerekecektir: LOWER.

İpucu: Google E-Tablolar'da metnin büyük/küçük harfini değiştirmenin diğer yollarına bakın.

Google Sheets LEN ve TRIM kadar basittir çünkü tek gereken metindir:

=LOWER(metin)

Ve tek yaptığı tüm metin dizesini küçük harfe dönüştürmektir. Bu numara, Google E-Tablolar'ın metin harfleri ne olursa olsun belirli karakterleri saymasını sağlamak için tam olarak ihtiyacınız olan şeydir:

=LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "s", ""))

İpucu: Daha önce olduğu gibi, aralıktaki belirli karakterlerin toplamını saymak için LEN değerinizi SUMPRODUCT içine sarın:

=SUMPRODUCT(LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "s", "")))

Google E-Tablolar'da sözcük sayma

Hücrelerde birden fazla sözcük olduğunda, büyük olasılıkla Google E-Tablolar dize uzunluğu yerine bunların sayısını almanız gerekecektir.

Bunu yapmanın birden fazla yolu olsa da, bugün Google Sheets LEN'in bu işi nasıl yaptığından bahsedeceğim.

Google E-Tablolar'da belirli karakterleri saymak için kullandığım formülü hatırlıyor musunuz? Aslında burada da işe yarayacak. Çünkü kelimeleri tam anlamıyla saymayacağım. Bunun yerine, kelimeler arasındaki boşluk sayısını sayacağım ve sonra sadece 1 ekleyeceğim:

=LEN(A2)-LEN(SUBSTITUTE((A2), " ", ""))+1

1. LEN(A2) hücredeki tüm karakterlerin sayısını sayar.
2. LEN(SUBSTITUTE((A2)," ","")) metin dizesindeki tüm boşlukları kaldırır ve kalan karakterleri sayar.
3. Sonra birini diğerinden çıkarırsınız ve elde ettiğiniz fark hücredeki boşluk sayısıdır.
4. Cümlede sözcük sayısı boşluk sayısından her zaman bir fazla olduğundan, cümlenin sonuna 1 eklersiniz.

Google E-Tablolar: belirli kelimeleri sayma

Son olarak, belirli kelimeleri saymak için kullanabileceğiniz bir Google E-Tablolar formülünü paylaşmak istiyorum.

Burada Alice'in Harikalar Diyarında Maceraları'ndan Sahte Kaplumbağa'nın Şarkısı var:

Her satırda 'will' kelimesinin kaç kez geçtiğini bilmek istiyorum. İhtiyacım olan formülün daha önce kullandığım işlevlerden oluştuğunu söylersem şaşırmayacağınızı düşünüyorum: Google E-Tablolar LEN, SUBSTITUTE ve LOWER:

=(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "will", ""))/LEN("will")

Formül korkutucu görünebilir, ancak sizi temin ederim ki anlaşılması kolaydır, bu yüzden bana katlanın :)

1. Metin büyük/küçük harf benim için önemli olmadığından LOWER(A2) her şeyi küçük harfe çevirmek için.
2. Sonra gider SUBSTITUTE(LOWER(A2), "will",""))) - 'will' kelimesinin tüm geçtiği yerleri boş dizelerle ("") değiştirerek ortadan kaldırır.
3. Bundan sonra, 'will' kelimesinin geçmediği karakter sayısını toplam dize uzunluğundan çıkarıyorum. Elde ettiğim sayı, her satırdaki 'will' kelimesinin tüm geçtiği yerlerdeki tüm karakterleri sayıyor.

   Dolayısıyla, 'will' kelimesi bir kez geçerse, kelimede 4 harf olduğu için sayı 4'tür. İki kez geçerse, sayı 8'dir ve bu böyle devam eder.

4. Son olarak, bu sayıyı tek bir 'will' kelimesinin uzunluğuna böldüm.

İpucu: Ve yine, 'will' kelimesinin tüm görünümlerinin toplam sayısını almayı tercih ederseniz, tüm formülü SUMPRODUCT ile çevreleyin:

=SUMPRODUCT((LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "will", ""))/LEN("will"))

Gördüğünüz gibi, tüm bu karakter sayısı durumları Google E-Tablolar için aynı işlevlerin aynı kalıplarıyla çözülür: LEN, SUBSTITUTE, LOWER ve SUMPRODUCT.

Bazı formüller hala kafanızı karıştırıyorsa veya her şeyi kendi görevinize nasıl uygulayacağınızdan emin değilseniz, çekinmeyin ve aşağıdaki yorumlar bölümünde sorun!