Ipinapaliwanag ng tutorial na ito ang syntax at paggamit ng Excel YEAR function at nagbibigay ng mga halimbawa ng formula upang kunin ang taon mula sa petsa, i-convert ang petsa sa buwan at taon, kalkulahin ang edad mula sa petsa ng kapanganakan at matukoy leap years.

Sa ilang kamakailang post, nag-explore kami ng iba't ibang paraan para kalkulahin ang mga petsa at oras sa Excel at natutunan ang iba't ibang kapaki-pakinabang na function gaya ng WEEKDAY, WEEKNUM, MONTH, at DAY. Ngayon, magtutuon tayo ng pansin sa isang mas malaking yunit ng oras at pag-uusapan ang pagkalkula ng mga taon sa iyong mga Excel worksheet.

Sa tutorial na ito, matututunan mo ang:

YEAR function sa Excel

Ang YEAR function sa Excel ay nagbabalik ng apat na digit na taon na tumutugma sa isang ibinigay na petsa bilang isang integer mula 1900 hanggang 9999.

Ang syntax ng Excel YEAR function ay kasing simple nito posibleng:

Kung saan ang serial_number ay anumang valid na petsa ng taon na gusto mong hanapin.

Excel YEAR formula

Upang gumawa ng YEAR formula sa Excel, maaari mong ibigay ang source date sa ilang paraan.

Gamit ang DATE function

Ang pinaka-maaasahang paraan upang magbigay ng petsa sa Excel ay ang paggamit ng DATE function.

Halimbawa, ibinabalik ng sumusunod na formula ang taon para sa Abril 28, 2015:

=YEAR(DATE(2015, 4, 28))

Bilang isang serial number na kumakatawan sa petsa

Sa internal na Excel system, ang mga petsa ay iniimbak bilang mga serial number na nagsisimula sa 1 Enero 1900, na nakaimbak bilang numero 1. Para sa higit paimpormasyon sa kung paano iniimbak ang mga petsa sa Excel, pakitingnan ang Format ng petsa ng Excel.

Ang 28 araw ng Abril, 2015 ay naka-store bilang 42122, kaya maaari mong direktang ilagay ang numerong ito sa formula:

=YEAR(42122)

Bagaman katanggap-tanggap, hindi inirerekomenda ang pamamaraang ito dahil maaaring mag-iba ang pagnunumero ng petsa sa iba't ibang system.

Bilang cell reference

Ipagpalagay na mayroon kang wastong petsa sa ilang cell, maaari ka lamang sumangguni sa cell na iyon. Halimbawa:

=YEAR(A1)

Bilang resulta ng ilang iba pang formula

Halimbawa, maaari mong gamitin ang TODAY() function para i-extract ang taon mula sa kasalukuyang petsa:

=YEAR(TODAY())

Bilang text

Sa isang simpleng kaso, mauunawaan pa nga ng YEAR formula ang mga petsang inilagay bilang text, tulad nito:

=YEAR("28-Apr-2015")

Kapag ginagamit ang paraang ito, mangyaring suriing muli kung ilalagay mo ang petsa sa format na nauunawaan ng Excel. Gayundin, pakitandaan na hindi ginagarantiya ng Microsoft ang mga tamang resulta kapag ang isang petsa ay ibinigay bilang isang text value.

Ang sumusunod na screenshot ay nagpapakita ng lahat ng nasa itaas na YEAR formula na gumagana, lahat ay babalik sa 2015 gaya ng inaasahan mo :)

Paano i-convert ang petsa sa taon sa Excel

Kapag nagtatrabaho ka gamit ang impormasyon ng petsa sa Excel, karaniwang ipinapakita ng iyong mga worksheet ang mga buong petsa, kabilang ang buwan, araw at taon . Gayunpaman, para sa mga pangunahing milestone at mahahalagang kaganapan tulad ng paglulunsad ng produkto o pagkuha ng asset, maaaring gusto mong tingnan lamang ang taon nang hindi muling ipinapasok o binago angorihinal na datos. Sa ibaba, makakahanap ka ng 3 mabilis na paraan para gawin ito.

Halimbawa 1. I-extract ang isang taon mula sa petsa gamit ang YEAR function

Sa katunayan, alam mo na kung paano gamitin ang YEAR function sa Excel upang i-convert ang isang petsa sa isang taon. Ang screenshot sa itaas ay nagpapakita ng isang grupo ng mga formula, at makakakita ka ng ilan pang halimbawa sa screenshot sa ibaba. Pansinin na ang YEAR function ay perpektong nauunawaan ang mga petsa sa lahat ng posibleng mga format:

Halimbawa 2. I-convert ang petsa sa buwan at taon sa Excel

Upang i-convert ang isang ibinigay na petsa sa taon at buwan, maaari mong gamitin ang TEXT function para i-extract ang bawat unit nang paisa-isa, at pagkatapos ay pagsamahin ang mga function na iyon sa loob ng isang formula.

Sa TEXT function, maaari kang gumamit ng iba't ibang code para sa mga buwan at taon, gaya ng:

• "mmm" - pinaikling mga pangalan ng buwan, bilang Ene - Dis.
• "mmmm" - buong buwang pangalan, bilang Enero - Disyembre.
• "yy" - 2-digit na taon
• "yyyy" - 4-digit na taon

Upang gawing mas madaling mabasa ang output, maaari mong paghiwalayin ang mga code gamit ang kuwit, gitling o anumang iba pang character, tulad ng sa mga sumusunod na formula ng Petsa hanggang Buwan at Taon :

=TEXT(B2, "mmmm") & ", " & TEXT(B2, "yyyy")

O

=TEXT(B2, "mmm") & "-" & TEXT(B2, "yy")

Kung saan ang B2 ay isang cell na naglalaman isang petsa.

Halimbawa 3. Ipakita ang isang petsa bilang isang taon

Kung hindi talaga mahalaga kung paano iniimbak ang mga petsa sa iyong workbook, maaari mong kumuha ng Excel na ipakita lamang ang mga taon kasama nito ut binabago ang orihinal na mga petsa. Sa madaling salita, maaari kang magkaroonbuong petsa na nakaimbak sa mga cell, ngunit ang mga taon lang ang ipinapakita.

Sa kasong ito, walang formula na kailangan. Buksan mo lang ang dialog na Format Cells sa pamamagitan ng pagpindot sa Ctrl + 1 , piliin ang kategoryang Custom sa tab na Number , at ilagay ang isa sa mga code sa ibaba sa Type box:

• yy - upang ipakita ang 2-digit na taon, bilang 00 - 99.
• yyyy - upang ipakita ang 4-digit na taon, bilang 1900 - 9999 .

Pakitandaan na ang pamamaraang ito ay hindi binabago ang orihinal na petsa , binabago lamang nito ang paraan ng pagpapakita ng petsa sa iyong worksheet. Kung sumangguni ka sa mga naturang cell sa iyong mga formula, magsasagawa ang Microsoft Excel ng mga kalkulasyon ng petsa kaysa sa mga kalkulasyon ng taon.

Maaari kang makakita ng higit pang mga detalye tungkol sa pagbabago ng format ng petsa sa tutorial na ito: Paano baguhin ang format ng petsa sa Excel.

Paano kalkulahin ang edad mula sa petsa ng kapanganakan sa Excel

May ilang paraan para kalkulahin ang form ng edad na petsa ng kapanganakan sa Excel - gamit ang DATEDIF, YEARFRAC o INT function kasama ng TODAY(). Ang TODAY function ay nagbibigay ng petsa upang kalkulahin ang edad sa, tinitiyak na ang iyong formula ay palaging ibabalik ang tamang edad.

Kalkulahin ang edad mula sa petsa ng kapanganakan sa mga taon

Ang tradisyunal na paraan upang kalkulahin ang edad ng isang tao sa mga taon ay upang ibawas ang petsa ng kapanganakan mula sa kasalukuyang petsa. Ang diskarte na ito ay gumagana nang maayos sa pang-araw-araw na buhay, ngunit ang isang katulad na formula ng pagkalkula ng edad ng Excel ay hindi ganap na totoo:

Kung saan ang DOB ay ang petsa ng kapanganakan.

Kinakalkula ng unang bahagi ng formula (TODAY()-B2) ang ang pagkakaiba ay mga araw, at hinati mo ito sa 365 upang makuha ang bilang ng mga taon. Sa karamihan ng mga kaso, ang resulta ng equation na ito ay isang decimal na numero, at mayroon kang INT function na bilugan ito pababa sa pinakamalapit na integer.

Ipagpalagay na ang petsa ng kapanganakan ay nasa cell B2, ang kumpletong formula ay napupunta sa mga sumusunod :

=INT((TODAY()-B2)/365)

Tulad ng nabanggit sa itaas, ang formula ng pagkalkula ng edad na ito ay hindi palaging walang kamali-mali, at narito kung bakit. Ang bawat ika-4 na taon ay isang leap year na naglalaman ng 366 na araw, samantalang hinahati ng formula ang bilang ng mga araw sa 365. Kaya, kung ang isang tao ay ipinanganak noong Pebrero 29 at ngayon ay Pebrero 28, ang pormula ng edad na ito ay magpapatanda sa isang tao ng isang araw.

Ang paghahati sa 365.25 sa halip na 365 ay hindi rin mali, halimbawa, kapag kinakalkula ang edad ng isang bata na hindi pa nabubuhay sa isang leap year.

Dahil sa nabanggit, gusto mong mas mabuting i-save ang ganitong paraan ng pagkalkula ng edad para sa normal na buhay, at gamitin ang isa sa mga sumusunod na formula para kalkulahin ang edad mula sa petsa ng kapanganakan sa Excel.

Ang detalyadong paliwanag ng mga formula sa itaas ay ibinibigay sa Paano makalkula ang edad sa Excel. At ang sumusunod na screenshot ay nagpapakita ng totoong buhay na formula ng pagkalkula ng edad na gumagana:

=DATEDIF(B2, TODAY(), "y")

Kinakalkula ang eksaktong edad mulapetsa ng kapanganakan (sa mga taon, buwan at araw)

Upang kalkulahin ang eksaktong edad sa mga taon, buwan at araw, sumulat ng tatlong DATEDIF function na may mga sumusunod na unit sa huling argumento:

• Y - upang kalkulahin ang bilang ng mga kumpletong taon.
• YM - upang makuha ang pagkakaiba sa pagitan ng mga buwan, binabalewala ang mga taon.
• MD - upang makuha ang pagkakaiba sa pagitan ng mga araw, hindi pinapansin ang mga taon at buwan. .

At pagkatapos, pagsamahin ang 3 DATEDIF function sa isang formula, paghiwalayin ang mga numerong ibinalik ng bawat function gamit ang mga kuwit, at tukuyin kung ano ang ibig sabihin ng bawat numero.

Ipagpalagay na ang petsa ng ang kapanganakan ay nasa cell B2, ang kumpletong formula ay sumusunod:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

Ang pormula ng edad na ito ay maaaring maging lubhang madaling gamitin, halimbawa, para sa isang doktor na ipakita ang eksaktong edad ng mga pasyente, o para sa isang personnel officer para malaman ang eksaktong edad ng lahat ng empleyado:

Para sa higit pang mga halimbawa ng formula gaya ng pagkalkula ng edad sa isang partikular na petsa o sa isang partikular na taon, pakitingnan ang sumusunod tutorial: Paano kalkulahin ang edad sa Excel.

Paano makukuha ang numero ng araw ng taon (1-365)

Ipinapakita ng halimbawang ito kung paano mo makukuha ang bilang ng isang partikular na araw sa isang taon, sa pagitan ng 1 at 365 (1-366 sa mga leap year) na ang Enero 1 ay itinuturing na araw 1.

Para dito, gamitin ang YEAR function kasama ng DATE sa ganitong paraan:

=A2-DATE(YEAR(A2), 1, 0)

Kung saan ang A2 ay isang cell na naglalaman ng petsa.

At ngayon, tingnan natin kung ano talaga ang ginagawa ng formula. AngKinukuha ng function na YEAR ang taon ng petsa sa cell A2, at ipinapasa ito sa function na DATE(year, month, day) , na nagbabalik ng sequential number na kumakatawan sa isang partikular na petsa.

Kaya, sa aming formula, ang year ay kinukuha mula sa orihinal na petsa (A2), ang month ay 1 (Enero) at ang day ay 0. Sa katunayan, ang isang zero na araw ay pinipilit ang Excel na ibalik ang Disyembre 31 ng nakaraang taon , dahil gusto naming ang Enero 1 ay tratuhin bilang 1st day. At pagkatapos, ibawas mo ang serial number na ibinalik ng DATE formula mula sa orihinal na petsa (na nakaimbak din bilang serial number sa Excel) at ang pagkakaiba ay ang araw ng taon na iyong hinahanap. Halimbawa, ang Enero 5, 2015 ay naka-store bilang 42009 at Disyembre 31, 2014 ay 42004, kaya 42009 - 42004 = 5.

Kung ang konsepto ng araw 0 ay mukhang hindi tama sa iyo, maaari mong gamitin ang sumusunod formula sa halip:

=A2-DATE(YEAR(A2), 1, 1)+1

Paano kalkulahin ang bilang ng mga araw na natitira sa taon

Upang kalkulahin ang bilang ng mga araw na natitira sa taon, gagamitin namin ang Muling gumana ang DATE at YEAR. Ang formula ay batay sa parehong diskarte gaya ng Halimbawa 3 sa itaas, kaya malamang na hindi ka magkaroon ng anumang mga kahirapan sa pag-unawa sa lohika nito:

=DATE(YEAR(A2),12,31)-A2

Kung ikaw gusto mong malaman kung ilang araw ang natitira hanggang sa katapusan ng taon batay sa kasalukuyang petsa, ginagamit mo ang Excel TODAY() function, gaya ng sumusunod:

=DATE(2015, 12, 31)-TODAY()

Kung saan ang 2015 ang kasalukuyang taon .

Kinakalkulaleap years sa Excel

Tulad ng alam mo, halos bawat ika-4 na taon ay may dagdag na araw sa Pebrero 29 at tinatawag itong leap year. Sa mga sheet ng Microsoft Excel, matutukoy mo kung ang isang partikular na petsa ay kabilang sa isang leap year o isang karaniwang taon sa iba't ibang paraan. Magpapakita lang ako ng ilang formula, na sa palagay ko ay pinakamadaling maunawaan.

Formula 1. Suriin kung may 29 na araw ang Pebrero

Ito ay isang napakalinaw na pagsubok. Dahil ang Pebrero ay may 29 na araw sa mga leap year, kinakalkula namin ang bilang ng mga araw sa buwan 2 ng isang partikular na taon at inihambing ito sa numero 29. Halimbawa:

=DAY(DATE(2015,3,1)-1)=29

Sa formula na ito, ang Ibinabalik ng function na DATE(2015,3,1) ang ika-1 araw ng Marso sa taong 2015, kung saan ibawas natin ang 1. Kinukuha ng function na DAY ang numero ng araw mula sa petsang ito, at ikinukumpara natin ang numerong iyon sa 29. Kung magkatugma ang mga numero, ang formula ay nagbabalik ng TRUE, FALSE kung hindi man.

Kung mayroon ka nang listahan ng mga petsa sa iyong Excel worksheet at gusto mong malaman kung alin ang mga leap year, pagkatapos ay isama ang YEAR function sa formula upang kunin ang isang taon mula isang petsa:

=DAY(DATE(YEAR(A2),3,1)-1)=29

Kung saan ang A2 ay isang cell na naglalaman ng petsa.

Ang mga resultang ibinalik ng formula ay ang mga sumusunod:

Bilang kahalili, maaari mong gamitin ang function na EOMONTH upang ibalik ang huling araw ng Pebrero, at ihambing ang numerong iyon sa 29:

=DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29

Upang gawing mas madaling gamitin ang formula , gamitin ang IF function at magkaroon nitoibalik, sabihin, "Leap year" at "Common year" sa halip na TRUE at FALSE:

=IF(DAY(DATE(YEAR(A2),3,1)-1)=29, "Leap year", "Common year")

=IF(DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29, "Leap year", "Common year")

Formula 2 . Suriin kung ang taon ay may 366 na araw

Ito ay isa pang halatang pagsubok na halos hindi nangangailangan ng anumang paliwanag. Gumagamit kami ng isang function na DATE para ibalik ang 1-Ene ng susunod na taon, isa pang function ng DATE para makakuha ng 1-Ene ng taong ito, ibawas ang huli sa nauna at tingnan kung ang pagkakaiba ay katumbas ng 366:

=DATE(2016,1,1) - DATE(2015,1,1)=366

Upang kalkulahin ang isang taon batay sa petsa na inilagay sa ilang cell, ginagamit mo ang Excel YEAR function nang eksakto sa parehong paraan tulad ng ginawa namin sa nakaraang halimbawa:

=DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366

Kung saan ang A2 ay isang cell na naglalaman ng petsa.

At natural, maaari mong ilakip ang formula na DATE / YEAR sa itaas sa function na IF para ito ay magbalik ng isang bagay na mas makabuluhan kaysa sa mga Boolean na halaga ng TRUE at FALSE:

=IF(DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366, "Leap year", "Non-leap year")

Tulad ng nabanggit na, hindi lamang ito ang mga posibleng paraan upang makalkula ang mga leap year sa Excel. Kung gusto mong malaman ang iba pang mga solusyon, maaari mong suriin ang paraan na iminungkahi ng Microsoft. Gaya ng dati, ang mga Microsoft guys ay hindi naghahanap ng mga madaling paraan, hindi ba?

Sana, nakatulong sa iyo ang artikulong ito na malaman ang mga kalkulasyon ng taon sa Excel. Salamat sa pagbabasa at umaasa akong makita ka sa susunod na linggo.