Αυτό το σεμινάριο εξηγεί τη σύνταξη και τις χρήσεις της συνάρτησης YEAR του Excel και παρέχει παραδείγματα τύπων για την εξαγωγή έτους από ημερομηνία, τη μετατροπή ημερομηνίας σε μήνα και έτος, τον υπολογισμό της ηλικίας από την ημερομηνία γέννησης και τη χρήση του έτους. προσδιορίζουν τα δίσεκτα έτη.

Σε μερικές πρόσφατες δημοσιεύσεις, εξερευνήσαμε διάφορους τρόπους υπολογισμού ημερομηνιών και ωρών στο Excel και μάθαμε μια ποικιλία χρήσιμων συναρτήσεων, όπως WEEKDAY, WEEKNUM, MONTH και DAY. Σήμερα, θα επικεντρωθούμε σε μια μεγαλύτερη χρονική μονάδα και θα μιλήσουμε για τον υπολογισμό ετών στα φύλλα εργασίας του Excel.

Σε αυτό το σεμινάριο, θα μάθετε:

Συνάρτηση YEAR στο Excel

Η συνάρτηση ΕΤΟΣ στο Excel επιστρέφει ένα τετραψήφιο έτος που αντιστοιχεί σε μια δεδομένη ημερομηνία ως ακέραιος αριθμός από το 1900 έως το 9999.

Η σύνταξη της συνάρτησης YEAR του Excel είναι όσο πιο απλή γίνεται:

Όπου serial_number είναι οποιαδήποτε έγκυρη ημερομηνία του έτους που θέλετε να βρείτε.

Τύπος του Excel YEAR

Για να δημιουργήσετε έναν τύπο ΕΤΟΣ στο Excel, μπορείτε να παρέχετε την ημερομηνία προέλευσης με διάφορους τρόπους.

Χρήση της λειτουργίας DATE

Ο πιο αξιόπιστος τρόπος παροχής μιας ημερομηνίας στο Excel είναι η χρήση της συνάρτησης DATE.

Για παράδειγμα, ο ακόλουθος τύπος επιστρέφει το έτος για τις 28 Απριλίου 2015:

=YEAR(DATE(2015, 4, 28))

Ως αύξων αριθμός που αντιπροσωπεύει την ημερομηνία

Στο εσωτερικό σύστημα του Excel, οι ημερομηνίες αποθηκεύονται ως αύξοντες αριθμοί ξεκινώντας από την 1η Ιανουαρίου 1900, η οποία αποθηκεύεται ως αριθμός 1. Για περισσότερες πληροφορίες σχετικά με τον τρόπο αποθήκευσης των ημερομηνιών στο Excel, ανατρέξτε στην ενότητα Μορφή ημερομηνίας του Excel.

Η 28η ημέρα του Απριλίου 2015 είναι αποθηκευμένη ως 42122, οπότε μπορείτε να εισαγάγετε αυτόν τον αριθμό απευθείας στον τύπο:

=YEAR(42122)

Αν και αποδεκτή, η μέθοδος αυτή δεν συνιστάται επειδή η αρίθμηση των ημερομηνιών μπορεί να διαφέρει στα διάφορα συστήματα.

Ως αναφορά κελιού

Υποθέτοντας ότι έχετε μια έγκυρη ημερομηνία σε κάποιο κελί, μπορείτε απλά να αναφερθείτε σε αυτό το κελί. Για παράδειγμα:

=YEAR(A1)

Ως αποτέλεσμα κάποιου άλλου τύπου

Για παράδειγμα, μπορείτε να χρησιμοποιήσετε τη συνάρτηση TODAY() για να εξάγετε το έτος από την τρέχουσα ημερομηνία:

=YEAR(TODAY())

Ως κείμενο

Σε μια απλή περίπτωση, ο τύπος YEAR μπορεί να καταλάβει ακόμη και ημερομηνίες που εισάγονται ως κείμενο, όπως εδώ:

=YEAR("28-Apr-2015")

Όταν χρησιμοποιείτε αυτή τη μέθοδο, παρακαλούμε να ελέγξετε δύο φορές ότι εισάγετε την ημερομηνία με τη μορφή που καταλαβαίνει το Excel. Επίσης, να θυμάστε ότι η Microsoft δεν εγγυάται σωστά αποτελέσματα όταν μια ημερομηνία παρέχεται ως τιμή κειμένου.

Το παρακάτω στιγμιότυπο οθόνης δείχνει όλους τους παραπάνω τύπους του ΕΤΟΥΣ σε δράση, και όλοι επιστρέφουν το 2015 όπως θα περίμενε κανείς :)

Πώς να μετατρέψετε την ημερομηνία σε έτος στο Excel

Όταν εργάζεστε με πληροφορίες ημερομηνίας στο Excel, τα φύλλα εργασίας σας συνήθως εμφανίζουν πλήρεις ημερομηνίες, συμπεριλαμβανομένου του μήνα, της ημέρας και του έτους. Ωστόσο, για σημαντικά ορόσημα και σημαντικά γεγονότα, όπως η κυκλοφορία προϊόντων ή η απόκτηση περιουσιακών στοιχείων, μπορεί να θέλετε να προβάλετε μόνο το έτος χωρίς να εισαγάγετε εκ νέου ή να τροποποιήσετε τα αρχικά δεδομένα. Παρακάτω, θα βρείτε 3 γρήγορους τρόπους για να το κάνετε αυτό.

Παράδειγμα 1. Εξαγωγή ενός έτους από την ημερομηνία χρησιμοποιώντας τη συνάρτηση YEAR

Στην πραγματικότητα, γνωρίζετε ήδη πώς να χρησιμοποιείτε τη συνάρτηση YEAR στο Excel για να μετατρέψετε μια ημερομηνία σε έτος. Το παραπάνω στιγμιότυπο δείχνει μια σειρά από τύπους και μπορείτε να δείτε μερικά ακόμη παραδείγματα στο παρακάτω στιγμιότυπο. Παρατηρήστε ότι η συνάρτηση YEAR κατανοεί τέλεια τις ημερομηνίες σε όλες τις πιθανές μορφές:

Παράδειγμα 2. Μετατροπή ημερομηνίας σε μήνα και έτος στο Excel

Για να μετατρέψετε μια δεδομένη ημερομηνία σε έτος και μήνα, μπορείτε να χρησιμοποιήσετε τη συνάρτηση TEXT για να εξαγάγετε κάθε μονάδα ξεχωριστά και, στη συνέχεια, να συνδέσετε αυτές τις συναρτήσεις σε έναν τύπο.

Στη λειτουργία TEXT, μπορείτε να χρησιμοποιήσετε διαφορετικούς κωδικούς για τους μήνες και τα έτη, όπως:

• "mmm" - συντομογραφημένα ονόματα μηνών, όπως Ιαν - Δεκ.
• "mmmm" - πλήρη ονόματα μηνών, όπως Ιανουάριος - Δεκέμβριος.
• "yy" - 2ψήφια έτη
• "yyyy" - 4ψήφια έτη

Για να κάνετε την έξοδο πιο ευανάγνωστη, μπορείτε να διαχωρίσετε τους κωδικούς με κόμμα, παύλα ή οποιονδήποτε άλλο χαρακτήρα, όπως στην ακόλουθη εικόνα Ημερομηνία σε Μήνα και Έτος τύπους:

=TEXT(B2, "mmmm") & ", " & TEXT(B2, "yyyy")

Ή

=TEXT(B2, "mmm") & "-" & TEXT(B2, "yy")

Όπου B2 είναι ένα κελί που περιέχει μια ημερομηνία.

Παράδειγμα 3. Εμφάνιση μιας ημερομηνίας ως έτος

Αν δεν έχει σημασία πώς αποθηκεύονται οι ημερομηνίες στο βιβλίο εργασίας σας, μπορείτε να κάνετε το Excel να εμφανίζει μόνο τα έτη χωρίς να αλλάζει τις αρχικές ημερομηνίες. Με άλλα λόγια, μπορείτε να έχετε πλήρεις ημερομηνίες αποθηκευμένες στα κελιά, αλλά να εμφανίζετε μόνο τα έτη.

Σε αυτή την περίπτωση, δεν χρειάζεται τύπος. Απλά ανοίγετε το αρχείο Κελιά μορφοποίησης πατώντας το πλήκτρο Ctrl + 1 , επιλέξτε το Προσαρμοσμένο στην κατηγορία Αριθμός και πληκτρολογήστε έναν από τους παρακάτω κωδικούς στο πεδίο Τύπος κουτί:

• yy - για την εμφάνιση 2ψήφιων ετών, όπως 00 - 99.
• yyyy - για την εμφάνιση τετραψήφιων ετών, όπως 1900 - 9999.

Να θυμάστε ότι αυτή η μέθοδος δεν αλλάζει την αρχική ημερομηνία , αλλάζει μόνο τον τρόπο με τον οποίο εμφανίζεται η ημερομηνία στο φύλλο εργασίας σας. Εάν αναφέρεστε σε τέτοια κελιά στους τύπους σας, το Microsoft Excel θα εκτελέσει υπολογισμούς ημερομηνίας αντί για υπολογισμούς έτους.

Μπορείτε να βρείτε περισσότερες λεπτομέρειες σχετικά με την αλλαγή της μορφής ημερομηνίας σε αυτό το σεμινάριο: Πώς να αλλάξετε τη μορφή ημερομηνίας στο Excel.

Πώς να υπολογίσετε την ηλικία από την ημερομηνία γέννησης στο Excel

Υπάρχουν διάφοροι τρόποι υπολογισμού της ηλικίας από την ημερομηνία γέννησης στο Excel - χρησιμοποιώντας τις συναρτήσεις DATEDIF, YEARFRAC ή INT σε συνδυασμό με τη συνάρτηση TODAY(). Η συνάρτηση TODAY παρέχει την ημερομηνία για τον υπολογισμό της ηλικίας, διασφαλίζοντας ότι ο τύπος σας θα επιστρέφει πάντα τη σωστή ηλικία.

Υπολογισμός της ηλικίας από την ημερομηνία γέννησης σε έτη

Ο παραδοσιακός τρόπος υπολογισμού της ηλικίας ενός ατόμου σε έτη είναι η αφαίρεση της ημερομηνίας γέννησης από την τρέχουσα ημερομηνία. Αυτή η προσέγγιση λειτουργεί μια χαρά στην καθημερινή ζωή, αλλά ένας ανάλογος τύπος υπολογισμού της ηλικίας στο Excel δεν είναι απόλυτα αληθινός:

Όπου DOB είναι η ημερομηνία γέννησης.

Το πρώτο μέρος του τύπου (TODAY()-B2) υπολογίζει τη διαφορά σε ημέρες, και το διαιρείτε με το 365 για να λάβετε τον αριθμό των ετών. Στις περισσότερες περιπτώσεις, το αποτέλεσμα αυτής της εξίσωσης είναι δεκαδικός αριθμός και πρέπει να το στρογγυλοποιήσετε με τη συνάρτηση INT στον πλησιέστερο ακέραιο.

Υποθέτοντας ότι η ημερομηνία γέννησης βρίσκεται στο κελί B2, ο πλήρης τύπος έχει ως εξής:

=INT((TODAY()-B2)/365)

Όπως αναφέρθηκε παραπάνω, αυτός ο τύπος υπολογισμού της ηλικίας δεν είναι πάντα άψογος, και να γιατί. Κάθε 4ο έτος είναι δίσεκτο έτος που περιέχει 366 ημέρες, ενώ ο τύπος διαιρεί τον αριθμό των ημερών με το 365. Έτσι, αν κάποιος γεννήθηκε στις 29 Φεβρουαρίου και σήμερα είναι 28 Φεβρουαρίου, αυτός ο τύπος ηλικίας θα κάνει ένα άτομο κατά μία ημέρα μεγαλύτερο.

Η διαίρεση με το 365,25 αντί για το 365 δεν είναι επίσης άψογη, για παράδειγμα, όταν υπολογίζεται η ηλικία ενός παιδιού που δεν έχει ζήσει ακόμη δίσεκτο έτος.

Λαμβάνοντας υπόψη τα παραπάνω, καλύτερα να αποθηκεύσετε αυτόν τον τρόπο υπολογισμού της ηλικίας για την κανονική ζωή και να χρησιμοποιήσετε έναν από τους ακόλουθους τύπους για τον υπολογισμό της ηλικίας από την ημερομηνία γέννησης στο Excel.

Η λεπτομερής εξήγηση των παραπάνω τύπων παρέχεται στην ενότητα Πώς να υπολογίσετε την ηλικία στο Excel. Και το ακόλουθο στιγμιότυπο οθόνης δείχνει έναν πραγματικό τύπο υπολογισμού της ηλικίας σε δράση:

=DATEDIF(B2, TODAY(), "y")

Υπολογισμός της ακριβούς ηλικίας από την ημερομηνία γέννησης (σε έτη, μήνες και ημέρες)

Για να υπολογίσετε μια ακριβή ηλικία σε έτη, μήνες και ημέρες, γράψτε τρεις συναρτήσεις DATEDIF με τις ακόλουθες μονάδες στο τελευταίο όρισμα:

• Y - για τον υπολογισμό του αριθμού των πλήρων ετών.
• YM - για να λάβετε τη διαφορά μεταξύ των μηνών, αγνοώντας τα έτη.
• MD - για να λάβετε τη διαφορά μεταξύ των ημερών, αγνοώντας τα έτη και τους μήνες.

Και στη συνέχεια, συνδέστε τις 3 συναρτήσεις DATEDIF σε έναν ενιαίο τύπο, διαχωρίστε τους αριθμούς που επιστρέφονται από κάθε συνάρτηση με κόμματα και ορίστε τι σημαίνει κάθε αριθμός.

Υποθέτοντας ότι η ημερομηνία γέννησης βρίσκεται στο κελί B2, ο πλήρης τύπος έχει ως εξής:

=DATEDIF(B2,TODAY(), "Y") & " Έτη, " &- DATEDIF(B2,TODAY(), "YM") &- " Μήνες, " &- DATEDIF(B2,TODAY(), "MD") &- " Ημέρες"

Αυτός ο τύπος ηλικίας μπορεί να φανεί πολύ χρήσιμος, π.χ. σε έναν γιατρό για να εμφανίζει την ακριβή ηλικία των ασθενών ή σε έναν υπεύθυνο προσωπικού για να γνωρίζει την ακριβή ηλικία όλων των εργαζομένων:

Για περισσότερα παραδείγματα τύπων, όπως ο υπολογισμός της ηλικίας σε μια συγκεκριμένη ημερομηνία ή σε ένα συγκεκριμένο έτος, ανατρέξτε στο ακόλουθο σεμινάριο: Πώς να υπολογίσετε την ηλικία στο Excel.

Πώς να βρείτε τον αριθμό της ημέρας του έτους (1-365)

Αυτό το παράδειγμα δείχνει πώς μπορείτε να λάβετε τον αριθμό μιας συγκεκριμένης ημέρας ενός έτους, μεταξύ 1 και 365 (1-366 σε δίσεκτα έτη), με την 1η Ιανουαρίου να θεωρείται ημέρα 1.

Για το σκοπό αυτό, χρησιμοποιήστε τη συνάρτηση ΕΤΟΣ μαζί με την ΗΜΕΡΟΜΗΝΙΑ με αυτόν τον τρόπο:

=A2-DATE(YEAR(A2), 1, 0)

Όπου A2 είναι ένα κελί που περιέχει την ημερομηνία.

Και τώρα, ας δούμε τι πραγματικά κάνει ο τύπος. ΕΤΟΣ ανακαλεί το έτος της ημερομηνίας στο κελί Α2 και το περνάει στη συνάρτηση DATE(έτος, μήνας, ημέρα) η οποία επιστρέφει τον αύξοντα αριθμό που αντιπροσωπεύει μια συγκεκριμένη ημερομηνία.

Έτσι, στον τύπο μας, έτος εξάγεται από την αρχική ημερομηνία (Α2), μήνας είναι 1 (Ιανουάριος) και ημέρα είναι 0. Στην πραγματικότητα, μια μηδενική ημέρα αναγκάζει το Excel να επιστρέψει την 31η Δεκεμβρίου του προηγούμενου έτους, επειδή θέλουμε η 1η Ιανουαρίου να αντιμετωπιστεί ως 1η ημέρα. Και στη συνέχεια, αφαιρείτε τον αύξοντα αριθμό που επιστρέφει ο τύπος DATE από την αρχική ημερομηνία (η οποία αποθηκεύεται επίσης ως αύξων αριθμός στο Excel) και η διαφορά είναι η ημέρα του έτους που αναζητάτε. Για παράδειγμα, η 5η Ιανουαρίου 2015 είναι αποθηκευμένη ως 42009 και ηΗ 31η Δεκεμβρίου 2014 είναι 42004, οπότε 42009 - 42004 = 5.

Αν η έννοια της ημέρας 0 δεν σας φαίνεται σωστή, μπορείτε να χρησιμοποιήσετε τον ακόλουθο τύπο:

=A2-DATE(YEAR(A2), 1, 1)+1

Πώς να υπολογίσετε τον αριθμό των ημερών που απομένουν στο έτος

Για να υπολογίσουμε τον αριθμό των ημερών που απομένουν στο έτος, θα χρησιμοποιήσουμε και πάλι τις συναρτήσεις DATE και YEAR. Ο τύπος βασίζεται στην ίδια προσέγγιση με το παράδειγμα 3 παραπάνω, οπότε είναι απίθανο να έχετε δυσκολίες στην κατανόηση της λογικής του:

=DATE(YEAR(A2),12,31)-A2

Αν θέλετε να μάθετε πόσες ημέρες απομένουν μέχρι το τέλος του έτους με βάση την τρέχουσα ημερομηνία, χρησιμοποιείτε τη συνάρτηση TODAY() του Excel, ως εξής:

=DATE(2015, 12, 31)-TODAY()

Όπου 2015 είναι το τρέχον έτος.

Υπολογισμός δίσεκτων ετών στο Excel

Όπως γνωρίζετε, σχεδόν κάθε 4ο έτος έχει μια επιπλέον ημέρα στις 29 Φεβρουαρίου και ονομάζεται δίσεκτο έτος. Στα φύλλα του Microsoft Excel, μπορείτε να προσδιορίσετε αν μια συγκεκριμένη ημερομηνία ανήκει σε δίσεκτο ή σε κοινό έτος με διάφορους τρόπους. Θα παρουσιάσω μόνο μερικούς τύπους, οι οποίοι κατά τη γνώμη μου είναι πιο εύκολα κατανοητοί.

Φόρμουλα 1. Ελέγξτε αν ο Φεβρουάριος έχει 29 ημέρες

Δεδομένου ότι ο Φεβρουάριος έχει 29 ημέρες στα δίσεκτα έτη, υπολογίζουμε τον αριθμό των ημερών του μήνα 2 ενός συγκεκριμένου έτους και τον συγκρίνουμε με τον αριθμό 29. Για παράδειγμα:

=DAY(DATE(2015,3,1)-1)=29

Σε αυτόν τον τύπο, η συνάρτηση DATE(2015,3,1) επιστρέφει την 1η ημέρα του Μαρτίου του έτους 2015, από την οποία αφαιρούμε το 1. Η συνάρτηση DAY εξάγει τον αριθμό της ημέρας από αυτή την ημερομηνία και συγκρίνουμε τον αριθμό αυτό με το 29. Εάν οι αριθμοί ταιριάζουν, ο τύπος επιστρέφει TRUE, διαφορετικά FALSE.

Εάν έχετε ήδη μια λίστα ημερομηνιών στο φύλλο εργασίας του Excel και θέλετε να γνωρίζετε ποιες από αυτές είναι δίσεκτα έτη, τότε ενσωματώστε τη συνάρτηση ΕΤΟΣ στον τύπο για να εξάγετε ένα έτος από μια ημερομηνία:

=DAY(DATE(YEAR(A2),3,1)-1)=29

Όπου A2 είναι ένα κελί που περιέχει την ημερομηνία.

Τα αποτελέσματα που επιστρέφονται από τον τύπο είναι τα εξής:

Εναλλακτικά, μπορείτε να χρησιμοποιήσετε τη συνάρτηση EOMONTH για να επιστρέψετε την τελευταία ημέρα του Φεβρουαρίου και να συγκρίνετε αυτόν τον αριθμό με το 29:

=DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29

Για να κάνετε τον τύπο πιο φιλικό προς το χρήστη, χρησιμοποιήστε τη συνάρτηση IF και βάλτε την να επιστρέφει, ας πούμε, "δίσεκτο έτος" και "κοινό έτος" αντί για TRUE και FALSE:

=IF(DAY(DATE(YEAR(A2),3,1)-1)=29, "Leap year", "Common year")

=IF(DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29, "Leap year", "Common year")

Τύπος 2. Ελέγξτε αν το έτος έχει 366 ημέρες

Χρησιμοποιούμε μια συνάρτηση DATE για να επιστρέψουμε την 1η Ιανουαρίου του επόμενου έτους, μια άλλη συνάρτηση DATE για να πάρουμε την 1η Ιανουαρίου του τρέχοντος έτους, αφαιρούμε τη δεύτερη από την πρώτη και ελέγχουμε αν η διαφορά ισούται με 366:

=DATE(2016,1,1) - DATE(2015,1,1)=366

Για να υπολογίσετε ένα έτος με βάση μια ημερομηνία που έχει εισαχθεί σε κάποιο κελί, χρησιμοποιείτε τη συνάρτηση YEAR του Excel με τον ίδιο ακριβώς τρόπο που κάναμε στο προηγούμενο παράδειγμα:

=DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366

Όπου A2 είναι ένα κελί που περιέχει την ημερομηνία.

Και φυσικά, μπορείτε να συμπεριλάβετε τον παραπάνω τύπο DATE / YEAR στη συνάρτηση IF για να επιστρέψει κάτι πιο ουσιαστικό από τις τιμές Boolean TRUE και FALSE:

=IF(DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366, "δίσεκτο έτος", "μη δίσεκτο έτος")

Όπως έχει ήδη αναφερθεί, αυτοί δεν είναι οι μόνοι δυνατοί τρόποι υπολογισμού δίσεκτων ετών στο Excel. Αν είστε περίεργοι να μάθετε άλλες λύσεις, μπορείτε να ελέγξετε τη μέθοδο που προτείνει η Microsoft. Ως συνήθως, οι άνθρωποι της Microsoft δεν ψάχνουν για εύκολους τρόπους, έτσι δεν είναι;

Ελπίζω ότι αυτό το άρθρο σας βοήθησε να καταλάβετε τους υπολογισμούς του έτους στο Excel. Σας ευχαριστώ για την ανάγνωση και ανυπομονώ να σας δω την επόμενη εβδομάδα.