এই টিউটোরিয়ালটি এক্সেল YEAR ফাংশনের সিনট্যাক্স এবং ব্যবহার ব্যাখ্যা করে এবং তারিখ থেকে বছর বের করতে, তারিখ থেকে মাসে এবং বছরে রূপান্তর করতে, জন্ম তারিখ থেকে বয়স গণনা করতে এবং নির্ধারণ করতে সূত্র উদাহরণ প্রদান করে অধিবর্ষ।

সাম্প্রতিক কয়েকটি পোস্টে, আমরা এক্সেলে তারিখ এবং সময় গণনা করার বিভিন্ন উপায় অনুসন্ধান করেছি এবং বিভিন্ন ধরনের দরকারী ফাংশন যেমন WEEKDAY, WEEKNUM, MONTH, এবং DAY শিখেছি। আজ, আমরা একটি বড় সময়ের এককের উপর ফোকাস করতে যাচ্ছি এবং আপনার এক্সেল ওয়ার্কশীটে বছর গণনা করার বিষয়ে কথা বলতে যাচ্ছি।

এই টিউটোরিয়ালে, আপনি শিখবেন:

YEAR ফাংশন এক্সেলের মধ্যে

এক্সেলের YEAR ফাংশনটি 1900 থেকে 9999 পর্যন্ত একটি পূর্ণসংখ্যা হিসাবে একটি প্রদত্ত তারিখের সাথে সম্পর্কিত একটি চার-সংখ্যার বছর প্রদান করে৷

এক্সেল YEAR ফাংশনের সিনট্যাক্স ততটাই সহজ সম্ভবত হতে পারে:

যেখানে ক্রমিক_সংখ্যা আপনি যে বছরের কোনো বৈধ তারিখ খুঁজে পেতে চান।

Excel YEAR সূত্র

Excel এ YEAR সূত্র তৈরি করতে, আপনি বিভিন্ন উপায়ে উৎস তারিখ সরবরাহ করতে পারেন।

DATE ফাংশনটি ব্যবহার করে

The এক্সেলে তারিখ সরবরাহ করার সবচেয়ে নির্ভরযোগ্য উপায় হল DATE ফাংশন ব্যবহার করা।

উদাহরণস্বরূপ, নিম্নলিখিত সূত্রটি 28 এপ্রিল, 2015 এর জন্য বছর প্রদান করে:

=YEAR(DATE(2015, 4, 28))

একটি ক্রমিক নম্বর তারিখের প্রতিনিধিত্ব করে

অভ্যন্তরীণ এক্সেল সিস্টেমে, তারিখগুলি ক্রমিক নম্বর হিসাবে সংরক্ষিত হয় 1 জানুয়ারী 1900 থেকে শুরু হয়, যা সংখ্যা 1 হিসাবে সংরক্ষিত হয়। আরও তথ্যের জন্যকিভাবে তারিখগুলি Excel এ সংরক্ষণ করা হয় তার তথ্য, অনুগ্রহ করে এক্সেল তারিখ বিন্যাস দেখুন৷

28 এপ্রিল, 2015 তারিখটি 42122 হিসাবে সংরক্ষণ করা হয়েছে, তাই আপনি এই নম্বরটি সরাসরি সূত্রে লিখতে পারেন:

=YEAR(42122)

যদিও গ্রহণযোগ্য, এই পদ্ধতিটি সুপারিশ করা হয় না কারণ তারিখ সংখ্যা বিভিন্ন সিস্টেমে পরিবর্তিত হতে পারে।

একটি সেল রেফারেন্স হিসাবে

অনুমান করা হচ্ছে আপনার কিছু কক্ষে একটি বৈধ তারিখ আছে, আপনি কেবল সেই ঘরটি উল্লেখ করতে পারেন। যেমন:

=YEAR(A1)

অন্য কিছু সূত্রের ফলে

উদাহরণস্বরূপ, আপনি বর্তমান তারিখ থেকে বছর বের করতে TODAY() ফাংশন ব্যবহার করতে পারেন:

=YEAR(TODAY())

পাঠ্য হিসাবে

একটি সাধারণ ক্ষেত্রে, YEAR সূত্র এমনকি পাঠ্য হিসাবে প্রবেশ করা তারিখগুলিকে বুঝতে পারে, যেমন:

=YEAR("28-Apr-2015")

এই পদ্ধতিটি ব্যবহার করার সময়, অনুগ্রহ করে দুবার চেক করুন যে আপনি যে বিন্যাসে তারিখটি এক্সেল বোঝেন সেটি প্রবেশ করান। এছাড়াও, অনুগ্রহ করে মনে রাখবেন যে টেক্সট মান হিসাবে একটি তারিখ সরবরাহ করা হলে মাইক্রোসফ্ট সঠিক ফলাফলের গ্যারান্টি দেয় না৷

নিম্নলিখিত স্ক্রিনশটটি উপরের সমস্ত YEAR সূত্রগুলিকে কার্যক্ষমভাবে প্রদর্শন করে, যা আপনি আশা করতে পারেন 2015 এ ফিরে আসবে :)

এক্সেলে তারিখে কীভাবে রূপান্তর করবেন

যখন আপনি এক্সেলে তারিখের তথ্য নিয়ে কাজ করেন, আপনার কার্যপত্রক সাধারণত মাস, দিন এবং বছর সহ সম্পূর্ণ তারিখগুলি প্রদর্শন করে . যাইহোক, প্রধান মাইলফলক এবং গুরুত্বপূর্ণ ইভেন্টগুলির জন্য যেমন পণ্য লঞ্চ বা সম্পদ অধিগ্রহণ, আপনি পুনরায় প্রবেশ বা পরিবর্তন না করে শুধুমাত্র বছর দেখতে চাইতে পারেনমূল তথ্য। নীচে, আপনি এটি করার 3টি দ্রুত উপায় পাবেন৷

উদাহরণ 1. YEAR ফাংশন ব্যবহার করে তারিখ থেকে একটি বছর বের করুন

আসলে, আপনি ইতিমধ্যেই জানেন কিভাবে Excel এ YEAR ফাংশন ব্যবহার করতে হয় একটি তারিখকে বছরে রূপান্তর করতে। উপরের স্ক্রিনশটটি সূত্রের একটি গুচ্ছ প্রদর্শন করে এবং আপনি নীচের স্ক্রিনশটে আরও কয়েকটি উদাহরণ দেখতে পারেন। লক্ষ্য করুন যে YEAR ফাংশন সমস্ত সম্ভাব্য বিন্যাসে তারিখগুলি পুরোপুরি বুঝতে পারে:

উদাহরণ 2. তারিখকে এক্সেলে মাসে এবং বছরে রূপান্তর করুন

প্রদত্ত তারিখে রূপান্তর করতে বছর এবং মাসে, আপনি প্রতিটি ইউনিটকে পৃথকভাবে বের করতে TEXT ফাংশন ব্যবহার করতে পারেন এবং তারপরে সেই ফাংশনগুলিকে একটি সূত্রের মধ্যে সংযুক্ত করতে পারেন৷

টেক্সট ফাংশনে, আপনি মাস এবং বছরের জন্য বিভিন্ন কোড ব্যবহার করতে পারেন, যেমন:

• "mmmm" - সংক্ষিপ্ত মাসের নাম, জানুয়ারি - ডিসেম্বর হিসাবে।
• "mmmm" - পুরো মাসের নাম, জানুয়ারি - ডিসেম্বর হিসাবে।
• "yy" - 2-সংখ্যার বছর
• "yyyy" - 4-সংখ্যার বছর

আউটপুটটি আরও ভালভাবে পাঠযোগ্য করতে, আপনি কমা, হাইফেন বা অন্য কোনও অক্ষর দিয়ে কোডগুলি আলাদা করতে পারেন, নিচের তারিখ থেকে মাস ও বছর সূত্রের মত:

=TEXT(B2, "mmmm") & ", " & TEXT(B2, "yyyy")

অথবা

=TEXT(B2, "mmm") & "-" & TEXT(B2, "yy")

যেখানে B2 হল একটি কোষ একটি তারিখ৷

উদাহরণ 3. একটি বছর হিসাবে একটি তারিখ প্রদর্শন করুন

আপনার ওয়ার্কবুকে তারিখগুলি কীভাবে সংরক্ষণ করা হয় তা যদি সত্যিই গুরুত্বপূর্ণ না হয় তবে আপনি করতে পারেন শুধুমাত্র বছরের সাথে দেখাতে এক্সেল পান মূল তারিখ পরিবর্তন. অন্য কথায়, আপনি থাকতে পারেনসম্পূর্ণ তারিখগুলি কক্ষে সংরক্ষণ করা হয়, কিন্তু শুধুমাত্র বছরগুলি প্রদর্শিত হয়৷

এই ক্ষেত্রে, কোনো সূত্রের প্রয়োজন নেই৷ আপনি কেবল Ctrl + 1 টিপে ফর্ম্যাট সেলস ডায়ালগটি খুলুন, সংখ্যা ট্যাবে কাস্টম বিভাগ নির্বাচন করুন এবং <এ নিচের কোডগুলির মধ্যে একটি লিখুন। 1>টাইপ করুন বক্স:

• yy - 2-সংখ্যার বছর প্রদর্শন করতে, 00 - 99 হিসাবে।
• yyyy - 4-সংখ্যার বছর প্রদর্শন করতে, 1900 - 9999 হিসাবে .

দয়া করে মনে রাখবেন যে এই পদ্ধতিটি মূল তারিখ পরিবর্তন করে না , এটি শুধুমাত্র আপনার ওয়ার্কশীটে তারিখটি দেখানোর উপায় পরিবর্তন করে। আপনি যদি আপনার সূত্রগুলিতে এই জাতীয় ঘরগুলি উল্লেখ করেন, তাহলে Microsoft Excel বছরের গণনার পরিবর্তে তারিখ গণনা করবে৷

আপনি এই টিউটোরিয়ালে তারিখ বিন্যাস পরিবর্তন সম্পর্কে আরও বিশদ জানতে পারেন: Excel এ তারিখ বিন্যাস কীভাবে পরিবর্তন করবেন৷

এক্সেলে জন্ম তারিখ থেকে বয়স কীভাবে গণনা করা যায়

এক্সেল-এ জন্ম তারিখের বয়স গণনা করার বিভিন্ন উপায় রয়েছে - TODAY() এর সাথে DATEDIF, YEARFRAC বা INT ফাংশন ব্যবহার করে। TODAY ফাংশনটি বয়স গণনা করার তারিখ সরবরাহ করে, নিশ্চিত করে যে আপনার সূত্রটি সর্বদা সঠিক বয়স ফিরিয়ে দেবে।

জন্ম তারিখ থেকে বছরগুলিতে বয়স গণনা করুন

একজন ব্যক্তির বয়স গণনা করার ঐতিহ্যগত উপায় বছরে বর্তমান তারিখ থেকে জন্ম তারিখ বিয়োগ করতে হয়। এই পদ্ধতিটি দৈনন্দিন জীবনে ভাল কাজ করে, কিন্তু একটি সাদৃশ্যপূর্ণ এক্সেল বয়স গণনা সূত্র পুরোপুরি সত্য নয়:

কোথায় DOB জন্ম তারিখ।

সূত্রের প্রথম অংশ (TODAY()-B2) গণনা করে পার্থক্য হল দিন, এবং আপনি বছরের সংখ্যা পেতে 365 দিয়ে ভাগ করবেন। বেশিরভাগ ক্ষেত্রে, এই সমীকরণের ফলাফল একটি দশমিক সংখ্যা, এবং আপনার কাছে আইএনটি ফাংশনটি এটিকে নিকটতম পূর্ণসংখ্যা পর্যন্ত বৃত্তাকার করে।

মানে জন্ম তারিখটি সেল B2-এ রয়েছে, সম্পূর্ণ সূত্রটি নিম্নরূপ :

=INT((TODAY()-B2)/365)

উপরে উল্লিখিত হিসাবে, এই বয়স গণনার সূত্রটি সর্বদা ত্রুটিহীন নয় এবং কেন তা এখানে। প্রতি 4র্থ বছর হল একটি লিপ ইয়ার যাতে 366 দিন থাকে, যেখানে সূত্রটি দিনের সংখ্যাকে 365 দিয়ে ভাগ করে। সুতরাং, যদি কেউ 29 ফেব্রুয়ারি এবং আজ 28 ফেব্রুয়ারি জন্মগ্রহণ করে, এই বয়স সূত্র একজন ব্যক্তিকে একদিন বড় করে তুলবে।

365 এর পরিবর্তে 365.25 দ্বারা ভাগ করাও ত্রুটিপূর্ণ নয়, উদাহরণস্বরূপ, একটি শিশুর বয়স গণনা করার সময় যেটি এখনও একটি লিপ ইয়ারে বেঁচে নেই৷

উপরে দেওয়া, আপনি স্বাভাবিক জীবনের জন্য বয়স গণনা করার এই পদ্ধতিটি আরও ভালভাবে সংরক্ষণ করুন, এবং Excel-এ জন্ম তারিখ থেকে বয়স গণনা করতে নিম্নলিখিত সূত্রগুলির মধ্যে একটি ব্যবহার করুন৷

উপরের সূত্রগুলির বিশদ ব্যাখ্যা এক্সেলে বয়স কীভাবে গণনা করতে হয় তাতে দেওয়া হয়েছে। এবং নিম্নলিখিত স্ক্রিনশটটি বাস্তব জীবনের বয়স গণনার সূত্র প্রদর্শন করে:

=DATEDIF(B2, TODAY(), "y")

থেকে সঠিক বয়স গণনা করাজন্ম তারিখ (বছর, মাস এবং দিনে)

বছর, মাস এবং দিনে একটি সঠিক বয়স গণনা করতে, শেষ আর্গুমেন্টে নিম্নলিখিত ইউনিটগুলির সাথে তিনটি DATEDIF ফাংশন লিখুন:

• Y - পূর্ণ বছরের সংখ্যা গণনা করতে।
• YM - মাসগুলির মধ্যে পার্থক্য পেতে, বছর উপেক্ষা করে।
• MD - বছর এবং মাস উপেক্ষা করে দিনের মধ্যে পার্থক্য পেতে .

এবং তারপর, একটি একক সূত্রে 3টি DATEDIF ফাংশন সংযুক্ত করুন, প্রতিটি ফাংশন দ্বারা প্রত্যাবর্তিত সংখ্যাগুলিকে কমা দিয়ে আলাদা করুন এবং প্রতিটি সংখ্যার অর্থ কী তা সংজ্ঞায়িত করুন৷

তারিখটি ধরে নেওয়া জন্ম কোষ B2-এ, সম্পূর্ণ সূত্রটি নিম্নরূপ:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

এই বয়স সূত্রটি খুব কার্যকর হতে পারে, বলুন, একজন ডাক্তার রোগীর সঠিক বয়স প্রদর্শন করতে বা সমস্ত কর্মচারীদের সঠিক বয়স জানতে একজন কর্মী কর্মকর্তা:

আরও সূত্র উদাহরণের জন্য যেমন একটি নির্দিষ্ট তারিখে বা একটি নির্দিষ্ট বছরে বয়স গণনা করা, অনুগ্রহ করে নিম্নলিখিতগুলি দেখুন টিউটোরিয়াল: কিভাবে এক্সেলে বয়স গণনা করা যায়।

বছরের দিন সংখ্যা কিভাবে পেতে হয় (1-365)

এই উদাহরণটি দেখায় কিভাবে আপনি বছরে একটি নির্দিষ্ট দিনের সংখ্যা 1 থেকে 365 এর মধ্যে পেতে পারেন (লিপ বছরে 1-366) জানুয়ারী 1 দিন 1 হিসাবে বিবেচিত হয়।

এর জন্য, YEAR ফাংশনটি DATE এর সাথে এইভাবে ব্যবহার করুন:

=A2-DATE(YEAR(A2), 1, 0)

যেখানে A2 তারিখটি সম্বলিত একটি সেল।

এবং এখন দেখা যাক সূত্রটি আসলে কী করে। দ্য YEAR ফাংশন A2 কক্ষে তারিখের বছর পুনরুদ্ধার করে, এবং এটিকে DATE(বছর, মাস, দিন) ফাংশনে পাস করে, যা একটি নির্দিষ্ট তারিখের প্রতিনিধিত্ব করে এমন অনুক্রমিক সংখ্যা প্রদান করে।

সুতরাং, আমাদের সূত্রে, মূল তারিখ (A2) থেকে year বের করা হয়েছে, month হল 1 (জানুয়ারি) এবং day হল 0৷ আসলে, একটি শূন্য দিন এক্সেলকে আগের বছরের 31 ডিসেম্বর ফিরে আসতে বাধ্য করে , কারণ আমরা চাই ১ জানুয়ারিকে ১ম দিন হিসেবে গণ্য করা হোক। এবং তারপর, আপনি আসল তারিখ থেকে DATE সূত্র দ্বারা প্রত্যাবর্তিত সিরিয়াল নম্বরটি বিয়োগ করুন (যা এক্সেলে একটি ক্রমিক নম্বর হিসাবেও সংরক্ষিত) এবং পার্থক্যটি হল আপনি যে বছরের দিনটি খুঁজছেন। উদাহরণস্বরূপ, 5 জানুয়ারী, 2015 42009 হিসাবে সংরক্ষণ করা হয়েছে এবং 31 ডিসেম্বর, 2014 হল 42004, তাই 42009 - 42004 = 5৷

যদি 0 দিনের ধারণাটি আপনার কাছে সঠিক মনে না হয় তবে আপনি নিম্নলিখিতগুলি ব্যবহার করতে পারেন এর পরিবর্তে সূত্র:

=A2-DATE(YEAR(A2), 1, 1)+1

বছরের বাকি দিনের সংখ্যা কীভাবে গণনা করা যায়

বছরে অবশিষ্ট দিনের সংখ্যা গণনা করতে, আমরা ব্যবহার করতে যাচ্ছি DATE এবং YEAR আবার ফাংশন. সূত্রটি উপরের উদাহরণ 3 এর মতো একই পদ্ধতির উপর ভিত্তি করে তৈরি, তাই এর যুক্তি বুঝতে আপনার কোন অসুবিধা হওয়ার সম্ভাবনা নেই:

=DATE(YEAR(A2),12,31)-A2

যদি আপনি বর্তমান তারিখের উপর ভিত্তি করে বছরের শেষ পর্যন্ত কত দিন বাকি আছে তা জানতে চান, আপনি Excel TODAY() ফাংশন ব্যবহার করেন, নিম্নরূপ:

=DATE(2015, 12, 31)-TODAY()

যেখানে 2015 বর্তমান বছর .

গণনা করা হচ্ছেএক্সেলে লিপ ইয়ার

যেমন আপনি জানেন, প্রায় প্রতি 4র্থ বছরে 29 ফেব্রুয়ারি একটি অতিরিক্ত দিন থাকে এবং একে অধিবর্ষ বলা হয়। মাইক্রোসফ্ট এক্সেল শীটগুলিতে, আপনি বিভিন্ন উপায়ে একটি নির্দিষ্ট তারিখ একটি লিপ ইয়ার বা একটি সাধারণ বছরের অন্তর্গত কিনা তা নির্ধারণ করতে পারেন। আমি শুধু কয়েকটি সূত্র দেখাতে যাচ্ছি, যেগুলো আমার মতে বোঝা সবচেয়ে সহজ।

সূত্র 1. ফেব্রুয়ারিতে 29 দিন আছে কিনা তা পরীক্ষা করে দেখুন

এটি একটি খুব স্পষ্ট পরীক্ষা। যেহেতু ফেব্রুয়ারিতে অধিবর্ষে 29 দিন থাকে, তাই আমরা একটি প্রদত্ত বছরের 2 মাসের দিনের সংখ্যা গণনা করি এবং 29 নম্বরের সাথে তুলনা করি। উদাহরণস্বরূপ:

=DAY(DATE(2015,3,1)-1)=29

এই সূত্রে, DATE(2015,3,1) ফাংশনটি 2015 সালের মার্চের 1লা দিন প্রদান করে, যেখান থেকে আমরা 1 বিয়োগ করি। DAY ফাংশন এই তারিখ থেকে দিনের সংখ্যা বের করে, এবং আমরা সেই সংখ্যাটিকে 29 এর সাথে তুলনা করি। যদি সংখ্যাগুলি মিলে যায়, সূত্রটি সত্য, অন্যথায় মিথ্যা প্রদান করে।

যদি আপনার এক্সেল ওয়ার্কশীটে ইতিমধ্যেই তারিখগুলির একটি তালিকা থাকে এবং আপনি কোনটি লিপ ইয়ার তা জানতে চান, তাহলে সূত্রে YEAR ফাংশনটি অন্তর্ভুক্ত করুন থেকে একটি বছর বের করতে। একটি তারিখ:

=DAY(DATE(YEAR(A2),3,1)-1)=29

যেখানে A2 হল একটি কক্ষ যেখানে তারিখ রয়েছে৷

সূত্র দ্বারা প্রত্যাবর্তিত ফলাফলগুলি নিম্নরূপ:

বিকল্পভাবে, আপনি ফেব্রুয়ারির শেষ দিনটি ফেরত দিতে EOMONTH ফাংশন ব্যবহার করতে পারেন এবং সেই সংখ্যাটিকে 29 এর সাথে তুলনা করতে পারেন:

=DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29

সূত্রটি আরও ব্যবহারকারী-বান্ধব করতে , IF ফাংশন নিয়োগ করুন এবং এটি আছেফিরে আসুন, বলুন, "লিপ ইয়ার" এবং সত্য এবং মিথ্যার পরিবর্তে "সাধারণ বছর":

=IF(DAY(DATE(YEAR(A2),3,1)-1)=29, "Leap year", "Common year")

=IF(DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29, "Leap year", "Common year")

সূত্র 2 বছরে 366 দিন আছে কিনা তা পরীক্ষা করুন

এটি আরেকটি সুস্পষ্ট পরীক্ষা যার জন্য খুব কমই কোনো ব্যাখ্যার প্রয়োজন হয়। আমরা পরের বছরের 1-জানুয়ারি ফেরত দিতে একটি DATE ফাংশন ব্যবহার করি, এই বছরের 1-জানুয়ারি পেতে আরেকটি DATE ফাংশন ব্যবহার করি, আগের থেকে পরবর্তীটি বিয়োগ করুন এবং পার্থক্যটি 366:

=DATE(2016,1,1) - DATE(2015,1,1)=366 <এর সমান কিনা তা পরীক্ষা করুন 3>

কিছু ​​কক্ষে প্রবেশ করা তারিখের উপর ভিত্তি করে একটি বছর গণনা করতে, আপনি এক্সেল YEAR ফাংশনটি ঠিক একইভাবে ব্যবহার করেন যেমনটি আমরা পূর্ববর্তী উদাহরণে করেছি:

=DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366

যেখানে A2 হল একটি সেল যেখানে তারিখ রয়েছে৷

এবং স্বাভাবিকভাবেই, আপনি IF ফাংশনে উপরের DATE/YEAR সূত্রটি জুড়ে দিতে পারেন যাতে এটি সত্য এবং মিথ্যার বুলিয়ান মানের চেয়ে আরও অর্থপূর্ণ কিছু ফেরত দেয়:

=IF(DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366, "Leap year", "Non-leap year")

ইতিমধ্যে উল্লিখিত হিসাবে, Excel এ লিপ ইয়ার গণনা করার একমাত্র সম্ভাব্য উপায় নয়। আপনি অন্যান্য সমাধান জানতে আগ্রহী হলে, আপনি Microsoft দ্বারা প্রস্তাবিত পদ্ধতি পরীক্ষা করতে পারেন. যথারীতি, মাইক্রোসফ্ট ছেলেরা সহজ উপায় খুঁজছেন না, তাই না?

আশা করি, এই নিবন্ধটি আপনাকে Excel এ বছরের হিসাব বের করতে সাহায্য করেছে। আমি পড়ার জন্য আপনাকে ধন্যবাদ এবং পরের সপ্তাহে আপনাকে দেখার জন্য অপেক্ষা করছি৷