Este titorial explica a sintaxe e os usos da función ANO de Excel e ofrece exemplos de fórmulas para extraer ano a data, converter data en mes e ano, calcular a idade desde a data de nacemento e determinar anos bisiestos.

Nalgunhas publicacións recentes, exploramos diferentes formas de calcular datas e horas en Excel e aprendemos unha variedade de funcións útiles, como WEEKDAY, WEEKNUM, MONTH e DAY. Hoxe centrarémonos nunha unidade de tempo máis grande e falaremos sobre o cálculo de anos nas túas follas de cálculo de Excel.

Neste titorial, aprenderás:

A función ANO en Excel

A función ANO en Excel devolve un ano de catro díxitos correspondente a unha data determinada como un número enteiro de 1900 a 9999.

A sintaxe da función ANO de Excel é tan sinxela como podería ser:

Onde serial_number é calquera data válida do ano que quere atopar.

Fórmula de ANO de Excel

Para crear unha fórmula de ANO en Excel, pode proporcionar a data de orixe de varias maneiras.

Utilizando a función DATA

O A forma máis fiable de proporcionar unha data en Excel é usar a función DATA.

Por exemplo, a seguinte fórmula devolve o ano para o 28 de abril de 2015:

=YEAR(DATE(2015, 4, 28))

Como un número de serie que representa a data

No sistema Excel interno, as datas gárdanse como números de serie que comezan co 1 de xaneiro de 1900, que se almacena como número 1. Para obter máis informacióninformación sobre como se almacenan as datas en Excel, consulta Formato de data de Excel.

O día 28 de abril de 2015 gárdase como 42122, polo que podes introducir este número directamente na fórmula:

=YEAR(42122)

Aínda que é aceptable, este método non se recomenda porque a numeración das datas pode variar nos distintos sistemas.

Como referencia de cela

Supoñendo que tes unha data válida nalgunha cela, pode simplemente referirse a esa cela. Por exemplo:

=YEAR("28-Apr-2015")

Como resultado doutra fórmula

Por exemplo, podes usar a función TODAY() para extraer o ano da data actual:

=YEAR(TODAY())

Como texto

Nun caso sinxelo, a fórmula ANO pode incluso comprender as datas introducidas como texto, así:

=YEAR("28-Apr-2015")

Cando use este método, comprobe que introduza a data no formato que Excel entende. Ademais, lembre que Microsoft non garante resultados correctos cando se proporciona unha data como valor de texto.

A seguinte captura de pantalla mostra todas as fórmulas de ANO anteriores en acción, todas devolvendo 2015 como podería esperar :)

Como converter data en ano en Excel

Cando traballas con información de data en Excel, as túas follas de traballo adoitan mostrar datas completas, incluíndo mes, día e ano . Non obstante, para fitos importantes e eventos importantes, como lanzamentos de produtos ou adquisicións de activos, pode querer ver só o ano sen volver entrar ou modificar odatos orixinais. A continuación, atoparás 3 formas rápidas de facelo.

Exemplo 1. Extrae un ano desde a data usando a función ANO

De feito, xa sabes como usar a función ANO en Excel para converter unha data nun ano. A captura de pantalla anterior mostra unha morea de fórmulas, e podes ver algúns exemplos máis na captura de pantalla a continuación. Teña en conta que a función ANO comprende perfectamente as datas en todos os formatos posibles:

Exemplo 2. Converte data en mes e ano en Excel

Para converter unha data determinada ao ano e ao mes, pode usar a función TEXTO para extraer cada unidade individualmente e, a continuación, concatenar esas funcións nunha fórmula.

Na función TEXTO, pode usar códigos diferentes para meses e anos, como:

• "mmm": nomes de meses abreviados, como xaneiro - decembro.
• "mmmm": nomes completos dos meses, como xaneiro - decembro.
• "aa" - Anos de 2 díxitos
• "aaaa" - Anos de 4 díxitos

Para que a saída sexa mellor lexible, pode separar os códigos cunha coma, guión ou calquera outro carácter. como nas seguintes fórmulas Data ao mes e ano :

=TEXT(B2, "mmmm") & ", " & TEXT(B2, "yyyy")

Ou

=TEXT(B2, "mmm") & "-" & TEXT(B2, "yy")

Onde B2 é unha cela que contén unha data.

Exemplo 3. Mostrar unha data como un ano

Se realmente non importa como se almacenan as datas no teu libro de traballo, podes obter Excel para mostrar só os anos sen cambiando as datas orixinais. Noutras palabras, podes terdatas completas almacenadas nas celas, pero só se mostran os anos.

Neste caso, non é necesaria ningunha fórmula. Só ten que abrir o diálogo Formato de celas premendo Ctrl + 1 , seleccione a categoría Personalizado na pestana Número e introduza un dos seguintes códigos no campo Escriba caixa:

• yy - para mostrar anos de 2 díxitos, como 00 - 99.
• yyyy - para mostrar anos de 4 díxitos, como 1900 - 9999 .

Lembre que este método non cambia a data orixinal , só cambia a forma en que se mostra a data na súa folla de traballo. Se se refire a estas celas nas súas fórmulas, Microsoft Excel realizará cálculos de data en lugar de cálculos de ano.

Podes atopar máis detalles sobre como cambiar o formato de data neste tutorial: Como cambiar o formato de data en Excel.

Como calcular a idade a partir da data de nacemento en Excel

Hai varias formas de calcular a idade da data de nacemento en Excel: usando a función DATEDIF, YEARFRAC ou INT en combinación con TODAY(). A función HOXE ofrece a data na que calcular a idade, o que garante que a túa fórmula sempre devolverá a idade correcta.

Calcula a idade desde a data de nacemento en anos

A forma tradicional de calcular a idade dunha persoa en anos é restar a data de nacemento da data actual. Este enfoque funciona ben na vida cotiá, pero unha fórmula análoga de cálculo de idade de Excel non é perfectamente verdadeira:

Onde DOB é a data de nacemento.

A primeira parte da fórmula (HOXE()-B2) calcula o a diferenza son días e divídese por 365 para obter o número de anos. Na maioría dos casos, o resultado desta ecuación é un número decimal e a función INT o redondea ata o número enteiro máis próximo.

Supoñendo que a data de nacemento está na cela B2, a fórmula completa é a seguinte :

=INT((TODAY()-B2)/365)

Como se mencionou anteriormente, esta fórmula de cálculo da idade non sempre é perfecta, e aquí tes por que. Cada cuarto ano é un ano bisiesto que contén 366 días, mentres que a fórmula divide o número de días entre 365. Así, se alguén naceu o 29 de febreiro e hoxe é 28 de febreiro, esta fórmula de idade fará que unha persoa sexa un día maior.

Dividir por 365,25 en lugar de 365 tampouco é impecable, por exemplo, cando se calcula a idade dun neno que aínda non viviu un ano bisiesto.

Tendo en conta o anterior, farías é mellor gardar esta forma de calcular a idade para a vida normal e utilizar unha das seguintes fórmulas para calcular a idade a partir da data de nacemento en Excel.

A explicación detallada das fórmulas anteriores ofrécese en Como calcular a idade en Excel. E a seguinte captura de pantalla mostra unha fórmula de cálculo da idade real en acción:

=DATEDIF(B2, TODAY(), "y")

Calculo da idade exacta a partir dedata de nacemento (en anos, mes e días)

Para calcular unha idade exacta en anos, meses e días, escribe tres funcións DATEDIF coas seguintes unidades no último argumento:

• Y - para calcular o número de anos completos.
• YM - para obter a diferenza entre os meses, ignorando os anos.
• MD - para obter a diferenza entre os días, ignorando anos e meses .

E logo, concatena as 3 funcións DATEDIF nunha única fórmula, separa os números devoltos por cada función con comas e define o que significa cada número.

Asumindo a data de o nacemento está na cela B2, a fórmula completa é a seguinte:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

Esta fórmula de idade pode resultar moi útil, por exemplo, para que un médico mostre a idade exacta dos pacientes ou para un oficial de persoal para coñecer a idade exacta de todos os empregados:

Para obter máis exemplos de fórmulas, como calcular a idade nunha data determinada ou nun ano determinado, consulte o seguinte titorial: Como calcular a idade en Excel.

Como obter o número do día do ano (1-365)

Este exemplo mostra como pode obter o número dun día determinado nun ano, entre 1 e 365 (1-366 nos anos bisestos) co 1 de xaneiro considerado día 1.

Para iso, utiliza a función ANO xunto con DATA deste xeito:

=A2-DATE(YEAR(A2), 1, 0)

Onde A2 é unha cela que contén a data.

E agora, vexamos o que fai realmente a fórmula. OA función ANO recupera o ano da data na cela A2 e pásao á función DATA(ano, mes, día) , que devolve o número secuencial que representa unha data determinada.

Entón, na nosa fórmula, year extráese da data orixinal (A2), month é 1 (xaneiro) e day é 0. De feito, un día cero obriga a Excel a devolver o 31 de decembro do ano anterior , porque queremos que o 1 de xaneiro sexa tratado como o 1o día. E entón, resta o número de serie devolto pola fórmula DATE da data orixinal (que tamén se almacena como número de serie en Excel) e a diferenza é o día do ano que buscas. Por exemplo, o 5 de xaneiro de 2015 gárdase como 42009 e o 31 de decembro de 2014 é 42004, polo que 42009 - 42004 = 5.

Se o concepto de día 0 non che parece correcto, podes utilizar o seguinte fórmula no seu lugar:

=A2-DATE(YEAR(A2), 1, 1)+1

Como calcular o número de días que quedan no ano

Para calcular o número de días que quedan no ano, imos utilizar o Funcións DATE e YEAR de novo. A fórmula baséase no mesmo enfoque que o exemplo 3 anterior, polo que é improbable que teñas dificultades para comprender a súa lóxica:

=DATE(YEAR(A2),12,31)-A2

Se queres saber cantos días quedan para o final do ano en función da data actual, utilizas a función Excel TODAY() do seguinte xeito:

=DATE(2015, 12, 31)-TODAY()

Onde 2015 é o ano actual .

Calculoanos bisiestos en Excel

Como sabes, case cada cuarto ano ten un día extra o 29 de febreiro e chámase ano bisiesto. Nas follas de Microsoft Excel, pode determinar se unha determinada data pertence a un ano bisiesto ou a un ano común de varias maneiras. Vou demostrar só un par de fórmulas, que na miña opinión son máis fáciles de entender.

Fórmula 1. Comproba se febreiro ten 29 días

Esta é unha proba moi obvia. Dado que febreiro ten 29 días nos anos bisestos, calculamos o número de días do mes 2 dun ano determinado e comparámolo co número 29. Por exemplo:

=DAY(DATE(2015,3,1)-1)=29

Nesta fórmula, o A función DATE(2015,3,1) devolve o día 1 de marzo do ano 2015, do que restamos 1. A función DÍA extrae o número do día desta data e comparamos ese número co 29. Se os números coinciden, a fórmula devolve VERDADEIRO, se non FALSO.

Se xa tes unha lista de datas na túa folla de cálculo de Excel e queres saber cales son anos bisiestos, incorpora a función ANO na fórmula para extraer un ano de unha data:

=DAY(DATE(YEAR(A2),3,1)-1)=29

Onde A2 é unha cela que contén a data.

Os resultados que devolve a fórmula son os seguintes:

Como alternativa, podes utilizar a función EOMONTH para devolver o último día de febreiro e comparar ese número co 29:

=DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29

Para facer a fórmula máis fácil de usar. , empregue a función SE e téñaadevolver, digamos, "Ano bisiesto" e "Ano común" en lugar de VERDADEIRO e FALSO:

=IF(DAY(DATE(YEAR(A2),3,1)-1)=29, "Leap year", "Common year")

=IF(DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29, "Leap year", "Common year")

Fórmula 2 Comproba se o ano ten 366 días

Esta é outra proba obvia que case non require explicación. Usamos unha función DATE para devolver o 1 de xaneiro do ano seguinte, outra función de DATA para obter o 1 de xaneiro deste ano, restar a segunda do primeiro e comprobar se a diferenza é igual a 366:

=DATE(2016,1,1) - DATE(2015,1,1)=366

Para calcular un ano a partir dunha data introducida nalgunha cela, usa a función ANO de Excel exactamente do mesmo xeito que fixemos no exemplo anterior:

=DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366

Onde A2 é unha cela que contén a data.

E, naturalmente, pode incluír a fórmula DATA/ANO anterior na función SE para que devolva algo máis significativo que os valores booleanos de VERDADEIRO e FALSO:

=IF(DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366, "Leap year", "Non-leap year")

Como xa se mencionou, estas non son as únicas formas posibles de calcular os anos bisiestos en Excel. Se tes curiosidade por coñecer outras solucións, podes consultar o método suxerido por Microsoft. Como é habitual, os mozos de Microsoft non buscan formas fáciles, non si?

Con sorte, este artigo che axudou a calcular os cálculos do ano en Excel. Agradézoche a lectura e espero verte a vindeira semana.