هي سبق وضاحت ڪري ٿو نحو ۽ Excel YEAR فنڪشن جي استعمال ۽ فارمولا مثال مهيا ڪري ٿو تاريخ مان سال ڪڍڻ، تاريخ کي مهيني ۽ سال ۾ تبديل ڪرڻ، ڄمڻ جي تاريخ کان عمر ڳڻڻ ۽ تعين ڪرڻ ليپ سال.

ڪجهه تازن پوسٽن ۾، اسان ايڪسل ۾ تاريخن ۽ وقتن کي ڳڻڻ جا مختلف طريقا ڳوليا آهن ۽ ڪيترن ئي مفيد ڪمن جهڙوڪ WEEKDAY، WEEKNUM، MONTH، ۽ DAY سکيا آهن. اڄ، اسان هڪ وڏي ٽائيم يونٽ تي ڌيان ڏيڻ وارا آهيون ۽ توهان جي ايڪسل ورڪ شيٽ ۾ سالن جي حساب سان ڳالهائڻ وارا آهيون.

هن سبق ۾، توهان سکندا:

YEAR فنڪشن Excel ۾

Excel ۾ YEAR فنڪشن 1900 کان 9999 تائين ڏنل تاريخ سان ملندڙ چار عددي سال ڏي ٿو.

Excel YEAR فنڪشن جو نحو ايترو سادو آهي جيترو اهو ٿي سگهي ٿو:

جتي serial_number سال جي ڪا به صحيح تاريخ آهي جنهن کي توهان ڳولڻ چاهيو ٿا.

Excel YEAR فارمولا

Excel ۾ YEAR فارمولا ٺاهڻ لاءِ، توهان ڪيترن ئي طريقن سان ماخذ جي تاريخ فراهم ڪري سگهو ٿا.

تاريخ فنڪشن کي استعمال ڪندي

The Excel ۾ تاريخ فراهم ڪرڻ جو سڀ کان وڌيڪ قابل اعتماد طريقو DATE فنڪشن استعمال ڪري رهيو آهي.

مثال طور، هيٺ ڏنل فارمولا 28 اپريل 2015 لاءِ سال ڏي ٿو:

=YEAR(DATE(2015, 4, 28))

جيئن هڪ سيريل نمبر تاريخ جي نمائندگي ڪري ٿو

اندروني Excel سسٽم ۾، تاريخون 1 جنوري 1900 کان شروع ٿيندڙ سيريل نمبر طور محفوظ ڪيون وينديون آهن، جيڪو نمبر 1 طور محفوظ ڪيو ويندو آهي. وڌيڪ لاءِمعلومات ڪيئن محفوظ ڪيون وڃن ٿيون تاريخون Excel ۾، مهرباني ڪري ڏسو Excel تاريخ فارميٽ.

28 اپريل 2015 جو ڏينهن 42122 طور محفوظ ڪيو ويو آهي، تنهنڪري توهان هن نمبر کي سڌو فارمولا ۾ داخل ڪري سگهو ٿا:

=YEAR(42122)

جيتوڻيڪ قابل قبول، هي طريقو سفارش نه ڪيو ويو آهي ڇاڪاڻ ته تاريخ نمبر مختلف سسٽم ۾ مختلف ٿي سگهن ٿا.

فرض ڪيو ته توهان وٽ ڪنهن سيل ۾ صحيح تاريخ آهي، توهان صرف انهي سيل ڏانهن اشارو ڪري سگهو ٿا. مثال طور:

=YEAR(A1)

ڪجهه ٻئي فارمولا جي نتيجي ۾

مثال طور، توهان استعمال ڪري سگهو ٿا TODAY() فنڪشن کي موجوده تاريخ مان سال ڪڍڻ لاءِ:

=YEAR(TODAY())

جيئن ٽيڪسٽ

هڪ سادي صورت ۾، YEAR فارمولا به سمجھي سگھي ٿو تاريخون داخل ٿيل متن جي طور تي، جيئن ته:

=YEAR("28-Apr-2015")

جڏهن هي طريقو استعمال ڪيو، مهرباني ڪري ٻه ڀيرا چيڪ ڪريو ته توهان تاريخ داخل ڪيو فارميٽ ۾ جيڪو Excel سمجهي ٿو. انهي سان گڏ، مهرباني ڪري ياد رکو ته Microsoft صحيح نتيجن جي ضمانت نه ڏيندو آهي جڏهن ڪا تاريخ ٽيڪسٽ ويل جي طور تي فراهم ڪئي ويندي آهي.

هيٺ ڏنل اسڪرين شاٽ ڏيکاري ٿو مٿين سڀني YEAR فارمولن کي عمل ۾، سڀ واپسي 2015 جيئن توهان توقع ڪري سگهو ٿا :)

جڏهن توهان Excel ۾ تاريخ جي معلومات سان ڪم ڪندا آهيو، توهان جا ورڪ شيٽ عام طور تي مڪمل تاريخون ڏيکاريندا آهن، بشمول مهينو، ڏينهن ۽ سال . بهرحال، وڏن سنگ ميلن ۽ اهم واقعن جهڙوڪ پراڊڪٽ لانچ يا اثاثن جي حصول لاءِ، توهان شايد صرف سال ڏسڻ چاهيو ٿا بغير ٻيهر داخل ٿيڻ يا تبديل ڪرڻ جي.اصل ڊيٽا. هيٺ، توهان هن کي ڪرڻ لاءِ 3 تڪڙا طريقا ڳوليندا.

مثال 1. YEAR فنڪشن استعمال ڪندي تاريخ مان هڪ سال ڪڍو

حقيقت ۾، توهان اڳ ۾ ئي ڄاڻو ٿا ته ايڪسل ۾ YEAR فنڪشن ڪيئن استعمال ڪجي تاريخ کي سال ۾ تبديل ڪرڻ. مٿي ڏنل اسڪرين شاٽ فارمولن جو ھڪڙو گروپ ڏيکاري ٿو، ۽ توھان ھيٺ ڏنل اسڪرين شاٽ ۾ ڪجھ وڌيڪ مثال ڏسي سگھو ٿا. نوٽ ڪريو ته YEAR فنڪشن مڪمل طور تي سڀني ممڪن فارميٽ ۾ تاريخن کي سمجهي ٿو:

مثال 2. تاريخ کي مهيني ۽ سال ۾ تبديل ڪريو Excel ۾

ڏنل تاريخ کي تبديل ڪرڻ لاءِ سال ۽ مهيني تائين، توهان TEXT فنڪشن استعمال ڪري سگهو ٿا هر يونٽ کي الڳ الڳ ڪڍڻ لاءِ، ۽ پوءِ انهن ڪمن کي هڪ فارمولي ۾ ڳنڍي سگهو ٿا.

TEXT فنڪشن ۾، توهان مهينن ۽ سالن لاءِ مختلف ڪوڊ استعمال ڪري سگهو ٿا، جهڙوڪ:

• "mmmm" - مختصر مهينن جا نالا، جيئن جنوري - ڊسمبر.
• "mmmm" - مڪمل مهينن جا نالا، جنوري - ڊسمبر وانگر.
• "yy" - 2-عددي سال
• "yyyy" - 4-عددي سال

آئوٽ پٽ کي بهتر پڙهڻ لاءِ، توهان ڪوڊس کي ڪاما، هائيفن يا ڪنهن ٻئي اکر سان الڳ ڪري سگهو ٿا، جيئن هيٺ ڏنل تاريخ کان مهيني ۽ سال فارمولن ۾:

=TEXT(B2, "mmmm") & ", " & TEXT(B2, "yyyy")

يا

=TEXT(B2, "mmm") & "-" & TEXT(B2, "yy")

جتي B2 هڪ سيل تي مشتمل آهي هڪ تاريخ.

مثال 3. هڪ سال جي طور تي هڪ تاريخ ڏيکاريو

جيڪڏهن اهو واقعي اهم ناهي ته تاريخون توهان جي ورڪ بڪ ۾ ڪيئن محفوظ ڪيون ويون آهن، توهان ڪري سگهو ٿا صرف سال ڏيکارڻ لاءِ Excel حاصل ڪريو اصل تاريخون تبديل ڪندي. ٻين لفظن ۾، توهان ڪري سگهو ٿامڪمل تاريخون سيلن ۾ ذخيرو ٿيل آهن، پر صرف سال ڏيکاريا ويا آهن.

هن صورت ۾، ڪنهن به فارمولا جي ضرورت ناهي. توھان صرف کوليو Ctrl + 1 کي دٻائيندي Cells dialog، منتخب ڪريو Custom زمرو Number ٽئب تي، ۽ ھيٺ ڏنل ڪوڊن مان ھڪڙو داخل ڪريو ٽائپ ڪريو باڪس:

• yy - 2-عددي سال ڏيکارڻ لاءِ، جيئن 00 - 99.
• yyyy - 4-عددي سال ڏيکارڻ لاءِ، جيئن 1900 - 9999 .

مهرباني ڪري ياد رکو ته هي طريقو اصل تاريخ کي تبديل نٿو ڪري ، اهو صرف ان طريقي سان تبديل ڪري ٿو جيڪا تاريخ توهان جي ورڪ شيٽ ۾ ڏيکاري ٿي. جيڪڏهن توهان پنهنجي فارمولين ۾ اهڙن سيلن جو حوالو ڏيو ٿا، ته Microsoft Excel سال جي حسابن جي بجاءِ تاريخ جي حساب سان ڪم ڪندو.

توهان هن سبق ۾ تاريخ جي فارميٽ کي تبديل ڪرڻ بابت وڌيڪ تفصيل حاصل ڪري سگهو ٿا: Excel ۾ تاريخ جي شڪل ڪيئن بدلجي.

ايڪسل ۾ ڄمڻ جي تاريخ کان عمر ڪيئن ڳڻجي

ايڪسل ۾ ڄمڻ جي تاريخ جي عمر کي ڳڻڻ جا ڪيترائي طريقا آهن - DATEDIF، YEARFRAC يا INT فنڪشن کي TODAY(). TODAY فنڪشن توهان جي عمر کي ڳڻڻ جي تاريخ فراهم ڪري ٿي، انهي کي يقيني بڻائي ته توهان جو فارمولا هميشه صحيح عمر واپس ڪندو.

سالن ۾ ڄمڻ جي تاريخ کان عمر ڳڻيو

هڪ شخص جي عمر کي ڳڻڻ جو روايتي طريقو سالن ۾ ڄمڻ جي تاريخ کي موجوده تاريخ مان گھٽائڻو آھي. اهو طريقو روزمره جي زندگيءَ ۾ ٺيڪ ڪم ڪري ٿو، پر هڪجهڙائي وارو Excel عمر جي حساب ڪتاب جو فارمولا بلڪل صحيح ناهي:

جتي DOB پيدائش جي تاريخ آهي.

فارمولا جو پهريون حصو (TODAY()-B2) حساب ڪري ٿو فرق ڏينهن آهي، ۽ توهان ان کي ورهايو 365 سالن جو تعداد حاصل ڪرڻ لاءِ. اڪثر صورتن ۾، هن مساوات جو نتيجو هڪ اعشاريه نمبر هوندو آهي، ۽ توهان وٽ INT فنڪشن آهي ان کي ويجھي انٽيجر تائين گول ڪريو.

فرض ڪيو ڄمڻ جي تاريخ سيل B2 ۾ آهي، مڪمل فارمولا هن ريت آهي :

=INT((TODAY()-B2)/365)

جيئن مٿي ذڪر ڪيو ويو آهي، هي عمر جي حساب ڪتاب جو فارمولا هميشه بي عيب ناهي، ۽ هتي ئي آهي ڇو. هر چوٿون سال هڪ ليپ سال هوندو آهي جنهن ۾ 366 ڏينهن هوندا آهن، جڏهن ته فارمولا ڏينهن جي تعداد کي 365 سان ورهائيندو آهي، تنهن ڪري، جيڪڏهن ڪو ماڻهو 29 فيبروري تي ڄائو هو ۽ اڄ 28 فيبروري آهي، اهو عمر وارو فارمولا هڪ ڏينهن وڏي عمر وارو شخص ڪندو.

365 جي بدران 365.25 سان ورهائڻ به بي عيب نه آهي، مثال طور، جڏهن ڪنهن ٻار جي عمر جو اندازو لڳايو جيڪو اڃا تائين هڪ ليپ سال نه گذريو آهي.

مٿي ڏنل آهي، توهان بهتر آهي ته عمر ڳڻڻ جي هن طريقي کي عام زندگي لاءِ محفوظ ڪريو، ۽ Excel ۾ ڄمڻ جي تاريخ کان عمر ڳڻڻ لاءِ هيٺ ڏنل فارمولين مان هڪ استعمال ڪريو.

مٿين فارمولن جي تفصيلي وضاحت ڏني وئي آھي Excel ۾ عمر ڪيئن ڳڻجي. ۽ هيٺ ڏنل اسڪرين شاٽ ڏيکاري ٿو حقيقي زندگي جي عمر جي حساب ڪتاب جو فارمولا عمل ۾:

=DATEDIF(B2, TODAY(), "y")

سالن، مھينن ۽ ڏينھن ۾ صحيح عمر ڳڻڻ لاءِ، آخري دليل ۾ ھيٺين يونٽن سان ٽي DATEDIF افعال لکو:

• Y - مڪمل سالن جو تعداد ڳڻڻ لاءِ.
• YM - مھينن جي وچ ۾ فرق حاصل ڪرڻ لاءِ، سالن کي نظر انداز ڪندي.
• MD - ڏينھن جي وچ ۾ فرق حاصل ڪرڻ لاءِ، سالن ۽ مھينن کي نظر انداز ڪري .

۽ پوءِ، 3 DATEDIF ڪمن کي ھڪڙي فارمولي ۾ ڳنڍيو، ھر فنڪشن پاران موٽايل انگن کي ڪاما سان الڳ ڪريو، ۽ بيان ڪريو ته ھر نمبر جو مطلب ڇا آھي.

تاريخ کي فرض ڪندي پيدائش سيل B2 ۾ آهي، مڪمل فارمولا هن ريت آهي:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

هي عمر وارو فارمولا تمام ڪارائتو ٿي سگهي ٿو، چئو ته، ڊاڪٽر مريضن جي صحيح عمر کي ظاهر ڪرڻ لاء، يا لاء هڪ عملي آفيسر سڀني ملازمن جي صحيح عمر ڄاڻڻ لاءِ:

20>

وڌيڪ فارمولا مثالن لاءِ جيئن ڪنهن خاص تاريخ تي يا ڪنهن خاص سال ۾ عمر جي ڳڻپ ڪرڻ لاءِ، مهرباني ڪري هيٺيون چيڪ ڪريو سبق: ايڪسل ۾ عمر ڪيئن ڳڻجي.

سال جو ڏينهن نمبر ڪيئن حاصل ڪجي (1-365)

هي مثال ڏيکاري ٿو ته توهان هڪ سال ۾ ڪنهن خاص ڏينهن جو تعداد ڪيئن حاصل ڪري سگهو ٿا، 1 ۽ 365 جي وچ ۾ (1-366 ليپ سالن ۾) جنوري 1 سان 1 ڏينهن سمجهيو وڃي.

هن لاءِ، DATE سان گڏ YEAR فنڪشن هن طرح استعمال ڪريو:

=A2-DATE(YEAR(A2), 1, 0)

جتي A2 هڪ سيل آهي جنهن ۾ تاريخ آهي.

21>

تنهنڪري، اسان جي فارمولي ۾، year اصل تاريخ (A2) مان ڪڍيو ويو آهي، month آهي 1 (جنوري) ۽ day آهي 0. حقيقت ۾، هڪ صفر ڏينهن Excel کي گذريل سال جي 31 ڊسمبر تي واپس ڪرڻ تي مجبور ڪري ٿو. ، ڇاڪاڻ ته اسان چاهيون ٿا ته جنوري 1 کي پهرين ڏينهن طور سمجهيو وڃي. ۽ پوءِ، توهان اصل تاريخ مان DATE فارمولا طرفان واپس ڪيل سيريل نمبر کي گھٽايو (جيڪو Excel ۾ سيريل نمبر جي طور تي پڻ ذخيرو ٿيل آهي) ۽ فرق اهو آهي سال جو ڏينهن جنهن کي توهان ڳولي رهيا آهيو. مثال طور، جنوري 5، 2015 42009 طور محفوظ ڪيو ويو آهي ۽ ڊسمبر 31، 2014 42004 آهي، تنهنڪري 42009 - 42004 = 5.

جيڪڏهن ڏينهن 0 جو تصور توهان کي درست نٿو لڳي، توهان هيٺ ڏنل استعمال ڪري سگهو ٿا ان جي بدران فارمولا:

=A2-DATE(YEAR(A2), 1, 1)+1

سال ۾ باقي ڏينهن جو تعداد ڪيئن ڳڻجي

سال ۾ باقي ڏينهن جو تعداد ڳڻڻ لاءِ، اسان استعمال ڪرڻ وارا آهيون. DATE ۽ YEAR وري ڪم ڪري ٿو. فارمولا ساڳئي طريقي تي ٻڌل آهي جيئن مٿي ڏنل مثال 3، تنهنڪري توهان کي ممڪن ناهي ته ان جي منطق کي سمجهڻ ۾ ڪا به مشڪلات هجي:

=DATE(YEAR(A2),12,31)-A2

22>

جيڪڏهن توهان ڄاڻڻ چاهيو ته سال جي آخر تائين ڪيترا ڏينهن باقي آهن موجوده تاريخ جي بنياد تي، توهان استعمال ڪريو Excel TODAY() فنڪشن، هن ريت:

=DATE(2015, 12, 31)-TODAY()

جتي 2015 موجوده سال آهي .

حساب ڪرڻExcel ۾ ليپ سال

جيئن ته توهان کي خبر آهي، تقريبن هر چوٿين سال ۾ 29 فيبروري تي هڪ اضافي ڏينهن هوندو آهي ۽ ان کي ليپ سال چئبو آهي. Microsoft Excel شيٽ ۾، توهان اهو طئي ڪري سگهو ٿا ته ڇا هڪ مخصوص تاريخ ليپ سال سان تعلق رکي ٿي يا هڪ عام سال مختلف طريقن سان. مان صرف چند فارمولين جو مظاهرو ڪرڻ وارو آھيان، جيڪي منھنجي خيال ۾ سمجھڻ ۾ آسان آھن.

فارمولا 1. چيڪ ڪريو ته ڇا فيبروري ۾ 29 ڏينھن آھن

ھي ھڪڙو بلڪل واضح امتحان آھي. فيبروري کان وٺي ليپ سال ۾ 29 ڏينهن آهن، اسان هڪ ڏنل سال جي مهيني 2 ۾ ڏينهن جو تعداد شمار ڪريون ٿا ۽ ان کي نمبر 29 سان ڀيٽيون ٿا. مثال طور:

=DAY(DATE(2015,3,1)-1)=29

هن فارمولا ۾، DATE(2015,3,1) فنڪشن سال 2015 ۾ مارچ جي پھرين ڏينھن کي موٽائي ٿو، جنھن مان اسان 1 کي گھٽائينداسين. DAY فنڪشن ھن تاريخ مان ڏينھن جو نمبر ڪڍي ٿو، ۽ اسان ان نمبر کي 29 سان ڀيٽيو. جيڪڏھن انگ اکر ملن ٿا، فارمولا واپس اچي ٿو صحيح، غلط ٻي صورت ۾.

جيڪڏهن توهان وٽ اڳ ۾ ئي توهان جي Excel ورڪ شيٽ ۾ تاريخن جي هڪ فهرست آهي ۽ توهان ڄاڻڻ چاهيو ٿا ته ڪهڙا ليپ سال آهن، پوءِ فارمولا ۾ YEAR فنڪشن شامل ڪريو هڪ سال ڪڍڻ لاءِ. هڪ تاريخ:

=DAY(DATE(YEAR(A2),3,1)-1)=29

جتي A2 هڪ سيل آهي جنهن ۾ تاريخ شامل آهي.

فارمولا طرفان ڏنل نتيجا هن ريت آهن:

متبادل طور تي، توهان استعمال ڪري سگهو ٿا EOMONTH فنڪشن کي واپس ڪرڻ لاءِ فيبروري جو آخري ڏينهن، ۽ ان نمبر کي 29 سان ڀيٽيو:

=DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29

فارمولا کي وڌيڪ صارف دوست بڻائڻ لاءِ IF فنڪشن کي ملازمت ڏيو ۽ ان کي حاصل ڪريوواپسي، چئو، ”ليپ سال“ ۽ ”عام سال“ بدران سچ ۽ غلط:

=IF(DAY(DATE(YEAR(A2),3,1)-1)=29, "Leap year", "Common year")

=IF(DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29, "Leap year", "Common year")

26>

فارمولا 2 چيڪ ڪريو ته ڇا سال ۾ 366 ڏينهن آهن

هي هڪ ٻيو واضح امتحان آهي جنهن لاءِ شايد ئي ڪنهن وضاحت جي ضرورت آهي. اسان هڪ DATE فنڪشن استعمال ڪندا آهيون ايندڙ سال جي 1-جنوري موٽڻ لاءِ، ٻيو DATE فنڪشن هن سال جي 1-جنوري حاصل ڪرڻ لاءِ، پوئين کان پوءِ کي ختم ڪريو ۽ چيڪ ڪريو ته فرق 366 جي برابر آهي:

=DATE(2016,1,1) - DATE(2015,1,1)=366

ڪجهه سيل ۾ داخل ٿيل تاريخ جي بنياد تي سال ڳڻڻ لاءِ، توهان Excel YEAR فنڪشن استعمال ڪريو بلڪل ساڳيءَ طرح جيئن اسان اڳئين مثال ۾ ڪيو هو:

=DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366

جتي A2 هڪ سيل آهي جنهن ۾ تاريخ آهي.

۽ قدرتي طور تي، توهان مٿي ڏنل DATE/YEAR فارمولا کي IF فنڪشن ۾ ڳنڍي سگهو ٿا ته جيئن صحيح ۽ غلط جي بولين قدرن کان وڌيڪ معنيٰ واري شيءِ موٽائي سگهجي:

=IF(DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366, "Leap year", "Non-leap year")

جيئن اڳ ۾ ئي ذڪر ڪيو ويو آهي، اهي صرف ممڪن طريقا نه آهن جيڪي ايڪسل ۾ ليپ سالن جي حساب سان. جيڪڏهن توهان ٻين حلن کي ڄاڻڻ جا شوقين آهيو، ته توهان Microsoft پاران تجويز ڪيل طريقي جي جانچ ڪري سگهو ٿا. عام طور تي، Microsoft ماڻهو نه ڳولي رهيا آهن آسان طريقا، اهي آهن؟

اميد آهي، هي آرٽيڪل توهان جي مدد ڪئي آهي ايڪسل ۾ سال جي حسابن جو اندازو لڳائڻ. مان توهان جي پڙهڻ جي مهرباني ۽ توهان کي ايندڙ هفتي ڏسڻ جو منتظر آهيان.