Hierdie tutoriaal verduidelik die sintaksis en gebruike van die Excel JAAR-funksie en verskaf formule-voorbeelde om jaar vanaf datum te onttrek, datum na maand en jaar om te skakel, ouderdom vanaf die geboortedatum te bereken en bepaal skrikkeljare.

In 'n paar onlangse plasings het ons verskillende maniere ondersoek om datums en tye in Excel te bereken en 'n verskeidenheid nuttige funksies soos WEEKDAG, WEEKNUM, MAAND en DAG geleer. Vandag gaan ons op 'n groter tydseenheid fokus en praat oor die berekening van jare in jou Excel-werkblaaie.

In hierdie tutoriaal sal jy leer:

JAAR-funksie in Excel

Die JAAR-funksie in Excel gee 'n viersyfer-jaar wat ooreenstem met 'n gegewe datum as 'n heelgetal van 1900 tot 9999.

Die sintaksis van die Excel JAAR-funksie is so eenvoudig soos dit kan moontlik wees:

Waar reeksnommer enige geldige datum van die jaar is wat jy wil vind.

Excel JAAR-formule

Om 'n JAAR-formule in Excel te maak, kan jy die brondatum op verskeie maniere verskaf.

Deur die DATUM funksie

Die mees betroubare manier om 'n datum in Excel te verskaf, is om die DATUM-funksie te gebruik.

Byvoorbeeld, die volgende formule gee die jaar vir 28 April 2015 terug:

=YEAR(DATE(2015, 4, 28))

As 'n reeksnommer wat die datum voorstel

In die interne Excel-stelsel word datums gestoor as reeksnommers wat begin met 1 Januarie 1900, wat as nommer 1 gestoor word. Vir meerinligting oor hoe datums in Excel gestoor word, sien asseblief Excel-datumformaat.

Die 28 dag van April 2015 word as 42122 gestoor, so jy kan hierdie nommer direk in die formule invoer:

=YEAR(42122)

Alhoewel dit aanvaarbaar is, word hierdie metode nie aanbeveel nie omdat datumnommering tussen verskillende stelsels kan verskil.

As 'n selverwysing

As jy aanvaar dat jy 'n geldige datum in een of ander sel het, jy kan eenvoudig na daardie sel verwys. Byvoorbeeld:

=YEAR(A1)

As gevolg van 'n ander formule

Jy kan byvoorbeeld die TODAY()-funksie gebruik om die jaar vanaf die huidige datum te onttrek:

=YEAR(TODAY())

As teks

In 'n eenvoudige geval kan die JAAR-formule selfs datums verstaan ​​wat as teks ingevoer is, soos volg:

=YEAR("28-Apr-2015")

Wanneer jy hierdie metode gebruik, maak asseblief seker dat jy die datum in die formaat invoer wat Excel verstaan. Onthou ook asseblief dat Microsoft nie korrekte resultate waarborg wanneer 'n datum as 'n tekswaarde verskaf word nie.

Die volgende skermkiekie demonstreer al die bogenoemde JAAR-formules in aksie, en almal gee 2015 terug soos jy kan verwag :)

Hoe om datum na jaar in Excel om te skakel

Wanneer jy met datuminligting in Excel werk, vertoon jou werkblaaie gewoonlik volledige datums, insluitend maand, dag en jaar . Vir groot mylpale en belangrike gebeurtenisse soos produkbekendstellings of bate-verkrygings, wil jy dalk net die jaar sien sonder om weer in te voer of te wysigoorspronklike data. Hieronder sal jy 3 vinnige maniere vind om dit te doen.

Voorbeeld 1. Onttrek 'n jaar vanaf datum deur die YEAR-funksie te gebruik

Trouens, jy weet reeds hoe om die YEAR-funksie in Excel te gebruik om 'n datum na 'n jaar om te skakel. Die skermkiekie hierbo demonstreer 'n klomp formules, en jy kan nog 'n paar voorbeelde in die skermkiekie hieronder sien. Let daarop dat die YEAR-funksie datums in alle moontlike formate perfek verstaan:

Voorbeeld 2. Skakel datum na maand en jaar om in Excel

Om 'n gegewe datum om te skakel na jaar en maand, kan jy die TEKS-funksie gebruik om elke eenheid individueel te onttrek, en dan daardie funksies binne een formule aaneen te skakel.

In die TEKS-funksie kan jy verskillende kodes vir maande en jare gebruik, soos:

• "mmm" - verkorte maande name, as Jan - Des.
• "mmmm" - volle maand name, as Januarie - Desember.
• "yy" - 2-syfer jare
• "yyyy" - 4-syfer jare

Om die uitvoer beter leesbaar te maak, kan jy die kodes skei met 'n komma, koppelteken of enige ander karakter, soos in die volgende Datum tot Maand en Jaar formules:

=TEXT(B2, "mmmm") & ", " & TEXT(B2, "yyyy")

Of

=TEXT(B2, "mmm") & "-" & TEXT(B2, "yy")

Waar B2 'n sel is wat bevat 'n datum.

Voorbeeld 3. Vertoon 'n datum as 'n jaar

As dit nie regtig saak maak hoe die datums in jou werkboek gestoor word nie, kan jy kry Excel om net die jare mee te wys ut die oorspronklike datums te verander. Met ander woorde, jy kan hêvolledige datums gestoor in selle, maar slegs die jare vertoon.

In hierdie geval is geen formule nodig nie. Jy maak net die Formateer selle -dialoog oop deur Ctrl + 1 te druk, kies die Custom -kategorie op die Getal -oortjie, en voer een van die onderstaande kodes in die Tik -blokkie:

• jj - om 2-syferjare te vertoon, as 00 - 99.
• jjjj - om 4-syferjare te vertoon, as 1900 - 9999 .

Onthou asseblief dat hierdie metode nie die oorspronklike datum verander nie , dit verander net die manier waarop die datum in jou werkblad vertoon word. As jy na sulke selle in jou formules verwys, sal Microsoft Excel datumberekeninge eerder as jaarberekeninge uitvoer.

Jy kan meer besonderhede oor die verandering van die datumformaat vind in hierdie tutoriaal: Hoe om datumformaat in Excel te verander.

Hoe om ouderdom vanaf geboortedatum in Excel te bereken

Daar is verskeie maniere om ouderdom van geboortedatum in Excel te bereken - met behulp van DATEDIF, YEARFRAC of INT funksie in kombinasie met TODAY(). Die TODAY-funksie verskaf die datum waarop ouderdom bereken moet word, om te verseker dat jou formule altyd die korrekte ouderdom sal gee.

Bereken ouderdom vanaf geboortedatum in jare

Die tradisionele manier om 'n persoon se ouderdom te bereken in jare is om die geboortedatum van die huidige datum af te trek. Hierdie benadering werk goed in die alledaagse lewe, maar 'n analoge Excel-ouderdomsberekeningsformule is nie heeltemal waar nie:

Waar DOB die geboortedatum is.

Die eerste deel van die formule (TODAY()-B2) bereken die verskil is dae, en jy deel dit deur 365 om die aantal jare te kry. In die meeste gevalle is die resultaat van hierdie vergelyking 'n desimale getal, en jy het die INT-funksie om dit af te rond tot die naaste heelgetal.

As aanvaar word dat die geboortedatum in sel B2 is, verloop die volledige formule soos volg :

=INT((TODAY()-B2)/365)

Soos hierbo genoem, is hierdie ouderdomsberekeningsformule nie altyd foutloos nie, en hier is hoekom. Elke 4de jaar is 'n skrikkeljaar wat 366 dae bevat, terwyl die formule die aantal dae deur 365 deel. Dus, as iemand op 29 Februarie gebore is en vandag is 28 Februarie, sal hierdie ouderdomsformule 'n persoon een dag ouer maak.

Om deur 365,25 in plaas van 365 te deel is ook nie onberispelik nie, byvoorbeeld wanneer die ouderdom van 'n kind bereken word wat nog nie 'n skrikkeljaar deurgemaak het nie.

Gegewe bogenoemde, sou jy beter hierdie manier van berekening van ouderdom vir normale lewe stoor, en gebruik een van die volgende formules om ouderdom vanaf geboortedatum in Excel te bereken.

Die gedetailleerde verduideliking van die bogenoemde formules word verskaf in Hoe om ouderdom in Excel te bereken. En die volgende skermkiekie demonstreer 'n werklike ouderdomsberekeningsformule in aksie:

=DATEDIF(B2, TODAY(), "y")

Berekening van presiese ouderdom vanafgeboortedatum (in jare, maand en dae)

Om 'n presiese ouderdom in jare, maande en dae te bereken, skryf drie DATEDIF-funksies met die volgende eenhede in die laaste argument:

• Y - om die aantal volledige jare te bereken.
• YM - om die verskil tussen die maande te kry, jare te ignoreer.
• MD - om die verskil tussen die dae te kry, met die ignorering van jare en maande .

En dan, koppel die 3 DATEDIF-funksies in 'n enkele formule aaneen, skei die getalle wat deur elke funksie teruggestuur word met kommas, en definieer wat elke getal beteken.

Gemeende die datum van geboorte is in sel B2, die volledige formule is soos volg:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

Hierdie ouderdomsformule kan baie handig te pas kom, byvoorbeeld vir 'n dokter om die presiese ouderdom van pasiënte te vertoon, of vir 'n personeelbeampte om die presiese ouderdom van alle werknemers te weet:

Vir meer formulevoorbeelde soos die berekening van ouderdom op 'n spesifieke datum of in 'n sekere jaar, kyk asseblief na die volgende handleiding: Hoe om ouderdom in Excel te bereken.

Hoe om die dagnommer van die jaar te kry (1-365)

Hierdie voorbeeld demonstreer hoe jy die nommer van 'n sekere dag in 'n jaar kan kry, tussen 1 en 365 (1-366 in skrikkeljare) met 1 Januarie as dag 1 beskou.

Gebruik hiervoor die YEAR-funksie saam met DATE op hierdie manier:

=A2-DATE(YEAR(A2), 1, 0)

Waar A2 'n sel is wat die datum bevat.

En nou, kom ons kyk wat die formule eintlik doen. Die YEAR -funksie haal die jaar van die datum in sel A2 op, en stuur dit na die DATE(year, month, day) -funksie, wat die opeenvolgende getal wat 'n sekere datum verteenwoordig, terugstuur.

Dus, in ons formule, word year uit die oorspronklike datum (A2) onttrek, month is 1 (Januarie) en day is 0. Trouens, 'n nuldag dwing Excel om 31 Desember van die vorige jaar terug te gee , want ons wil hê dat 1 Januarie as die 1ste dag behandel moet word. En dan trek jy die reeksnommer wat deur die DATUM-formule teruggestuur word af van die oorspronklike datum (wat ook as 'n reeksnommer in Excel gestoor word) en die verskil is die dag van die jaar waarna jy soek. Byvoorbeeld, 5 Januarie 2015 word as 42009 gestoor en 31 Desember 2014 is 42004, dus 42009 - 42004 = 5.

As die konsep van dag 0 nie vir jou reg lyk nie, kan jy die volgende gebruik formule in plaas daarvan:

=A2-DATE(YEAR(A2), 1, 1)+1

Hoe om die aantal dae wat oorbly in die jaar te bereken

Om die aantal dae wat oorbly in die jaar te bereken, gaan ons die DATE en YEAR funksioneer weer. Die formule is gebaseer op dieselfde benadering as Voorbeeld 3 hierbo, so dit is onwaarskynlik dat jy enige probleme sal hê om die logika daarvan te verstaan:

=DATE(YEAR(A2),12,31)-A2

As jy wil weet hoeveel dae oorbly tot die einde van die jaar gebaseer op die huidige datum, gebruik jy die Excel TODAY() funksie, soos volg:

=DATE(2015, 12, 31)-TODAY()

Waar 2015 die huidige jaar is .

Berekenskrikkeljare in Excel

Soos jy weet, het byna elke 4de jaar 'n ekstra dag op 29 Februarie en word dit 'n skrikkeljaar genoem. In Microsoft Excel-blaaie kan jy op verskeie maniere bepaal of 'n sekere datum aan 'n skrikkeljaar of 'n gewone jaar behoort. Ek gaan net 'n paar formules demonstreer, wat na my mening die maklikste is om te verstaan.

Formule 1. Kyk of Februarie 29 dae het

Dit is 'n baie ooglopende toets. Aangesien Februarie 29 dae in skrikkeljare het, bereken ons die aantal dae in maand 2 van 'n gegewe jaar en vergelyk dit met nommer 29. Byvoorbeeld:

=DAY(DATE(2015,3,1)-1)=29

In hierdie formule, die DATE(2015,3,1)-funksie gee die 1ste dag van Maart in die jaar 2015 terug, waarvan ons 1 aftrek. Die DAY-funksie onttrek die dagnommer van hierdie datum, en ons vergelyk daardie getal met 29. As die getalle ooreenstem, die formule gee WAAR, ONWAAR anders.

As jy reeds 'n lys datums in jou Excel-werkblad het en jy wil weet watter skrikkeljare is, inkorporeer dan die JAAR-funksie in die formule om 'n jaar uit te haal 'n datum:

=DAY(DATE(YEAR(A2),3,1)-1)=29

Waar A2 'n sel is wat die datum bevat.

Die resultate wat deur die formule teruggegee word, is soos volg:

Alternatiewelik kan jy die EOMONTH-funksie gebruik om die laaste dag in Februarie terug te gee en daardie getal met 29 te vergelyk:

=DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29

Om die formule meer gebruikersvriendelik te maak , gebruik die IF-funksie en het ditgee terug, sê, "Schrikkeljaar" en "Gewone jaar" in plaas van WAAR en ONWAAR:

=IF(DAY(DATE(YEAR(A2),3,1)-1)=29, "Leap year", "Common year")

=IF(DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29, "Leap year", "Common year")

Formule 2 Kyk of die jaar 366 dae het

Dit is nog 'n ooglopende toets wat skaars enige verduideliking vereis. Ons gebruik een DATE-funksie om 1-Jan van die volgende jaar terug te gee, 'n ander DATUM-funksie om 1-Jan van hierdie jaar te kry, trek laasgenoemde af van eersgenoemde en kyk of die verskil gelyk is aan 366:

=DATE(2016,1,1) - DATE(2015,1,1)=366

Om 'n jaar te bereken gebaseer op 'n datum wat in een of ander sel ingevoer is, gebruik jy die Excel JAAR-funksie presies op dieselfde manier as wat ons in die vorige voorbeeld gedoen het:

=DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366

Waar A2 'n sel is wat die datum bevat.

En natuurlik kan jy die DATUM/JAAR-formule hierbo in die IF-funksie insluit sodat dit iets betekenisvoller as die Boole-waardes van WAAR en ONWAAR kan terugstuur:

=IF(DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366, "Leap year", "Non-leap year")

Soos reeds genoem, is dit nie die enigste moontlike maniere om skrikkeljare in Excel te bereken nie. As jy nuuskierig is om ander oplossings te ken, kan jy die metode nagaan wat deur Microsoft voorgestel is. Soos gewoonlik soek Microsoft-ouens nie maklike maniere nie, is hulle?

Hopelik het hierdie artikel jou gehelp om jaarberekeninge in Excel uit te vind. Ek bedank jou vir die lees en sien uit daarna om jou volgende week te sien.