Tutorial ini menerangkan sintaks dan penggunaan fungsi Excel YEAR dan menyediakan contoh formula untuk mengekstrak tahun dari tarikh, menukar tarikh kepada bulan dan tahun, mengira umur dari tarikh lahir dan menentukan tahun lompat.

Dalam beberapa catatan baru-baru ini, kami telah meneroka cara yang berbeza untuk mengira tarikh dan masa dalam Excel dan mempelajari pelbagai fungsi berguna seperti WEEKDAY, WEEKNUM, MONTH dan DAY. Hari ini, kita akan menumpukan pada unit masa yang lebih besar dan bercakap tentang pengiraan tahun dalam lembaran kerja Excel anda.

Dalam tutorial ini, anda akan belajar:

Fungsi TAHUN dalam Excel

Fungsi YEAR dalam Excel mengembalikan tahun empat digit sepadan dengan tarikh tertentu sebagai integer dari 1900 hingga 9999.

Sintaks fungsi Excel YEAR adalah semudah ia mungkin:

Di mana nombor_siri ialah tarikh sah tahun yang anda ingin cari.

Formula Excel YEAR

Untuk membuat formula YEAR dalam Excel, anda boleh membekalkan tarikh sumber dalam beberapa cara.

Menggunakan fungsi DATE

cara paling boleh dipercayai untuk membekalkan tarikh dalam Excel adalah menggunakan fungsi DATE.

Sebagai contoh, formula berikut mengembalikan tahun untuk 28 April 2015:

=YEAR(DATE(2015, 4, 28))

Sebagaimana nombor siri yang mewakili tarikh

Dalam sistem Excel dalaman, tarikh disimpan sebagai nombor siri bermula dengan 1 Januari 1900, yang disimpan sebagai nombor 1. Untuk maklumat lanjutmaklumat tentang cara tarikh disimpan dalam Excel, sila lihat format tarikh Excel.

Hari 28 April 2015 disimpan sebagai 42122, jadi anda boleh memasukkan nombor ini terus dalam formula:

=YEAR(42122)

Walaupun boleh diterima, kaedah ini tidak disyorkan kerana penomboran tarikh mungkin berbeza-beza merentas sistem yang berbeza.

Sebagai rujukan sel

Dengan mengandaikan anda mempunyai tarikh yang sah dalam sesetengah sel, anda hanya boleh merujuk kepada sel itu. Contohnya:

=YEAR(A1)

Hasil daripada beberapa formula lain

Sebagai contoh, anda boleh menggunakan fungsi TODAY() untuk mengekstrak tahun daripada tarikh semasa:

=YEAR(TODAY())

Sebagai teks

Dalam kes yang mudah, formula YEAR malah boleh memahami tarikh yang dimasukkan sebagai teks, seperti ini:

=YEAR("28-Apr-2015")

Apabila menggunakan kaedah ini, sila semak semula sama ada anda memasukkan tarikh dalam format yang Excel fahami. Selain itu, sila ingat bahawa Microsoft tidak menjamin hasil yang betul apabila tarikh dibekalkan sebagai nilai teks.

Tangkapan skrin berikut menunjukkan semua formula YEAR di atas dalam tindakan, semuanya kembali 2015 seperti yang anda jangkakan :)

Cara menukar tarikh kepada tahun dalam Excel

Apabila anda menggunakan maklumat tarikh dalam Excel, lembaran kerja anda biasanya memaparkan tarikh penuh, termasuk bulan, hari dan tahun . Walau bagaimanapun, untuk peristiwa penting dan peristiwa penting seperti pelancaran produk atau pemerolehan aset, anda mungkin mahu melihat tahun sahaja tanpa memasukkan semula atau mengubah suaidata asal. Di bawah, anda akan menemui 3 cara cepat untuk melakukan ini.

Contoh 1. Ekstrak tahun dari tarikh menggunakan fungsi YEAR

Malah, anda sudah tahu cara menggunakan fungsi YEAR dalam Excel untuk menukar tarikh kepada tahun. Tangkapan skrin di atas menunjukkan sekumpulan formula dan anda boleh melihat beberapa lagi contoh dalam tangkapan skrin di bawah. Perhatikan bahawa fungsi YEAR memahami tarikh dengan sempurna dalam semua format yang mungkin:

Contoh 2. Tukar tarikh kepada bulan dan tahun dalam Excel

Untuk menukar tarikh tertentu kepada tahun dan bulan, anda boleh menggunakan fungsi TEXT untuk mengekstrak setiap unit secara individu, dan kemudian menggabungkan fungsi tersebut dalam satu formula.

Dalam fungsi TEXT, anda boleh menggunakan kod yang berbeza untuk bulan dan tahun, seperti:

• "mmm" - nama bulan yang disingkatkan, sebagai Jan - Dis.
• "mmmm" - nama bulan penuh, sebagai Januari - Disember.
• "yy" - 2 digit tahun
• "yyyy" - 4 digit tahun

Untuk menjadikan output lebih mudah dibaca, anda boleh memisahkan kod dengan koma, sempang atau mana-mana aksara lain, seperti dalam formula Tarikh ke Bulan dan Tahun berikut:

=TEXT(B2, "mmmm") & ", " & TEXT(B2, "yyyy")

Atau

=TEXT(B2, "mmm") & "-" & TEXT(B2, "yy")

Di mana B2 ialah sel yang mengandungi tarikh.

Contoh 3. Paparkan tarikh sebagai tahun

Jika tidak begitu penting bagaimana tarikh disimpan dalam buku kerja anda, anda boleh dapatkan Excel untuk menunjukkan hanya tahun dengannya ut menukar tarikh asal. Dalam erti kata lain, anda boleh mempunyaitarikh penuh disimpan dalam sel, tetapi hanya tahun yang dipaparkan.

Dalam kes ini, tiada formula diperlukan. Anda hanya membuka dialog Format Sel dengan menekan Ctrl + 1 , pilih kategori Tersuai pada tab Nombor dan masukkan salah satu kod di bawah dalam Jenis kotak:

• yy - untuk memaparkan 2 digit tahun, sebagai 00 - 99.
• yyyy - untuk memaparkan 4 digit tahun, sebagai 1900 - 9999 .

Sila ingat bahawa kaedah ini tidak mengubah tarikh asal , ia hanya mengubah cara tarikh dipaparkan dalam lembaran kerja anda. Jika anda merujuk kepada sel sedemikian dalam formula anda, Microsoft Excel akan melakukan pengiraan tarikh dan bukannya pengiraan tahun.

Anda boleh mendapatkan butiran lanjut tentang menukar format tarikh dalam tutorial ini: Cara menukar format tarikh dalam Excel.

Cara mengira umur dari tarikh lahir dalam Excel

Terdapat beberapa cara untuk mengira umur borang tarikh lahir dalam Excel - menggunakan fungsi DATEDIF, YEARFRAC atau INT dalam kombinasi dengan TODAY(). Fungsi TODAY membekalkan tarikh untuk mengira umur pada, memastikan formula anda akan sentiasa mengembalikan umur yang betul.

Kira umur dari tarikh lahir dalam tahun

Cara tradisional untuk mengira umur seseorang dalam tahun adalah untuk menolak tarikh lahir daripada tarikh semasa. Pendekatan ini berfungsi dengan baik dalam kehidupan seharian, tetapi formula pengiraan umur Excel yang serupa tidak sepenuhnya benar:

Di mana DOB ialah tarikh lahir.

Bahagian pertama formula (TODAY()-B2) mengira perbezaan ialah hari, dan anda membahagikannya dengan 365 untuk mendapatkan bilangan tahun. Dalam kebanyakan kes, hasil persamaan ini ialah nombor perpuluhan dan anda mempunyai fungsi INT membundarkannya ke integer terdekat.

Dengan mengandaikan tarikh lahir dalam sel B2, formula lengkap adalah seperti berikut :

=INT((TODAY()-B2)/365)

Seperti yang dinyatakan di atas, formula pengiraan umur ini tidak selalunya sempurna, dan inilah sebabnya. Setiap tahun ke-4 ialah tahun lompat yang mengandungi 366 hari, manakala formula membahagikan bilangan hari dengan 365. Jadi, jika seseorang itu lahir pada 29 Februari dan hari ini 28 Februari, formula umur ini akan menjadikan seseorang itu satu hari lebih tua.

Membahagikan dengan 365.25 dan bukannya 365 juga tidak sempurna, contohnya, apabila mengira umur kanak-kanak yang belum lagi mencapai tahun lompat.

Memandangkan perkara di atas, anda akan lebih baik simpan cara pengiraan umur ini untuk kehidupan normal dan gunakan salah satu daripada formula berikut untuk mengira umur dari tarikh lahir dalam Excel.

Penjelasan terperinci tentang formula di atas disediakan dalam Cara mengira umur dalam Excel. Dan tangkapan skrin berikut menunjukkan formula pengiraan umur sebenar dalam tindakan:

=DATEDIF(B2, TODAY(), "y")

Mengira umur tepat daritarikh lahir (dalam tahun, bulan dan hari)

Untuk mengira umur tepat dalam tahun, bulan dan hari, tulis tiga fungsi DATEDIF dengan unit berikut dalam hujah terakhir:

• Y - untuk mengira bilangan tahun yang lengkap.
• YM - untuk mendapatkan perbezaan antara bulan, mengabaikan tahun.
• MD - untuk mendapatkan perbezaan antara hari, mengabaikan tahun dan bulan .

Dan kemudian, gabungkan 3 fungsi DATEDIF dalam satu formula, pisahkan nombor yang dikembalikan oleh setiap fungsi dengan koma dan tentukan maksud setiap nombor.

Dengan mengandaikan tarikh kelahiran berada dalam sel B2, formula lengkapnya adalah seperti berikut:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

Formula umur ini mungkin sangat berguna, katakan, untuk doktor memaparkan umur pesakit yang tepat, atau untuk pegawai kakitangan untuk mengetahui umur sebenar semua pekerja:

Untuk lebih banyak contoh formula seperti mengira umur pada tarikh tertentu atau dalam tahun tertentu, sila semak perkara berikut tutorial: Cara mengira umur dalam Excel.

Cara mendapatkan nombor hari dalam setahun (1-365)

Contoh ini menunjukkan cara anda boleh mendapatkan nombor hari tertentu dalam setahun, antara 1 dan 365 (1-366 dalam tahun lompat) dengan 1 Januari dianggap hari 1.

Untuk ini, gunakan fungsi YEAR bersama-sama dengan DATE dengan cara ini:

=A2-DATE(YEAR(A2), 1, 0)

Di mana A2 ialah sel yang mengandungi tarikh.

Dan sekarang, mari kita lihat apa yang formula sebenarnya lakukan. TheFungsi TAHUN mendapatkan semula tahun tarikh dalam sel A2 dan menyerahkannya kepada fungsi DATE(tahun, bulan, hari) , yang mengembalikan nombor jujukan yang mewakili tarikh tertentu.

Jadi, dalam formula kami, year diekstrak daripada tarikh asal (A2), month ialah 1 (Januari) dan day ialah 0. Malah, hari sifar memaksa Excel untuk mengembalikan 31 Disember tahun sebelumnya , kerana kami mahu 1 Januari dianggap sebagai hari pertama. Dan kemudian, anda menolak nombor siri yang dikembalikan oleh formula DATE daripada tarikh asal (yang juga disimpan sebagai nombor siri dalam Excel) dan perbezaannya ialah hari dalam tahun yang anda cari. Contohnya, 5 Januari 2015 disimpan sebagai 42009 dan 31 Disember 2014 ialah 42004, jadi 42009 - 42004 = 5.

Jika konsep hari 0 nampaknya tidak sesuai untuk anda, anda boleh menggunakan yang berikut sebaliknya formula:

=A2-DATE(YEAR(A2), 1, 1)+1

Cara mengira bilangan hari yang tinggal dalam tahun

Untuk mengira bilangan hari yang tinggal dalam tahun itu, kami akan menggunakan DATE dan YEAR berfungsi semula. Formula ini adalah berdasarkan pendekatan yang sama seperti Contoh 3 di atas, jadi anda tidak mungkin menghadapi sebarang kesulitan dalam memahami logiknya:

=DATE(YEAR(A2),12,31)-A2

Jika anda ingin tahu berapa hari lagi sehingga akhir tahun berdasarkan tarikh semasa, anda menggunakan fungsi Excel TODAY(), seperti berikut:

=DATE(2015, 12, 31)-TODAY()

Di mana 2015 adalah tahun semasa .

Mengiratahun lompat dalam Excel

Seperti yang anda ketahui, hampir setiap tahun ke-4 mempunyai hari tambahan pada 29 Februari dan dipanggil tahun lompat. Dalam helaian Microsoft Excel, anda boleh menentukan sama ada tarikh tertentu tergolong dalam tahun lompat atau tahun biasa dalam pelbagai cara. Saya akan menunjukkan hanya beberapa formula, yang pada pendapat saya paling mudah difahami.

Formula 1. Semak sama ada Februari mempunyai 29 hari

Ini adalah ujian yang sangat jelas. Memandangkan Februari mempunyai 29 hari dalam tahun lompat, kami mengira bilangan hari dalam bulan 2 tahun tertentu dan membandingkannya dengan nombor 29. Contohnya:

=DAY(DATE(2015,3,1)-1)=29

Dalam formula ini, Fungsi DATE(2015,3,1) mengembalikan hari 1 Mac pada tahun 2015, yang daripadanya kita tolak 1. Fungsi DAY mengekstrak nombor hari dari tarikh ini dan kita membandingkan nombor itu dengan 29. Jika nombor sepadan, formula mengembalikan BENAR, SALAH sebaliknya.

Jika anda sudah mempunyai senarai tarikh dalam lembaran kerja Excel anda dan anda ingin tahu yang mana merupakan tahun lompat, maka masukkan fungsi YEAR dalam formula untuk mengekstrak satu tahun daripada tarikh:

=DAY(DATE(YEAR(A2),3,1)-1)=29

Di mana A2 ialah sel yang mengandungi tarikh.

Keputusan yang dikembalikan oleh formula adalah seperti berikut:

Sebagai alternatif, anda boleh menggunakan fungsi EOMONTH untuk mengembalikan hari terakhir pada bulan Februari dan bandingkan nombor itu dengan 29:

=DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29

Untuk menjadikan formula lebih mesra pengguna , gunakan fungsi IF dan milikinyakembali, katakan, "Tahun lompat" dan "Tahun biasa" bukannya BENAR dan SALAH:

=IF(DAY(DATE(YEAR(A2),3,1)-1)=29, "Leap year", "Common year")

=IF(DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29, "Leap year", "Common year")

Formula 2 . Semak sama ada tahun itu mempunyai 366 hari

Ini adalah satu lagi ujian jelas yang hampir tidak memerlukan sebarang penjelasan. Kami menggunakan satu fungsi DATE untuk mengembalikan 1-Jan tahun depan, satu lagi fungsi DATE untuk mendapatkan 1-Jan tahun ini, tolak yang terakhir daripada yang pertama dan semak jika perbezaannya sama dengan 366:

=DATE(2016,1,1) - DATE(2015,1,1)=366

Untuk mengira tahun berdasarkan tarikh yang dimasukkan dalam beberapa sel, anda menggunakan fungsi Excel YEAR sama seperti yang kami lakukan dalam contoh sebelumnya:

=DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366

Di mana A2 ialah sel yang mengandungi tarikh.

Dan secara semula jadi, anda boleh menyertakan formula DATE / YEAR di atas dalam fungsi IF untuknya mengembalikan sesuatu yang lebih bermakna daripada nilai Boolean TRUE dan FALSE:

=IF(DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366, "Leap year", "Non-leap year")

Seperti yang telah dinyatakan, ini bukan satu-satunya cara yang mungkin untuk mengira tahun lompat dalam Excel. Jika anda ingin tahu penyelesaian lain, anda boleh menyemak kaedah yang dicadangkan oleh Microsoft. Seperti biasa, lelaki Microsoft tidak mencari jalan mudah, bukan?

Semoga artikel ini telah membantu anda memikirkan pengiraan tahun dalam Excel. Saya mengucapkan terima kasih kerana membaca dan tidak sabar-sabar untuk berjumpa anda minggu hadapan.