یہ ٹیوٹوریل ایکسل YEAR فنکشن کے نحو اور استعمال کی وضاحت کرتا ہے اور تاریخ سے سال نکالنے، تاریخ کو مہینے اور سال میں تبدیل کرنے، تاریخ پیدائش سے عمر کا حساب لگانے اور کا تعین کرنے کے لیے فارمولے کی مثالیں فراہم کرتا ہے۔ لیپ سال۔

چند حالیہ پوسٹس میں، ہم نے ایکسل میں تاریخوں اور اوقات کا حساب لگانے کے مختلف طریقے تلاش کیے ہیں اور متعدد مفید افعال جیسے WEEKDAY، WEEKNUM، MONTH، اور DAY سیکھے ہیں۔ آج، ہم وقت کی ایک بڑی اکائی پر توجہ مرکوز کرنے جا رہے ہیں اور آپ کے ایکسل ورک شیٹس میں سالوں کا حساب لگانے کے بارے میں بات کرنے جا رہے ہیں۔

اس ٹیوٹوریل میں، آپ سیکھیں گے:

YEAR فنکشن ایکسل میں

ایکسل میں YEAR فنکشن 1900 سے 9999 تک ایک عدد کے بطور ایک دی گئی تاریخ کے مطابق چار ہندسوں کا سال دیتا ہے۔

ایکسل YEAR فنکشن کا نحو اتنا ہی آسان ہے جتنا کہ ممکنہ طور پر یہ ہو سکتا ہے:

جہاں serial_number سال کی کوئی بھی درست تاریخ ہے جسے آپ تلاش کرنا چاہتے ہیں۔

Excel YEAR فارمولہ

Excel میں YEAR فارمولہ بنانے کے لیے، آپ کئی طریقوں سے ماخذ کی تاریخ فراہم کر سکتے ہیں۔

DATE فنکشن کا استعمال کرتے ہوئے

The ایکسل میں تاریخ فراہم کرنے کا سب سے قابل اعتماد طریقہ DATE فنکشن کا استعمال کرنا ہے۔

مثال کے طور پر، درج ذیل فارمولہ 28 اپریل 2015 کا سال لوٹاتا ہے:

=YEAR(DATE(2015, 4, 28))

بطور ایک سیریل نمبر جو تاریخ کی نمائندگی کرتا ہے

اندرونی ایکسل سسٹم میں، تاریخیں 1 جنوری 1900 سے شروع ہونے والے سیریل نمبرز کے طور پر محفوظ کی جاتی ہیں، جو کہ نمبر 1 کے طور پر محفوظ ہوتی ہیں۔ مزید کے لیےایکسل میں تاریخیں کیسے محفوظ کی جاتی ہیں اس کے بارے میں معلومات، براہ کرم ایکسل کی تاریخ کا فارمیٹ دیکھیں۔

28 اپریل، 2015 کو 42122 کے طور پر محفوظ کیا جاتا ہے، لہذا آپ اس نمبر کو براہ راست فارمولے میں درج کر سکتے ہیں:

=YEAR(42122)

اگرچہ قابل قبول ہے، اس طریقہ کی سفارش نہیں کی جاتی ہے کیونکہ تاریخ کی تعداد مختلف سسٹمز میں مختلف ہوسکتی ہے۔

سیل حوالہ کے طور پر

یہ فرض کرتے ہوئے کہ آپ کے پاس کسی سیل میں درست تاریخ ہے، آپ صرف اس سیل کا حوالہ دے سکتے ہیں۔ مثال کے طور پر:

=YEAR(A1)

کسی دوسرے فارمولے کے نتیجے میں

مثال کے طور پر، آپ موجودہ تاریخ سے سال نکالنے کے لیے TODAY() فنکشن استعمال کر سکتے ہیں:

=YEAR(TODAY())

بطور متن

ایک آسان صورت میں، YEAR فارمولہ متن کے طور پر درج کی گئی تاریخوں کو بھی سمجھ سکتا ہے، اس طرح:

=YEAR("28-Apr-2015")

اس طریقہ کو استعمال کرتے وقت، براہ کرم دو بار چیک کریں کہ آپ تاریخ اس فارمیٹ میں درج کرتے ہیں جسے Excel سمجھتا ہے۔ اس کے علاوہ، براہ کرم یاد رکھیں کہ مائیکروسافٹ درست نتائج کی ضمانت نہیں دیتا جب کسی تاریخ کو ٹیکسٹ ویلیو کے طور پر فراہم کیا جاتا ہے۔

مندرجہ ذیل اسکرین شاٹ مندرجہ بالا تمام YEAR فارمولوں کو عملی شکل میں ظاہر کرتا ہے، یہ سب 2015 میں واپس آ رہے ہیں جیسا کہ آپ کی توقع ہے :)

ایکسل میں تاریخ کو سال میں کیسے تبدیل کریں

جب آپ ایکسل میں تاریخ کی معلومات کے ساتھ کام کرتے ہیں، تو آپ کی ورک شیٹس عام طور پر پوری تاریخیں دکھاتی ہیں، بشمول مہینہ، دن اور سال . تاہم، اہم سنگ میلوں اور اہم واقعات جیسے کہ پروڈکٹ کے اجراء یا اثاثوں کے حصول کے لیے، آپ دوبارہ داخل یا ترمیم کیے بغیر صرف سال دیکھنا چاہتے ہیں۔اصل ڈیٹا. ذیل میں، آپ کو ایسا کرنے کے 3 فوری طریقے ملیں گے۔

مثال 1. YEAR فنکشن کا استعمال کرتے ہوئے تاریخ سے ایک سال نکالیں

درحقیقت، آپ پہلے سے ہی جانتے ہیں کہ ایکسل میں YEAR فنکشن کو کس طرح استعمال کرنا ہے۔ ایک تاریخ کو سال میں تبدیل کرنا۔ مندرجہ بالا اسکرین شاٹ فارمولوں کے ایک گروپ کو ظاہر کرتا ہے، اور آپ ذیل میں اسکرین شاٹ میں کچھ اور مثالیں دیکھ سکتے ہیں۔ نوٹ کریں کہ YEAR فنکشن تمام ممکنہ فارمیٹس میں تاریخوں کو بالکل سمجھتا ہے:

مثال 2. ایکسل میں تاریخ کو مہینے اور سال میں تبدیل کریں

دی گئی تاریخ کو تبدیل کرنے کے لیے سال اور مہینے تک، آپ TEXT فنکشن کا استعمال کرکے ہر یونٹ کو الگ الگ نکال سکتے ہیں، اور پھر ان فنکشنز کو ایک فارمولے میں جوڑ سکتے ہیں۔

TEXT فنکشن میں، آپ مہینوں اور سالوں کے لیے مختلف کوڈز استعمال کرسکتے ہیں، جیسے:

• "mmm" - مہینوں کے مختصر نام، جیسا کہ جنوری - دسمبر۔
• "mmmm" - پورے مہینے کے نام، جنوری - دسمبر کے طور پر۔
• "yy" - 2 ہندسوں کے سال
• "yyyy" - 4 ہندسوں کے سال

آؤٹ پٹ کو بہتر طور پر پڑھنے کے قابل بنانے کے لیے، آپ کوما، ہائفن یا کسی دوسرے حرف سے کوڈز کو الگ کر سکتے ہیں، جیسا کہ درج ذیل تاریخ سے مہینہ اور سال فارمولوں میں:

=TEXT(B2, "mmmm") & ", " & TEXT(B2, "yyyy")

یا

=TEXT(B2, "mmm") & "-" & TEXT(B2, "yy")

جہاں B2 ایک سیل پر مشتمل ہے ایک تاریخ۔

مثال 3۔ تاریخ کو بطور سال دکھائیں

اگر اس سے کوئی فرق نہیں پڑتا ہے کہ تاریخیں آپ کی ورک بک میں کیسے محفوظ کی جاتی ہیں، تو آپ صرف سال دکھانے کے لیے Excel حاصل کریں۔ اصل تاریخوں کو تبدیل کرنا۔ دوسرے الفاظ میں، آپ کر سکتے ہیںسیل میں ذخیرہ شدہ مکمل تاریخیں، لیکن صرف سال دکھائے جاتے ہیں۔

اس صورت میں، کسی فارمولے کی ضرورت نہیں ہے۔ آپ صرف Ctrl + 1 دباکر Cells کی شکل ڈائیلاگ کو کھولیں، نمبر ٹیب پر اپنی مرضی کے زمرہ کو منتخب کریں، اور ذیل میں سے ایک کوڈ درج کریں ٹائپ کریں باکس:

• yy - 2 ہندسوں کے سالوں کو ظاہر کرنے کے لیے، 00 - 99 کے طور پر۔
• yyyy - 4 ہندسوں کے سال ظاہر کرنے کے لیے، 1900 - 9999 .

براہ کرم یاد رکھیں کہ یہ طریقہ اصل تاریخ کو تبدیل نہیں کرتا ہے ، یہ صرف آپ کی ورک شیٹ میں تاریخ کے ظاہر ہونے کے طریقے کو تبدیل کرتا ہے۔ اگر آپ اپنے فارمولوں میں ایسے سیلز کا حوالہ دیتے ہیں، تو Microsoft Excel سال کے حساب کے بجائے تاریخ کا حساب لگائے گا۔

آپ اس ٹیوٹوریل میں تاریخ کی شکل تبدیل کرنے کے بارے میں مزید تفصیلات حاصل کر سکتے ہیں: Excel میں تاریخ کی شکل کو کیسے تبدیل کیا جائے۔

ایکسل میں تاریخ پیدائش سے عمر کا حساب کیسے لگائیں

ایکسل میں عمر کے فارم کی تاریخ پیدائش کا حساب لگانے کے کئی طریقے ہیں - DATEDIF، YEARFRAC یا INT فنکشن کو TODAY() کے ساتھ ملا کر استعمال کریں۔ ٹوڈے فنکشن عمر کا حساب لگانے کے لیے تاریخ فراہم کرتا ہے، اس بات کو یقینی بناتا ہے کہ آپ کا فارمولا ہمیشہ صحیح عمر لوٹائے گا۔

سال میں تاریخ پیدائش سے عمر کا حساب لگائیں

کسی شخص کی عمر کا حساب لگانے کا روایتی طریقہ سالوں میں تاریخ پیدائش کو موجودہ تاریخ سے گھٹانا ہے۔ یہ طریقہ روزمرہ کی زندگی میں ٹھیک کام کرتا ہے، لیکن ایکسل کی عمر کے حساب کتاب کا فارمولہ بالکل درست نہیں ہے:

جہاں DOB تاریخ پیدائش ہے۔

فارمولے کا پہلا حصہ (TODAY()-B2) حساب کرتا ہے فرق دنوں کا ہے، اور آپ سالوں کی تعداد حاصل کرنے کے لیے اسے 365 سے تقسیم کرتے ہیں۔ زیادہ تر معاملات میں، اس مساوات کا نتیجہ ایک اعشاریہ نمبر ہے، اور آپ کے پاس INT فنکشن ہے جو اسے قریب ترین عدد تک گول کر دیتا ہے۔

یہ فرض کرتے ہوئے کہ تاریخ پیدائش سیل B2 میں ہے، مکمل فارمولہ مندرجہ ذیل ہے :

=INT((TODAY()-B2)/365)

جیسا کہ اوپر ذکر کیا گیا ہے، عمر کے حساب کتاب کا یہ فارمولا ہمیشہ بے عیب نہیں ہوتا، اور اس کی وجہ یہ ہے۔ ہر چوتھا سال ایک لیپ سال ہوتا ہے جس میں 366 دن ہوتے ہیں، جبکہ فارمولہ دنوں کی تعداد کو 365 سے تقسیم کرتا ہے۔ لہٰذا، اگر کوئی 29 فروری کو پیدا ہوا اور آج 28 فروری ہے، تو عمر کا یہ فارمولا انسان کو ایک دن بڑا بنا دے گا۔

365 کے بجائے 365.25 سے تقسیم کرنا بھی بے قصور نہیں ہے، مثال کے طور پر، جب کسی ایسے بچے کی عمر کا حساب لگانا جو ابھی تک لیپ سال سے گزرا نہیں ہے۔

اوپر کو دیکھتے ہوئے، آپ بہتر ہے کہ عام زندگی کے لیے عمر کا حساب لگانے کے اس طریقے کو محفوظ کریں، اور ایکسل میں تاریخ پیدائش سے عمر کا حساب لگانے کے لیے درج ذیل فارمولوں میں سے ایک استعمال کریں۔

مندرجہ بالا فارمولوں کی تفصیلی وضاحت ایکسل میں عمر کا حساب کرنے کے طریقہ میں فراہم کی گئی ہے۔ اور درج ذیل اسکرین شاٹ عملی زندگی میں عمر کے حساب کتاب کے فارمولے کو ظاہر کرتا ہے:

=DATEDIF(B2, TODAY(), "y")

سے صحیح عمر کا حساب لگاناتاریخ پیدائش (سال، مہینے اور دنوں میں)

سال، مہینوں اور دنوں میں صحیح عمر کا حساب لگانے کے لیے، آخری دلیل میں درج ذیل اکائیوں کے ساتھ تین DATEDIF فنکشن لکھیں:

• Y - مکمل سالوں کی تعداد کا حساب لگانے کے لیے۔
• YM - مہینوں کے درمیان فرق جاننے کے لیے، سالوں کو نظر انداز کر کے۔
• MD - دنوں کے درمیان فرق حاصل کرنے کے لیے، سالوں اور مہینوں کو نظر انداز کر کے .

اور پھر، 3 DATEDIF فنکشنز کو ایک فارمولے میں جوڑیں، ہر فنکشن کے ذریعے لوٹائے گئے نمبروں کو کوما سے الگ کریں، اور وضاحت کریں کہ ہر نمبر کا کیا مطلب ہے۔

کی تاریخ فرض کرتے ہوئے پیدائش سیل B2 میں ہوتی ہے، مکمل فارمولہ مندرجہ ذیل ہے:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

یہ عمر کا فارمولہ بہت کارآمد ثابت ہوسکتا ہے، یوں کہئے، ڈاکٹر کے لیے مریضوں کی صحیح عمر ظاہر کرنے کے لیے، یا تمام ملازمین کی صحیح عمر جاننے کے لیے ایک پرسنل آفیسر:

مزید فارمولہ مثالوں کے لیے جیسے کہ کسی خاص تاریخ یا کسی خاص سال میں عمر کا حساب لگانا، براہ کرم درج ذیل کو چیک کریں۔ سبق: ایکسل میں عمر کا حساب کیسے لگائیں۔

سال کے دن کا نمبر کیسے حاصل کیا جائے (1-365)

یہ مثال ظاہر کرتی ہے کہ آپ سال میں کسی مخصوص دن کا نمبر کیسے حاصل کر سکتے ہیں، 1 اور 365 کے درمیان (لیپ سالوں میں 1-366) 1 جنوری کے ساتھ دن 1 سمجھا جاتا ہے۔

اس کے لیے، YEAR فنکشن کو DATE کے ساتھ اس طرح استعمال کریں:

=A2-DATE(YEAR(A2), 1, 0)

جہاں A2 ایک سیل ہے جس میں تاریخ ہے۔

اور اب، دیکھتے ہیں کہ فارمولہ اصل میں کیا کرتا ہے۔ دی16

لہذا، ہمارے فارمولے میں، year اصل تاریخ (A2) سے نکالا جاتا ہے، month 1 (جنوری) اور day ہے 0۔ درحقیقت، ایک صفر دن Excel کو پچھلے سال کے 31 دسمبر کو واپس کرنے پر مجبور کرتا ہے۔ کیونکہ ہم چاہتے ہیں کہ یکم جنوری کو پہلا دن سمجھا جائے۔ اور پھر، آپ DATE کے فارمولے کے ذریعے لوٹائے گئے سیریل نمبر کو اصل تاریخ سے گھٹا دیتے ہیں (جو ایکسل میں سیریل نمبر کے طور پر بھی ذخیرہ کیا جاتا ہے) اور فرق اس سال کا دن ہے جس کی آپ تلاش کر رہے ہیں۔ مثال کے طور پر، 5 جنوری 2015 کو 42009 اور 31 دسمبر 2014 کو 42004 کے طور پر ذخیرہ کیا گیا ہے، لہذا 42009 - 42004 = 5۔

اگر دن 0 کا تصور آپ کو درست نہیں لگتا ہے، تو آپ درج ذیل کو استعمال کر سکتے ہیں۔ اس کے بجائے فارمولا:

=A2-DATE(YEAR(A2), 1, 1)+1

سال میں باقی دنوں کی تعداد کا حساب کیسے لگائیں

سال میں باقی دنوں کی گنتی کرنے کے لیے، ہم استعمال کرنے جا رہے ہیں۔ DATE اور YEAR دوبارہ کام کرتا ہے۔ فارمولہ اسی نقطہ نظر پر مبنی ہے جیسا کہ اوپر دی گئی مثال 3، لہذا آپ کو اس کی منطق کو سمجھنے میں کسی قسم کی دشواری کا امکان نہیں ہے:

=DATE(YEAR(A2),12,31)-A2

22>

اگر آپ موجودہ تاریخ کی بنیاد پر سال کے آخر تک کتنے دن باقی ہیں جاننا چاہتے ہیں، آپ Excel TODAY() فنکشن کو اس طرح استعمال کرتے ہیں:

=DATE(2015, 12, 31)-TODAY()

کہاں 2015 موجودہ سال ہے .

حساب لگاناایکسل میں لیپ سال

جیسا کہ آپ جانتے ہیں، تقریباً ہر چوتھے سال میں 29 فروری کو ایک اضافی دن ہوتا ہے اور اسے لیپ سال کہا جاتا ہے۔ مائیکروسافٹ ایکسل شیٹس میں، آپ مختلف طریقوں سے اس بات کا تعین کر سکتے ہیں کہ آیا کوئی مخصوص تاریخ لیپ سال سے تعلق رکھتی ہے یا عام سال سے۔ میں صرف چند فارمولوں کا مظاہرہ کرنے جا رہا ہوں، جن کو سمجھنا میری رائے میں سب سے آسان ہے۔

فارمولہ 1۔ چیک کریں کہ آیا فروری میں 29 دن ہیں

یہ ایک بہت واضح امتحان ہے۔ چونکہ فروری کے لیپ سالوں میں 29 دن ہوتے ہیں، اس لیے ہم کسی سال کے مہینے 2 میں دنوں کی تعداد کا حساب لگاتے ہیں اور اس کا نمبر 29 سے موازنہ کرتے ہیں۔ مثال کے طور پر:

=DAY(DATE(2015,3,1)-1)=29

اس فارمولے میں، DATE(2015,3,1) فنکشن سال 2015 میں مارچ کا 1st دن لوٹاتا ہے، جس سے ہم 1 کو گھٹاتے ہیں۔ DAY فنکشن اس تاریخ سے دن کا نمبر نکالتا ہے، اور ہم اس نمبر کا 29 سے موازنہ کرتے ہیں۔ اگر نمبرز مماثل ہوں، فارمولہ صحیح، غلط ورنہ واپس کرتا ہے۔

اگر آپ کے پاس پہلے سے ہی اپنی ایکسل ورک شیٹ میں تاریخوں کی فہرست موجود ہے اور آپ جاننا چاہتے ہیں کہ کون سے لیپ سال ہیں، تو فارمولے میں YEAR فنکشن کو شامل کریں تاکہ ایک سال نکالا جائے۔ ایک تاریخ:

=DAY(DATE(YEAR(A2),3,1)-1)=29

جہاں A2 ایک سیل ہے جس میں تاریخ ہے۔

فارمولے کے ذریعے واپس کیے گئے نتائج درج ذیل ہیں:

متبادل طور پر، آپ فروری کے آخری دن کو واپس کرنے کے لیے EOMONTH فنکشن کا استعمال کر سکتے ہیں، اور اس نمبر کا 29:

=DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29

فارمولے کو مزید صارف دوست بنانے کے لیے موازنہ کر سکتے ہیں۔ IF فنکشن کا استعمال کریں اور اسے حاصل کریں۔واپس جائیں، صحیح اور غلط کی بجائے "لیپ سال" اور "عام سال" کہیے:

=IF(DAY(DATE(YEAR(A2),3,1)-1)=29, "Leap year", "Common year")

=IF(DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29, "Leap year", "Common year")

فارمولہ 2 چیک کریں کہ آیا سال میں 366 دن ہیں

یہ ایک اور واضح امتحان ہے جس کے لیے شاید ہی کسی وضاحت کی ضرورت ہو۔ ہم اگلے سال کے 1-جنوری کو واپس کرنے کے لیے ایک DATE فنکشن استعمال کرتے ہیں، اس سال کے 1-جنوری کو حاصل کرنے کے لیے ایک اور DATE فنکشن استعمال کرتے ہیں، مؤخر الذکر کو سابقہ ​​سے گھٹائیں اور چیک کریں کہ آیا فرق 366 کے برابر ہے:

=DATE(2016,1,1) - DATE(2015,1,1)=366

کسی سیل میں درج تاریخ کی بنیاد پر سال کا حساب لگانے کے لیے، آپ Excel YEAR فنکشن کو بالکل اسی طرح استعمال کرتے ہیں جیسا کہ ہم نے پچھلی مثال میں کیا تھا:

=DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366

جہاں A2 تاریخ پر مشتمل ایک سیل ہے۔

اور قدرتی طور پر، آپ اوپر والے DATE/YEAR فارمولے کو IF فنکشن میں منسلک کر سکتے ہیں تاکہ یہ TRUE اور FALSE کی بولین اقدار سے زیادہ معنی خیز چیز واپس کر سکے:

=IF(DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366, "Leap year", "Non-leap year")

جیسا کہ پہلے ہی ذکر کیا گیا ہے، یہ ایکسل میں لیپ سالوں کا حساب لگانے کے واحد ممکنہ طریقے نہیں ہیں۔ اگر آپ دوسرے حل جاننا چاہتے ہیں، تو آپ مائیکروسافٹ کے تجویز کردہ طریقہ کو چیک کر سکتے ہیں۔ ہمیشہ کی طرح، مائیکروسافٹ کے لوگ آسان طریقے نہیں ڈھونڈ رہے ہیں، کیا وہ ہیں؟

امید ہے، اس مضمون نے آپ کو ایکسل میں سال کے حساب کتاب کرنے میں مدد کی ہے۔ میں پڑھنے کے لیے آپ کا شکریہ ادا کرتا ہوں اور اگلے ہفتے آپ سے ملنے کا منتظر ہوں۔