Энэ заавар нь Excel-ийн YEAR функцийн синтакс, хэрэглээг тайлбарлаж, оныг огнооноос гаргаж авах, огноог сар, жил болгон хөрвүүлэх, төрсөн өдрөөс эхлэн насыг тооцоолох, тодорхойлох томъёоны жишээг өгдөг. үсрэнгүй жил.

Сүүлийн хэдэн нийтлэлээрээ бид Excel программ дээр огноо, цагийг тооцоолох янз бүрийн аргуудыг судалж, WEEK DAY, WEEKNUM, MONTH, DAY гэх мэт олон төрлийн ашигтай функцуудыг сурсан. Өнөөдөр бид илүү том цагийн нэгж дээр анхаарлаа төвлөрүүлж, Excel-ийн ажлын хуудсан дээр жилүүдийг тооцоолох талаар ярилцах болно.

Энэ зааварт та:

ЖИЛ функцийг сурах болно. Excel-д

Excel-ийн YEAR функц нь өгөгдсөн огноотой харгалзах дөрвөн оронтой жилийг 1900-аас 9999 хүртэлх бүхэл тоогоор буцаана.

Excel-ийн YEAR функцын синтакс нь үүнтэй адил энгийн. дараах байж болно:

Энд серийн_тоо нь таны олохыг хүссэн жилийн хүчинтэй огноо юм.

Excel YEAR томъёо

Excel-д YEAR томьёо хийхийн тулд та эх огноог хэд хэдэн аргаар оруулж болно.

ОГноо функцийг ашиглах

Excel-д огноог оруулах хамгийн найдвартай арга бол DATE функцийг ашиглах явдал юм.

Жишээ нь, дараах томьёо нь 2015 оны 4-р сарын 28-ны оныг буцаана:

=YEAR(DATE(2015, 4, 28))

Дотоод Excel системд

-ийг илэрхийлсэн серийн дугаар, огноо нь 1-р сарын 1-ний өдөр хадгалагданаExcel-д огноог хэрхэн хадгалдаг талаарх мэдээллийг Excel огнооны форматаас харна уу.

2015 оны 4-р сарын 28-ны өдрийг 42122 гэж хадгалсан тул та энэ тоог дараах томьёонд шууд оруулах боломжтой.

=YEAR(42122)

Хэдийгээр зөвшөөрөгдөх боловч огнооны дугаарлалт өөр өөр системд өөр байж болох тул энэ аргыг хэрэглэхийг зөвлөдөггүй.

Нүдний лавлагааны хувьд

Таныг зарим нүдэнд хүчинтэй огноотой гэж үзвэл, та зүгээр л тэр нүд рүү хандаж болно. Жишээ нь:

=YEAR(A1)

Өөр томьёоны үр дүнд

Жишээ нь, та TODAY() функцийг ашиглан одоогийн огнооноос оныг гаргаж болно:

=YEAR(TODAY())

Текст байдлаар

Энгийн тохиолдолд YEAR томьёо нь текст хэлбэрээр оруулсан огноог ч ойлгох боломжтой, жишээ нь:

=INT((TODAY()-B2)/365)

Энэ аргыг ашиглахдаа огноог Excel-ийн ойлгосон форматаар оруулсан эсэхээ давхар шалгана уу. Түүнчлэн, Microsoft нь огноог текст утга болгон оруулсан тохиолдолд зөв үр дүнг баталгаажуулахгүй гэдгийг санаарай.

Дараах дэлгэцийн агшинд дээрх YEAR-ийн бүх томьёо ажиллаж байгаа бөгөөд бүгд таны бодож байсанчлан 2015 оныг буцаана :)

Excel дээр огноог жил рүү хэрхэн хөрвүүлэх вэ

Та Excel-д огнооны мэдээлэлтэй ажиллах үед таны ажлын хуудсанд ихэвчлэн сар, өдөр, жил зэрэг бүтэн огноо харагдана. . Гэсэн хэдий ч томоохон үйл явдлууд болон бүтээгдэхүүн худалдаанд гаргах, хөрөнгө худалдаж авах зэрэг чухал үйл явдлуудын хувьд та дахин оруулах эсвэл өөрчлөхгүйгээр зөвхөн оныг харахыг хүсэж болно.анхны өгөгдөл. Доор та үүнийг хийх 3 хурдан арга замыг олох болно.

Жишээ 1. YEAR функцийг ашиглан огнооноос нэг жилийг задлах

Үнэндээ та Excel дээр YEAR функцийг хэрхэн ашиглахаа аль хэдийн мэддэг болсон. огноог жил болгон хөрвүүлэх. Дээрх дэлгэцийн агшин нь олон тооны томъёог харуулж байгаа бөгөөд та доорх дэлгэцийн агшинд цөөн хэдэн жишээг харж болно. YEAR функц нь огноог бүх боломжит форматаар төгс ойлгодог болохыг анхаарна уу:

Жишээ 2. Excel-д огноог сар, жил болгон хөрвүүлэх

Өгөгдсөн огноог хөрвүүлэх Та TEXT функцийг ашиглан нэгж бүрийг тус тусад нь задалж, дараа нь нэг томьёоны дотор тэдгээр функцийг нэгтгэж болно.

TEXT функцэд та сар, жилээр өөр өөр кодуудыг ашиглаж болно, тухайлбал:

• "ммм" - 1-р сараас 12-р сарын хооронд товчилсон нэрс
• "мммм" - бүтэн сарын нэр, 1-р сараас 12-р сарын байдлаар.
• "yy" - 2 оронтой жил
• "yyyy" - 4 оронтой жил

Гаралтыг илүү сайн уншигдахын тулд та кодыг таслал, зураас эсвэл бусад тэмдэгтээр тусгаарлаж болно. дараах Огноо сар, Жил томьёотой адил:

=TEXT(B2, "mmmm") & ", " & TEXT(B2, "yyyy")

Эсвэл

=TEXT(B2, "mmm") & "-" & TEXT(B2, "yy")

Энд B2 нь агуулсан нүд юм огноо.

Жишээ 3. Огноог жилээр харуулах

Хэрэв таны ажлын дэвтэрт огноог хэрхэн хадгалах нь хамаагүй бол та Excel-ийг зөвхөн өнгөрсөн жилүүдийг харуулахын тулд аваарай анхны огноог өөрчлөх. Өөрөөр хэлбэл, та байж болнобүрэн огноог нүднүүдэд хадгалсан боловч зөвхөн он жилийг харуулна.

Энэ тохиолдолд томьёо шаардлагагүй. Та зүгээр л Ctrl + 1 дарж Формат нүднүүдийг харилцах цонхыг нээгээд Дугаар таб дээрээс Захиалгат ангиллыг сонгоод <-д доорх кодуудын аль нэгийг оруулна уу. 1>Type хайрцаг:

• yy - 2 оронтой жилийг 00 - 99 гэж харуулах.
• yyyy - 4 оронтой жилийг 1900 - 9999 гэж харуулах .

Энэ арга нь анхны огноог өөрчилдөггүй , зөвхөн таны ажлын хуудсанд огноог харуулах хэлбэрийг өөрчилдөг гэдгийг санаарай. Хэрэв та томьёоныхоо ийм нүднүүдийг харвал Microsoft Excel нь жилийн тооцоолол гэхээсээ илүү огнооны тооцоолол хийх болно.

Огнооны форматыг өөрчлөх талаар дэлгэрэнгүй мэдээллийг Excel-ийн огнооны форматыг хэрхэн өөрчлөх талаар энэ заавараас авах боломжтой.

Excel дээр төрсөн огнооноос насыг хэрхэн тооцох вэ

Excel дээр төрсөн огнооны насыг тооцоолох хэд хэдэн арга байдаг - DATEDIF, YEARFRAC эсвэл INT функцийг TODAY()-тай хослуулан ашиглах. TODAY функц нь насыг тооцоолох огноог өгдөг бөгөөд таны томъёолол үргэлж зөв насыг буцаана.

Төрсөн өдрөөс эхлэн насыг жилээр тооцох

Хүний насыг тооцоолох уламжлалт арга жилээр бол одоогийн огнооноос төрсөн огноог хасна. Энэ арга нь өдөр тутмын амьдралд сайн ажилладаг боловч Excel-ийн насыг тооцоолох ижил төстэй томъёо нь бүрэн үнэн биш юм:

DOB нь төрсөн огноо юм.

Томъёоны эхний хэсэг (TODAY()-B2) нь ялгаа нь хоног бөгөөд та үүнийг 365-д хувааж, жилийн тоог гаргана. Ихэнх тохиолдолд энэ тэгшитгэлийн үр дүн нь аравтын бутархай тоо бөгөөд та үүнийг хамгийн ойрын бүхэл тоо хүртэл дугуйлах INT функцтэй байна.

Төрсөн он сар өдрийг B2 нүдэнд байна гэж үзвэл бүрэн томъёо дараах байдлаар гарна. :

=INT((TODAY()-B2)/365)

Дээр дурьдсанчлан энэ насны тооцооны томъёо нь үргэлж өө сэвгүй байдаггүй, яагаад гэвэл эндээс. Дөрөв дэх жил бүр үсрэнгүй жил бөгөөд 366 хоног байдаг бол томьёо нь өдрийн тоог 365-д хуваадаг. Тэгэхээр, хэрэв хэн нэгэн 2-р сарын 29-нд төрсөн бол өнөөдөр 2-р сарын 28 бол энэ насны томъёо нь хүнийг нэг өдөр хөгшрүүлнэ.

365-ын оронд 365.25-д хуваах нь бас төгс биш юм, жишээлбэл, өндөр жилийг туулж амжаагүй байгаа хүүхдийн насыг тооцоолоход.

Дээрх зүйлийг харгалзан үзвэл та үүнийг хийх болно. хэвийн амьдралын насыг тооцоолох энэ аргыг илүү сайн хадгалж, Excel дээр төрсөн огнооноос насыг тооцоолохдоо дараах томъёоны аль нэгийг ашиглана уу.

Дээрх томъёоны дэлгэрэнгүй тайлбарыг Excel програмын насыг хэрхэн тооцоолох талаар өгсөн болно. Дараах дэлгэцийн агшин нь насыг тооцоолох бодит томъёог харуулж байна:

=DATEDIF(B2, TODAY(), "y")

Насыг яг тооцоолох ньтөрсөн он сар өдөр (жил, сар, өдрөөр)

Насыг яг он, сар, өдрөөр тооцоолохын тулд сүүлийн аргумент дээр DATEDIF гурван функцийг дараах нэгжээр бичнэ үү:

• Y - бүтэн жилийн тоог тооцоолох.
• YM - жилүүдийг үл тоомсорлож, саруудын зөрүүг гаргах.
• MD - жил, сарыг үл тоомсорлох өдрийн зөрүүг гаргах. .

Дараа нь DATEDIF 3 функцийг нэг томьёонд нэгтгэж, функц тус бүрээр буцаасан тоог таслалаар тусгаарлаж, тоо бүр ямар утгатай болохыг тодорхойл.

Огноог нь тооцвол. Төрөлт нь В2 нүдэнд байгаа тул бүрэн томьёо нь дараах байдалтай байна:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

Энэ насны томъёо нь өвчтөний насыг нарийн харуулах, эсвэл эмч нарт маш хэрэгтэй байж болно. бүх ажилтны насыг яг таг мэдэх боловсон хүчний ажилтан:

Тодорхой өдөр эсвэл тодорхой жил насыг тооцох гэх мэт илүү томьёоны жишээг дараахаас үзнэ үү. заавар: Excel программ дээр насыг хэрхэн тооцоолох талаар.

Жилийн өдрийн дугаарыг (1-365) хэрхэн авах вэ

Энэ жишээ нь жилийн тодорхой өдрийн тоог 1-ээс 365 хүртэлх (өндөр жилүүдэд 1-366) хэрхэн авах боломжтойг харуулж байна. 1-р сарын 1-ний өдөр гэж тооцогдоно.

Үүний тулд YEAR функцийг огноотой хамт дараах байдлаар ашиглаарай:

=A2-DATE(YEAR(A2), 1, 0)

А2 нь огноог агуулсан нүд юм.

Тэгээд одоо томъёо нь яг юу болохыг харцгаая. The YEAR функц нь A2 нүдэн дэх огнооны оныг олж аваад DATE(жил, сар, өдөр) функц руу дамжуулж, тодорхой огноог илэрхийлсэн дараалсан дугаарыг буцаана.

Тиймээс манай томьёогоор year -ыг анхны огнооноос (A2), month -ыг 1 (1-р сар), day нь 0-ээс гаргаж авсан. Үнэн хэрэгтээ тэг өдөр нь Excel-ийг өмнөх оны 12-р сарын 31-нд буцаахыг шаарддаг. , учир нь бид 1-р сарын 1-ний өдрийг 1 дэх өдөр гэж үзэхийг хүсч байна. Дараа нь та DATE томьёогоор буцаасан серийн дугаарыг анхны огнооноос (энэ нь Excel-д серийн дугаар хэлбэрээр хадгалагддаг) хасах ба ялгаа нь таны хайж буй жилийн өдөр юм. Жишээлбэл, 2015 оны 1-р сарын 5-ны өдрийг 42009, 2014 оны 12-р сарын 31-ний өдрийг 42004 гэж хадгалсан тул 42009 - 42004 = 5 байна.

Хэрэв 0 өдрийн тухай ойлголт танд тохирохгүй байвал та дараахыг ашиглаж болно. оронд нь томьёо:

=A2-DATE(YEAR(A2), 1, 1)+1

Жилд үлдсэн өдрүүдийн тоог хэрхэн тооцох вэ

Онд үлдсэн өдрийн тоог тооцоолохын тулд бид дараахыг ашиглана. DATE болон YEAR функцууд дахин ажиллана. Томъёо нь дээрх жишээ 3-тай ижил арга дээр үндэслэсэн тул түүний логикийг ойлгоход танд хүндрэл гарахгүй байх магадлалтай:

=DATE(YEAR(A2),12,31)-A2

Хэрэв та Хэрэв та одоогийн огнооноос хамааран он дуусахад хэдэн өдөр үлдсэнийг мэдэхийг хүсвэл Excel TODAY() функцийг дараах байдлаар ашиглана:

=DATE(2015, 12, 31)-TODAY()

2015 он бол тухайн жил юм. .

ТооцоолохExcel дэх үсрэлтийн жилүүд

Таны мэдэж байгаагаар бараг 4 дэх жил бүр 2-р сарын 29-нд нэмэлт өдөртэй байдаг бөгөөд үүнийг үсрэлтийн жил гэж нэрлэдэг. Microsoft Excel-ийн хуудаснуудад та тодорхой огноо нь үсрэлтийн жил эсвэл нийтлэг жилд хамаарах эсэхийг янз бүрийн аргаар тодорхойлж болно. Миний бодлоор ойлгоход хялбар хэдхэн томьёо үзүүлье.

Формула 1. Хоёрдугаар сард 29 хоног байгаа эсэхийг шалгаарай

Энэ бол маш ойлгомжтой шалгалт. 2-р сар үсрэнгүй жил 29 хоногтой тул тухайн жилийн 2-р сарын хэдэн өдрийн тоог тооцоолж, 29-тэй харьцуулна. Жишээ нь:

=DAY(DATE(2015,3,1)-1)=29

Энэ томъёонд DATE(2015,3,1) функц нь 2015 оны 3-р сарын 1-ний өдрийг буцаадаг бөгөөд үүнээс бид 1-ийг хасдаг. DAY функц нь энэ огнооноос өдрийн дугаарыг гаргаж авдаг бөгөөд бид энэ тоог 29-тэй харьцуулдаг. Хэрэв тоонууд таарч байвал, томьёо нь ҮНЭН, өөрөөр бол ХУДАЛ гэж буцаана.

Хэрэв танд Excel-ийн ажлын хуудсанд огнооны жагсаалт байгаа бөгөөд аль нь өндөр жил болохыг мэдэхийг хүсвэл YEAR функцийг томъёоноос нэг жилийг гаргаж авна уу. огноо:

=DAY(DATE(YEAR(A2),3,1)-1)=29

А2 нь огноо агуулсан нүд юм.

Томьёогоор буцаасан үр дүн дараах байдалтай байна:

Өөрөөр та EOMONTH функцийг ашиглан 2-р сарын сүүлийн өдрийг буцааж, энэ тоог 29-тэй харьцуулж болно:

=DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29

Томьёог хэрэглэгчдэд илүү ээлтэй болгохын тулд , IF функцийг ажиллуулж, түүнд байгаарайҮНЭН, ХУДАЛ гэхийн оронд "Үсрэнгүй жил", "Нийтийн жил" гэж буцаа:

=IF(DAY(DATE(YEAR(A2),3,1)-1)=29, "Leap year", "Common year")

=IF(DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29, "Leap year", "Common year")

Формула 2 Жилд 366 хоног байгаа эсэхийг шалгаарай

Энэ бол ямар ч тайлбар шаарддаггүй өөр нэг илэрхий шалгалт юм. Бид дараагийн жилийн 1-р сарын 1-нийг буцаахын тулд нэг DATE функцийг, энэ оны 1-р сарын 1-нийг авахын тулд өөр DATE функцийг ашиглаж, эхнийхээс сүүлийнхийг хасч, зөрүү нь 366-тай тэнцэх эсэхийг шалгана:

=DATE(2016,1,1) - DATE(2015,1,1)=366

Зарим нүдэнд оруулсан огноог үндэслэн жилийг тооцоолохын тулд та Excel YEAR функцийг өмнөх жишээн дээр ашигласантай яг адилхан ашиглана:

=DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366

Энд A2 нь огноо агуулсан нүд юм.

Мөн мэдээжийн хэрэг та дээрх ОГНОО/ЖИЛ томьёог IF функцэд хавсаргаж, ҮНЭН ба ХУДАЛ гэсэн логикийн утгуудаас илүү утгатай зүйлийг буцаана:

=IF(DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366, "Leap year", "Non-leap year")

Урьд дурьдсанчлан эдгээр нь Excel дээр үсрэлтийн жилийг тооцоолох цорын ганц боломжит арга биш юм. Хэрэв та өөр шийдлүүдийг мэдэхийг хүсч байвал Microsoft-ын санал болгосон аргыг шалгаж болно. Ердийнх шигээ Майкрософт залуус амархан арга хайдаггүй биз дээ?

Энэ нийтлэл танд Excel-ийн жилийн тооцоог гаргахад тусалсан гэж найдаж байна. Уншиж байгаад баярлалаа, ирэх долоо хоногт тантай уулзахыг тэсэн ядан хүлээж байна.