Ang tutorial ay nagpapaliwanag kung paano magbilang ng mga salita sa Excel sa pamamagitan ng paggamit ng LEN function kasama ng iba pang mga Excel function, at nagbibigay ng case-sensitive at case-insensitive na mga formula upang mabilang ang kabuuan o partikular na mga salita/text sa isang cell o range .

Ang Microsoft Excel ay may ilang mga kapaki-pakinabang na function na maaaring bilangin ang halos lahat: ang COUNT function upang mabilang ang mga cell na may mga numero, COUNTA upang mabilang ang mga cell na hindi blangko, COUNTIF at COUNTIFS upang mabilang ang mga cell na may kondisyon, at LEN para kalkulahin ang haba ng isang text string.

Sa kasamaang palad, hindi nagbibigay ang Excel ng anumang built-in na tool para sa pagbibilang ng bilang ng mga salita. Sa kabutihang palad, sa pamamagitan ng pagsasama-sama ng mga function ng serval maaari kang gumawa ng mas kumplikadong mga formula upang magawa ang halos anumang gawain. At gagamitin namin ang diskarteng ito para magbilang ng mga salita sa Excel.

Paano bilangin ang kabuuang bilang ng mga salita sa isang cell

Upang magbilang ng mga salita sa isang cell, gamitin ang sumusunod na kumbinasyon ng mga function ng LEN, SUBSTITUTE at TRIM:

Kung saan ang cell ay ang address ng cell kung saan mo gustong magbilang ng mga salita.

Halimbawa, para magbilang ng mga salita sa cell A2, gamitin ang formula na ito:

=LEN(TRIM(A2))-LEN(SUBSTITUTE(A2," ",""))+1

At pagkatapos, maaari mong kopyahin ang formula pababa upang mabilang ang mga salita sa iba pang mga cell ng column A:

Paano gumagana ang word counting formula na ito

Una, ginagamit mo ang SUBSTITUTE function upang alisin ang lahat ng mga puwang sa cell sa pamamagitan ng pagpapalit sa mga ito ng walang laman na textstring ("") para sa function na LEN upang ibalik ang haba ng string na walang mga puwang:

LEN(SUBSTITUTE(A2," ",""))

Pagkatapos nito, ibawas mo ang haba ng string nang walang mga puwang mula sa kabuuang haba ng string, at magdagdag ng 1 sa huling bilang ng salita, dahil ang bilang ng mga salita sa isang cell ay katumbas ng bilang ng mga puwang at 1.

Bukod pa rito, ginagamit mo ang TRIM function upang alisin ang mga karagdagang espasyo sa cell, kung mayroon man. Minsan ang isang worksheet ay maaaring maglaman ng maraming hindi nakikitang mga puwang, halimbawa dalawa o higit pang mga puwang sa pagitan ng mga salita, o mga character na espasyo na hindi sinasadyang na-type sa simula o dulo ng teksto (ibig sabihin, mga puwang sa unahan at likuran). At lahat ng dagdag na puwang na iyon ay maaaring itapon ang iyong bilang ng salita. Upang maiwasan ito, bago kalkulahin ang kabuuang haba ng string, ginagamit namin ang TRIM function upang alisin ang lahat ng labis na espasyo maliban sa mga solong espasyo sa pagitan ng mga salita.

Pinahusay na formula na maayos na humahawak sa mga walang laman na cell

Ang formula sa itaas upang mabilang ang mga salita sa Excel ay matatawag na perpekto kung hindi para sa isang disbentaha - nagbabalik ito ng 1 para sa mga walang laman na cell. Para ayusin ito, maaari kang magdagdag ng IF statement para tingnan kung may mga blangkong cell:

=IF(A2="", 0, LEN(TRIM(A2))-LEN(SUBSTITUTE(A2," ",""))+1)

Gaya ng nakikita mo sa screenshot sa itaas, bumabalik ang formula zero para sa mga blangkong cell, at ang tamang bilang ng salita para sa mga cell na hindi walang laman.

Paano magbilang ng mga partikular na salita sa isang cell

Upang bilangin kung ilang beses lumalabas ang isang partikular na salita, teksto, o substring sa isang cell, gamitin ang sumusunodformula:

=(LEN( cell )-LEN(SUBSTITUTE( cell , word ,"")))/LEN( word )

Halimbawa, kalkulahin natin ang bilang ng mga paglitaw ng " moon " sa cell A2:

=(LEN(A2)-LEN(SUBSTITUTE(A2, "moon","")))/LEN("moon")

Sa halip na ilagay ang salitang direktang mabibilang sa formula, maaari mo itong i-type sa ilang cell, at i-reference ang cell na iyon sa iyong formula. Bilang resulta, makakakuha ka ng mas maraming nalalaman na formula upang mabilang ang mga salita sa Excel.

Tip. Kung plano mong kopyahin ang iyong formula sa maraming mga cell, tiyaking ayusin ang reference sa cell na naglalaman ng salitang bibilangin gamit ang $ sign. Halimbawa:

=(LEN(A2)-LEN(SUBSTITUTE(A2, $B$1,"")))/LEN($B$1)

Paano binibilang ng formula na ito ang mga paglitaw ng isang partikular na text sa isang cell

1. Tinatanggal ng SUBSTITUTE function ang tinukoy salita mula sa orihinal na text.

Sa halimbawang ito, inaalis namin ang salitang input sa cell B1 mula sa orihinal na text na matatagpuan sa A2:

SUBSTITUTE(A2, $B$1,"")

Sa halimbawang ito, ibinabalik ng LEN(SUBSTITUTE(A2, $B$1,"")) ang haba ng text sa cell A2 pagkatapos alisin ang lahat ng character na nasa lahat ng paglitaw ng salitang " moon ".

(LEN(A2)-LEN(SUBSTITUTE(A2, $B$1,"")))

Ang resulta nito ang operation ay ang bilang ng mga character na nasa lahat ng paglitaw ng target na salita, na 12 sa halimbawang ito (3 paglitaw ng salitang " moon ", 4 na character bawat isa).

Bukod sa pagbibilang ng bilang ng ilang partikular na salita sa isang cell, maaari mong gamitin ang formula na ito upang mabilang ang mga paglitaw ng alinmang text (substring). Halimbawa, mabibilang mo kung ilang beses lumalabas ang text na " pick " sa cell A2:

Case-sensitive na formula upang mabilang ang mga partikular na salita sa isang cell

Tulad ng malamang na alam mo, ang Excel SUBSTITUTE ay isang case-sensitive na function, at samakatuwid ang word counting formula batay sa SUBSTITUTE ay case-sensitive bilang default:

Case-insensitive na formula upang mabilang ang mga partikular na salita sa isang cell

Kung kailangan mong bilangin ang parehong uppercase at lowercase na paglitaw ng isang partikular na salita, gamitin ang alinman sa UPPER o LOWER function sa loob ng SUBSTITUTE upang i-convert ang orihinal na text at ang text na gusto mong bilangin sa parehong case.

O

Halimbawa, para mabilang ang bilang ng mga paglitaw ng salita sa B1 sa loob ng cell A2 hindi pinapansin ang case, gamitin ang formula na ito:

=(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2),LOWER($B$1),"")))/LEN($B$1)

Gaya ng ipinakita sa ibabascreenshot, ibinabalik ng formula ang parehong bilang ng salita hindi alintana kung ang salita ay nai-type sa UPPERCASE (cell B1), lowercase (cell D1) o Sentence case (cell C1):

Bilangin ang kabuuang bilang ng mga salita sa isang hanay

Upang malaman kung ilang salita ang nilalaman ng isang partikular na hanay, kunin ang formula na nagbibilang ng kabuuang mga salita sa isang cell at i-embed ito sa loob ng alinman sa SUMPRODUCT o SUM function:

O

Ang SUMPRODUCT ay isa sa ilang Excel na function na kayang humawak ng mga array, at kumpletuhin mo ang formula sa karaniwang paraan sa pamamagitan ng pagpindot sa Enter key.

Para sa SUM function na kalkulahin ang mga array, dapat itong gamitin sa array formula, na kinukumpleto sa pamamagitan ng pagpindot sa Ctrl+Shift+Enter sa halip na ang karaniwang Enter stroke.

Halimbawa, para mabilang ang lahat ng salita sa hanay na A2:A4, gamitin ang isa sa mga sumusunod na formula:

=SUMPRODUCT(LEN(TRIM(A2:A4))-LEN(SUBSTITUTE(A2:A4," ",""))+1)

=SUM(LEN(TRIM(A2:A4))-LEN(SUBSTITUTE(A2:A4," ",""))+1)

Bilangin ang mga partikular na salita sa isang ra nge

Kung gusto mong bilangin kung ilang beses lumalabas ang isang partikular na salita o teksto sa loob ng isang hanay ng mga cell, gumamit ng katulad na diskarte - kunin ang formula upang mabilang ang mga partikular na salita sa isang cell, at pagsamahin ito sa SUM o SUMPRODUCT function:

O

Pakitandaang pindutin ang Ctrl+Shift+Enter para makumpleto nang tama ang array SUM formula.

Halimbawa, upang bilangin ang lahat ng paglitaw ng salitang ipinasok sa cell C1 sa loob ng hanay na A2:A4, gamitin ang formula na ito:

=SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE(A2:A4, C1,"")))/LEN(C1))

Habang ikaw tandaan, ang SUBSTITUTE ay isang function na case-sensitive , at samakatuwid ang formula sa itaas ay nakikilala sa pagitan ng uppercase at lowercase na text:

Upang gawin ang formula case-insensitive , gamitin ang alinman sa UPPER o LOWER na function:

=SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE((UPPER(A2:A4)),UPPER(C1),"")))/LEN(C1))

O

=SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE((LOWER(A2:A4)),LOWER(C1),"")))/LEN(C1))

Ito ay kung paano mo binibilang ang mga salita sa Excel. Upang mas maunawaan at malamang na ma-reverse-engineer ang mga formula, maaari kang mag-download ng sample na Excel Count Words workbook.

Kung wala sa mga formula na tinalakay sa tutorial na ito ang nakalutas sa iyong gawain, pakitingnan ang sumusunod na listahan ng mga mapagkukunan na nagpapakita ng iba pang mga solusyon sa pagbilang ng mga cell, text at indibidwal na mga character sa Excel.