Aquest tutorial explica la sintaxi i els usos de la funció ANY d'Excel i ofereix exemples de fórmules per extreure l'any de la data, convertir la data en el mes i l'any, calcular l'edat a partir de la data de naixement i determinar anys de traspàs.

En algunes publicacions recents, hem explorat diferents maneres de calcular dates i hores a Excel i hem après diverses funcions útils com ara WEEKDAY, WEEKNUM, MONTH i DAY. Avui ens centrarem en una unitat de temps més gran i parlarem sobre el càlcul d'anys als vostres fulls de treball d'Excel.

En aquest tutorial, aprendràs:

Funció YEAR a Excel

La funció ANY a Excel retorna un any de quatre dígits corresponent a una data determinada com a nombre enter de 1900 a 9999.

La sintaxi de la funció ANY d'Excel és tan senzilla com podria ser:

On serial_number és qualsevol data vàlida de l'any que vulgueu trobar.

Fórmula d'ANY d'Excel

Per crear una fórmula d'ANY a Excel, podeu proporcionar la data d'origen de diverses maneres.

Usant la funció DATA

El La manera més fiable de proporcionar una data a Excel és utilitzar la funció DATA.

Per exemple, la fórmula següent retorna l'any del 28 d'abril de 2015:

=YEAR(DATE(2015, 4, 28))

Com un número de sèrie que representa la data

Al sistema Excel intern, les dates s'emmagatzemen com a números de sèrie a partir de l'1 de gener de 1900, que s'emmagatzema com a número 1. Per a més informacióinformació sobre com s'emmagatzemen les dates a Excel, consulteu Format de data d'Excel.

El dia 28 d'abril de 2015 s'emmagatzema com a 42122, de manera que podeu introduir aquest número directament a la fórmula:

=YEAR(42122)

Tot i que és acceptable, aquest mètode no es recomana perquè la numeració de la data pot variar en diferents sistemes.

Com a referència de cel·la

Suposant que teniu una data vàlida en alguna cel·la, simplement podeu fer referència a aquesta cel·la. Per exemple:

=YEAR(A1)

Com a resultat d'alguna altra fórmula

Per exemple, podeu utilitzar la funció TODAY() per extreure l'any de la data actual:

=YEAR(TODAY())

Com a text

En un cas simple, la fórmula ANY fins i tot pot entendre les dates introduïdes com a text, com aquesta:

=YEAR("28-Apr-2015")

Quan utilitzeu aquest mètode, comproveu que introduïu la data en el format que entén Excel. A més, recordeu que Microsoft no garanteix resultats correctes quan s'ofereix una data com a valor de text.

La captura de pantalla següent mostra totes les fórmules ANY anteriors en acció, totes retornant el 2015 com podríeu esperar :)

Com convertir la data en any a Excel

Quan treballeu amb informació de data a Excel, els vostres fulls de treball solen mostrar dates completes, inclosos el mes, el dia i l'any . Tanmateix, per a fites importants i esdeveniments importants, com ara llançaments de productes o adquisicions d'actius, és possible que vulgueu veure només l'any sense tornar a introduir ni modificar eldades originals. A continuació, trobareu 3 maneres ràpides de fer-ho.

Exemple 1. Extraieu un any des de la data mitjançant la funció ANY

De fet, ja sabeu com utilitzar la funció ANY a Excel convertir una data en un any. La captura de pantalla anterior mostra un munt de fórmules, i podeu veure alguns exemples més a la captura de pantalla següent. Observeu que la funció ANY entén perfectament les dates en tots els formats possibles:

Exemple 2. Converteix la data en mes i any a Excel

Per convertir una data determinada a any i mes, podeu utilitzar la funció TEXT per extreure cada unitat individualment i, a continuació, concatenar aquestes funcions dins d'una fórmula.

A la funció TEXT, podeu utilitzar codis diferents per a mesos i anys, com ara:

• "mmm": noms de mesos abreujats, com a gener - desembre.
• "mmmm": noms de mesos complets, com a gener - desembre.
• "aa" - Anys de 2 dígits
• "aaaa" - Anys de 4 dígits

Per facilitar la lectura de la sortida, podeu separar els codis amb una coma, un guionet o qualsevol altre caràcter. com a les fórmules Data a mes i any següents:

=TEXT(B2, "mmmm") & ", " & TEXT(B2, "yyyy")

O

=TEXT(B2, "mmm") & "-" & TEXT(B2, "yy")

On B2 és una cel·la que conté una data.

Exemple 3. Mostra una data com a any

Si realment no importa com s'emmagatzemen les dates al vostre llibre de treball, podeu obtenir Excel per mostrar només els anys sense canviant les dates originals. En altres paraules, pots tenirles dates completes s'emmagatzemen a les cel·les, però només es mostren els anys.

En aquest cas, no cal cap fórmula. Només heu d'obrir el diàleg Format de cel·les prement Ctrl + 1 , seleccioneu la categoria Personalitzat a la pestanya Número i introduïu un dels codis següents a Escriviu el quadre:

• yy - per mostrar anys de 2 dígits, com a 00 - 99.
• yyyy - per mostrar anys de 4 dígits, com 1900 - 9999 .

Recordeu que aquest mètode no canvia la data original , només canvia la manera com es mostra la data al vostre full de treball. Si feu referència a aquestes cel·les a les vostres fórmules, Microsoft Excel farà càlculs de dates en lloc de càlculs d'anys.

Podeu trobar més detalls sobre com canviar el format de la data en aquest tutorial: Com canviar el format de la data a Excel.

Com calcular l'edat a partir de la data de naixement a Excel

Hi ha diverses maneres de calcular l'edat a partir de la data de naixement a Excel: utilitzant la funció DATEDIF, YEARFRAC o INT en combinació amb TODAY(). La funció AVUI proporciona la data per calcular l'edat, assegurant-se que la fórmula sempre retornarà l'edat correcta.

Calculeu l'edat des de la data de naixement en anys

La forma tradicional de calcular l'edat d'una persona en anys és restar la data de naixement de la data actual. Aquest enfocament funciona bé a la vida quotidiana, però una fórmula anàloga de càlcul d'edat d'Excel no és perfectament certa:

On DAB és la data de naixement.

La primera part de la fórmula (TODAY()-B2) calcula el la diferència són dies i la divideixes per 365 per obtenir el nombre d'anys. En la majoria dels casos, el resultat d'aquesta equació és un nombre decimal i la funció INT l'arrodoneix fins a l'enter més proper.

Suposant que la data de naixement es troba a la cel·la B2, la fórmula completa és la següent :

=INT((TODAY()-B2)/365)

Com s'ha esmentat anteriorment, aquesta fórmula de càlcul d'edat no sempre és perfecta, i aquí teniu el perquè. Cada 4t any és un any de traspàs que conté 366 dies, mentre que la fórmula divideix el nombre de dies per 365. Per tant, si algú va néixer el 29 de febrer i avui és el 28 de febrer, aquesta fórmula d'edat farà que una persona sigui un dia més gran.

Dividir per 365,25 en comptes de 365 tampoc és impecable, per exemple, quan es calcula l'edat d'un nen que encara no ha viscut un any de traspàs.

Tenint en compte l'anterior, hauríeu millor deseu aquesta manera de calcular l'edat per a la vida normal i utilitzeu una de les fórmules següents per calcular l'edat a partir de la data de naixement a Excel.

L'explicació detallada de les fórmules anteriors es proporciona a Com calcular l'edat a Excel. I la següent captura de pantalla mostra una fórmula de càlcul de l'edat real en acció:

=DATEDIF(B2, TODAY(), "y")

Calcul de l'edat exacta a partir dedata de naixement (en anys, mes i dies)

Per calcular una edat exacta en anys, mesos i dies, escriu tres funcions DATEDIF amb les unitats següents a l'últim argument:

• Y - per calcular el nombre d'anys complets.
• YM - per obtenir la diferència entre els mesos, ignorant els anys.
• MD - per obtenir la diferència entre els dies, ignorant els anys i els mesos. .

A continuació, concateneu les 3 funcions DATEDIF en una única fórmula, separeu els nombres retornats per cada funció amb comes i definiu el que significa cada nombre.

Suposant la data de el naixement es troba a la cel·la B2, la fórmula completa és la següent:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

Aquesta fórmula d'edat pot ser molt útil, per exemple, perquè un metge mostri l'edat exacta dels pacients o per un oficial de personal per conèixer l'edat exacta de tots els empleats:

Per obtenir més exemples de fórmules com ara calcular l'edat en una data determinada o en un any determinat, consulteu el següent tutorial: Com calcular l'edat a Excel.

Com obtenir el número de dia de l'any (1-365)

Aquest exemple demostra com es pot obtenir el número d'un dia determinat en un any, entre 1 i 365 (1-366 en anys de traspàs) amb l'1 de gener considerat el dia 1.

Per a això, utilitzeu la funció ANY juntament amb DATA d'aquesta manera:

=A2-DATE(YEAR(A2), 1, 0)

On A2 és una cel·la que conté la data.

I ara, anem a veure què fa realment la fórmula. ElLa funció YEAR recupera l'any de la data a la cel·la A2 i el passa a la funció DATE(any, mes, dia) , que retorna el número seqüencial que representa una data determinada.

Així, a la nostra fórmula, year s'extreu de la data original (A2), month és 1 (gener) i day és 0. De fet, un dia zero obliga Excel a tornar el 31 de desembre de l'any anterior , perquè volem que l'1 de gener sigui tractat com el 1r dia. A continuació, resteu el número de sèrie que retorna la fórmula DATE de la data original (que també s'emmagatzema com a número de sèrie a Excel) i la diferència és el dia de l'any que busqueu. Per exemple, el 5 de gener de 2015 s'emmagatzema com a 42009 i el 31 de desembre de 2014 és 42004, de manera que 42009 - 42004 = 5.

Si el concepte del dia 0 no us sembla correcte, podeu utilitzar el següent fórmula en lloc d'això:

=A2-DATE(YEAR(A2), 1, 1)+1

Com calcular el nombre de dies que queden a l'any

Per calcular el nombre de dies que queden a l'any, farem servir el Funcions DATE i YEAR de nou. La fórmula es basa en el mateix enfocament que l'exemple 3 anterior, de manera que és poc probable que tingueu cap dificultat per entendre la seva lògica:

=DATE(YEAR(A2),12,31)-A2

Si Si voleu saber quants dies queden per al final de l'any en funció de la data actual, feu servir la funció Excel TODAY(), de la següent manera:

=DATE(2015, 12, 31)-TODAY()

On 2015 és l'any actual .

Càlculanys de traspàs a Excel

Com ja sabeu, gairebé cada 4t any té un dia addicional el 29 de febrer i s'anomena any de traspàs. Als fulls de Microsoft Excel, podeu determinar si una data determinada pertany a un any de traspàs o a un any comú de diverses maneres. Vaig a demostrar només un parell de fórmules, que al meu entendre són més fàcils d'entendre.

Fórmula 1. Comproveu si febrer té 29 dies

Aquesta és una prova molt òbvia. Com que febrer té 29 dies en anys de traspàs, calculem el nombre de dies del mes 2 d'un any determinat i el comparem amb el número 29. Per exemple:

=DAY(DATE(2015,3,1)-1)=29

En aquesta fórmula, la La funció DATE(2015,3,1) retorna el dia 1 de març de l'any 2015, del qual restem 1. La funció DIA extreu el número del dia d'aquesta data i el comparem amb el 29. Si els números coincideixen, la fórmula retorna TRUE, FALSE en cas contrari.

Si ja teniu una llista de dates al vostre full de treball Excel i voleu saber quines són anys de traspàs, incorporeu la funció ANY a la fórmula per extreure un any de una data:

=DAY(DATE(YEAR(A2),3,1)-1)=29

On A2 és una cel·la que conté la data.

Els resultats que retorna la fórmula són els següents:

Com a alternativa, podeu utilitzar la funció EOMONTH per tornar l'últim dia de febrer i comparar aquest número amb 29:

=DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29

Per fer la fórmula més fàcil d'utilitzar , utilitzeu la funció SI i tingueu-latorna, per exemple, "Any de traspàs" i "Any comú" en lloc de VERTADER i FALS:

=IF(DAY(DATE(YEAR(A2),3,1)-1)=29, "Leap year", "Common year")

=IF(DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29, "Leap year", "Common year")

Fórmula 2 Comprova si l'any té 366 dies

Aquesta és una altra prova evident que gairebé no requereix cap explicació. Utilitzem una funció DATE per retornar l'1 de gener de l'any següent, una altra funció de DATA per obtenir l'1 de gener d'aquest any, restem la segona de la primera i comproveu si la diferència és igual a 366:

=DATE(2016,1,1) - DATE(2015,1,1)=366

Per calcular un any a partir d'una data introduïda en alguna cel·la, utilitzeu la funció ANY d'Excel exactament de la mateixa manera que vam fer a l'exemple anterior:

=DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366

On A2 és una cel·la que conté la data.

I, naturalment, podeu incloure la fórmula DATA/ANY anterior a la funció SI perquè retorni quelcom més significatiu que els valors booleans de TRUE i FALSE:

=IF(DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366, "Leap year", "Non-leap year")

Com ja s'ha esmentat, aquestes no són les úniques maneres possibles de calcular els anys de traspàs a Excel. Si teniu curiositat per conèixer altres solucions, podeu consultar el mètode suggerit per Microsoft. Com és habitual, els nois de Microsoft no busquen maneres fàcils, oi?

Tant de bo, aquest article t'hagi ajudat a esbrinar els càlculs anuals a Excel. Us agraeixo la lectura i espero veure-us la setmana vinent.