Nakakakuha ng maraming #N/A na error sa iyong mga worksheet at gusto mong malaman kung may paraan para magpakita ng custom na text sa halip? Ang formula ng IFNA ay ang solusyon na kailangan mo.

Kapag ang isang Excel formula ay hindi matukoy o makahanap ng isang bagay, ito ay naglalabas ng #N/A error. Upang mahuli ang ganoong error at palitan ito ng isang user-friendly na mensahe, maaari mong gamitin ang function ng IFNA. Sa madaling salita, ang #N/A ay ang paraan ng Excel para sabihin na ang value na hinahanap mo ay wala sa reference na dataset. Ang IFNA ay ang iyong paraan ng pag-trap at paghawak sa error na iyon.

IFNA function sa Excel

Ang Excel IFNA function ay nilayon para sa paghuli at paghawak ng #N/A error. Kung ang isang formula ay nagsusuri sa #N/A, ang IFNA ay na-trap ang error na iyon at pinapalitan ito ng custom na halaga na iyong tinukoy; kung hindi ay nagbabalik ng normal na resulta ng formula.

IFNA syntax

Ang syntax ng IFNA function ay ang sumusunod:

Where:

Value (kinakailangan) - ang formula, value, o reference para tingnan kung may #N/A error.

Value_if_na (kinakailangan) - ang value upang bumalik kung may nakitang #N/A na error.

Mga tala sa paggamit

• Hinahawakan lang ng function ng IFNA ang #N/A nang hindi pinipigilan ang anumang iba pang mga error.
• Kung ang argument na value ay isang array formula , ang IFNA ay nagbabalik ng hanay ng mga resulta, isa sa bawat cell, tulad ng ipinapakita sa halimbawang ito.

IFNA availability

Ang IFNA function ay ipinakilala saExcel 2013 at available sa lahat ng kasunod na bersyon kabilang ang Excel 2016, Excel 2019, Excel 2021, at Microsoft 365.

Sa mga naunang bersyon, maaari mong makuha ang #N/A error sa pamamagitan ng paggamit ng IF at ISNA function nang magkasama.

Paano gamitin ang function ng IFNA sa Excel

Upang epektibong magamit ang IFNA sa Excel, sundin ang generic na diskarte na ito:

1. Sa unang argumento ( value ), maglagay ng formula na naapektuhan ng #N/A error.
2. Sa pangalawang argumento ( value_if_na ), i-type ang text na gusto mong ibalik sa halip na ang karaniwang notation ng error. Upang ibalik ang isang walang laman na cell kapag walang nahanap, magbigay ng walang laman na string ('"").

Upang ibalik ang custom na text , ang generic na formula ay:

Upang magbalik ng blank cell , ang generic na formula ay:

Tingnan natin kung paano ito gumagana sa isang simpleng halimbawa. Sa talahanayan sa ibaba, ipagpalagay na gusto mong malaman kung paano nagra-rank ang isang marka ng isang estudyante sa iba pa. Dahil ang data ay pinagbukud-bukod ayon sa column na Score mula sa pinakamataas hanggang sa pinakamababa, tutugma ang ranggo sa relatibong posisyon ng mag-aaral sa talahanayan. At para makuha ang posisyon, maaari mong gamitin ang MATCH function sa pinakasimpleng anyo nito:

=MATCH(E1, A2:A10, 0)

Dahil hindi available ang lookup value (Neal) sa lookup array (A2:A10), may naganap na #N/A error.

Nararanasan ang error na ito, maaaring isipin ng mga bagitong user na may mali saformula, at ikaw bilang tagalikha ng workbook ay makakatanggap ng maraming tanong. Upang maiwasan ito, maaari mong tahasang ipahiwatig na tama ang formula, hindi lang nito mahanap ang halaga na hinihiling na hanapin. Kaya, ilalagay mo ang formula ng MATCH sa unang argument ng IFNA at, sa pangalawang argumento, i-type ang iyong custom na text, "Not found" sa aming kaso:

=IFNA(MATCH(E1, A2:A10, 0), "Not found")

Ngayon, sa halip na ang karaniwang notation ng error, ang sarili mong text ay ipinapakita sa isang cell, na nagpapaalam sa mga user na ang lookup value ay wala sa dataset:

Paano gamitin ang IFNA sa VLOOKUP

Kadalasan nangyayari ang #N/A error sa mga function na naghahanap ng isang bagay gaya ng VLOOKUP, HLOOKUP, LOOKUP, at MATCH. Ang mga halimbawa sa ibaba ay sumasaklaw sa ilang karaniwang mga kaso ng paggamit.

Halimbawa 1. Pangunahing IFNA VLOOKUP formula

Upang ma-trap ang #N/A error na nangyayari kapag ang VLOOKUP ay hindi makahanap ng tugma, tingnan ang resulta nito gamit ang IFNA at tukuyin ang halaga na ipapakita sa halip na ang error. Ang karaniwang kasanayan ay i-wrap ang function ng IFNA sa iyong umiiral nang VLOOKUP formula gamit ang syntax na ito:

Sa aming sample na talahanayan, ipagpalagay na gusto mong kumuha ng marka ng isang partikular na mag-aaral (E1). Para dito, ginagamit mo ang klasikong formula ng VLOOKUP na ito:

=VLOOKUP(E1, A2:B10, 2, FALSE)

Ang isyu ay hindi kumuha ng pagsusulit si Neal, kaya wala ang kanyang pangalan sa listahan, at halatang nabigo ang VLOOKUP na mahanap isang tugma.

Upang itago ang error, kamibalutin ang VLOOKUP sa IFNA ng ganito:

=IFNA(VLOOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

Ngayon, ang resulta ay hindi mukhang nakakatakot sa user at mas nagbibigay-kaalaman:

Halimbawa 2. IFNA VLOOKUP upang maghanap sa maraming sheet

Ang IFNA function ay magagamit din para sa pagsasagawa ng tinatawag na sequential o chained lookup sa maraming sheet o iba't ibang workbook. Ang ideya ay ang paglalagay mo ng ilang magkakaibang IFNA(VLOOKUP(…)) na mga formula sa isa't isa sa ganitong paraan:

Kung ang isang pangunahing VLOOKUP ay walang mahanap, ang IFNA function nito ay tatakbo sa susunod na VLOOKUP hanggang sa makita ang nais na halaga. Kung nabigo ang lahat ng paghahanap, ibabalik ng formula ang tinukoy na teksto.

Ipagpalagay na mayroon kang mga marka ng iba't ibang klase na nakalista sa iba't ibang sheet (pinangalanang Class A , Class B , at Class C ). Ang iyong layunin ay makuha ang marka ng isang partikular na mag-aaral, na ang pangalan ay nakalagay sa cell B1 sa iyong kasalukuyang worksheet. Upang matupad ang gawain, gamitin ang formula na ito:

=IFNA(VLOOKUP(B1, 'Class A'!A2:B5, 2, FALSE), IFNA(VLOOKUP(B1, 'Class B'!A2:B5, 2, FALSE), IFNA(VLOOKUP(B1, 'Class C'!A2:B5, 2, FALSE), "Not found")))

Ang formula ay sunud-sunod na naghahanap para sa tinukoy na pangalan sa tatlong magkakaibang mga sheet sa pagkakasunud-sunod na ang VLOOKUP ay naka-nest at nagdadala ng unang nakitang tugma:

Halimbawa 3. IFNA na may INDEX MATCH

Sa katulad na paraan, mahuhuli ng IFNA ang #N/A na error na nabuo ng iba pang mga function ng paghahanap. Bilang halimbawa, gamitin natin ito kasama ng INDEX MATCHformula:

=IFNA(INDEX(B2:B10, MATCH(E1, A2:A10, 0)), "Not found")

Ang diwa ng formula ay pareho sa lahat ng nakaraang halimbawa - INDEX MATCH ay nagsasagawa ng lookup, at sinusuri ng IFNA ang resulta at nakakuha ng #N/A error kung ang hindi nakita ang reference na value.

IFNA na magbabalik ng maraming resulta

Kung sakaling ang panloob na function (ibig sabihin, ang formula na inilagay sa value argument) ay nagbabalik ng maraming halaga, susubok ang IFNA sa bawat ibinalik na halaga nang paisa-isa at maglalabas ng hanay ng mga resulta. Halimbawa:

=IFNA(VLOOKUP(D2:D4, A2:B10, 2, FALSE), "Not found")

Sa Dynamic Array Excel (Microsoft 365 at Excel 2021), ang isang regular na formula sa pinakatuktok na cell (E2) ay awtomatikong naglalabas ng lahat ng resulta sa mga kalapit na cell (sa mga termino ng Excel, tinatawag itong spill range).

Sa mga pre-dynamic na bersyon (Excel 2019 at mas mababa), maaaring makamit ang isang katulad na epekto sa pamamagitan ng paggamit ng multi-cell array formula, na kinumpleto gamit ang shortcut na Ctrl + Shift + Enter.

Ano ang pagkakaiba ng IFNA at IFERROR?

Depende sa root cause ng problema, ang isang Excel formula ay maaaring mag-trigger ng iba't ibang mga error gaya ng #N/A, #NAME, #VALUE, #REF, #DIV/0, #NUM, at iba pa. Ang IFERROR function ay nakakakuha ng lahat ng mga error habang ang IFNA ay limitado lamang sa #N/A. Alin ang mas mahusay na piliin? Depende iyon sa sitwasyon.

Kung gusto mong sugpuin ang anumang uri ng error , gamitin ang function na IFERROR. Ito ay lalong kapaki-pakinabang sa mga kumplikadong kalkulasyon kapag ang isang formulamay kasamang ilang function na maaaring makabuo ng iba't ibang error.

Sa lookup functions , mas mabuting gamitin mo ang IFNA dahil nagpapakita lang ito ng custom na resulta kapag hindi nakita ang value ng lookup at hindi itinago ang pinagbabatayan. mga problema sa mismong formula.

Upang ilarawan ang pagkakaiba, ibalik natin ang ating pangunahing IFNA VLOOKUP formula at "aksidenteng" maling spell ang pangalan ng function (VLOKUP sa halip na VLOOKUP).

=IFNA(VLOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

Hindi pinipigilan ng IFNA ang error na ito, kaya malinaw mong makikita na may mali sa isa sa mga pangalan ng function:

Ngayon, tingnan natin kung ano ang mangyayari kung gagamit ka IFERROR:

=IFERROR(VLOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

Hmm… sinasabi nito na hindi kumuha ng pagsusulit si Olivia, na hindi totoo! Ito ay dahil ang function ng IFERROR ay nakulong ang #NAME? error at ibinabalik sa halip ang custom na text. Sa sitwasyong ito, hindi lang ito nagbabalik ng maling impormasyon ngunit tinatakpan din nito ang isyu sa formula.

Ganyan gamitin ang formula ng IFNA sa Excel. Salamat sa pagbabasa at umaasa akong makita ka sa aming blog sa susunod na linggo!

Mga available na download

Mga halimbawa ng formula ng Excel IFNA (.xlsx file)