यह ट्यूटोरियल एक्सेल YEAR फ़ंक्शन के वाक्य-विन्यास और उपयोग की व्याख्या करता है और वर्ष को तिथि से निकालने, तिथि को महीने और वर्ष में बदलने, जन्म तिथि से आयु की गणना करने और निर्धारित करने के लिए सूत्र उदाहरण प्रदान करता है लीप वर्ष।

हाल की कुछ पोस्टों में, हमने एक्सेल में तिथियों और समयों की गणना करने के विभिन्न तरीकों की खोज की है और विभिन्न प्रकार के उपयोगी कार्यों जैसे WEEKDAY, WEEKNUM, MONTH, और DAY को सीखा है। आज, हम एक बड़ी समय इकाई पर ध्यान केंद्रित करने जा रहे हैं और आपकी एक्सेल वर्कशीट में वर्षों की गणना के बारे में बात करेंगे।

इस ट्यूटोरियल में, आप सीखेंगे:

YEAR फ़ंक्शन एक्सेल में

एक्सेल में YEAR फ़ंक्शन किसी दी गई तारीख के अनुरूप चार अंकों वाला वर्ष 1900 से 9999 तक एक पूर्णांक के रूप में देता है।

एक्सेल YEAR फ़ंक्शन का सिंटैक्स उतना ही सरल है जितना कि यह संभवतः हो सकता है:

जहां serial_number उस वर्ष की कोई मान्य तिथि है जिसे आप खोजना चाहते हैं।

एक्सेल वर्ष सूत्र

एक्सेल में वर्ष सूत्र बनाने के लिए, आप कई तरीकों से स्रोत दिनांक की आपूर्ति कर सकते हैं।

दिनांक फ़ंक्शन का उपयोग करके

एक्सेल में तिथि प्रदान करने का सबसे विश्वसनीय तरीका DATE फ़ंक्शन का उपयोग कर रहा है। दिनांक का प्रतिनिधित्व करने वाला एक सीरियल नंबर

आंतरिक एक्सेल सिस्टम में, दिनांक 1 जनवरी 1900 से शुरू होने वाले सीरियल नंबर के रूप में संग्रहीत होते हैं, जिसे नंबर 1 के रूप में संग्रहीत किया जाता है। अधिक के लिएएक्सेल में तिथियां कैसे संग्रहीत की जाती हैं, इस बारे में जानकारी, कृपया एक्सेल तिथि प्रारूप देखें।

28 अप्रैल, 2015 को 42122 के रूप में संग्रहीत किया जाता है, इसलिए आप इस संख्या को सीधे सूत्र में दर्ज कर सकते हैं:

=YEAR(42122)

हालांकि स्वीकार्य है, इस पद्धति की अनुशंसा नहीं की जाती है क्योंकि विभिन्न प्रणालियों में दिनांक क्रमांकन भिन्न हो सकता है। आप बस उस सेल का उल्लेख कर सकते हैं। उदाहरण के लिए:

=YEAR(A1)

किसी अन्य सूत्र के परिणामस्वरूप

उदाहरण के लिए, आप वर्तमान दिनांक से वर्ष निकालने के लिए TODAY() फ़ंक्शन का उपयोग कर सकते हैं:

=YEAR(TODAY())

पाठ के रूप में

एक साधारण स्थिति में, YEAR सूत्र पाठ के रूप में दर्ज की गई तारीखों को भी समझ सकता है, जैसे:

=YEAR("28-Apr-2015")

इस पद्धति का उपयोग करते समय, कृपया दोबारा जांच लें कि आप दिनांक को उस प्रारूप में दर्ज करते हैं जिसे एक्सेल समझता है। साथ ही, कृपया याद रखें कि Microsoft सही परिणाम की गारंटी नहीं देता है जब किसी दिनांक को पाठ मान के रूप में प्रदान किया जाता है।

निम्नलिखित स्क्रीनशॉट क्रियाशील उपरोक्त सभी YEAR फ़ार्मुलों को प्रदर्शित करता है, जैसा कि आप उम्मीद कर सकते हैं सभी 2015 लौट रहे हैं :)

एक्सेल में तारीख को साल में कैसे बदलें

जब आप एक्सेल में तारीख की जानकारी के साथ काम करते हैं, तो आपकी वर्कशीट में आमतौर पर महीने, दिन और साल सहित पूरी तारीखें दिखती हैं . हालांकि, प्रमुख मील के पत्थर और महत्वपूर्ण घटनाओं जैसे उत्पाद लॉन्च या परिसंपत्ति अधिग्रहण के लिए, आप केवल वर्ष को फिर से दर्ज या संशोधित किए बिना देखना चाह सकते हैंमूल डेटा। नीचे, आपको ऐसा करने के 3 त्वरित तरीके मिलेंगे।

उदाहरण 1. YEAR फ़ंक्शन का उपयोग करके दिनांक से एक वर्ष निकालें

वास्तव में, आप पहले से ही जानते हैं कि Excel में YEAR फ़ंक्शन का उपयोग कैसे करें एक तारीख को एक साल में बदलने के लिए। ऊपर दिया गया स्क्रीनशॉट सूत्रों का एक समूह प्रदर्शित करता है, और आप नीचे स्क्रीनशॉट में कुछ और उदाहरण देख सकते हैं। ध्यान दें कि YEAR फ़ंक्शन सभी संभावित स्वरूपों में तिथियों को पूरी तरह से समझता है:

उदाहरण 2. Excel में दिनांक को माह और वर्ष में बदलें

किसी दी गई तिथि को परिवर्तित करने के लिए वर्ष और महीने के लिए, आप प्रत्येक इकाई को अलग-अलग निकालने के लिए टेक्स्ट फ़ंक्शन का उपयोग कर सकते हैं, और फिर उन कार्यों को एक सूत्र में जोड़ सकते हैं।

टेक्स्ट फ़ंक्शन में, आप महीनों और वर्षों के लिए अलग-अलग कोड का उपयोग कर सकते हैं, जैसे:

• "एमएमएम" - संक्षिप्त महीनों के नाम, जनवरी - दिसंबर के रूप में।
• "एमएमएमएम" - पूरे महीने के नाम, जनवरी - दिसंबर के रूप में। - 2-अंकीय वर्ष
• "yyyy" - 4-अंकीय वर्ष

आउटपुट को बेहतर पठनीय बनाने के लिए, आप कोड को अल्पविराम, हाइफ़न या किसी अन्य वर्ण से अलग कर सकते हैं, जैसे निम्नलिखित में महीने और साल की तारीख सूत्र:

=TEXT(B2, "mmmm") & ", " & TEXT(B2, "yyyy")

या

=TEXT(B2, "mmm") & "-" & TEXT(B2, "yy")

जहां B2 एक सेल है जिसमें एक तिथि।

उदाहरण 3. एक तिथि को एक वर्ष के रूप में प्रदर्शित करें

यदि वास्तव में इससे कोई फर्क नहीं पड़ता है कि आपकी कार्यपुस्तिका में तिथियां कैसे संग्रहीत की जाती हैं, तो आप कर सकते हैं केवल वर्षों को दिखाने के लिए एक्सेल प्राप्त करें मूल तिथियों को बदलना। दूसरे शब्दों में, आपके पास हो सकता हैसेल में पूर्ण तिथियां संग्रहीत होती हैं, लेकिन केवल वर्ष प्रदर्शित होते हैं।

इस मामले में, किसी सूत्र की आवश्यकता नहीं है। आप बस Ctrl + 1 दबाकर फ़ॉर्मेट सेल संवाद खोलें, संख्या टैब पर कस्टम श्रेणी का चयन करें, और नीचे दिए गए कोडों में से एक दर्ज करें टाइप करें बॉक्स:

• yy - 2-अंकीय वर्षों को प्रदर्शित करने के लिए, 00 - 99 के रूप में।
• yyyy - 4-अंकीय वर्षों को प्रदर्शित करने के लिए, 1900 - 9999 के रूप में .

कृपया याद रखें कि यह विधि मूल तिथि नहीं बदलती , यह केवल आपके कार्यपत्रक में दिनांक प्रदर्शित होने के तरीके को बदलती है। यदि आप अपने फ़ार्मुलों में ऐसी कोशिकाओं का उल्लेख करते हैं, तो Microsoft Excel वर्ष की गणना के बजाय दिनांक गणना करेगा।

आप इस ट्यूटोरियल में दिनांक स्वरूप बदलने के बारे में अधिक विवरण प्राप्त कर सकते हैं: Excel में दिनांक स्वरूप कैसे बदलें।

एक्सेल में जन्म तिथि से आयु की गणना कैसे करें

एक्सेल में जन्म तिथि से आयु की गणना करने के कई तरीके हैं - DATEDIF, YEARFRAC या INT फ़ंक्शन का उपयोग TODAY() के संयोजन में करें। TODAY फ़ंक्शन आयु की गणना करने के लिए दिनांक की आपूर्ति करता है, यह सुनिश्चित करता है कि आपका सूत्र हमेशा सही आयु लौटाएगा।

वर्षों में जन्म तिथि से आयु की गणना करें

किसी व्यक्ति की आयु की गणना करने का पारंपरिक तरीका वर्षों में वर्तमान तिथि से जन्म तिथि घटाना है। यह दृष्टिकोण रोजमर्रा की जिंदगी में ठीक काम करता है, लेकिन एक समान एक्सेल आयु गणना सूत्र पूरी तरह से सही नहीं है:

जहां DOB जन्मतिथि है।

सूत्र का पहला भाग (TODAY()-B2) गणना करता है अंतर दिनों का है, और आप वर्षों की संख्या प्राप्त करने के लिए इसे 365 से विभाजित करते हैं। ज्यादातर मामलों में, इस समीकरण का परिणाम एक दशमलव संख्या है, और आपके पास INT फ़ंक्शन है जो इसे निकटतम पूर्णांक तक ले जाता है।

यह मानते हुए कि जन्म तिथि सेल B2 में है, पूरा सूत्र इस प्रकार है :

=INT((TODAY()-B2)/365)

जैसा कि ऊपर बताया गया है, उम्र की गणना करने का यह फ़ॉर्मूला हमेशा दोषरहित नहीं होता है, और इसकी वजह यह है। प्रत्येक चौथा वर्ष एक लीप वर्ष होता है जिसमें 366 दिन होते हैं, जबकि सूत्र दिनों की संख्या को 365 से विभाजित करता है। इसलिए, यदि किसी का जन्म 29 फरवरी को हुआ था और आज 28 फरवरी है, तो यह आयु सूत्र एक व्यक्ति को एक दिन बड़ा बना देगा।

365 के बजाय 365.25 से विभाजित करना भी त्रुटिहीन नहीं है, उदाहरण के लिए, एक ऐसे बच्चे की उम्र की गणना करते समय जो अभी तक एक लीप वर्ष से नहीं जीया है।

उपरोक्त को देखते हुए, आप सामान्य जीवन के लिए आयु की गणना करने के इस तरीके को बेहतर ढंग से बचाएं, और एक्सेल में जन्म तिथि से आयु की गणना करने के लिए निम्न में से किसी एक सूत्र का उपयोग करें।

उपरोक्त सूत्रों की विस्तृत व्याख्या एक्सेल में उम्र की गणना कैसे करें में दी गई है। और निम्न स्क्रीनशॉट कार्रवाई में वास्तविक जीवन की आयु गणना सूत्र प्रदर्शित करता है:

=DATEDIF(B2, TODAY(), "y")

से सटीक आयु की गणना करनाजन्म तिथि (वर्षों, महीनों और दिनों में)

वर्षों, महीनों और दिनों में सटीक आयु की गणना करने के लिए, अंतिम तर्क में निम्नलिखित इकाइयों के साथ तीन DATEDIF फ़ंक्शन लिखें:

• Y - पूर्ण वर्षों की संख्या की गणना करने के लिए।
• YM - वर्षों की उपेक्षा करते हुए महीनों के बीच अंतर प्राप्त करने के लिए।
• MD - वर्षों और महीनों की उपेक्षा करते हुए दिनों के बीच अंतर प्राप्त करने के लिए .

और फिर, 3 DATEDIF फ़ंक्शन को एक सूत्र में जोड़ें, प्रत्येक फ़ंक्शन द्वारा दी गई संख्याओं को अल्पविराम से अलग करें, और परिभाषित करें कि प्रत्येक संख्या का क्या अर्थ है।

मान लें कि दिनांक जन्म कक्ष B2 में है, पूरा सूत्र इस प्रकार है:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

यह आयु सूत्र बहुत काम आ सकता है, मान लीजिए, एक डॉक्टर के लिए रोगियों की सटीक आयु प्रदर्शित करने के लिए, या सभी कर्मचारियों की सही आयु जानने के लिए एक कार्मिक अधिकारी:

अधिक सूत्र उदाहरणों के लिए जैसे किसी विशेष तिथि या किसी विशेष वर्ष में आयु की गणना करने के लिए, कृपया निम्नलिखित देखें ट्यूटोरियल: एक्सेल में उम्र की गणना कैसे करें।

वर्ष का दिन संख्या कैसे प्राप्त करें (1-365)

यह उदाहरण दर्शाता है कि आप एक वर्ष में 1 और 365 के बीच एक निश्चित दिन की संख्या कैसे प्राप्त कर सकते हैं (लीप वर्ष में 1-366) 1 जनवरी को पहला दिन माना जाता है।

इसके लिए, DATE के साथ YEAR फ़ंक्शन का उपयोग इस तरह करें:

=A2-DATE(YEAR(A2), 1, 0)

जहां A2 तारीख वाला सेल है।

और अब, देखते हैं कि सूत्र वास्तव में क्या करता है। YEAR फ़ंक्शन सेल A2 में दिनांक के वर्ष को पुनर्प्राप्त करता है, और इसे DATE(वर्ष, माह, दिन) फ़ंक्शन में पास करता है, जो एक निश्चित दिनांक का प्रतिनिधित्व करने वाली अनुक्रमिक संख्या लौटाता है।

इसलिए, हमारे सूत्र में, year मूल दिनांक (A2) से निकाला गया है, month 1 (जनवरी) है और day 0 है। वास्तव में, एक शून्य दिन एक्सेल को पिछले वर्ष के 31 दिसंबर को वापस करने के लिए बाध्य करता है। , क्योंकि हम चाहते हैं कि 1 जनवरी को पहला दिन माना जाए। और फिर, आप मूल दिनांक (जिसे एक्सेल में सीरियल नंबर के रूप में भी संग्रहीत किया जाता है) से दिनांक सूत्र द्वारा लौटाए गए सीरियल नंबर घटाते हैं और अंतर उस वर्ष का दिन होता है जिसे आप ढूंढ रहे हैं। उदाहरण के लिए, 5 जनवरी, 2015 को 42009 और 31 दिसंबर, 2014 को 42004 के रूप में संग्रहीत किया जाता है, इसलिए 42009 - 42004 = 5.

यदि दिन 0 की अवधारणा आपको सही नहीं लगती है, तो आप निम्न का उपयोग कर सकते हैं इसके बजाय सूत्र:

=A2-DATE(YEAR(A2), 1, 1)+1

वर्ष में शेष दिनों की संख्या की गणना कैसे करें

वर्ष में शेष दिनों की संख्या की गणना करने के लिए, हम इसका उपयोग करने जा रहे हैं DATE और YEAR फिर से कार्य करते हैं। सूत्र उपरोक्त उदाहरण 3 के समान दृष्टिकोण पर आधारित है, इसलिए आपको इसके तर्क को समझने में कोई कठिनाई होने की संभावना नहीं है:

=DATE(YEAR(A2),12,31)-A2

यदि आप जानना चाहते हैं कि वर्तमान तिथि के आधार पर वर्ष के अंत तक कितने दिन शेष हैं, तो आप एक्सेल टुडे () फ़ंक्शन का उपयोग निम्नानुसार करते हैं:

=DATE(2015, 12, 31)-TODAY()

वर्तमान वर्ष 2015 कहां है .

गणना करनाएक्सेल में लीप वर्ष

जैसा कि आप जानते हैं, लगभग हर चौथे वर्ष में 29 फरवरी को एक अतिरिक्त दिन होता है और इसे लीप वर्ष कहा जाता है। माइक्रोसॉफ्ट एक्सेल शीट्स में, आप यह निर्धारित कर सकते हैं कि एक निश्चित तिथि एक लीप वर्ष या सामान्य वर्ष से संबंधित है या नहीं। मैं केवल कुछ सूत्र प्रदर्शित करने जा रहा हूं, जो मेरी राय में समझने में सबसे आसान हैं।

फॉर्मूला 1. जांचें कि क्या फरवरी में 29 दिन हैं

यह एक बहुत ही स्पष्ट परीक्षा है। चूंकि फरवरी में लीप वर्ष में 29 दिन होते हैं, इसलिए हम दिए गए वर्ष के दूसरे महीने में दिनों की संख्या की गणना करते हैं और इसकी तुलना संख्या 29 से करते हैं। उदाहरण के लिए:

=DAY(DATE(2015,3,1)-1)=29

इस सूत्र में, DATE(2015,3,1) फ़ंक्शन वर्ष 2015 में मार्च का पहला दिन लौटाता है, जिसमें से हम 1 घटाते हैं। DAY फ़ंक्शन इस दिनांक से दिन की संख्या निकालता है, और हम उस संख्या की तुलना 29 से करते हैं। यदि संख्याएँ मेल खाती हैं, सूत्र TRUE लौटाता है, अन्यथा FALSE।

यदि आपके पास पहले से ही एक्सेल वर्कशीट में तारीखों की एक सूची है और आप जानना चाहते हैं कि कौन से लीप वर्ष हैं, तो एक वर्ष निकालने के लिए सूत्र में YEAR फ़ंक्शन को शामिल करें। दिनांक:

=DAY(DATE(YEAR(A2),3,1)-1)=29

जहां A2 दिनांक युक्त सेल है।

सूत्र द्वारा लौटाए गए परिणाम इस प्रकार हैं:

वैकल्पिक रूप से, आप फरवरी के अंतिम दिन को लौटाने के लिए EOMONTH फ़ंक्शन का उपयोग कर सकते हैं, और उस संख्या की तुलना 29 से कर सकते हैं:

=DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29

फ़ॉर्मूला को अधिक उपयोगकर्ता-अनुकूल बनाने के लिए , IF फ़ंक्शन को नियोजित करें और इसे प्राप्त करेंवापसी, TRUE और FALSE के बजाय "लीप वर्ष" और "सामान्य वर्ष" कहें:

=IF(DAY(DATE(YEAR(A2),3,1)-1)=29, "Leap year", "Common year")

=IF(DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29, "Leap year", "Common year")

फ़ॉर्मूला 2 . जांचें कि क्या वर्ष में 366 दिन हैं

यह एक और स्पष्ट परीक्षण है जिसके लिए शायद ही किसी स्पष्टीकरण की आवश्यकता है। हम अगले वर्ष के 1-जनवरी को वापस करने के लिए एक DATE फ़ंक्शन का उपयोग करते हैं, इस वर्ष का 1-जनवरी प्राप्त करने के लिए एक और DATE फ़ंक्शन, बाद वाले को पूर्व से घटाते हैं और जाँचते हैं कि क्या अंतर 366 के बराबर है:

=DATE(2016,1,1) - DATE(2015,1,1)=366

किसी सेल में दर्ज की गई तिथि के आधार पर वर्ष की गणना करने के लिए, आप एक्सेल वर्ष फ़ंक्शन का ठीक उसी तरह उपयोग करते हैं जैसे हमने पिछले उदाहरण में किया था:

=DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366

जहाँ A2 दिनांक युक्त सेल है।

और स्वाभाविक रूप से, आप उपरोक्त DATE / YEAR सूत्र को IF फ़ंक्शन में संलग्न कर सकते हैं ताकि यह TRUE और FALSE के बूलियन मानों की तुलना में कुछ अधिक सार्थक लौटा सके:

=IF(DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366, "Leap year", "Non-leap year")

जैसा कि पहले ही उल्लेख किया गया है, एक्सेल में लीप वर्ष की गणना करने के लिए ये एकमात्र संभव तरीके नहीं हैं। यदि आप अन्य समाधानों को जानने के लिए उत्सुक हैं, तो आप Microsoft द्वारा सुझाई गई विधि की जाँच कर सकते हैं। हमेशा की तरह, माइक्रोसॉफ्ट के लोग आसान तरीकों की तलाश नहीं कर रहे हैं, है ना?

उम्मीद है, इस लेख से आपको एक्सेल में साल की गणना करने में मदद मिली होगी। मैं आपको पढ़ने के लिए धन्यवाद देता हूं और अगले सप्ताह आपसे मिलने के लिए उत्सुक हूं।