हे ट्युटोरियल एक्सेल YEAR फंक्शनचे वाक्यरचना आणि वापर स्पष्ट करते आणि तारखेपासून वर्ष काढण्यासाठी, तारीख महिन्यात आणि वर्षात रूपांतरित करण्यासाठी, जन्म तारखेपासून वयाची गणना करण्यासाठी आणि निर्धारित करण्यासाठी सूत्र उदाहरणे प्रदान करते लीप वर्षे.

काही अलीकडील पोस्ट्समध्ये, आम्ही एक्सेलमध्ये तारखा आणि वेळा मोजण्याचे वेगवेगळे मार्ग शोधले आहेत आणि WEEKDAY, WEEKNUM, MONTH आणि DAY सारख्या विविध उपयुक्त कार्ये शिकलो आहोत. आज, आम्ही एका मोठ्या वेळेच्या युनिटवर लक्ष केंद्रित करणार आहोत आणि तुमच्या एक्सेल वर्कशीट्समध्ये वर्षांची गणना करण्याबद्दल बोलणार आहोत.

या ट्युटोरियलमध्ये तुम्ही शिकाल:

YEAR फंक्शन Excel मध्ये

Excel मधील YEAR फंक्शन 1900 ते 9999 पर्यंत पूर्णांक म्हणून दिलेल्या तारखेशी संबंधित चार-अंकी वर्ष मिळवते.

Excel YEAR फंक्शनची वाक्यरचना तितकीच सोपी आहे. कदाचित असे असू शकते:

जेथे अनुक्रमांक ही वर्षाची कोणतीही वैध तारीख आहे जी तुम्हाला शोधायची आहे.

Excel YEAR फॉर्म्युला

Excel मध्ये YEAR फॉर्म्युला बनवण्यासाठी, तुम्ही स्त्रोत तारीख अनेक प्रकारे देऊ शकता.

DATE फंक्शन वापरणे

द एक्सेलमध्ये तारीख पुरवण्याचा सर्वात विश्वासार्ह मार्ग म्हणजे DATE फंक्शन वापरणे.

उदाहरणार्थ, खालील सूत्र 28 एप्रिल, 2015 साठी वर्ष मिळवते:

=YEAR(DATE(2015, 4, 28))

म्हणून तारखेचे प्रतिनिधित्व करणारा अनुक्रमांक

अंतर्गत एक्सेल सिस्टीममध्ये, तारखा 1 जानेवारी 1900 पासून सुरू होणार्‍या अनुक्रमांक म्हणून संग्रहित केल्या जातात, ज्या क्रमांक 1 म्हणून संग्रहित केल्या जातात. अधिकसाठीएक्सेलमध्ये तारखा कशा संग्रहित केल्या जातात याबद्दल माहिती, कृपया एक्सेल तारीख स्वरूप पहा.

एप्रिल 28, 2015 चा दिवस 42122 म्हणून संग्रहित केला जातो, त्यामुळे तुम्ही हा क्रमांक थेट सूत्रामध्ये प्रविष्ट करू शकता:

=YEAR(42122)

स्वीकार्य असले तरी, या पद्धतीची शिफारस केलेली नाही कारण तारीख क्रमांक वेगवेगळ्या प्रणालींमध्ये बदलू शकतात.

सेल संदर्भ म्हणून

तुमच्याकडे काही सेलमध्ये वैध तारीख आहे असे गृहीत धरून, तुम्ही फक्त त्या सेलचा संदर्भ घेऊ शकता. उदाहरणार्थ:

=YEAR(A1)

काही इतर सूत्राचा परिणाम म्हणून

उदाहरणार्थ, तुम्ही वर्तमान तारखेपासून वर्ष काढण्यासाठी TODAY() फंक्शन वापरू शकता:

=YEAR(TODAY())

मजकूर म्हणून

सोप्या बाबतीत, YEAR सूत्र मजकूर म्हणून प्रविष्ट केलेल्या तारखा देखील समजू शकतो, जसे की:

=YEAR("28-Apr-2015")

ही पद्धत वापरताना, कृपया एक्सेलला समजत असलेल्या फॉरमॅटमध्ये तुम्ही तारीख टाकली आहे का ते पुन्हा तपासा. तसेच, कृपया लक्षात ठेवा की जेव्हा एखादी तारीख मजकूर मूल्य म्हणून पुरवली जाते तेव्हा Microsoft योग्य परिणामांची हमी देत ​​नाही.

खालील स्क्रीनशॉट वरील सर्व YEAR सूत्र कृतीत दर्शवतो, सर्व 2015 मध्ये तुमच्या अपेक्षेप्रमाणे परत येतात :)

Excel मध्ये तारखेला वर्षात कसे रूपांतरित करावे

जेव्हा तुम्ही Excel मध्ये तारखेच्या माहितीसह काम करता, तेव्हा तुमची वर्कशीट्स सहसा महिना, दिवस आणि वर्षासह पूर्ण तारखा प्रदर्शित करतात . तथापि, प्रमुख टप्पे आणि महत्त्वाच्या इव्हेंट्ससाठी जसे की उत्पादन लॉन्च किंवा मालमत्ता संपादन, आपण पुन्हा प्रविष्ट न करता किंवा सुधारित न करता फक्त वर्ष पाहू शकता.मूळ डेटा. खाली, तुम्हाला हे करण्यासाठी 3 द्रुत मार्ग सापडतील.

उदाहरण 1. YEAR फंक्शन वापरून तारखेपासून एक वर्ष काढा

खरं तर, तुम्हाला Excel मध्ये YEAR फंक्शन कसे वापरायचे हे आधीच माहित आहे. तारखेला वर्षात रूपांतरित करण्यासाठी. वरील स्क्रीनशॉट अनेक सूत्रांचे प्रदर्शन करतो आणि आपण खालील स्क्रीनशॉटमध्ये आणखी काही उदाहरणे पाहू शकता. लक्षात घ्या की YEAR फंक्शन सर्व संभाव्य फॉरमॅटमधील तारखा चांगल्या प्रकारे समजते:

उदाहरण 2. एक्सेलमध्ये तारखेला महिन्यात आणि वर्षात रूपांतरित करा

दिलेली तारीख रूपांतरित करण्यासाठी वर्ष आणि महिन्यासाठी, तुम्ही प्रत्येक युनिट स्वतंत्रपणे काढण्यासाठी TEXT फंक्शन वापरू शकता आणि नंतर ती फंक्शन्स एका सूत्रामध्ये एकत्र करू शकता.

TEXT फंक्शनमध्ये, तुम्ही महिने आणि वर्षांसाठी वेगवेगळे कोड वापरू शकता, जसे की:

• "mmmm" - संक्षेपित महिन्यांची नावे, जानेवारी - डिसेंबर म्हणून.
• "mmmm" - पूर्ण महिन्याची नावे, जानेवारी - डिसेंबर.
• "yy" - 2-अंकी वर्षे
• "yyyy" - 4-अंकी वर्षे

आउटपुट चांगले वाचनीय बनवण्यासाठी, तुम्ही स्वल्पविराम, हायफन किंवा इतर कोणत्याही वर्णाने कोड वेगळे करू शकता, खालील तारीख ते महिना आणि वर्ष सूत्रांप्रमाणे:

=TEXT(B2, "mmmm") & ", " & TEXT(B2, "yyyy")

किंवा

=TEXT(B2, "mmm") & "-" & TEXT(B2, "yy")

जेथे B2 हा सेल आहे एक तारीख.

उदाहरण 3. वर्ष म्हणून तारीख प्रदर्शित करा

जर तुमच्या वर्कबुकमध्ये तारखा कशा संग्रहित केल्या आहेत हे महत्त्वाचे नसेल, तर तुम्ही हे करू शकता फक्त वर्षे दाखवण्यासाठी Excel मिळवा मूळ तारखा बदलणे. दुसऱ्या शब्दांत, आपल्याकडे असू शकतेपूर्ण तारखा सेलमध्ये संग्रहित केल्या आहेत, परंतु केवळ वर्षे प्रदर्शित केल्या आहेत.

या प्रकरणात, कोणत्याही सूत्राची आवश्यकता नाही. तुम्ही फक्त Ctrl + 1 दाबून सेल्स फॉरमॅट करा डायलॉग उघडा, नंबर टॅबवर सानुकूल श्रेणी निवडा आणि <मध्ये खालीलपैकी एक कोड प्रविष्ट करा. 1>टाइप करा बॉक्स:

• yy - 2-अंकी वर्षे प्रदर्शित करण्यासाठी, 00 - 99 म्हणून.
• yyyy - 4-अंकी वर्षे प्रदर्शित करण्यासाठी, 1900 - 9999 म्हणून .

कृपया लक्षात ठेवा की ही पद्धत मूळ तारीख बदलत नाही , ती फक्त तुमच्या वर्कशीटमध्ये तारीख प्रदर्शित करण्याचा मार्ग बदलते. तुम्ही तुमच्या सूत्रांमध्ये अशा सेलचा संदर्भ घेतल्यास, मायक्रोसॉफ्ट एक्सेल वर्षाच्या गणनेऐवजी तारीख गणना करेल.

तुम्हाला या ट्युटोरियलमध्ये तारीख स्वरूप बदलण्याबद्दल अधिक तपशील मिळू शकतात: Excel मध्ये तारीख स्वरूप कसे बदलावे.

एक्सेलमध्ये जन्मतारखेपासून वयाची गणना कशी करायची

एक्सेलमध्ये जन्मतारखेचे वय मोजण्याचे अनेक मार्ग आहेत - TODAY() सह DATEDIF, YEARFRAC किंवा INT फंक्शन वापरून. TODAY फंक्शन वयाची गणना करण्यासाठी तारीख पुरवते, हे सुनिश्चित करते की तुमचे सूत्र नेहमी योग्य वय देईल.

जन्म तारखेपासून वर्षांमध्ये वयाची गणना करा

व्यक्तीचे वय मोजण्याचा पारंपारिक मार्ग वर्षे म्हणजे वर्तमान तारखेपासून जन्मतारीख वजा करणे. हा दृष्टीकोन दैनंदिन जीवनात चांगले कार्य करतो, परंतु समान एक्सेल वय गणना सूत्र पूर्णपणे सत्य नाही:

जिथे DOB ही जन्मतारीख आहे.

सूत्राचा पहिला भाग (TODAY()-B2) गणना करतो फरक दिवसांचा आहे आणि वर्षांची संख्या मिळविण्यासाठी तुम्ही त्यास ३६५ ने भागता. बर्‍याच प्रकरणांमध्ये, या समीकरणाचा परिणाम दशांश संख्या असतो आणि तुमच्याकडे INT फंक्शन जवळच्या पूर्णांकापर्यंत पूर्ण होते.

जन्मतारीख सेल B2 मध्ये आहे असे गृहीत धरून, संपूर्ण सूत्र खालीलप्रमाणे आहे :

=INT((TODAY()-B2)/365)

वर नमूद केल्याप्रमाणे, हे वय मोजणीचे सूत्र नेहमीच निर्दोष नसते आणि याचे कारण येथे आहे. प्रत्येक 4थे वर्ष हे लीप वर्ष असते ज्यामध्ये 366 दिवस असतात, तर सूत्र दिवसांच्या संख्येला 365 ने भागते. म्हणून, जर एखाद्याचा जन्म 29 फेब्रुवारीला झाला असेल आणि आज 28 फेब्रुवारी असेल तर, हे वय सूत्र एखाद्या व्यक्तीला एक दिवस मोठे करेल.

365 ऐवजी 365.25 ने भागणे देखील निर्दोष नाही, उदाहरणार्थ, अद्याप लीप वर्षात न जगलेल्या मुलाच्या वयाची गणना करताना.

वरील गोष्टी दिल्यास, तुम्ही सामान्य जीवनासाठी वयाची गणना करण्याचा हा मार्ग अधिक चांगला जतन करा आणि Excel मध्ये जन्मतारीख पासून वय मोजण्यासाठी खालीलपैकी एक सूत्र वापरा.

वरील सूत्रांचे तपशीलवार स्पष्टीकरण Excel मध्ये वय कसे मोजायचे ते दिले आहे. आणि खालील स्क्रीनशॉट वास्तविक जीवनातील वय मोजण्याचे सूत्र दाखवतो:

=DATEDIF(B2, TODAY(), "y")

पासून अचूक वय मोजत आहेजन्मतारीख (वर्षे, महिना आणि दिवसांमध्ये)

वर्षे, महिने आणि दिवसांमध्ये अचूक वय काढण्यासाठी, शेवटच्या युक्तिवादात खालील एककांसह तीन DATEDIF फंक्शन्स लिहा:

• Y - पूर्ण वर्षांची संख्या मोजण्यासाठी.
• YM - वर्षांकडे दुर्लक्ष करून महिन्यांमधील फरक मिळवण्यासाठी.
• MD - वर्ष आणि महिन्यांकडे दुर्लक्ष करून दिवसांमधील फरक मिळवण्यासाठी .

आणि नंतर, एकाच सूत्रात 3 DATEDIF फंक्शन्स एकत्र करा, प्रत्येक फंक्शनद्वारे मिळालेल्या संख्यांना स्वल्पविरामाने विभक्त करा आणि प्रत्येक संख्येचा अर्थ काय ते परिभाषित करा.

ची तारीख गृहीत धरून जन्म सेल B2 मध्ये आहे, संपूर्ण सूत्र खालीलप्रमाणे आहे:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

हे वयाचे सूत्र अतिशय उपयुक्त ठरू शकते, म्हणा, डॉक्टर रुग्णांचे नेमके वय दाखवण्यासाठी किंवा सर्व कर्मचार्‍यांचे नेमके वय जाणून घेण्यासाठी कर्मचारी अधिकारी:

विशिष्ट तारखेला किंवा विशिष्ट वर्षात वय मोजणे यासारख्या अधिक सूत्र उदाहरणांसाठी, कृपया खालील गोष्टी पहा ट्यूटोरियल: एक्सेलमध्ये वय कसे मोजायचे.

वर्षाचा दिवस क्रमांक कसा मिळवायचा (1-365)

हे उदाहरण दाखवते की तुम्ही एका वर्षातील ठराविक दिवसाची संख्या 1 ते 365 (लीप वर्षांमध्ये 1-366) मध्ये कशी मिळवू शकता. 1 जानेवारी हा दिवस 1 मानला जातो.

यासाठी, DATE सह YEAR फंक्शन या प्रकारे वापरा:

=A2-DATE(YEAR(A2), 1, 0)

जेथे A2 हा सेल आहे ज्यामध्ये तारीख आहे.

आणि आता, सूत्र प्रत्यक्षात काय करते ते पाहू. द YEAR फंक्शन सेल A2 मधील तारखेचे वर्ष पुनर्प्राप्त करते, आणि ते DATE(वर्ष, महिना, दिवस) फंक्शनमध्ये पास करते, जे एका विशिष्ट तारखेचे प्रतिनिधित्व करणारी अनुक्रमांक मिळवते.

म्हणून, आमच्या फॉर्म्युलामध्ये, year मूळ तारखेपासून (A2), month 1 (जानेवारी) आणि day 0 आहे. खरेतर, एक शून्य दिवस Excel ला मागील वर्षाच्या 31 डिसेंबरला परत करण्यास भाग पाडतो. , कारण 1 जानेवारी हा पहिला दिवस मानला जावा अशी आमची इच्छा आहे. आणि नंतर, तुम्ही मूळ तारखेपासून DATE सूत्राद्वारे परत आलेला अनुक्रमांक वजा करा (जो एक्सेलमध्ये अनुक्रमांक म्हणून देखील संग्रहित केला जातो) आणि फरक म्हणजे तुम्ही शोधत असलेल्या वर्षाचा दिवस. उदाहरणार्थ, 5 जानेवारी 2015 42009 म्हणून संग्रहित केले आहे आणि 31 डिसेंबर 2014 42004 आहे, म्हणून 42009 - 42004 = 5.

दिवस 0 ची संकल्पना तुम्हाला योग्य वाटत नसल्यास, तुम्ही खालील वापरू शकता त्याऐवजी सूत्र:

=A2-DATE(YEAR(A2), 1, 1)+1

वर्षातील उरलेल्या दिवसांची संख्या कशी मोजायची

वर्षातील उरलेल्या दिवसांची गणना करण्यासाठी, आपण वापरणार आहोत. DATE आणि YEAR पुन्हा कार्य करते. सूत्र हे वरील उदाहरण ३ सारख्याच दृष्टिकोनावर आधारित आहे, त्यामुळे तुम्हाला त्याचे तर्क समजण्यात काही अडचणी येण्याची शक्यता नाही:

=DATE(YEAR(A2),12,31)-A2

जर तुम्ही वर्तमान तारखेच्या आधारे वर्ष संपेपर्यंत किती दिवस शिल्लक आहेत हे जाणून घ्यायचे आहे, तुम्ही Excel TODAY() फंक्शन खालीलप्रमाणे वापरता:

=DATE(2015, 12, 31)-TODAY()

2015 हे चालू वर्ष कुठे आहे .

गणना करत आहेExcel मध्ये लीप वर्ष

तुम्हाला माहिती आहे की, जवळजवळ प्रत्येक चौथ्या वर्षात २९ फेब्रुवारीला एक अतिरिक्त दिवस असतो आणि त्याला लीप वर्ष म्हणतात. मायक्रोसॉफ्ट एक्सेल शीटमध्ये, तुम्ही ठराविक तारीख लीप वर्षाची आहे की सामान्य वर्षाची आहे हे विविध प्रकारे ठरवू शकता. मी फक्त काही सूत्रे दाखवणार आहे, जी माझ्या मते समजण्यास सर्वात सोपी आहेत.

फॉर्म्युला 1. फेब्रुवारीमध्ये 29 दिवस आहेत का ते तपासा

ही अतिशय स्पष्ट चाचणी आहे. लीप वर्षांमध्ये फेब्रुवारीमध्ये 29 दिवस असल्याने, आपण दिलेल्या वर्षाच्या महिन्या 2 मधील दिवसांची संख्या मोजतो आणि त्याची संख्या 29 शी तुलना करतो. उदाहरणार्थ:

=DAY(DATE(2015,3,1)-1)=29

या सूत्रात, DATE(2015,3,1) फंक्शन वर्ष 2015 मध्ये मार्चचा 1 ला दिवस मिळवते, ज्यामधून आपण 1 वजा करतो. DAY फंक्शन या तारखेपासून दिवस क्रमांक काढतो आणि आम्ही त्या संख्येची 29 शी तुलना करतो. जर संख्या जुळत असेल तर, फॉर्म्युला बरोबर मिळतो, अन्यथा असत्य.

तुमच्या एक्सेल वर्कशीटमध्ये तारखांची आधीच यादी असेल आणि तुम्हाला लीप वर्ष कोणते हे जाणून घ्यायचे असेल, तर फॉर्म्युलामध्ये YEAR फंक्शन समाविष्ट करा एक तारीख:

=DAY(DATE(YEAR(A2),3,1)-1)=29

जेथे A2 हा सेल आहे ज्यामध्ये तारीख आहे.

सूत्राद्वारे दिलेले परिणाम खालीलप्रमाणे आहेत:

वैकल्पिकपणे, तुम्ही फेब्रुवारीमधील शेवटचा दिवस परत करण्यासाठी EOMONTH फंक्शन वापरू शकता आणि त्या संख्येची तुलना 29:

=DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29

फॉर्म्युला अधिक वापरकर्ता-अनुकूल बनवण्यासाठी करू शकता. , IF फंक्शन वापरा आणि ते मिळवापरत करा, खरे आणि असत्य ऐवजी "लीप वर्ष" आणि "सामान्य वर्ष" म्हणा:

=IF(DAY(DATE(YEAR(A2),3,1)-1)=29, "Leap year", "Common year")

=IF(DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29, "Leap year", "Common year")

सूत्र 2 वर्षात 366 दिवस आहेत का ते तपासा

ही आणखी एक स्पष्ट चाचणी आहे ज्यासाठी क्वचितच काही स्पष्टीकरण आवश्यक आहे. आम्ही पुढील वर्षाचा 1-जानेवारी परत करण्यासाठी एक DATE फंक्शन वापरतो, या वर्षाचा 1-जानेवारी मिळवण्यासाठी दुसरे DATE फंक्शन वापरतो, आधीच्या मधून नंतरचे वजा करतो आणि फरक 366:

=DATE(2016,1,1) - DATE(2015,1,1)=366 <इतका आहे का ते तपासतो. 3>

काही सेलमध्ये एंटर केलेल्या तारखेवर आधारित वर्षाची गणना करण्यासाठी, आपण मागील उदाहरणाप्रमाणेच Excel YEAR फंक्शन वापरता:

=DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366

जेथे A2 हा सेल आहे ज्यामध्ये तारीख आहे.

आणि स्वाभाविकपणे, तुम्ही वरील DATE/YEAR सूत्र IF फंक्शनमध्ये संलग्न करू शकता जेणेकरून ते सत्य आणि असत्य या बूलियन मूल्यांपेक्षा अधिक अर्थपूर्ण परत येईल:

=IF(DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366, "Leap year", "Non-leap year")

आधीच नमूद केल्याप्रमाणे, Excel मध्ये लीप वर्षांची गणना करण्याचे हे एकमेव संभाव्य मार्ग नाहीत. तुम्ही इतर उपाय जाणून घेण्यास उत्सुक असल्यास, तुम्ही Microsoft ने सुचवलेली पद्धत तपासू शकता. नेहमीप्रमाणे, मायक्रोसॉफ्टचे लोक सोपे मार्ग शोधत नाहीत, ते आहेत का?

आशेने, या लेखाने तुम्हाला Excel मध्ये वर्षाची गणना करण्यात मदत केली आहे. वाचल्याबद्दल मी तुमचा आभारी आहे आणि पुढच्या आठवड्यात तुम्हाला भेटण्यास उत्सुक आहे.