Dieses Tutorial erklärt die Syntax und die Verwendung der Excel-Funktion JAHR und bietet Formelbeispiele, um das Jahr aus dem Datum zu extrahieren, das Datum in Monat und Jahr umzuwandeln, das Alter aus dem Geburtsdatum zu berechnen und Schaltjahre bestimmen.

In den letzten Beiträgen haben wir verschiedene Möglichkeiten zur Berechnung von Datums- und Zeitangaben in Excel untersucht und eine Reihe nützlicher Funktionen wie WOCHENTAG, WOCHENZAHL, MONAT und TAG kennengelernt. Heute werden wir uns auf eine größere Zeiteinheit konzentrieren und über die Berechnung von Jahren in Ihren Excel-Arbeitsblättern sprechen.

In diesem Lernprogramm lernen Sie:

YEAR-Funktion in Excel

Die Funktion JAHR in Excel gibt ein vierstelliges Jahr, das einem bestimmten Datum entspricht, als Ganzzahl von 1900 bis 9999 zurück.

Die Syntax der Excel-Funktion YEAR ist so einfach wie nur möglich:

Dabei ist serial_number ein beliebiges gültiges Datum des Jahres, das Sie suchen.

Excel YEAR-Formel

Um eine JAHRESformel in Excel zu erstellen, können Sie das Ausgangsdatum auf verschiedene Weise angeben.

Verwendung der Funktion DATE

Die zuverlässigste Methode, ein Datum in Excel anzugeben, ist die Funktion DATE.

Die folgende Formel gibt zum Beispiel das Jahr für den 28. April 2015 an:

=JAHR(DATUM(2015, 4, 28))

Als Seriennummer, die das Datum darstellt

Im internen Excel-System werden Datumsangaben als fortlaufende Nummern gespeichert, beginnend mit dem 1. Januar 1900, der als Nummer 1 gespeichert wird. Weitere Informationen darüber, wie Datumsangaben in Excel gespeichert werden, finden Sie unter Excel-Datumsformat.

Der 28. Tag des Monats April 2015 ist als 42122 gespeichert, so dass Sie diese Zahl direkt in die Formel eingeben können:

=JAHR(42122)

Diese Methode ist zwar akzeptabel, wird aber nicht empfohlen, da die Datumsnummerierung in verschiedenen Systemen unterschiedlich sein kann.

Als Zellreferenz

Wenn Sie ein gültiges Datum in einer Zelle haben, können Sie sich einfach auf diese Zelle beziehen, zum Beispiel:

=JAHR(A1)

Als Ergebnis einer anderen Formel

Sie können beispielsweise die Funktion HEUTE() verwenden, um das Jahr aus dem aktuellen Datum zu extrahieren:

=YEAR(TODAY())

Als Text

In einem einfachen Fall kann die YEAR-Formel sogar Datumsangaben verstehen, die als Text eingegeben werden, etwa so:

=YEAR("28-Apr-2015")

Wenn Sie diese Methode verwenden, vergewissern Sie sich bitte, dass Sie das Datum in einem Format eingeben, das Excel versteht, und denken Sie daran, dass Microsoft keine Garantie für korrekte Ergebnisse übernimmt, wenn ein Datum als Textwert eingegeben wird.

Der folgende Screenshot zeigt alle oben genannten JAHR-Formeln in Aktion, die alle das Jahr 2015 zurückgeben, wie Sie es vielleicht erwarten :)

Umrechnung von Datum in Jahr in Excel

Wenn Sie in Excel mit Datumsinformationen arbeiten, zeigen Ihre Arbeitsblätter normalerweise das vollständige Datum an, einschließlich Monat, Tag und Jahr. Bei großen Meilensteinen und wichtigen Ereignissen wie Produkteinführungen oder Anlagenkäufen möchten Sie jedoch vielleicht nur das Jahr anzeigen, ohne die ursprünglichen Daten erneut eingeben oder ändern zu müssen. Im Folgenden finden Sie 3 schnelle Möglichkeiten, dies zu tun.

Beispiel 1: Extrahieren einer Jahreszahl aus einem Datum mit der Funktion YEAR

Sie wissen bereits, wie Sie die Funktion JAHR in Excel verwenden können, um ein Datum in eine Jahreszahl umzuwandeln. Die obige Abbildung zeigt eine Reihe von Formeln, und in der Abbildung unten sehen Sie einige weitere Beispiele. Beachten Sie, dass die Funktion JAHR alle möglichen Datumsformate versteht:

Beispiel 2: Konvertierung von Datum in Monat und Jahr in Excel

Um ein bestimmtes Datum in Jahr und Monat umzuwandeln, können Sie die Funktion TEXT verwenden, um jede Einheit einzeln zu extrahieren, und diese Funktionen dann in einer Formel miteinander verknüpfen.

In der Funktion TEXT können Sie verschiedene Codes für Monate und Jahre verwenden, wie z. B.:

• "mmm" - abgekürzte Monatsnamen, wie Jan - Dez.
• "mmmm" - vollständige Monatsnamen, wie Januar - Dezember.
• "yy" - 2-stellige Jahreszahl
• "jjjj" - 4-stellige Jahre

Um die Ausgabe besser lesbar zu machen, können Sie die Codes durch ein Komma, einen Bindestrich oder ein anderes Zeichen trennen, wie im folgenden Beispiel Datum zu Monat und Jahr Formeln:

=TEXT(B2, "mmmm") & ", " & TEXT(B2, "yyyy")

Oder

=TEXT(B2, "mmm") & "-" & TEXT(B2, "yy")

Dabei ist B2 eine Zelle, die ein Datum enthält.

Beispiel 3: Anzeige eines Datums als Jahr

Wenn es keine Rolle spielt, wie die Daten in Ihrer Arbeitsmappe gespeichert sind, können Sie Excel dazu bringen, nur die Jahreszahlen anzuzeigen, ohne die ursprünglichen Daten zu ändern, d. h. Sie können die vollständigen Daten in den Zellen speichern, aber nur die Jahreszahlen anzeigen lassen.

In diesem Fall ist keine Formel erforderlich, Sie öffnen einfach die Zellen formatieren durch Drücken der Tastenkombination Strg + 1 , wählen Sie das Benutzerdefiniert Kategorie auf der Nummer und geben Sie einen der folgenden Codes in das Feld Typ Box:

• yy - zur Anzeige von zweistelligen Jahreszahlen, wie 00 - 99.
• jjjj - zur Anzeige von 4-stelligen Jahreszahlen, wie 1900 - 9999.

Bitte beachten Sie, dass diese Methode ändert das ursprüngliche Datum nicht Wenn Sie sich in Ihren Formeln auf solche Zellen beziehen, führt Microsoft Excel Datumsberechnungen anstelle von Jahresberechnungen durch.

Weitere Einzelheiten zum Ändern des Datumsformats finden Sie in diesem Tutorial: Wie man das Datumsformat in Excel ändert.

Wie berechnet man das Alter aus dem Geburtsdatum in Excel?

Es gibt mehrere Möglichkeiten, das Alter aus dem Geburtsdatum in Excel zu berechnen - mit den Funktionen DATEDIF, YEARFRAC oder INT in Kombination mit TODAY(). Die Funktion TODAY liefert das Datum, zu dem das Alter berechnet werden soll, und stellt sicher, dass Ihre Formel immer das richtige Alter zurückgibt.

Berechnen des Alters anhand des Geburtsdatums in Jahren

Die traditionelle Methode, das Alter einer Person in Jahren zu berechnen, besteht darin, das Geburtsdatum vom aktuellen Datum abzuziehen. Dieser Ansatz funktioniert im Alltag gut, aber eine analoge Excel-Formel zur Altersberechnung ist nicht ganz korrekt:

Dabei ist DOB das Geburtsdatum.

Der erste Teil der Formel (HEUTE()-B2) berechnet die Differenz in Tagen, und Sie teilen sie durch 365, um die Anzahl der Jahre zu erhalten. In den meisten Fällen ist das Ergebnis dieser Gleichung eine Dezimalzahl, und Sie lassen es mit der INT-Funktion auf die nächste ganze Zahl abrunden.

Angenommen, das Geburtsdatum steht in Zelle B2, dann sieht die vollständige Formel wie folgt aus:

=INT((HEUTE()-B2)/365)

Wie bereits erwähnt, ist diese Altersberechnungsformel nicht immer fehlerfrei, und zwar aus folgendem Grund: Jedes vierte Jahr ist ein Schaltjahr, das 366 Tage umfasst, während die Formel die Anzahl der Tage durch 365 teilt. Wenn also jemand am 29. Februar geboren wurde und heute der 28. Februar ist, macht diese Altersformel die Person einen Tag älter.

Die Division durch 365,25 anstelle von 365 ist auch nicht einwandfrei, zum Beispiel bei der Berechnung des Alters eines Kindes, das noch kein Schaltjahr erlebt hat.

In Anbetracht der obigen Ausführungen sollten Sie sich diese Art der Altersberechnung für das normale Leben aufheben und eine der folgenden Formeln verwenden, um das Alter anhand des Geburtsdatums in Excel zu berechnen.

Eine ausführliche Erklärung der obigen Formeln finden Sie unter Wie man das Alter in Excel berechnet. Und der folgende Screenshot zeigt eine Formel zur Altersberechnung in der Praxis:

=DATEDIF(B2, TODAY(), "y")

Berechnung des genauen Alters anhand des Geburtsdatums (in Jahren, Monaten und Tagen)

Um ein genaues Alter in Jahren, Monaten und Tagen zu berechnen, schreiben Sie drei DATEDIF-Funktionen mit den folgenden Einheiten im letzten Argument:

• Y - zur Berechnung der Anzahl der vollständigen Jahre.
• YM - um die Differenz zwischen den Monaten zu erhalten, ohne Berücksichtigung der Jahre.
• MD - um die Differenz zwischen den Tagen zu erhalten, ohne Berücksichtigung von Jahren und Monaten.

Verketten Sie dann die 3 DATEDIF-Funktionen in einer einzigen Formel, trennen Sie die von jeder Funktion zurückgegebenen Zahlen durch Kommas und definieren Sie, was die einzelnen Zahlen bedeuten.

Angenommen, das Geburtsdatum steht in Zelle B2, dann sieht die vollständige Formel wie folgt aus:

=DATEDIF(B2,TODAY(), "Y") & " Jahre, " & DATEDIF(B2,TODAY(), "YM") & " Monate, " & DATEDIF(B2,TODAY(), "MD") & " Tage"

Diese Altersformel kann sehr nützlich sein, z. B. für einen Arzt, um das genaue Alter der Patienten anzuzeigen, oder für einen Personalchef, um das genaue Alter aller Mitarbeiter zu kennen:

Weitere Beispiele für Formeln, z. B. zur Berechnung des Alters an einem bestimmten Datum oder in einem bestimmten Jahr, finden Sie in folgendem Lernprogramm: Wie man das Alter in Excel berechnet.

So erhalten Sie die Tageszahl des Jahres (1-365)

Dieses Beispiel zeigt, wie man die Zahl eines bestimmten Tages in einem Jahr zwischen 1 und 365 (1-366 in Schaltjahren) ermitteln kann, wobei der 1. Januar als Tag 1 gilt.

Verwenden Sie dazu die Funktion JAHR zusammen mit DATUM auf diese Weise:

=A2-DATUM(JAHR(A2), 1, 0)

Dabei ist A2 eine Zelle, die das Datum enthält.

Und nun wollen wir sehen, was die Formel tatsächlich bewirkt: Die JAHR Funktion ruft das Jahr des Datums in Zelle A2 ab und übergibt es an die DATE(Jahr, Monat, Tag) die die fortlaufende Nummer für ein bestimmtes Datum zurückgibt.

Also, in unserer Formel, Jahr wird aus dem ursprünglichen Datum (A2) extrahiert, Monat ist 1 (Januar) und Tag ist 0. Tatsächlich zwingt ein Nulltag Excel dazu, den 31. Dezember des Vorjahres zurückzugeben, da wir den 1. Januar als 1. Tag behandeln wollen. Und dann subtrahieren Sie die von der DATE-Formel zurückgegebene fortlaufende Nummer vom ursprünglichen Datum (das ebenfalls als fortlaufende Nummer in Excel gespeichert ist), und die Differenz ist der Tag des gesuchten Jahres. Zum Beispiel ist der 5. Januar 2015 als 42009 gespeichert undDer 31. Dezember 2014 ist 42004, also 42009 - 42004 = 5.

Wenn Ihnen das Konzept des Tages 0 nicht richtig erscheint, können Sie stattdessen die folgende Formel verwenden:

=A2-DATUM(JAHR(A2), 1, 1)+1

So berechnen Sie die Anzahl der verbleibenden Tage im Jahr

Um die Anzahl der verbleibenden Tage im Jahr zu berechnen, verwenden wir wieder die Funktionen DATE und YEAR. Die Formel basiert auf demselben Ansatz wie in Beispiel 3, so dass Sie wahrscheinlich keine Schwierigkeiten haben werden, die Logik zu verstehen:

=DATE(YEAR(A2),12,31)-A2

Wenn Sie wissen möchten, wie viele Tage bis zum Ende des Jahres verbleiben, verwenden Sie die Excel-Funktion HEUTE() wie folgt:

=DATE(2015, 12, 31)-HEUTE()

Dabei ist 2015 das laufende Jahr.

Berechnen von Schaltjahren in Excel

Wie Sie wissen, hat fast jedes 4. Jahr am 29. Februar einen zusätzlichen Tag und wird als Schaltjahr bezeichnet. In Microsoft Excel können Sie auf verschiedene Weise feststellen, ob ein bestimmtes Datum zu einem Schaltjahr oder zu einem gewöhnlichen Jahr gehört. Ich werde nur ein paar Formeln demonstrieren, die meiner Meinung nach am einfachsten zu verstehen sind.

Formel 1: Prüfen Sie, ob der Februar 29 Tage hat.

Dies ist ein sehr offensichtlicher Test. Da der Februar in Schaltjahren 29 Tage hat, berechnen wir die Anzahl der Tage im Monat 2 eines bestimmten Jahres und vergleichen sie mit der Zahl 29. Zum Beispiel:

=DAY(DATE(2015,3,1)-1)=29

In dieser Formel gibt die Funktion DATUM(2015,3,1) den 1. März des Jahres 2015 zurück, von dem wir 1 abziehen. Die Funktion TAG extrahiert die Tageszahl aus diesem Datum, und wir vergleichen diese Zahl mit 29. Wenn die Zahlen übereinstimmen, gibt die Formel TRUE zurück, ansonsten FALSE.

Wenn Sie bereits eine Liste von Datumsangaben in Ihrem Excel-Arbeitsblatt haben und wissen wollen, welche davon Schaltjahre sind, können Sie die Funktion JAHR in die Formel einbauen, um ein Jahr aus einem Datum zu extrahieren:

=DAY(DATE(YEAR(A2),3,1)-1)=29

Dabei ist A2 eine Zelle, die das Datum enthält.

Die von der Formel gelieferten Ergebnisse sind wie folgt:

Alternativ können Sie auch die Funktion EOMONTH verwenden, um den letzten Tag im Februar zu ermitteln und diese Zahl mit 29 zu vergleichen:

=DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29

Um die Formel benutzerfreundlicher zu gestalten, verwenden Sie die IF-Funktion und lassen Sie sie z. B. "Schaltjahr" und "gewöhnliches Jahr" anstelle von TRUE und FALSE zurückgeben:

=IF(DAY(DATE(YEAR(A2),3,1)-1)=29, "Schaltjahr", "gewöhnliches Jahr")

=IF(DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29, "Schaltjahr", "Allgemeines Jahr")

Formel 2: Prüfen Sie, ob das Jahr 366 Tage hat.

Dies ist ein weiterer offensichtlicher Test, der kaum einer Erklärung bedarf. Wir verwenden eine DATE-Funktion, um den 1-Jan des nächsten Jahres zu erhalten, eine andere DATE-Funktion, um den 1-Jan dieses Jahres zu erhalten, subtrahieren die letztere von der ersteren und prüfen, ob die Differenz gleich 366 ist:

=DATUM(2016,1,1) - DATUM(2015,1,1)=366

Um ein Jahr auf der Grundlage eines in einer Zelle eingegebenen Datums zu berechnen, verwenden Sie die Excel-Funktion JAHR genau so wie im vorherigen Beispiel:

=DATUM(JAHR(A2)+1,1,1) - DATUM(JAHR(A2),1,1)=366

Dabei ist A2 eine Zelle, die das Datum enthält.

Und natürlich können Sie die obige DATUM/JAHR-Formel in die WENN-Funktion einschließen, damit sie etwas Sinnvolleres als die booleschen Werte WAHR und FALSCH zurückgibt:

=IF(DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366, "Schaltjahr", "Nicht-Schaltjahr")

Wie bereits erwähnt, sind dies nicht die einzigen Möglichkeiten zur Berechnung von Schaltjahren in Excel. Wenn Sie neugierig auf andere Lösungen sind, können Sie die von Microsoft vorgeschlagene Methode prüfen. Wie üblich suchen die Jungs von Microsoft nicht nach einfachen Wegen, oder?

Ich hoffe, dieser Artikel hat Ihnen geholfen, die Jahresberechnungen in Excel zu verstehen. Ich danke Ihnen für die Lektüre und freue mich darauf, Sie nächste Woche wiederzusehen.