Tutorial ieu ngajelaskeun sintaksis sareng kagunaan fungsi Excel YEAR sareng nyayogikeun conto rumus pikeun nimba taun ti tanggal, ngarobih tanggal ka bulan sareng taun, ngitung umur ti tanggal lahir sareng nangtukeun taun kabisat.

Dina sababaraha tulisan panganyarna, kami geus ngajajah sababaraha cara pikeun ngitung tanggal sareng waktos dina Excel sareng diajar rupa-rupa fungsi anu mangpaat sapertos WEEKDAY, WEEKNUM, MONTH, sareng DAY. Dinten ieu, urang bade difokuskeun unit waktu anu langkung ageung sareng ngobrol ngeunaan ngitung taun dina lembar kerja Excel anjeun.

Dina tutorial ieu, anjeun bakal diajar:

fungsi YEAR dina Excel

Pungsi YEAR dina Excel ngabalikeun taun opat-angka anu pakait sareng tanggal anu dipasihkeun salaku integer ti 1900 dugi ka 9999.

Sintaksis pungsi YEAR Excel saderhana pisan. bisa jadi:

Dimana serial_number mangrupa tanggal valid taun nu Anjeun hoyong manggihan.

Rumus Excel YEAR

Pikeun nyieun rumus YEAR dina Excel, anjeun tiasa nyadiakeun tanggal sumber ku sababaraha cara.

Nganggo fungsi DATE

The Cara anu paling dipercaya pikeun nyayogikeun tanggal dina Excel nyaéta nganggo pungsi DATE.

Contona, rumus di handap ieu ngabalikeun taun kanggo 28 April 2015:

=YEAR(DATE(2015, 4, 28))

Salaku a nomer serial ngawakilan tanggal

Dina sistem Excel internal, kaping disimpen salaku nomer serial dimimitian 1 Januari 1900, nu disimpen salaku nomer 1. Pikeun leuwih lengkepInpormasi ngeunaan kumaha tanggal disimpen dina Excel, mangga tingali format tanggal Excel.

Kaping 28 April 2015 disimpen salaku 42122, janten anjeun tiasa langsung ngalebetkeun nomer ieu dina rumus:

=YEAR(42122)

Sanaos tiasa ditampi, metode ieu henteu disarankeun sabab panomeran tanggal tiasa béda-béda dina sistem anu béda.

Salaku rujukan sél

Anggap anjeun gaduh tanggal anu valid dina sababaraha sél, anjeun ngan saukur tiasa ngarujuk kana sél éta. Contona:

=YEAR(A1)

Salaku hasil tina sababaraha rumus lain

Misalna, anjeun tiasa nganggo fungsi TODAY() pikeun nimba taun ti tanggal ayeuna:

=YEAR(TODAY())

Salaku téks

Dina kasus basajan, rumus YEAR malah bisa ngarti tanggal diasupkeun salaku téks, kawas kieu:

=YEAR("28-Apr-2015")

Nalika nganggo metodeu ieu, mangga parios deui yén anjeun ngasupkeun tanggal dina format anu kahartos ku Excel. Ogé, punten émut yén Microsoft henteu ngajamin hasil anu leres nalika tanggal dipasihkeun salaku nilai téks.

Potret layar di handap ieu nunjukkeun sadaya rumus YEAR di luhur dina tindakan, sadayana balik deui ka 2015 sapertos anu anjeun ngarepkeun :)

Kumaha cara ngarobah tanggal ka taun dina Excel

Nalika anjeun damel sareng inpormasi tanggal dina Excel, lembar kerja anjeun biasana nunjukkeun tanggal lengkep, kalebet bulan, dinten sareng taun . Tapi, pikeun tonggak utama sareng acara penting sapertos peluncuran produk atanapi akuisisi aset, anjeun tiasa waé ningali taunna tanpa ngalebetkeun deui atanapi ngarobihdata aslina. Di handap, anjeun bakal mendakan 3 cara gancang pikeun ngalakukeun ieu.

Conto 1. Ekstrak taun ti tanggal nganggo fungsi YEAR

Malah, anjeun parantos terang kumaha ngagunakeun fungsi YEAR dina Excel. pikeun ngarobah tanggal ka taun. Potret layar di luhur nunjukkeun sakumpulan rumus, sareng anjeun tiasa ningali sababaraha conto deui dina layar di handap ieu. Perhatikeun yén fungsi YEAR sampurna ngartos kaping dina sagala format mungkin:

Conto 2. Convert tanggal ka bulan jeung taun dina Excel

Pikeun ngarobah tanggal nu tangtu ka taun sareng bulan, anjeun tiasa nganggo pungsi TEXT pikeun nimba unggal unit, teras ngahijikeun fungsi-fungsi éta dina hiji rumus.

Dina fungsi TEXT, anjeun tiasa nganggo kode anu béda-béda pikeun sababaraha bulan sareng taun, sapertos:

• "mmm" - disingkat ngaran bulan, sakumaha Jan - Dec.
• "mmmm" - ngaran bulan pinuh, sakumaha Januari - Désémber.
• "yy" - 2-angka taun
• "yyyy" - 4-angka taun

Pikeun nyieun kaluaran leuwih hadé dibaca, anjeun bisa misahkeun kodeu ku koma, hyphen atawa karakter sejenna, kawas dina rumus Tanggal ka Bulan jeung Taun ieu:

=TEXT(B2, "mmmm") & ", " & TEXT(B2, "yyyy")

Atawa

=TEXT(B2, "mmm") & "-" & TEXT(B2, "yy")

Dimana B2 mangrupa sél nu ngandung titimangsa.

Conto 3. Témbongkeun tanggal sabagé taun

Lamun teu pati penting kumaha tanggal disimpen dina buku kerja, anjeun bisa kéngingkeun Excel ngan ukur nunjukkeun taun sareng ut ngarobah tanggal aslina. Dina basa sejen, anjeun tiasa gaduhtanggal lengkep disimpen dina sél, tapi ngan taun ditémbongkeun.

Dina hal ieu, euweuh rumus diperlukeun. Anjeun ngan muka dialog Format Sél ku mencét Ctrl + 1 , pilih kategori Custom dina tab Number , teras lebetkeun salah sahiji kodeu di handap dina Jenis kotak:

• yy - pikeun mintonkeun 2-angka taun, sakumaha 00 - 99.
• yyyy - pikeun mintonkeun 4-angka taun, sakumaha 1900 - 9999 .

Punten émut yén metodeu ieu henteu ngarobih tanggal aslina , ngan ukur ngarobih cara tampilan tanggal dina lembar kerja anjeun. Upami anjeun ngarujuk kana sél sapertos dina rumus anjeun, Microsoft Excel bakal ngalakukeun itungan tanggal tinimbang itungan taun.

Anjeun tiasa mendakan langkung rinci ngeunaan ngarobih format tanggal dina tutorial ieu: Kumaha ngarobih format tanggal dina Excel.

Kumaha carana ngitung umur ti tanggal lahir dina Excel

Aya sababaraha cara pikeun ngitung umur formulir tanggal lahir di Excel - ngagunakeun DATEDIF, YEARFRAC atawa fungsi INT dina kombinasi jeung TODAY (). Fungsi TODAY nyadiakeun tanggal keur ngitung umur, mastikeun yén rumus anjeun bakal salawasna mulangkeun umur nu bener.

Itung umur ti tanggal lahir dina taun

Cara tradisional ngitung umur hiji jalma. dina taun nyaéta ngurangan tanggal lahir ti tanggal ayeuna. Pendekatan ieu tiasa dianggo saé dina kahirupan sapopoe, tapi rumus itungan umur Excel anu sami henteu leres leres:

Dimana DOB nyaéta tanggal lahir.

Bagian kahiji rumus (TODAY()-B2) ngitung bédana nyaéta poé, jeung anjeun ngabagi ku 365 pikeun meunangkeun jumlah taun. Dina kalolobaan kasus, hasil tina persamaan ieu mangrupa angka desimal, jeung anjeun boga fungsi INT buleud ka handap ka integer pangdeukeutna.

Anggap tanggal lahir aya dina sél B2, rumus lengkepna kieu. :

=INT((TODAY()-B2)/365)

Saperti disebutkeun di luhur, rumus itungan umur ieu teu salawasna flawless, sarta ieu sababna. Unggal taun ka-4 nyaéta taun kabisat anu ngandung 366 poé, sedengkeun rumusna ngabagi jumlah poé ku 365. Jadi, lamun aya nu lahir tanggal 29 Pébruari jeung poé ieu 28 Pébruari, rumus umur ieu bakal ngajadikeun hiji jalma leuwih kolot.

Ngabagi ku 365,25 tibatan 365 ogé henteu sampurna, contona, nalika ngitung umur murangkalih anu henteu acan hirup dina taun kabisat.

Nunjukkeun di luhur, anjeun kedah leuwih hadé simpen cara ieu ngitung umur pikeun kahirupan normal, sarta ngagunakeun salah sahiji rumus di handap pikeun ngitung umur ti tanggal lahir dina Excel.

Penjelasan rinci ngeunaan rumus di luhur disayogikeun dina Kumaha ngitung umur dina Excel. Jeung screenshot di handap ieu nunjukkeun rumus itungan umur nyata dina aksi:

=DATEDIF(B2, TODAY(), "y")

Ngitung umur pasti titanggal lahir (dina taun, bulan jeung poé)

Pikeun ngitung umur pasti dina taun, bulan jeung poé, tulis tilu fungsi DATEDIF kalawan unit handap dina argumen panungtungan:

• Y - keur ngitung jumlah taun gembleng.
• YM - pikeun meunangkeun bedana antara bulan, teu malire taun.
• MD - pikeun meunangkeun bédana antara poé, malire taun jeung bulan. .

Terus, sambungkeun 3 fungsi DATEDIF dina hiji rumus, pisahkeun angka nu dipulangkeun ku unggal fungsi ku koma, jeung tangtukeun naon hartina unggal angka.

Anggap tanggal tina kalahiran aya dina sél B2, rumus lengkepna kieu:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

Rumus umur ieu bisa jadi mangpaat pisan, contona, pikeun dokter pikeun mintonkeun umur pasti pasén, atawa pikeun perwira tanaga pikeun terang umur pasti sadaya karyawan:

Pikeun conto rumus langkung seueur sapertos ngitung umur dina tanggal tinangtu atanapi dina taun anu tangtu, mangga parios ieu di handap. tutorial: Kumaha ngitung umur dina Excel.

Kumaha cara meunangkeun angka poé dina sataun (1-365)

Conto ieu nunjukkeun kumaha anjeun bisa meunangkeun jumlah poé nu tangtu dina sataun, antara 1 jeung 365 (1-366 dina taun kabisat) kalawan 1 Januari dianggap poé 1.

Pikeun ieu, gunakeun pungsi YEAR bareng jeung DATE ku cara kieu:

=A2-DATE(YEAR(A2), 1, 0)

Dimana A2 mangrupa sél nu ngandung tanggal.

Jeung ayeuna, hayu urang tingali naon sabenerna rumus. Thefungsi TAHUN retrieves taun tanggal dina sél A2, sarta ngalirkeun kana fungsi TANGGAL(taun, bulan, poé) , nu mulihkeun angka runtuyan nu ngagambarkeun tanggal nu tangtu.

Jadi, dina rumus urang, year diekstrak tina tanggal aslina (A2), month nyaéta 1 (Januari) jeung day nyaéta 0. Kanyataanna, enol poé maksakeun Excel pikeun mulangkeun 31 Désémber taun saméméhna. , sabab urang hoyong 1 Januari diperlakukeun salaku dinten 1st. Teras, anjeun ngirangan jumlah séri anu dipulangkeun ku rumus DATE ti tanggal aslina (anu ogé disimpen salaku nomer séri dina Excel) sareng bédana nyaéta dinten dina taun anu anjeun milarian. Salaku conto, 5 Januari 2015 disimpen salaku 42009 sareng 31 Désémber 2014 nyaéta 42004, janten 42009 - 42004 = 5.

Upami konsép dinten 0 sigana henteu leres pikeun anjeun, anjeun tiasa nganggo ieu di handap. rumus:

=A2-DATE(YEAR(A2), 1, 1)+1

Kumaha carana ngitung jumlah poé sésana dina sataun

Pikeun ngitung jumlah poé sésana dina taun, urang bade ngagunakeun DATE jeung YEAR fungsi deui. Rumusna didasarkeun kana pendekatan anu sami sareng Conto 3 di luhur, ku kituna anjeun moal aya masalah dina ngartos logikana:

=DATE(YEAR(A2),12,31)-A2

Upami anjeun hoyong terang sabaraha dinten tetep dugi ka akhir taun dumasar kana tanggal ayeuna, anjeun nganggo fungsi Excel TODAY(), sapertos kieu:

=DATE(2015, 12, 31)-TODAY()

Dimana 2015 mangrupikeun taun ayeuna .

Ngitungtaun kabisat dina Excel

Sakumaha anjeun terang, ampir unggal taun ka-4 gaduh dinten tambahan dina tanggal 29 Pébruari sareng disebut taun kabisat. Dina lambaran Microsoft Excel, anjeun tiasa nangtukeun naha tanggal anu tangtu kalebet taun kabisat atanapi taun umum dina sababaraha cara. Abdi badé nunjukkeun sababaraha rumus, anu menurut kuring paling gampang kahartos.

Rumus 1. Pariksa naha Pébruari gaduh 29 dinten

Ieu tés anu écés pisan. Kusabab Pébruari boga 29 poé dina taun kabisat, urang ngitung jumlah poé dina bulan 2 taun tinangtu sarta dibandingkeun jeung angka 29. Contona:

=DAY(DATE(2015,3,1)-1)=29

Dina rumus ieu, DATE (2015,3,1) fungsi mulih 1st dinten Maret dina taun 2015, ti mana urang subtract 1. Fungsi DAY extracts jumlah poé ti tanggal ieu, sarta kami ngabandingkeun angka nu mibanda 29. Lamun angka cocog, rumusna ngabalikeun BENER, SALAH sabalikna.

Upami anjeun parantos gaduh daptar tanggal dina lembar kerja Excel anjeun sareng anjeun hoyong terang mana anu taun kabisat, teras lebetkeun fungsi YEAR dina rumus pikeun nimba sataun ti titimangsa:

=DAY(DATE(YEAR(A2),3,1)-1)=29

Dimana A2 mangrupa sél nu ngandung tanggal.

Hasilna dipulangkeun ku rumus nyaéta kieu:

Alternatipna, anjeun tiasa nganggo fungsi EOMONTH pikeun mulangkeun dinten terakhir dina bulan Pebruari, sareng bandingkeun angka éta sareng 29:

=DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29

Pikeun ngajantenkeun rumus langkung ramah-pamaké. , employ fungsi IF sarta mibanda etabalik, sebutkeun, "Taun kabisat" jeung "Taun umum" tinimbang BENER jeung SALAH:

=IF(DAY(DATE(YEAR(A2),3,1)-1)=29, "Leap year", "Common year")

=IF(DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29, "Leap year", "Common year")

Rumus 2 .Parios upami taun aya 366 dinten

Ieu tés écés sanés anu henteu peryogi katerangan. Kami nganggo hiji fungsi DATE pikeun mulangkeun 1-Jan taun payun, fungsi DATE anu sanés pikeun nampi 1-Jan taun ieu, ngirangan anu terakhir tina anu baheula sareng pariksa naha bédana sami sareng 366:

=DATE(2016,1,1) - DATE(2015,1,1)=366

Pikeun ngitung taun dumasar kana tanggal anu diasupkeun dina sababaraha sél, anjeun nganggo pungsi Excel YEAR persis dina cara anu sami sareng conto sateuacana:

=DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366

Dimana A2 mangrupikeun sél anu ngandung tanggal.

Sareng alami, anjeun tiasa ngalampirkeun rumus DATE / YEAR di luhur dina fungsi IF pikeun ngabalikeun hal anu langkung bermakna tibatan nilai Boolean BENER sareng SALAH:

=IF(DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366, "Leap year", "Non-leap year")

Sapertos anu parantos disebatkeun, ieu sanés hiji-hijina cara pikeun ngitung taun kabisat dina Excel. Upami anjeun panasaran hoyong terang solusi anu sanés, anjeun tiasa pariksa metode anu disarankeun ku Microsoft. Sakumaha biasa, budak Microsoft henteu milarian cara anu gampang, naha?

Mudah-mudahan tulisan ieu tiasa ngabantosan anjeun ngitung taun dina Excel. Abdi ngahaturkeun nuhun pikeun maca sareng ngarepkeun pendak sareng anjeun minggu payun.