Овој туторијал ја објаснува синтаксата и употребата на функцијата Excel YEAR и дава примери на формула за извлекување година од датум, претворање датум во месец и година, пресметување возраст од датумот на раѓање и одредување престапни години.

Во неколку неодамнешни објави, истраживме различни начини за пресметување датуми и времиња во Excel и научивме различни корисни функции како што се WEEKDAY, WEEKNUM, MONTH и DAY. Денес, ќе се фокусираме на поголема временска единица и ќе разговараме за пресметување години во вашите работни листови во Excel.

Во ова упатство ќе научите:

Функција ГОДИНА во Excel

Функцијата YEAR во Excel враќа четирицифрена година што одговара на даден датум како цел број од 1900 до 9999 година.

Синтаксата на функцијата Excel YEAR е едноставна како што е може да биде:

Каде што серискиот_број е кој било важечки датум од годината што сакате да го најдете.

Формула Excel YEAR

За да направите формула YEAR во Excel, можете да го наведете изворниот датум на неколку начини.

Користејќи ја функцијата DATE

најсигурен начин за давање датум во Excel е користење на функцијата DATE.

На пример, следнава формула ја враќа годината за 28 април 2015 година:

=YEAR(DATE(2015, 4, 28))

Како сериски број што го претставува датумот

Во внатрешниот систем на Excel, датумите се зачувуваат како сериски броеви почнувајќи од 1 јануари 1900 година, кој се чува како број 1. За повеќеинформации за тоа како се зачувуваат датумите во Excel, погледнете го форматот на датумот на Excel.

Денот на 28 април 2015 година е зачуван како 42122, па можете да го внесете овој број директно во формулата:

=YEAR(42122)

Иако е прифатлив, овој метод не се препорачува бидејќи нумерирањето на датумите може да варира во различни системи.

Како референца на ќелија

Претпоставувајќи дека имате важечки датум во некоја ќелија, можете едноставно да се повикате на таа ќелија. На пример:

=YEAR(A1)

Како резултат на некоја друга формула

На пример, можете да ја користите функцијата TODAY() за да ја извлечете годината од тековниот датум:

=YEAR(TODAY())

Како текст

Во едноставен случај, формулата ГОДИНА може да ги разбере дури и датумите внесени како текст, вака:

=YEAR("28-Apr-2015")

Кога го користите овој метод, проверете двапати дали го внесувате датумот во форматот што го разбира Excel. Исто така, запомнете дека Microsoft не гарантира точни резултати кога датумот е доставен како текстуална вредност.

Следната слика од екранот ги прикажува сите горенаведени формули YEAR во акција, сите се враќаат во 2015 година како што може да очекувате :)

Како да конвертирате датум во година во Excel

Кога работите со информации за датум во Excel, вашите работни листови обично прикажуваат целосни датуми, вклучувајќи месец, ден и година . Сепак, за големи пресвртници и важни настани како што се лансирање производи или стекнување средства, можеби ќе сакате да ја прегледате само годината без повторно внесување или менување наоригинални податоци. Подолу, ќе најдете 3 брзи начини да го направите ова.

Пример 1. Извлечете една година од датумот користејќи ја функцијата YEAR

Всушност, веќе знаете како да ја користите функцијата YEAR во Excel да конвертирате датум во година. Сликата од екранот погоре покажува еден куп формули, а можете да видите уште неколку примери на сликата од екранот подолу. Забележете дека функцијата YEAR совршено ги разбира датумите во сите можни формати:

Пример 2. Конвертирај датум во месец и година во Excel

За конвертирање даден датум на година и месец, можете да ја користите функцијата TEXT за да ја извлечете секоја единица поединечно, а потоа да ги споите тие функции во една формула.

Во функцијата TEXT, можете да користите различни кодови за месеци и години, како што се:

• „ммм“ - скратени имиња на месеци, како јануари - декември.
• „мммм“ - имиња на цели месеци, како јануари - декември.
• „гг“ - 2-цифрени години
• „yyyy“ - 4-цифрени години

За да го направите излезот подобро читлив, можете да ги одделите шифрите со запирка, цртичка или кој било друг знак, како во следните формули Датум до месец и година :

=TEXT(B2, "mmmm") & ", " & TEXT(B2, "yyyy")

Или

=TEXT(B2, "mmm") & "-" & TEXT(B2, "yy")

Каде B2 е ќелија која содржи датум.

Пример 3. Прикажете го датумот како година

Ако навистина не е важно како датумите се зачувани во вашата работна книга, можете да земете Excel за да ги прикажува само годините менување на оригиналните датуми. Со други зборови, можете да иматецелосните датуми се зачувани во ќелиите, но само прикажаните години.

Во овој случај, не е потребна формула. Само го отворате дијалогот Форматирајте ги ќелиите со притискање на Ctrl + 1 , изберете ја категоријата Прилагодено на картичката Број и внесете еден од долунаведените кодови во Впишете поле:

• yy - за прикажување 2-цифрени години, како 00 - 99.
• yyyy - за прикажување 4-цифрени години, како 1900 - 9999 .

Запомнете дека овој метод не го менува оригиналниот датум , туку само го менува начинот на прикажување на датумот во вашиот работен лист. Ако се повикувате на такви ќелии во вашите формули, Microsoft Excel ќе врши пресметки на датум наместо пресметки на година.

Повеќе детали за промена на форматот на датумот можете да најдете во ова упатство: Како да го промените форматот на датумот во Excel.

Како да се пресмета возраста од датумот на раѓање во Excel

Постојат неколку начини за пресметување возраст од датумот на раѓање во Excel - користејќи DATEDIF, YEARFRAC или INT функција во комбинација со TODAY(). Функцијата ДЕНЕС го обезбедува датумот за пресметување на возраста, осигурувајќи дека вашата формула секогаш ќе ја враќа точната возраст.

Пресметајте ја возраста од датумот на раѓање во години

Традиционалниот начин за пресметување на возраста на една личност во години е да се одземе датумот на раѓање од тековниот датум. Овој пристап функционира добро во секојдневниот живот, но аналогната формула за пресметување возраст на Excel не е сосема точна:

Каде што DOB е датумот на раѓање.

Првиот дел од формулата (TODAY()-B2) го пресметува разликата е денови, а вие ја делите со 365 за да го добиете бројот на години. Во повеќето случаи, резултатот од оваа равенка е децимален број и ја имате функцијата INT заокружете го надолу до најблискиот цел број.

Претпоставувајќи дека датумот на раѓање е во ќелијата B2, целосната формула оди на следниов начин :

=INT((TODAY()-B2)/365)

Како што споменавме погоре, оваа формула за пресметување на возраста не е секогаш беспрекорна, а еве зошто. Секоја 4-та година е престапна година која содржи 366 дена, додека формулата го дели бројот на денови со 365. Значи, ако некој е роден на 29 февруари, а денес е 28 февруари, оваа старосна формула ќе го направи човекот еден ден постар. 3>

Не е беспрекорно ниту делењето со 365,25 наместо 365, на пример, кога се пресметува возраста на дете кое сè уште не преживеало престапна година.

Со оглед на горенаведеното, би подобро зачувајте го овој начин на пресметување возраст за нормален живот и користете една од следните формули за да ја пресметате возраста од датумот на раѓање во Excel.

Детално објаснување на горенаведените формули е дадено во Како да се пресмета возраста во Excel. И следнава слика од екранот ја покажува реалната формула за пресметување на возраста во акција:

=DATEDIF(B2, TODAY(), "y")

Пресметување точна возраст оддатум на раѓање (во години, месец и денови)

За да пресметате точна возраст во години, месеци и денови, напишете три функции DATEDIF со следните единици во последниот аргумент:

• Y - да се пресмета бројот на целосни години.
• YM - да се добие разликата помеѓу месеците, игнорирајќи ги годините.
• MD - да се добие разликата помеѓу деновите, игнорирајќи ги годините и месеците .

И потоа, спојте ги 3-те DATEDIF функции во една формула, одделете ги броевите вратени од секоја функција со запирки и дефинирајте што значи секој број.

Претпоставувајќи го датумот на раѓањето е во клетката Б2, комплетната формула оди на следниов начин:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

Оваа формула за возраст може да биде многу корисна, да речеме, за лекарот да ја прикаже точната возраст на пациентите или за персонален службеник за да ја знае точната возраст на сите вработени:

За повеќе примери на формула како што се пресметување возраст на одреден датум или во одредена година, ве молиме проверете го следново упатство: Како да се пресмета возраста во Excel.

Како да го добиете бројот на денот во годината (1-365)

Овој пример покажува како можете да го добиете бројот на одреден ден во годината, помеѓу 1 и 365 (1-366 во престапна година) при што 1 јануари се смета за ден 1.

За ова, користете ја функцијата YEAR заедно со DATE на овој начин:

=A2-DATE(YEAR(A2), 1, 0)

Каде што A2 е ќелија која го содржи датумот.

И сега, да видиме што всушност прави формулата. НаФункцијата YEAR ја враќа годината на датумот во ќелијата A2 и ја пренесува на функцијата DATE(година, месец, ден) , која го враќа секвенцијалниот број што претставува одреден датум.

Значи, во нашата формула, year е извлечен од оригиналниот датум (A2), month е 1 (јануари) и day е 0. Всушност, нулта ден го принудува Excel да го врати 31 декември претходната година , затоа што сакаме 1 јануари да се третира како 1-ви ден. А потоа, го одземате серискиот број вратен со формулата DATE од оригиналниот датум (кој исто така е зачуван како сериски број во Excel) и разликата е денот во годината што ја барате. На пример, 5 јануари 2015 година е зачуван како 42009, а 31 декември 2014 година е 42004, така што 42009 - 42004 = 5.

Ако концептот на денот 0 не ви се чини правилен, можете да го користите следново наместо формула:

=A2-DATE(YEAR(A2), 1, 1)+1

Како да се пресмета бројот на преостанати денови во годината

За да се пресмета бројот на преостанати денови во годината, ќе го користиме DATE и YEAR повторно функционираат. Формулата се заснова на истиот пристап како примерот 3 погоре, така што веројатно нема да имате потешкотии со разбирањето на нејзината логика:

=DATE(YEAR(A2),12,31)-A2

Ако сакате да знаете колку денови остануваат до крајот на годината врз основа на тековниот датум, ја користите функцијата Excel TODAY(), на следниов начин:

=DATE(2015, 12, 31)-TODAY()

Каде 2015 е тековната година .

Пресметувањепрестапни години во Excel

Како што знаете, скоро секоја 4-та година има дополнителен ден на 29 февруари и се нарекува престапна година. Во листовите на Microsoft Excel, можете да одредите дали одреден датум припаѓа на престапна или вообичаена година на различни начини. Ќе покажам само неколку формули, кои според мене се најлесно за разбирање.

Формула 1. Проверете дали февруари има 29 дена

Ова е многу очигледен тест. Бидејќи февруари има 29 дена во престапна година, го пресметуваме бројот на денови во месецот 2 од дадена година и го споредуваме со бројот 29. На пример:

=DAY(DATE(2015,3,1)-1)=29

Во оваа формула, Функцијата DATE(2015,3,1) го враќа првиот ден од март во 2015 година, од кој одземаме 1. Функцијата DAY го извлекува бројот на денот од овој датум и го споредуваме тој број со 29. Ако броевите се совпаѓаат, формулата враќа TRUE, FALSE инаку.

Ако веќе имате листа на датуми во вашиот работен лист во Excel и сакате да знаете кои се престапни, тогаш вклучете ја функцијата YEAR во формулата за да извлечете година од датум:

=DAY(DATE(YEAR(A2),3,1)-1)=29

Каде A2 е ќелија која го содржи датумот.

Резултатите вратени со формулата се како што следува:

Алтернативно, можете да ја користите функцијата EOMONTH за да го вратите последниот ден во февруари и да го споредите тој број со 29:

=DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29

За да ја направите формулата попријатна за користење , употребете ја функцијата IF и имајте јаврати, да речеме, „Престапна година“ и „Заедничка година“ наместо ТОЧНО и НЕТОЧНО:

=IF(DAY(DATE(YEAR(A2),3,1)-1)=29, "Leap year", "Common year")

=IF(DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29, "Leap year", "Common year")

Формула 2 Проверете дали годината има 366 дена

Ова е уште еден очигледен тест кој едвај бара какво било објаснување. Ние користиме една функција DATE за да вратиме 1-јан од следната година, друга функција DATE за да добиеме 1-јан од оваа година, ја одземаме втората од првата и проверуваме дали разликата е еднаква на 366:

=DATE(2016,1,1) - DATE(2015,1,1)=366

За да пресметате година врз основа на датум внесен во некоја ќелија, ја користите функцијата Excel YEAR точно на ист начин како што направивме во претходниот пример:

=DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366

Каде што A2 е ќелија што го содржи датумот.

И нормално, можете да ја приложите горната формула DATE / YEAR во функцијата IF за да врати нешто позначајно од Булованите вредности на TRUE и FALSE:

=IF(DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366, "Leap year", "Non-leap year")

Како што веќе беше споменато, ова не се единствените можни начини за пресметување на престапни години во Excel. Ако сте љубопитни да знаете други решенија, можете да го проверите методот предложен од Microsoft. Како и обично, момците од Microsoft не бараат лесни начини, нели?

Се надеваме дека овој напис ви помогна да ги сфатите годишните пресметки во Excel. Ви благодарам што прочитавте и со нетрпение очекувам да се видиме следната недела.