У гэтым падручніку тлумачыцца сінтаксіс і выкарыстанне функцыі YEAR у Excel, а таксама даюцца прыклады формул для вылучэння года з даты, пераўтварэння даты ў месяц і год, вылічэння ўзросту з даты нараджэння і вызначэння высакосныя гады.

У некалькіх апошніх паведамленнях мы даследавалі розныя спосабы вылічэння дат і часу ў Excel і даведаліся пра мноства карысных функцый, такіх як WEEKDAY, WEEKNUM, MONTH і DAY. Сёння мы засяродзімся на большай адзінцы часу і пагаворым аб вылічэнні гадоў у вашых лістах Excel.

У гэтым уроку вы даведаецеся:

функцыю YEAR у Excel

Функцыя YEAR у Excel вяртае чатырохзначны год, які адпавядае зададзенай даце ў выглядзе цэлага ліку ад 1900 да 9999.

Сінтаксіс функцыі Excel YEAR такі ж просты, як і можа быць:

Дзе парадкавы_нумар - гэта любая сапраўдная дата года, якую вы хочаце знайсці.

Формула ГОД Excel

Каб стварыць формулу ГОД у Excel, вы можаце падаць зыходную дату некалькімі спосабамі.

Выкарыстанне функцыі ДАТА

самы надзейны спосаб увесці дату ў Excel - гэта выкарыстанне функцыі ДАТА.

Напрыклад, наступная формула вяртае год 28 красавіка 2015 г.:

=YEAR(DATE(2015, 4, 28))

Як серыйны нумар, які ўяўляе дату

Ва ўнутранай сістэме Excel даты захоўваюцца як парадкавыя нумары, пачынаючы з 1 студзеня 1900 г., які захоўваецца пад нумарам 1. Больш падрабязнаінфармацыю пра тое, як даты захоўваюцца ў Excel, глядзіце ў фармаце даты Excel.

28 красавіка 2015 г. захоўваецца як 42122, таму вы можаце ўвесці гэты лік непасрэдна ў формулу:

=YEAR(42122)

Хоць і прымальны, гэты метад не рэкамендуецца, таму што нумарацыя дат можа адрознівацца ў розных сістэмах.

У якасці спасылкі на ячэйку

Калі ў вас ёсць сапраўдная дата ў нейкай ячэйцы, вы можаце проста звярнуцца да гэтай ячэйкі. Напрыклад:

=YEAR(A1)

У выніку нейкай іншай формулы

Напрыклад, вы можаце выкарыстоўваць функцыю TODAY(), каб атрымаць год з бягучай даты:

=YEAR(TODAY())

Як тэкст

У простым выпадку формула ГОД можа нават разумець даты, уведзеныя як тэкст, напрыклад:

=YEAR("28-Apr-2015")

Пры выкарыстанні гэтага метаду яшчэ раз праверце, што вы ўводзіце дату ў фармаце, які разумее Excel. Таксама памятайце, што Microsoft не гарантуе правільных вынікаў, калі дата ўводзіцца ў выглядзе тэкставага значэння.

На наступным здымку экрана паказаны ўсе вышэйпералічаныя формулы YEAR у дзеянні, усе вяртаюць 2015 год, як і варта было чакаць :)

Як пераўтварыць дату ў год у Excel

Калі вы працуеце з інфармацыяй пра дату ў Excel, вашы працоўныя аркушы звычайна адлюстроўваюць поўныя даты, уключаючы месяц, дзень і год . Аднак для асноўных этапаў і важных падзей, такіх як запуск прадукту або набыццё актываў, вы можаце праглядаць толькі год без паўторнага ўводу або зменызыходныя дадзеныя. Ніжэй вы знойдзеце 3 хуткіх спосабу зрабіць гэта.

Прыклад 1. Вылучыце год з даты з дапамогай функцыі YEAR

Насамрэч, вы ўжо ведаеце, як выкарыстоўваць функцыю YEAR у Excel. каб пераўтварыць дату ў год. На скрыншоце вышэй дэманструецца мноства формул, і вы можаце ўбачыць яшчэ некалькі прыкладаў на скрыншоце ніжэй. Звярніце ўвагу, што функцыя YEAR выдатна разумее даты ва ўсіх магчымых фарматах:

Прыклад 2. Пераўтварэнне даты ў месяц і год у Excel

Каб пераўтварыць дадзеную дату у год і месяц, вы можаце выкарыстоўваць функцыю TEXT, каб атрымаць кожную адзінку асобна, а затым аб'яднаць гэтыя функцыі ў адну формулу.

У функцыі TEXT вы можаце выкарыстоўваць розныя коды для месяцаў і гадоў, напрыклад:

• "ммм" - скарочаныя назвы месяцаў, як ян - снежань.
• "мммм" - поўныя назвы месяцаў, як студзень - снежань.
• "yy" - 2-значныя гады
• "гггг" - 4-значныя гады

Каб зрабіць вывад лепш чытальным, вы можаце падзяліць коды коскай, злучком або любым іншым сімвалам, як у наступных формулах Дата ў месяц і год :

=TEXT(B2, "mmmm") & ", " & TEXT(B2, "yyyy")

Або

=TEXT(B2, "mmm") & "-" & TEXT(B2, "yy")

Дзе B2 - ячэйка, якая змяшчае дата.

Прыклад 3. Адлюстраванне даты ў выглядзе года

Калі не мае значэння, як даты захоўваюцца ў вашай працоўнай кніжцы, вы можаце прымусіць Excel паказваць толькі гады але змяненне першапачатковых дат. Іншымі словамі, вы можаце мецьпоўныя даты захоўваюцца ў ячэйках, але адлюстроўваюцца толькі гады.

У гэтым выпадку формула не патрэбна. Проста адкрыйце дыялогавае акно Фарматаваць вочкі , націснуўшы Ctrl + 1 , абярыце катэгорыю Карыстальніцкі на ўкладцы Лік і ўвядзіце адзін з прыведзеных ніжэй кодаў у Увядзіце поле:

• yy - для адлюстравання 2-значных гадоў, як 00 - 99.
• yyyy - для адлюстравання 4-значных гадоў, як 1900 - 9999 .

Калі ласка, памятайце, што гэты метад не змяняе зыходную дату , ён толькі змяняе спосаб адлюстравання даты ў вашым аркушы. Калі вы спасылаецеся на такія ячэйкі ў сваіх формулах, Microsoft Excel будзе выконваць разлікі даты, а не года.

Вы можаце знайсці больш падрабязную інфармацыю аб змене фармату даты ў гэтым падручніку: Як змяніць фармат даты ў Excel.

Як разлічыць узрост па даце нараджэння ў Excel

Ёсць некалькі спосабаў вылічыць узрост па даце нараджэння ў Excel - з дапамогай функцыі DATEDIF, YEARFRAC або INT у спалучэнні з TODAY(). Функцыя СЁННЯ дае дату для разліку ўзросту, гарантуючы, што ваша формула заўсёды будзе вяртаць правільны ўзрост.

Вылічыць узрост па даце нараджэння ў гадах

Традыцыйны спосаб вылічыць узрост чалавека у гадах - гэта адняць дату нараджэння ад бягучай даты. Такі падыход добра працуе ў паўсядзённым жыцці, але аналагічная формула разліку ўзросту ў Excel не зусім дакладная:

Дзе DOB - дата нараджэння.

Першая частка формулы (TODAY()-B2) вылічае розніца складае дні, і вы дзеліце гэта на 365, каб атрымаць колькасць гадоў. У большасці выпадкаў вынікам гэтага ўраўнення з'яўляецца дзесятковы лік, і вы маеце функцыю INT акругліць яго ў меншы бок да бліжэйшага цэлага.

Пры ўмове, што дата нараджэння знаходзіцца ў ячэйцы B2, поўная формула выглядае наступным чынам :

=INT((TODAY()-B2)/365)

Як згадвалася вышэй, гэтая формула разліку ўзросту не заўсёды бездакорная, і вось чаму. Кожны 4-ы год - гэта высакосны год, які змяшчае 366 дзён, у той час як формула дзеліць колькасць дзён на 365. Такім чынам, калі хтосьці нарадзіўся 29 лютага, а сёння 28 лютага, гэтая формула ўзросту зробіць чалавека на адзін дзень старэйшым.

Дзяленне на 365,25 замест 365 таксама не бездакорнае, напрыклад, пры вылічэнні ўзросту дзіцяці, якое яшчэ не перажыло высакосны год.

Улічваючы вышэйсказанае, вы б лепш захавайце гэты спосаб вылічэння ўзросту для нармальнага жыцця і выкарыстоўвайце адну з наступных формул для вылічэння ўзросту ад даты нараджэння ў Excel.

Падрабязнае тлумачэнне прыведзеных вышэй формул прыведзена ў раздзеле "Як вылічыць узрост у Excel". А наступны скрыншот дэманструе рэальную формулу разліку ўзросту ў дзеянні:

=DATEDIF(B2, TODAY(), "y")

Разлік дакладнага ўзросту здата нараджэння (у гадах, месяцах і днях)

Каб вылічыць дакладны ўзрост у гадах, месяцах і днях, напішыце тры функцыі DATEDIF з наступнымі адзінкамі ў апошнім аргументе:

• Y - каб вылічыць колькасць поўных гадоў.
• YM - каб атрымаць розніцу паміж месяцамі без уліку гадоў.
• MD - каб атрымаць розніцу паміж днямі, ігнаруючы гады і месяцы .

А затым аб'яднайце 3 функцыі DATEDIF у адну формулу, аддзяліце коскамі лічбы, якія вяртае кожная функцыя, і вызначце, што азначае кожны лік.

Мяркуючы, што дата нараджэнне адбываецца ў ячэйцы B2, поўная формула выглядае наступным чынам:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

Гэтая формула ўзросту можа быць вельмі зручнай, скажам, для лекара, каб паказаць дакладны ўзрост пацыентаў, або для афіцэр па персаналу, каб ведаць дакладны ўзрост усіх супрацоўнікаў:

Для атрымання дадатковых прыкладаў формул, такіх як вылічэнне ўзросту на пэўную дату або ў пэўны год, праверце наступнае падручнік: Як вылічыць узрост у Excel.

Як атрымаць нумар дня ў годзе (1-365)

Гэты прыклад дэманструе, як можна атрымаць нумар пэўнага дня ў годзе ад 1 да 365 (1-366 у высакосныя гады) 1 студзеня лічыцца днём 1.

Для гэтага выкарыстоўвайце функцыю YEAR разам з DATE наступным чынам:

=A2-DATE(YEAR(A2), 1, 0)

Дзе A2 — ячэйка, якая змяшчае дату.

А цяпер давайце паглядзім, што насамрэч робіць формула. TheФункцыя YEAR здабывае год даты ў ячэйцы A2 і перадае яго ў функцыю DATE(год, месяц, дзень) , якая вяртае парадкавы нумар, які прадстаўляе пэўную дату.

Такім чынам, у нашай формуле year вынята з зыходнай даты (A2), month роўна 1 (студзень), а day роўна 0. Фактычна нулявы дзень прымушае Excel вярнуць 31 снежня папярэдняга года , таму што мы хочам, каб 1 студзеня лічылася першым днём. Затым вы адымаеце парадкавы нумар, атрыманы формулай ДАТА, ад зыходнай даты (якая таксама захоўваецца як парадкавы нумар у Excel), і розніца - дзень года, які вы шукаеце. Напрыклад, 5 студзеня 2015 г. захоўваецца як 42009, а 31 снежня 2014 г. - 42004, так што 42009 - 42004 = 5.

Калі канцэпцыя дня 0 не здаецца вам правільнай, вы можаце выкарыстоўваць наступнае формула замест гэтага:

=A2-DATE(YEAR(A2), 1, 1)+1

Як разлічыць колькасць дзён, якія засталіся ў годзе

Каб вылічыць колькасць дзён, якія засталіся ў годзе, мы будзем выкарыстоўваць Зноў функцыі ДАТА і ГОД. Формула заснавана на тым жа падыходзе, што і ў прыкладзе 3 вышэй, таму ў вас наўрад ці ўзнікнуць цяжкасці з разуменнем яе логікі:

=DATE(YEAR(A2),12,31)-A2

Калі вы хочаце даведацца, колькі дзён засталося да канца года на падставе бягучай даты, выкарыстайце функцыю Excel TODAY() наступным чынам:

=DATE(2015, 12, 31)-TODAY()

Дзе 2015 - гэта бягучы год .

Разліквысакосныя гады ў Excel

Як вядома, амаль кожны 4-ы год мае дадатковы дзень 29 лютага і называецца высакосным годам. У табліцах Microsoft Excel вы можаце рознымі спосабамі вызначыць, ці належыць пэўная дата да высакоснага або да звычайнага года. Я збіраюся прадэманстраваць толькі пару формул, якія, на мой погляд, найбольш простыя для разумення.

Формула 1. Праверце, ці ёсць у лютым 29 дзён

Гэта вельмі відавочны тэст. Паколькі люты мае 29 дзён у высакосным годзе, мы вылічаем колькасць дзён у месяцы 2 дадзенага года і параўноўваем яе з лікам 29. Напрыклад:

=DAY(DATE(2015,3,1)-1)=29

У гэтай формуле Функцыя ДАТА(2015,3,1) вяртае 1 сакавіка 2015 года, з якога мы адымаем 1. Функцыя ДЗЕНЬ здабывае нумар дня з гэтай даты, і мы параўноўваем гэты лік з 29. Калі лічбы супадаюць, формула вяртае TRUE, FALSE у адваротным выпадку.

Калі ў вас ужо ёсць спіс дат у вашым аркушы Excel і вы хочаце ведаць, якія з іх з'яўляюцца высакоснымі гадамі, уключыце функцыю YEAR у формулу, каб атрымаць год з дата:

=DAY(DATE(YEAR(A2),3,1)-1)=29

Дзе A2 — ячэйка, якая змяшчае дату.

Вынікі, якія вяртае формула, наступныя:

У якасці альтэрнатывы вы можаце выкарыстоўваць функцыю EOMONTH, каб вярнуць апошні дзень лютага і параўнаць гэты лік з 29:

=DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29

Каб зрабіць формулу больш зручнай , выкарыстоўваць функцыю IF і атрымаць яевярнуць, скажам, "Высакосны год" і "Звычайны год" замест TRUE і FALSE:

=IF(DAY(DATE(YEAR(A2),3,1)-1)=29, "Leap year", "Common year")

=IF(DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29, "Leap year", "Common year")

Формула 2 Праверце, ці мае год 366 дзён

Гэта яшчэ адзін відавочны тэст, які наўрад ці патрабуе тлумачэнняў. Мы выкарыстоўваем адну функцыю DATE, каб вярнуць 1 студзеня наступнага года, іншую функцыю DATE, каб атрымаць 1 студзеня гэтага года, аднімем апошнюю з першай і правяраем, ці роўная розніца 366:

=DATE(2016,1,1) - DATE(2015,1,1)=366

Каб вылічыць год на аснове даты, уведзенай у некаторую ячэйку, вы выкарыстоўваеце функцыю Excel YEAR сапраўды гэтак жа, як і ў папярэднім прыкладзе:

=DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366

Дзе A2 — ячэйка, якая змяшчае дату.

І, натуральна, вы можаце ўключыць прыведзеную вышэй формулу ДАТА / ГОД у функцыю КАЛІ, каб яна вярнула нешта больш значнае, чым лагічныя значэнні TRUE і FALSE:

=IF(DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366, "Leap year", "Non-leap year")

Як ужо згадвалася, гэта не адзіныя магчымыя спосабы разліку высакосных гадоў у Excel. Калі вам цікава даведацца пра іншыя рашэнні, вы можаце праверыць метад, прапанаваны Microsoft. Як звычайна, хлопцы з Microsoft не шукаюць лёгкіх шляхоў, праўда?

Спадзяемся, што гэты артыкул дапамог вам разабрацца ў разліках года ў Excel. Я дзякую вам за чытанне і з нецярпеннем чакаю сустрэчы з вамі на наступным тыдні.