ਇਹ ਟਿਊਟੋਰਿਅਲ ਐਕਸਲ YEAR ਫੰਕਸ਼ਨ ਦੇ ਸੰਟੈਕਸ ਅਤੇ ਵਰਤੋਂ ਦੀ ਵਿਆਖਿਆ ਕਰਦਾ ਹੈ ਅਤੇ ਮਿਤੀ ਤੋਂ ਸਾਲ ਕੱਢਣ, ਤਾਰੀਖ ਨੂੰ ਮਹੀਨੇ ਅਤੇ ਸਾਲ ਵਿੱਚ ਬਦਲਣ, ਜਨਮ ਮਿਤੀ ਤੋਂ ਉਮਰ ਦੀ ਗਣਨਾ ਕਰਨ ਅਤੇ ਨਿਰਧਾਰਤ ਕਰਨ ਲਈ ਫਾਰਮੂਲਾ ਉਦਾਹਰਣ ਪ੍ਰਦਾਨ ਕਰਦਾ ਹੈ ਲੀਪ ਸਾਲ।

ਕੁਝ ਹਾਲੀਆ ਪੋਸਟਾਂ ਵਿੱਚ, ਅਸੀਂ Excel ਵਿੱਚ ਤਾਰੀਖਾਂ ਅਤੇ ਸਮੇਂ ਦੀ ਗਣਨਾ ਕਰਨ ਦੇ ਵੱਖੋ-ਵੱਖਰੇ ਤਰੀਕਿਆਂ ਦੀ ਖੋਜ ਕੀਤੀ ਹੈ ਅਤੇ ਕਈ ਤਰ੍ਹਾਂ ਦੇ ਉਪਯੋਗੀ ਫੰਕਸ਼ਨਾਂ ਜਿਵੇਂ ਕਿ WEEKDAY, WEEKNUM, MONTH, ਅਤੇ DAY ਸਿੱਖੇ ਹਨ। ਅੱਜ, ਅਸੀਂ ਇੱਕ ਵੱਡੀ ਸਮੇਂ ਦੀ ਇਕਾਈ 'ਤੇ ਧਿਆਨ ਕੇਂਦਰਿਤ ਕਰਨ ਜਾ ਰਹੇ ਹਾਂ ਅਤੇ ਤੁਹਾਡੀਆਂ ਐਕਸਲ ਵਰਕਸ਼ੀਟਾਂ ਵਿੱਚ ਸਾਲਾਂ ਦੀ ਗਣਨਾ ਕਰਨ ਬਾਰੇ ਗੱਲ ਕਰਨ ਜਾ ਰਹੇ ਹਾਂ।

ਇਸ ਟਿਊਟੋਰਿਅਲ ਵਿੱਚ, ਤੁਸੀਂ ਸਿੱਖੋਗੇ:

YEAR ਫੰਕਸ਼ਨ Excel ਵਿੱਚ

ਐਕਸਲ ਵਿੱਚ YEAR ਫੰਕਸ਼ਨ 1900 ਤੋਂ 9999 ਤੱਕ ਇੱਕ ਪੂਰਨ ਅੰਕ ਦੇ ਰੂਪ ਵਿੱਚ ਦਿੱਤੀ ਗਈ ਮਿਤੀ ਦੇ ਅਨੁਸਾਰੀ ਇੱਕ ਚਾਰ-ਅੰਕ ਵਾਲਾ ਸਾਲ ਦਿੰਦਾ ਹੈ।

ਐਕਸਲ YEAR ਫੰਕਸ਼ਨ ਦਾ ਸੰਟੈਕਸ ਓਨਾ ਹੀ ਸਰਲ ਹੈ ਜਿੰਨਾ ਕਿ ਸੰਭਾਵਤ ਤੌਰ 'ਤੇ ਇਹ ਹੋ ਸਕਦਾ ਹੈ:

ਜਿੱਥੇ ਸੀਰੀਅਲ_ਨੰਬਰ ਉਸ ਸਾਲ ਦੀ ਕੋਈ ਵੈਧ ਮਿਤੀ ਹੈ ਜਿਸ ਨੂੰ ਤੁਸੀਂ ਲੱਭਣਾ ਚਾਹੁੰਦੇ ਹੋ।

Excel YEAR ਫਾਰਮੂਲਾ

Excel ਵਿੱਚ YEAR ਫਾਰਮੂਲਾ ਬਣਾਉਣ ਲਈ, ਤੁਸੀਂ ਸਰੋਤ ਮਿਤੀ ਨੂੰ ਕਈ ਤਰੀਕਿਆਂ ਨਾਲ ਸਪਲਾਈ ਕਰ ਸਕਦੇ ਹੋ।

DATE ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰਨਾ

The ਐਕਸਲ ਵਿੱਚ ਮਿਤੀ ਦੀ ਸਪਲਾਈ ਕਰਨ ਦਾ ਸਭ ਤੋਂ ਭਰੋਸੇਮੰਦ ਤਰੀਕਾ DATE ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰਨਾ ਹੈ।

ਉਦਾਹਰਨ ਲਈ, ਹੇਠਾਂ ਦਿੱਤਾ ਫਾਰਮੂਲਾ 28 ਅਪ੍ਰੈਲ, 2015 ਲਈ ਸਾਲ ਵਾਪਸ ਕਰਦਾ ਹੈ:

=YEAR(DATE(2015, 4, 28))

ਇਸ ਤਰ੍ਹਾਂ ਮਿਤੀ ਨੂੰ ਦਰਸਾਉਂਦਾ ਸੀਰੀਅਲ ਨੰਬਰ

ਅੰਦਰੂਨੀ ਐਕਸਲ ਸਿਸਟਮ ਵਿੱਚ, ਮਿਤੀਆਂ ਨੂੰ 1 ਜਨਵਰੀ 1900 ਤੋਂ ਸ਼ੁਰੂ ਹੋਣ ਵਾਲੇ ਸੀਰੀਅਲ ਨੰਬਰਾਂ ਵਜੋਂ ਸਟੋਰ ਕੀਤਾ ਜਾਂਦਾ ਹੈ, ਜੋ ਕਿ ਨੰਬਰ 1 ਵਜੋਂ ਸਟੋਰ ਕੀਤਾ ਜਾਂਦਾ ਹੈ। ਹੋਰ ਲਈਐਕਸਲ ਵਿੱਚ ਤਾਰੀਖਾਂ ਨੂੰ ਕਿਵੇਂ ਸਟੋਰ ਕੀਤਾ ਜਾਂਦਾ ਹੈ ਇਸ ਬਾਰੇ ਜਾਣਕਾਰੀ, ਕਿਰਪਾ ਕਰਕੇ ਐਕਸਲ ਮਿਤੀ ਫਾਰਮੈਟ ਦੇਖੋ।

ਅਪਰੈਲ 28, 2015 ਦਾ ਦਿਨ 42122 ਵਜੋਂ ਸਟੋਰ ਕੀਤਾ ਜਾਂਦਾ ਹੈ, ਇਸ ਲਈ ਤੁਸੀਂ ਇਸ ਨੰਬਰ ਨੂੰ ਫਾਰਮੂਲੇ ਵਿੱਚ ਸਿੱਧਾ ਦਾਖਲ ਕਰ ਸਕਦੇ ਹੋ:

=YEAR(42122)

ਹਾਲਾਂਕਿ ਸਵੀਕਾਰਯੋਗ ਹੈ, ਇਸ ਵਿਧੀ ਦੀ ਸਿਫ਼ਾਰਸ਼ ਨਹੀਂ ਕੀਤੀ ਜਾਂਦੀ ਕਿਉਂਕਿ ਮਿਤੀ ਨੰਬਰਿੰਗ ਵੱਖ-ਵੱਖ ਪ੍ਰਣਾਲੀਆਂ ਵਿੱਚ ਵੱਖ-ਵੱਖ ਹੋ ਸਕਦੀ ਹੈ।

ਸੈੱਲ ਸੰਦਰਭ ਵਜੋਂ

ਇਹ ਮੰਨ ਕੇ ਕਿ ਤੁਹਾਡੇ ਕੋਲ ਕਿਸੇ ਸੈੱਲ ਵਿੱਚ ਇੱਕ ਵੈਧ ਮਿਤੀ ਹੈ, ਤੁਸੀਂ ਸਿਰਫ਼ ਉਸ ਸੈੱਲ ਦਾ ਹਵਾਲਾ ਦੇ ਸਕਦੇ ਹੋ। ਉਦਾਹਰਨ ਲਈ:

=YEAR(A1)

ਕਿਸੇ ਹੋਰ ਫਾਰਮੂਲੇ ਦੇ ਨਤੀਜੇ ਵਜੋਂ

ਉਦਾਹਰਨ ਲਈ, ਤੁਸੀਂ ਮੌਜੂਦਾ ਮਿਤੀ ਤੋਂ ਸਾਲ ਕੱਢਣ ਲਈ TODAY() ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰ ਸਕਦੇ ਹੋ:

=YEAR(TODAY())

ਲਿਖਤ ਦੇ ਰੂਪ ਵਿੱਚ

ਇੱਕ ਸਧਾਰਨ ਸਥਿਤੀ ਵਿੱਚ, YEAR ਫਾਰਮੂਲਾ ਟੈਕਸਟ ਦੇ ਰੂਪ ਵਿੱਚ ਦਰਜ ਕੀਤੀਆਂ ਮਿਤੀਆਂ ਨੂੰ ਵੀ ਸਮਝ ਸਕਦਾ ਹੈ, ਜਿਵੇਂ ਕਿ:

=YEAR("28-Apr-2015")

ਇਸ ਵਿਧੀ ਦੀ ਵਰਤੋਂ ਕਰਦੇ ਸਮੇਂ, ਕਿਰਪਾ ਕਰਕੇ ਦੋ ਵਾਰ ਜਾਂਚ ਕਰੋ ਕਿ ਤੁਸੀਂ ਉਸ ਫਾਰਮੈਟ ਵਿੱਚ ਮਿਤੀ ਦਾਖਲ ਕਰਦੇ ਹੋ ਜਿਸਨੂੰ Excel ਸਮਝਦਾ ਹੈ। ਨਾਲ ਹੀ, ਕਿਰਪਾ ਕਰਕੇ ਯਾਦ ਰੱਖੋ ਕਿ Microsoft ਸਹੀ ਨਤੀਜਿਆਂ ਦੀ ਗਾਰੰਟੀ ਨਹੀਂ ਦਿੰਦਾ ਹੈ ਜਦੋਂ ਇੱਕ ਮਿਤੀ ਇੱਕ ਟੈਕਸਟ ਮੁੱਲ ਦੇ ਤੌਰ 'ਤੇ ਸਪਲਾਈ ਕੀਤੀ ਜਾਂਦੀ ਹੈ।

ਹੇਠ ਦਿੱਤੇ ਸਕ੍ਰੀਨਸ਼ੌਟ ਵਿੱਚ ਉਪਰੋਕਤ ਸਾਰੇ YEAR ਫਾਰਮੂਲੇ ਕਾਰਜਸ਼ੀਲ ਹਨ, ਸਾਰੇ 2015 ਵਾਪਸ ਆਉਣਗੇ ਜਿਵੇਂ ਤੁਸੀਂ ਉਮੀਦ ਕਰ ਸਕਦੇ ਹੋ :)

ਐਕਸਲ ਵਿੱਚ ਮਿਤੀ ਨੂੰ ਸਾਲ ਵਿੱਚ ਕਿਵੇਂ ਬਦਲਿਆ ਜਾਵੇ

ਜਦੋਂ ਤੁਸੀਂ ਐਕਸਲ ਵਿੱਚ ਮਿਤੀ ਜਾਣਕਾਰੀ ਨਾਲ ਕੰਮ ਕਰਦੇ ਹੋ, ਤਾਂ ਤੁਹਾਡੀਆਂ ਵਰਕਸ਼ੀਟਾਂ ਆਮ ਤੌਰ 'ਤੇ ਮਹੀਨਾ, ਦਿਨ ਅਤੇ ਸਾਲ ਸਮੇਤ ਪੂਰੀਆਂ ਤਾਰੀਖਾਂ ਨੂੰ ਪ੍ਰਦਰਸ਼ਿਤ ਕਰਦੀਆਂ ਹਨ। . ਹਾਲਾਂਕਿ, ਪ੍ਰਮੁੱਖ ਮੀਲਪੱਥਰਾਂ ਅਤੇ ਮਹੱਤਵਪੂਰਨ ਘਟਨਾਵਾਂ ਜਿਵੇਂ ਕਿ ਉਤਪਾਦ ਲਾਂਚ ਜਾਂ ਸੰਪੱਤੀ ਪ੍ਰਾਪਤੀ ਲਈ, ਤੁਸੀਂ ਮੁੜ-ਪ੍ਰਵੇਸ਼ ਕੀਤੇ ਜਾਂ ਸੰਸ਼ੋਧਿਤ ਕੀਤੇ ਬਿਨਾਂ ਸਿਰਫ਼ ਸਾਲ ਦੇਖਣਾ ਚਾਹ ਸਕਦੇ ਹੋ।ਅਸਲੀ ਡਾਟਾ. ਹੇਠਾਂ, ਤੁਹਾਨੂੰ ਅਜਿਹਾ ਕਰਨ ਦੇ 3 ਤੇਜ਼ ਤਰੀਕੇ ਮਿਲਣਗੇ।

ਉਦਾਹਰਨ 1. YEAR ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰਕੇ ਮਿਤੀ ਤੋਂ ਇੱਕ ਸਾਲ ਕੱਢੋ

ਅਸਲ ਵਿੱਚ, ਤੁਸੀਂ ਪਹਿਲਾਂ ਹੀ ਜਾਣਦੇ ਹੋ ਕਿ ਐਕਸਲ ਵਿੱਚ YEAR ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਿਵੇਂ ਕਰਨੀ ਹੈ। ਇੱਕ ਮਿਤੀ ਨੂੰ ਇੱਕ ਸਾਲ ਵਿੱਚ ਤਬਦੀਲ ਕਰਨ ਲਈ. ਉਪਰੋਕਤ ਸਕ੍ਰੀਨਸ਼ੌਟ ਫਾਰਮੂਲੇ ਦੇ ਇੱਕ ਸਮੂਹ ਨੂੰ ਪ੍ਰਦਰਸ਼ਿਤ ਕਰਦਾ ਹੈ, ਅਤੇ ਤੁਸੀਂ ਹੇਠਾਂ ਦਿੱਤੇ ਸਕ੍ਰੀਨਸ਼ਾਟ ਵਿੱਚ ਕੁਝ ਹੋਰ ਉਦਾਹਰਣਾਂ ਦੇਖ ਸਕਦੇ ਹੋ। ਧਿਆਨ ਦਿਓ ਕਿ YEAR ਫੰਕਸ਼ਨ ਸਾਰੇ ਸੰਭਾਵੀ ਫਾਰਮੈਟਾਂ ਵਿੱਚ ਮਿਤੀਆਂ ਨੂੰ ਪੂਰੀ ਤਰ੍ਹਾਂ ਸਮਝਦਾ ਹੈ:

ਉਦਾਹਰਨ 2. ਐਕਸਲ ਵਿੱਚ ਤਾਰੀਖ ਨੂੰ ਮਹੀਨੇ ਅਤੇ ਸਾਲ ਵਿੱਚ ਬਦਲੋ

ਦਿੱਤੀ ਗਈ ਮਿਤੀ ਨੂੰ ਬਦਲਣ ਲਈ ਸਾਲ ਅਤੇ ਮਹੀਨੇ ਤੱਕ, ਤੁਸੀਂ ਹਰੇਕ ਯੂਨਿਟ ਨੂੰ ਵੱਖਰੇ ਤੌਰ 'ਤੇ ਐਕਸਟਰੈਕਟ ਕਰਨ ਲਈ ਟੈਕਸਟ ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰ ਸਕਦੇ ਹੋ, ਅਤੇ ਫਿਰ ਉਹਨਾਂ ਫੰਕਸ਼ਨਾਂ ਨੂੰ ਇੱਕ ਫਾਰਮੂਲੇ ਵਿੱਚ ਜੋੜ ਸਕਦੇ ਹੋ।

TEXT ਫੰਕਸ਼ਨ ਵਿੱਚ, ਤੁਸੀਂ ਮਹੀਨਿਆਂ ਅਤੇ ਸਾਲਾਂ ਲਈ ਵੱਖ-ਵੱਖ ਕੋਡਾਂ ਦੀ ਵਰਤੋਂ ਕਰ ਸਕਦੇ ਹੋ, ਜਿਵੇਂ ਕਿ:

• "mmmm" - ਸੰਖੇਪ ਮਹੀਨਿਆਂ ਦੇ ਨਾਮ, ਜਨਵਰੀ - ਦਸੰਬਰ ਦੇ ਰੂਪ ਵਿੱਚ।
• "mmmm" - ਪੂਰੇ ਮਹੀਨੇ ਦੇ ਨਾਮ, ਜਨਵਰੀ - ਦਸੰਬਰ ਦੇ ਤੌਰ 'ਤੇ।
• "yy" - 2-ਅੰਕ ਦੇ ਸਾਲ
• "yyyy" - 4-ਅੰਕ ਸਾਲ

ਆਉਟਪੁੱਟ ਨੂੰ ਬਿਹਤਰ ਢੰਗ ਨਾਲ ਪੜ੍ਹਨਯੋਗ ਬਣਾਉਣ ਲਈ, ਤੁਸੀਂ ਕੋਡਾਂ ਨੂੰ ਕਾਮੇ, ਹਾਈਫਨ ਜਾਂ ਕਿਸੇ ਹੋਰ ਅੱਖਰ ਨਾਲ ਵੱਖ ਕਰ ਸਕਦੇ ਹੋ, ਜਿਵੇਂ ਕਿ ਹੇਠਾਂ ਦਿੱਤੇ ਮਿਤੀ ਤੋਂ ਮਹੀਨਾ ਅਤੇ ਸਾਲ ਫਾਰਮੂਲੇ:

=TEXT(B2, "mmmm") & ", " & TEXT(B2, "yyyy")

ਜਾਂ

=TEXT(B2, "mmm") & "-" & TEXT(B2, "yy")

ਜਿੱਥੇ B2 ਇੱਕ ਸੈੱਲ ਰੱਖਦਾ ਹੈ ਇੱਕ ਮਿਤੀ।

ਉਦਾਹਰਨ 3. ਇੱਕ ਤਾਰੀਖ ਨੂੰ ਇੱਕ ਸਾਲ ਦੇ ਰੂਪ ਵਿੱਚ ਪ੍ਰਦਰਸ਼ਿਤ ਕਰੋ

ਜੇਕਰ ਇਹ ਅਸਲ ਵਿੱਚ ਮਾਇਨੇ ਨਹੀਂ ਰੱਖਦਾ ਕਿ ਤਾਰੀਖਾਂ ਨੂੰ ਤੁਹਾਡੀ ਵਰਕਬੁੱਕ ਵਿੱਚ ਕਿਵੇਂ ਸਟੋਰ ਕੀਤਾ ਜਾਂਦਾ ਹੈ, ਤਾਂ ਤੁਸੀਂ ਸਿਰਫ਼ ਸਾਲ ਦਿਖਾਉਣ ਲਈ ਐਕਸਲ ਪ੍ਰਾਪਤ ਕਰੋ ਮੂਲ ਤਾਰੀਖਾਂ ਨੂੰ ਬਦਲਣਾ। ਦੂਜੇ ਸ਼ਬਦਾਂ ਵਿਚ, ਤੁਹਾਡੇ ਕੋਲ ਹੋ ਸਕਦਾ ਹੈਸੈੱਲਾਂ ਵਿੱਚ ਸਟੋਰ ਕੀਤੀਆਂ ਪੂਰੀਆਂ ਤਾਰੀਖਾਂ, ਪਰ ਸਿਰਫ਼ ਸਾਲ ਹੀ ਦਿਖਾਏ ਗਏ ਹਨ।

ਇਸ ਕੇਸ ਵਿੱਚ, ਕਿਸੇ ਫਾਰਮੂਲੇ ਦੀ ਲੋੜ ਨਹੀਂ ਹੈ। ਤੁਸੀਂ Ctrl + 1 ਦਬਾ ਕੇ ਫਾਰਮੈਟ ਸੈੱਲ ਡਾਇਲਾਗ ਖੋਲ੍ਹੋ, ਨੰਬਰ ਟੈਬ 'ਤੇ ਕਸਟਮ ਸ਼੍ਰੇਣੀ ਚੁਣੋ, ਅਤੇ ਹੇਠਾਂ ਦਿੱਤੇ ਕੋਡਾਂ ਵਿੱਚੋਂ ਇੱਕ ਨੂੰ ਟਾਇਪ ਕਰੋ ਬਾਕਸ:

• yy - 00 - 99 ਦੇ ਰੂਪ ਵਿੱਚ 2-ਅੰਕ ਦੇ ਸਾਲਾਂ ਨੂੰ ਪ੍ਰਦਰਸ਼ਿਤ ਕਰਨ ਲਈ।
• yyyy - 4-ਅੰਕ ਦੇ ਸਾਲਾਂ ਨੂੰ ਦਿਖਾਉਣ ਲਈ, 1900 - 9999 ਦੇ ਰੂਪ ਵਿੱਚ .

ਕਿਰਪਾ ਕਰਕੇ ਯਾਦ ਰੱਖੋ ਕਿ ਇਹ ਵਿਧੀ ਮੂਲ ਮਿਤੀ ਨੂੰ ਨਹੀਂ ਬਦਲਦੀ , ਇਹ ਸਿਰਫ ਤੁਹਾਡੀ ਵਰਕਸ਼ੀਟ ਵਿੱਚ ਮਿਤੀ ਨੂੰ ਪ੍ਰਦਰਸ਼ਿਤ ਕਰਨ ਦੇ ਤਰੀਕੇ ਨੂੰ ਬਦਲਦੀ ਹੈ। ਜੇਕਰ ਤੁਸੀਂ ਆਪਣੇ ਫਾਰਮੂਲੇ ਵਿੱਚ ਅਜਿਹੇ ਸੈੱਲਾਂ ਦਾ ਹਵਾਲਾ ਦਿੰਦੇ ਹੋ, ਤਾਂ Microsoft Excel ਸਾਲ ਦੀ ਗਣਨਾ ਕਰਨ ਦੀ ਬਜਾਏ ਤਾਰੀਖ ਦੀ ਗਣਨਾ ਕਰੇਗਾ।

ਤੁਸੀਂ ਇਸ ਟਿਊਟੋਰਿਅਲ ਵਿੱਚ ਮਿਤੀ ਫਾਰਮੈਟ ਨੂੰ ਬਦਲਣ ਬਾਰੇ ਹੋਰ ਵੇਰਵੇ ਪ੍ਰਾਪਤ ਕਰ ਸਕਦੇ ਹੋ: ਐਕਸਲ ਵਿੱਚ ਮਿਤੀ ਫਾਰਮੈਟ ਨੂੰ ਕਿਵੇਂ ਬਦਲਣਾ ਹੈ।

ਐਕਸਲ ਵਿੱਚ ਜਨਮ ਮਿਤੀ ਤੋਂ ਉਮਰ ਦੀ ਗਣਨਾ ਕਿਵੇਂ ਕਰੀਏ

ਐਕਸਲ ਵਿੱਚ ਜਨਮ ਮਿਤੀ ਦੀ ਉਮਰ ਫਾਰਮ ਦੀ ਗਣਨਾ ਕਰਨ ਦੇ ਕਈ ਤਰੀਕੇ ਹਨ - TODAY() ਦੇ ਨਾਲ DATEDIF, YEARFRAC ਜਾਂ INT ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰਦੇ ਹੋਏ। TODAY ਫੰਕਸ਼ਨ ਉਮਰ ਦੀ ਗਣਨਾ ਕਰਨ ਲਈ ਮਿਤੀ ਪ੍ਰਦਾਨ ਕਰਦਾ ਹੈ, ਇਹ ਯਕੀਨੀ ਬਣਾਉਂਦਾ ਹੈ ਕਿ ਤੁਹਾਡਾ ਫਾਰਮੂਲਾ ਹਮੇਸ਼ਾ ਸਹੀ ਉਮਰ ਵਾਪਸ ਕਰੇਗਾ।

ਜਨਮ ਮਿਤੀ ਤੋਂ ਸਾਲਾਂ ਵਿੱਚ ਉਮਰ ਦੀ ਗਣਨਾ ਕਰੋ

ਕਿਸੇ ਵਿਅਕਤੀ ਦੀ ਉਮਰ ਦੀ ਗਣਨਾ ਕਰਨ ਦਾ ਰਵਾਇਤੀ ਤਰੀਕਾ ਸਾਲਾਂ ਵਿੱਚ ਮੌਜੂਦਾ ਮਿਤੀ ਤੋਂ ਜਨਮ ਮਿਤੀ ਨੂੰ ਘਟਾਉਣਾ ਹੈ। ਇਹ ਪਹੁੰਚ ਰੋਜ਼ਾਨਾ ਜੀਵਨ ਵਿੱਚ ਵਧੀਆ ਕੰਮ ਕਰਦੀ ਹੈ, ਪਰ ਇੱਕ ਸਮਾਨ ਐਕਸਲ ਉਮਰ ਗਣਨਾ ਫਾਰਮੂਲਾ ਬਿਲਕੁਲ ਸਹੀ ਨਹੀਂ ਹੈ:

ਜਿੱਥੇ DOB ਜਨਮ ਮਿਤੀ ਹੈ।

ਫਾਰਮੂਲੇ ਦਾ ਪਹਿਲਾ ਹਿੱਸਾ (TODAY()-B2) ਦੀ ਗਣਨਾ ਕਰਦਾ ਹੈ ਅੰਤਰ ਦਿਨ ਹੈ, ਅਤੇ ਤੁਸੀਂ ਸਾਲਾਂ ਦੀ ਸੰਖਿਆ ਪ੍ਰਾਪਤ ਕਰਨ ਲਈ ਇਸਨੂੰ 365 ਨਾਲ ਵੰਡਦੇ ਹੋ। ਜ਼ਿਆਦਾਤਰ ਮਾਮਲਿਆਂ ਵਿੱਚ, ਇਸ ਸਮੀਕਰਨ ਦਾ ਨਤੀਜਾ ਇੱਕ ਦਸ਼ਮਲਵ ਸੰਖਿਆ ਹੁੰਦਾ ਹੈ, ਅਤੇ ਤੁਹਾਡੇ ਕੋਲ INT ਫੰਕਸ਼ਨ ਇਸ ਨੂੰ ਨਜ਼ਦੀਕੀ ਪੂਰਨ ਅੰਕ ਤੱਕ ਗੋਲ ਕਰਦਾ ਹੈ।

ਇਹ ਮੰਨ ਕੇ ਕਿ ਜਨਮ ਮਿਤੀ ਸੈੱਲ B2 ਵਿੱਚ ਹੈ, ਪੂਰਾ ਫਾਰਮੂਲਾ ਇਸ ਤਰ੍ਹਾਂ ਹੈ :

=INT((TODAY()-B2)/365)

ਜਿਵੇਂ ਕਿ ਉੱਪਰ ਦੱਸਿਆ ਗਿਆ ਹੈ, ਇਹ ਉਮਰ ਗਣਨਾ ਫਾਰਮੂਲਾ ਹਮੇਸ਼ਾ ਨਿਰਦੋਸ਼ ਨਹੀਂ ਹੁੰਦਾ, ਅਤੇ ਇਸਦਾ ਕਾਰਨ ਇੱਥੇ ਹੈ। ਹਰ ਚੌਥਾ ਸਾਲ ਇੱਕ ਲੀਪ ਸਾਲ ਹੁੰਦਾ ਹੈ ਜਿਸ ਵਿੱਚ 366 ਦਿਨ ਹੁੰਦੇ ਹਨ, ਜਦੋਂ ਕਿ ਫਾਰਮੂਲਾ ਦਿਨਾਂ ਦੀ ਗਿਣਤੀ ਨੂੰ 365 ਨਾਲ ਵੰਡਦਾ ਹੈ। ਇਸ ਲਈ, ਜੇਕਰ ਕੋਈ ਵਿਅਕਤੀ 29 ਫਰਵਰੀ ਨੂੰ ਪੈਦਾ ਹੋਇਆ ਸੀ ਅਤੇ ਅੱਜ 28 ਫਰਵਰੀ ਹੈ, ਤਾਂ ਇਹ ਉਮਰ ਫਾਰਮੂਲਾ ਇੱਕ ਵਿਅਕਤੀ ਨੂੰ ਇੱਕ ਦਿਨ ਵੱਡਾ ਬਣਾ ਦੇਵੇਗਾ।

365 ਦੀ ਬਜਾਏ 365.25 ਨਾਲ ਵੰਡਣਾ ਵੀ ਨਿਰਦੋਸ਼ ਨਹੀਂ ਹੈ, ਉਦਾਹਰਨ ਲਈ, ਕਿਸੇ ਬੱਚੇ ਦੀ ਉਮਰ ਦੀ ਗਣਨਾ ਕਰਦੇ ਸਮੇਂ ਜੋ ਅਜੇ ਤੱਕ ਇੱਕ ਲੀਪ ਸਾਲ ਵਿੱਚ ਨਹੀਂ ਗੁਜ਼ਰਿਆ ਹੈ।

ਉੱਪਰ ਦਿੱਤੇ ਅਨੁਸਾਰ, ਤੁਸੀਂ ਆਮ ਜੀਵਨ ਲਈ ਉਮਰ ਦੀ ਗਣਨਾ ਕਰਨ ਦੇ ਇਸ ਤਰੀਕੇ ਨੂੰ ਬਿਹਤਰ ਢੰਗ ਨਾਲ ਸੁਰੱਖਿਅਤ ਕਰੋ, ਅਤੇ Excel ਵਿੱਚ ਜਨਮ ਮਿਤੀ ਤੋਂ ਉਮਰ ਦੀ ਗਣਨਾ ਕਰਨ ਲਈ ਹੇਠਾਂ ਦਿੱਤੇ ਫਾਰਮੂਲੇ ਵਿੱਚੋਂ ਇੱਕ ਦੀ ਵਰਤੋਂ ਕਰੋ।

ਉਪਰੋਕਤ ਫਾਰਮੂਲੇ ਦੀ ਵਿਸਤ੍ਰਿਤ ਵਿਆਖਿਆ ਐਕਸਲ ਵਿੱਚ ਉਮਰ ਦੀ ਗਣਨਾ ਕਿਵੇਂ ਕਰੀਏ ਵਿੱਚ ਦਿੱਤੀ ਗਈ ਹੈ। ਅਤੇ ਨਿਮਨਲਿਖਤ ਸਕ੍ਰੀਨਸ਼ੌਟ ਕਾਰਵਾਈ ਵਿੱਚ ਇੱਕ ਅਸਲ-ਜੀਵਨ ਉਮਰ ਗਣਨਾ ਫਾਰਮੂਲੇ ਨੂੰ ਦਰਸਾਉਂਦਾ ਹੈ:

=DATEDIF(B2, TODAY(), "y")

ਤੋਂ ਸਹੀ ਉਮਰ ਦੀ ਗਣਨਾਜਨਮ ਮਿਤੀ (ਸਾਲ, ਮਹੀਨੇ ਅਤੇ ਦਿਨਾਂ ਵਿੱਚ)

ਸਾਲਾਂ, ਮਹੀਨਿਆਂ ਅਤੇ ਦਿਨਾਂ ਵਿੱਚ ਸਹੀ ਉਮਰ ਦੀ ਗਣਨਾ ਕਰਨ ਲਈ, ਆਖਰੀ ਆਰਗੂਮੈਂਟ ਵਿੱਚ ਹੇਠਾਂ ਦਿੱਤੀਆਂ ਇਕਾਈਆਂ ਦੇ ਨਾਲ ਤਿੰਨ DATEDIF ਫੰਕਸ਼ਨਾਂ ਨੂੰ ਲਿਖੋ:

• Y - ਪੂਰੇ ਸਾਲਾਂ ਦੀ ਗਿਣਤੀ ਦੀ ਗਣਨਾ ਕਰਨ ਲਈ।
• YM - ਮਹੀਨਿਆਂ ਵਿੱਚ ਅੰਤਰ ਪ੍ਰਾਪਤ ਕਰਨ ਲਈ, ਸਾਲਾਂ ਨੂੰ ਨਜ਼ਰਅੰਦਾਜ਼ ਕਰਦੇ ਹੋਏ।
• MD - ਦਿਨਾਂ ਵਿੱਚ ਅੰਤਰ ਪ੍ਰਾਪਤ ਕਰਨ ਲਈ, ਸਾਲਾਂ ਅਤੇ ਮਹੀਨਿਆਂ ਨੂੰ ਅਣਡਿੱਠ ਕਰਦੇ ਹੋਏ .

ਅਤੇ ਫਿਰ, ਇੱਕ ਇੱਕਲੇ ਫਾਰਮੂਲੇ ਵਿੱਚ 3 DATEDIF ਫੰਕਸ਼ਨਾਂ ਨੂੰ ਜੋੜੋ, ਹਰੇਕ ਫੰਕਸ਼ਨ ਦੁਆਰਾ ਦਿੱਤੇ ਗਏ ਸੰਖਿਆਵਾਂ ਨੂੰ ਕਾਮਿਆਂ ਨਾਲ ਵੱਖ ਕਰੋ, ਅਤੇ ਪਰਿਭਾਸ਼ਿਤ ਕਰੋ ਕਿ ਹਰੇਕ ਸੰਖਿਆ ਦਾ ਕੀ ਅਰਥ ਹੈ।

ਦੀ ਮਿਤੀ ਨੂੰ ਮੰਨਦੇ ਹੋਏ ਜਨਮ ਸੈੱਲ B2 ਵਿੱਚ ਹੁੰਦਾ ਹੈ, ਪੂਰਾ ਫਾਰਮੂਲਾ ਇਸ ਤਰ੍ਹਾਂ ਹੁੰਦਾ ਹੈ:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

ਇਹ ਉਮਰ ਫਾਰਮੂਲਾ ਬਹੁਤ ਉਪਯੋਗੀ ਹੋ ਸਕਦਾ ਹੈ, ਜਿਵੇਂ ਕਿ, ਇੱਕ ਡਾਕਟਰ ਲਈ ਮਰੀਜ਼ਾਂ ਦੀ ਸਹੀ ਉਮਰ ਦਿਖਾਉਣ ਲਈ, ਜਾਂ ਸਾਰੇ ਕਰਮਚਾਰੀਆਂ ਦੀ ਸਹੀ ਉਮਰ ਜਾਣਨ ਲਈ ਇੱਕ ਕਰਮਚਾਰੀ ਅਧਿਕਾਰੀ:

ਹੋਰ ਫਾਰਮੂਲਾ ਉਦਾਹਰਨਾਂ ਜਿਵੇਂ ਕਿ ਕਿਸੇ ਖਾਸ ਮਿਤੀ ਜਾਂ ਕਿਸੇ ਖਾਸ ਸਾਲ ਵਿੱਚ ਉਮਰ ਦੀ ਗਣਨਾ ਕਰਨ ਲਈ, ਕਿਰਪਾ ਕਰਕੇ ਹੇਠਾਂ ਦਿੱਤੇ ਨੂੰ ਦੇਖੋ ਟਿਊਟੋਰਿਅਲ: ਐਕਸਲ ਵਿੱਚ ਉਮਰ ਦੀ ਗਣਨਾ ਕਿਵੇਂ ਕਰੀਏ।

ਸਾਲ ਦਾ ਦਿਨ ਸੰਖਿਆ ਕਿਵੇਂ ਪ੍ਰਾਪਤ ਕਰੀਏ (1-365)

ਇਹ ਉਦਾਹਰਨ ਦਰਸਾਉਂਦੀ ਹੈ ਕਿ ਤੁਸੀਂ ਸਾਲ ਵਿੱਚ ਕਿਸੇ ਖਾਸ ਦਿਨ ਦੀ ਸੰਖਿਆ ਕਿਵੇਂ ਪ੍ਰਾਪਤ ਕਰ ਸਕਦੇ ਹੋ, 1 ਅਤੇ 365 (ਲੀਪ ਸਾਲਾਂ ਵਿੱਚ 1-366) ਦੇ ਵਿਚਕਾਰ। 1 ਜਨਵਰੀ ਦੇ ਨਾਲ ਦਿਨ 1 ਮੰਨਿਆ ਜਾਂਦਾ ਹੈ।

ਇਸਦੇ ਲਈ, DATE ਦੇ ਨਾਲ ਇਸ ਤਰੀਕੇ ਨਾਲ YEAR ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰੋ:

=A2-DATE(YEAR(A2), 1, 0)

ਜਿੱਥੇ A2 ਇੱਕ ਸੈੱਲ ਹੈ ਜਿਸ ਵਿੱਚ ਮਿਤੀ ਹੈ।

ਅਤੇ ਹੁਣ, ਆਓ ਦੇਖੀਏ ਕਿ ਫਾਰਮੂਲਾ ਅਸਲ ਵਿੱਚ ਕੀ ਕਰਦਾ ਹੈ। ਦ YEAR ਫੰਕਸ਼ਨ ਸੈੱਲ A2 ਵਿੱਚ ਮਿਤੀ ਦੇ ਸਾਲ ਨੂੰ ਮੁੜ ਪ੍ਰਾਪਤ ਕਰਦਾ ਹੈ, ਅਤੇ ਇਸਨੂੰ DATE(ਸਾਲ, ਮਹੀਨਾ, ਦਿਨ) ਫੰਕਸ਼ਨ ਵਿੱਚ ਪਾਸ ਕਰਦਾ ਹੈ, ਜੋ ਇੱਕ ਨਿਸ਼ਚਿਤ ਮਿਤੀ ਨੂੰ ਦਰਸਾਉਣ ਵਾਲੀ ਕ੍ਰਮਵਾਰ ਸੰਖਿਆ ਵਾਪਸ ਕਰਦਾ ਹੈ।

ਇਸ ਲਈ, ਸਾਡੇ ਫਾਰਮੂਲੇ ਵਿੱਚ, year ਨੂੰ ਮੂਲ ਮਿਤੀ (A2), month 1 (ਜਨਵਰੀ) ਅਤੇ day 0 ਹੈ। ਅਸਲ ਵਿੱਚ, ਇੱਕ ਜ਼ੀਰੋ ਦਿਨ ਐਕਸਲ ਨੂੰ ਪਿਛਲੇ ਸਾਲ ਦੇ 31 ਦਸੰਬਰ ਨੂੰ ਵਾਪਸ ਕਰਨ ਲਈ ਮਜਬੂਰ ਕਰਦਾ ਹੈ। , ਕਿਉਂਕਿ ਅਸੀਂ ਚਾਹੁੰਦੇ ਹਾਂ ਕਿ 1 ਜਨਵਰੀ ਨੂੰ ਪਹਿਲਾ ਦਿਨ ਮੰਨਿਆ ਜਾਵੇ। ਅਤੇ ਫਿਰ, ਤੁਸੀਂ DATE ਫਾਰਮੂਲੇ ਦੁਆਰਾ ਵਾਪਸ ਕੀਤੇ ਗਏ ਸੀਰੀਅਲ ਨੰਬਰ ਨੂੰ ਅਸਲ ਮਿਤੀ ਤੋਂ ਘਟਾਉਂਦੇ ਹੋ (ਜਿਸ ਨੂੰ ਐਕਸਲ ਵਿੱਚ ਇੱਕ ਸੀਰੀਅਲ ਨੰਬਰ ਵਜੋਂ ਵੀ ਸਟੋਰ ਕੀਤਾ ਜਾਂਦਾ ਹੈ) ਅਤੇ ਅੰਤਰ ਉਸ ਸਾਲ ਦਾ ਦਿਨ ਹੁੰਦਾ ਹੈ ਜਿਸਦੀ ਤੁਸੀਂ ਭਾਲ ਕਰ ਰਹੇ ਹੋ। ਉਦਾਹਰਨ ਲਈ, 5 ਜਨਵਰੀ, 2015 ਨੂੰ 42009 ਅਤੇ 31 ਦਸੰਬਰ, 2014 ਨੂੰ 42004 ਵਜੋਂ ਸਟੋਰ ਕੀਤਾ ਗਿਆ ਹੈ, ਇਸਲਈ 42009 - 42004 = 5।

ਜੇਕਰ ਦਿਨ 0 ਦਾ ਸੰਕਲਪ ਤੁਹਾਨੂੰ ਸਹੀ ਨਹੀਂ ਲੱਗਦਾ ਹੈ, ਤਾਂ ਤੁਸੀਂ ਹੇਠਾਂ ਦਿੱਤੀਆਂ ਚੀਜ਼ਾਂ ਦੀ ਵਰਤੋਂ ਕਰ ਸਕਦੇ ਹੋ। ਇਸਦੀ ਬਜਾਏ ਫਾਰਮੂਲਾ:

=A2-DATE(YEAR(A2), 1, 1)+1

ਸਾਲ ਵਿੱਚ ਬਾਕੀ ਬਚੇ ਦਿਨਾਂ ਦੀ ਸੰਖਿਆ ਦੀ ਗਣਨਾ ਕਿਵੇਂ ਕਰੀਏ

ਸਾਲ ਵਿੱਚ ਬਾਕੀ ਰਹਿੰਦੇ ਦਿਨਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ, ਅਸੀਂ ਇਸਦੀ ਵਰਤੋਂ ਕਰਨ ਜਾ ਰਹੇ ਹਾਂ। DATE ਅਤੇ YEAR ਫੰਕਸ਼ਨ ਦੁਬਾਰਾ। ਫਾਰਮੂਲਾ ਉਪਰੋਕਤ ਉਦਾਹਰਨ 3 ਦੇ ਸਮਾਨ ਪਹੁੰਚ 'ਤੇ ਅਧਾਰਤ ਹੈ, ਇਸਲਈ ਤੁਹਾਨੂੰ ਇਸਦੇ ਤਰਕ ਨੂੰ ਸਮਝਣ ਵਿੱਚ ਕੋਈ ਮੁਸ਼ਕਲ ਹੋਣ ਦੀ ਸੰਭਾਵਨਾ ਨਹੀਂ ਹੈ:

=DATE(YEAR(A2),12,31)-A2

ਜੇਕਰ ਤੁਸੀਂ ਇਹ ਜਾਣਨਾ ਚਾਹੁੰਦੇ ਹੋ ਕਿ ਮੌਜੂਦਾ ਮਿਤੀ ਦੇ ਆਧਾਰ 'ਤੇ ਸਾਲ ਦੇ ਅੰਤ ਤੱਕ ਕਿੰਨੇ ਦਿਨ ਬਾਕੀ ਹਨ, ਤੁਸੀਂ Excel TODAY() ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਇਸ ਤਰ੍ਹਾਂ ਕਰਦੇ ਹੋ:

=DATE(2015, 12, 31)-TODAY()

ਕਿੱਥੇ 2015 ਮੌਜੂਦਾ ਸਾਲ ਹੈ .

ਗਣਨਾ ਕੀਤੀ ਜਾ ਰਹੀ ਹੈExcel ਵਿੱਚ ਲੀਪ ਸਾਲ

ਜਿਵੇਂ ਕਿ ਤੁਸੀਂ ਜਾਣਦੇ ਹੋ, ਲਗਭਗ ਹਰ ਚੌਥੇ ਸਾਲ ਵਿੱਚ 29 ਫਰਵਰੀ ਨੂੰ ਇੱਕ ਵਾਧੂ ਦਿਨ ਹੁੰਦਾ ਹੈ ਅਤੇ ਇਸਨੂੰ ਲੀਪ ਸਾਲ ਕਿਹਾ ਜਾਂਦਾ ਹੈ। ਮਾਈਕਰੋਸਾਫਟ ਐਕਸਲ ਸ਼ੀਟਾਂ ਵਿੱਚ, ਤੁਸੀਂ ਕਈ ਤਰੀਕਿਆਂ ਨਾਲ ਇਹ ਨਿਰਧਾਰਤ ਕਰ ਸਕਦੇ ਹੋ ਕਿ ਇੱਕ ਨਿਸ਼ਚਿਤ ਮਿਤੀ ਲੀਪ ਸਾਲ ਨਾਲ ਸਬੰਧਤ ਹੈ ਜਾਂ ਇੱਕ ਆਮ ਸਾਲ। ਮੈਂ ਸਿਰਫ਼ ਕੁਝ ਫਾਰਮੂਲੇ ਦਿਖਾਉਣ ਜਾ ਰਿਹਾ ਹਾਂ, ਜੋ ਮੇਰੀ ਰਾਏ ਵਿੱਚ ਸਮਝਣ ਵਿੱਚ ਸਭ ਤੋਂ ਆਸਾਨ ਹਨ।

ਫ਼ਾਰਮੂਲਾ 1. ਜਾਂਚ ਕਰੋ ਕਿ ਕੀ ਫਰਵਰੀ ਵਿੱਚ 29 ਦਿਨ ਹਨ

ਇਹ ਇੱਕ ਬਹੁਤ ਸਪੱਸ਼ਟ ਟੈਸਟ ਹੈ। ਕਿਉਂਕਿ ਫਰਵਰੀ ਵਿੱਚ ਲੀਪ ਸਾਲਾਂ ਵਿੱਚ 29 ਦਿਨ ਹੁੰਦੇ ਹਨ, ਅਸੀਂ ਇੱਕ ਦਿੱਤੇ ਸਾਲ ਦੇ ਮਹੀਨੇ 2 ਵਿੱਚ ਦਿਨਾਂ ਦੀ ਗਿਣਤੀ ਦੀ ਗਣਨਾ ਕਰਦੇ ਹਾਂ ਅਤੇ ਇਸਦੀ ਗਿਣਤੀ 29 ਨਾਲ ਤੁਲਨਾ ਕਰਦੇ ਹਾਂ। ਉਦਾਹਰਨ ਲਈ:

=DAY(DATE(2015,3,1)-1)=29

ਇਸ ਫਾਰਮੂਲੇ ਵਿੱਚ, DATE(2015,3,1) ਫੰਕਸ਼ਨ ਸਾਲ 2015 ਵਿੱਚ ਮਾਰਚ ਦਾ 1ਲਾ ਦਿਨ ਵਾਪਸ ਕਰਦਾ ਹੈ, ਜਿਸ ਤੋਂ ਅਸੀਂ 1 ਨੂੰ ਘਟਾਉਂਦੇ ਹਾਂ। DAY ਫੰਕਸ਼ਨ ਇਸ ਮਿਤੀ ਤੋਂ ਦਿਨ ਦੀ ਸੰਖਿਆ ਨੂੰ ਕੱਢਦਾ ਹੈ, ਅਤੇ ਅਸੀਂ ਉਸ ਸੰਖਿਆ ਦੀ 29 ਨਾਲ ਤੁਲਨਾ ਕਰਦੇ ਹਾਂ। ਜੇਕਰ ਸੰਖਿਆਵਾਂ ਮੇਲ ਖਾਂਦੀਆਂ ਹਨ, ਫਾਰਮੂਲਾ ਸਹੀ, ਗਲਤ ਨਹੀਂ ਤਾਂ ਵਾਪਸ ਕਰਦਾ ਹੈ।

ਜੇਕਰ ਤੁਹਾਡੀ ਐਕਸਲ ਵਰਕਸ਼ੀਟ ਵਿੱਚ ਪਹਿਲਾਂ ਤੋਂ ਹੀ ਤਾਰੀਖਾਂ ਦੀ ਸੂਚੀ ਹੈ ਅਤੇ ਤੁਸੀਂ ਜਾਣਨਾ ਚਾਹੁੰਦੇ ਹੋ ਕਿ ਕਿਹੜੇ ਲੀਪ ਸਾਲ ਹਨ, ਤਾਂ ਇੱਕ ਸਾਲ ਕੱਢਣ ਲਈ ਫਾਰਮੂਲੇ ਵਿੱਚ YEAR ਫੰਕਸ਼ਨ ਨੂੰ ਸ਼ਾਮਲ ਕਰੋ। ਇੱਕ ਮਿਤੀ:

=DAY(DATE(YEAR(A2),3,1)-1)=29

ਜਿੱਥੇ A2 ਇੱਕ ਸੈੱਲ ਹੈ ਜਿਸ ਵਿੱਚ ਮਿਤੀ ਹੁੰਦੀ ਹੈ।

ਫਾਰਮੂਲੇ ਦੁਆਰਾ ਦਿੱਤੇ ਨਤੀਜੇ ਇਸ ਤਰ੍ਹਾਂ ਹਨ:

ਵਿਕਲਪਿਕ ਤੌਰ 'ਤੇ, ਤੁਸੀਂ ਫਰਵਰੀ ਦੇ ਆਖਰੀ ਦਿਨ ਨੂੰ ਵਾਪਸ ਕਰਨ ਲਈ EOMONTH ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰ ਸਕਦੇ ਹੋ, ਅਤੇ ਉਸ ਨੰਬਰ ਦੀ 29 ਨਾਲ ਤੁਲਨਾ ਕਰ ਸਕਦੇ ਹੋ:

=DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29

ਫਾਰਮੂਲੇ ਨੂੰ ਵਧੇਰੇ ਉਪਭੋਗਤਾ-ਅਨੁਕੂਲ ਬਣਾਉਣ ਲਈ , IF ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰੋ ਅਤੇ ਇਸਨੂੰ ਰੱਖੋਵਾਪਿਸ, ਕਹੋ, "ਲੀਪ ਸਾਲ" ਅਤੇ ਸਹੀ ਅਤੇ ਗਲਤ ਦੀ ਬਜਾਏ "ਆਮ ਸਾਲ":

=IF(DAY(DATE(YEAR(A2),3,1)-1)=29, "Leap year", "Common year")

=IF(DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29, "Leap year", "Common year")

ਫਾਰਮੂਲਾ 2 ਜਾਂਚ ਕਰੋ ਕਿ ਕੀ ਸਾਲ ਵਿੱਚ 366 ਦਿਨ ਹਨ

ਇਹ ਇੱਕ ਹੋਰ ਸਪੱਸ਼ਟ ਟੈਸਟ ਹੈ ਜਿਸ ਲਈ ਸ਼ਾਇਦ ਹੀ ਕਿਸੇ ਵਿਆਖਿਆ ਦੀ ਲੋੜ ਹੋਵੇ। ਅਸੀਂ ਅਗਲੇ ਸਾਲ ਦੇ 1-ਜਨਵਰੀ ਨੂੰ ਵਾਪਸ ਕਰਨ ਲਈ ਇੱਕ DATE ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰਦੇ ਹਾਂ, ਇਸ ਸਾਲ ਦੀ 1-ਜਨਵਰੀ ਪ੍ਰਾਪਤ ਕਰਨ ਲਈ ਇੱਕ ਹੋਰ DATE ਫੰਕਸ਼ਨ, ਪਹਿਲੇ ਤੋਂ ਬਾਅਦ ਵਾਲੇ ਨੂੰ ਘਟਾਓ ਅਤੇ ਜਾਂਚ ਕਰੋ ਕਿ ਕੀ ਅੰਤਰ 366:

=DATE(2016,1,1) - DATE(2015,1,1)=366 <ਦੇ ਬਰਾਬਰ ਹੈ। 3>

ਕਿਸੇ ਸੈੱਲ ਵਿੱਚ ਦਰਜ ਕੀਤੀ ਮਿਤੀ ਦੇ ਆਧਾਰ 'ਤੇ ਸਾਲ ਦੀ ਗਣਨਾ ਕਰਨ ਲਈ, ਤੁਸੀਂ Excel YEAR ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਬਿਲਕੁਲ ਉਸੇ ਤਰ੍ਹਾਂ ਕਰਦੇ ਹੋ ਜਿਵੇਂ ਅਸੀਂ ਪਿਛਲੀ ਉਦਾਹਰਨ ਵਿੱਚ ਕੀਤਾ ਸੀ:

=DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366

ਜਿੱਥੇ A2 ਇੱਕ ਸੈੱਲ ਹੈ ਜਿਸ ਵਿੱਚ ਮਿਤੀ ਹੁੰਦੀ ਹੈ।

ਅਤੇ ਕੁਦਰਤੀ ਤੌਰ 'ਤੇ, ਤੁਸੀਂ ਉਪਰੋਕਤ DATE/YEAR ਫਾਰਮੂਲੇ ਨੂੰ IF ਫੰਕਸ਼ਨ ਵਿੱਚ ਨੱਥੀ ਕਰ ਸਕਦੇ ਹੋ ਤਾਂ ਜੋ ਇਹ TRUE ਅਤੇ FALSE ਦੇ ਬੂਲੀਅਨ ਮੁੱਲਾਂ ਨਾਲੋਂ ਵਧੇਰੇ ਅਰਥਪੂਰਨ ਵਾਪਸ ਕਰ ਸਕੇ:

=IF(DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366, "Leap year", "Non-leap year")

ਜਿਵੇਂ ਕਿ ਪਹਿਲਾਂ ਹੀ ਦੱਸਿਆ ਗਿਆ ਹੈ, ਇਹ ਐਕਸਲ ਵਿੱਚ ਲੀਪ ਸਾਲਾਂ ਦੀ ਗਣਨਾ ਕਰਨ ਦੇ ਇੱਕੋ ਇੱਕ ਸੰਭਵ ਤਰੀਕੇ ਨਹੀਂ ਹਨ। ਜੇਕਰ ਤੁਸੀਂ ਹੋਰ ਹੱਲ ਜਾਣਨ ਲਈ ਉਤਸੁਕ ਹੋ, ਤਾਂ ਤੁਸੀਂ Microsoft ਦੁਆਰਾ ਸੁਝਾਏ ਗਏ ਢੰਗ ਦੀ ਜਾਂਚ ਕਰ ਸਕਦੇ ਹੋ। ਆਮ ਵਾਂਗ, ਮਾਈਕਰੋਸਾਫਟ ਦੇ ਲੋਕ ਆਸਾਨ ਤਰੀਕੇ ਨਹੀਂ ਲੱਭ ਰਹੇ ਹਨ, ਕੀ ਉਹ ਹਨ?

ਉਮੀਦ ਹੈ, ਇਸ ਲੇਖ ਨੇ ਤੁਹਾਨੂੰ Excel ਵਿੱਚ ਸਾਲ ਦੀ ਗਣਨਾ ਦਾ ਪਤਾ ਲਗਾਉਣ ਵਿੱਚ ਮਦਦ ਕੀਤੀ ਹੈ। ਮੈਂ ਪੜ੍ਹਨ ਲਈ ਤੁਹਾਡਾ ਧੰਨਵਾਦ ਕਰਦਾ ਹਾਂ ਅਤੇ ਅਗਲੇ ਹਫ਼ਤੇ ਤੁਹਾਨੂੰ ਮਿਲਣ ਦੀ ਉਮੀਦ ਕਰਦਾ ਹਾਂ।