Bu dərslik Excel YEAR funksiyasının sintaksisini və istifadəsini izah edir və tarixdən il çıxarmaq, tarixi aya və ilə çevirmək, doğum tarixindən yaşı hesablamaq və müəyyən etmək üçün düstur nümunələri təqdim edir. sıçrayış illəri.

Bir neçə son yazıda biz Excel-də tarix və vaxtı hesablamaq üçün müxtəlif yolları araşdırdıq və HƏFTƏ GÜNÜ, HƏFTƏNİN SAYISI, AY və GÜN kimi müxtəlif faydalı funksiyaları öyrəndik. Bu gün biz daha böyük vaxt vahidinə diqqət yetirəcəyik və Excel iş vərəqlərində illərin hesablanması haqqında danışacağıq.

Bu dərslikdə siz öyrənəcəksiniz:

YEAR funksiyası Excel-də

Excel-də YEAR funksiyası 1900-dən 9999-a qədər tam ədəd kimi verilmiş tarixə uyğun gələn dörd rəqəmli ili qaytarır.

Excel YEAR funksiyasının sintaksisi onun qədər sadədir. ola bilər:

Burada seriya_nömrəsi tapmaq istədiyiniz ilin hər hansı etibarlı tarixidir.

Excel İL düsturu

Excel-də YEAR düsturu yaratmaq üçün mənbə tarixini bir neçə yolla təmin edə bilərsiniz.

TARİX funksiyasından istifadə etməklə

Excel-də tarix təqdim etməyin ən etibarlı yolu TARİX funksiyasından istifadə etməkdir.

Məsələn, aşağıdakı düstur 28 aprel 2015-ci il üçün ili qaytarır:

=YEAR(DATE(2015, 4, 28))

As tarixi təmsil edən seriya nömrəsi

Daxili Excel sistemində tarixlər 1 yanvar 1900-cü ildən başlayan seriya nömrələri kimi saxlanılır. Daha çox məlumat üçüntarixlərin Excel-də necə saxlandığı haqqında məlumat üçün Excel tarix formatına baxın.

28 aprel 2015-ci il 42122 kimi saxlanılır, ona görə də bu rəqəmi birbaşa düstura daxil edə bilərsiniz:

=YEAR(42122)

Məqbul olsa da, bu üsul tövsiyə edilmir, çünki tarixlərin nömrələnməsi müxtəlif sistemlərdə fərqli ola bilər.

Hüceyrə arayışı kimi

Fərz edək ki, bəzi xanalarda etibarlı tarix var. sadəcə olaraq həmin hücrəyə müraciət edə bilərsiniz. Məsələn:

=YEAR(A1)

Bəzi başqa formula nəticəsində

Məsələn, cari tarixdən ili çıxarmaq üçün TODAY() funksiyasından istifadə edə bilərsiniz:

=YEAR(TODAY())

Mətn olaraq

Sadə halda YEAR düsturu mətn kimi daxil edilmiş tarixləri belə başa düşə bilər, məsələn:

=YEAR("28-Apr-2015")

Bu metoddan istifadə edərkən, lütfən, tarixi Excel-in başa düşdüyü formatda daxil etdiyinizi iki dəfə yoxlayın. Həmçinin, yadda saxlayın ki, tarix mətn dəyəri kimi təqdim edildikdə Microsoft düzgün nəticələrə zəmanət vermir.

Aşağıdakı skrinşt yuxarıda göstərilən YEAR düsturlarının hamısının işlədiyini nümayiş etdirir, hamısı gözlədiyiniz kimi 2015-ci ili qaytarır :)

Excel-də tarixi ilə necə çevirmək olar

Excel-də tarix məlumatları ilə işlədiyiniz zaman iş vərəqləriniz adətən ay, gün və il daxil olmaqla tam tarixləri göstərir. . Bununla belə, əsas mərhələlər və məhsulun təqdimatı və ya aktivlərin alınması kimi mühüm hadisələr üçün siz yenidən daxil etmədən və ya dəyişdirmədən yalnız ili görmək istəyə bilərsiniz.orijinal məlumatlar. Aşağıda bunun üçün 3 sürətli üsul tapacaqsınız.

Nümunə 1. YEAR funksiyasından istifadə edərək tarixdən bir il çıxarın

Əslində Excel-də YEAR funksiyasından necə istifadə edəcəyinizi artıq bilirsiniz. tarixi bir ilə çevirmək. Yuxarıdakı ekran görüntüsü bir çox düsturları nümayiş etdirir və aşağıdakı ekran görüntüsündə daha bir neçə nümunə görə bilərsiniz. Diqqət yetirin ki, YEAR funksiyası bütün mümkün formatlarda tarixləri mükəmməl başa düşür:

Misal 2. Excel-də tarixi aya və ilə çevirin

Verilmiş tarixi çevirmək üçün il və aya görə hər bir vahidi ayrıca çıxarmaq üçün MƏTN funksiyasından istifadə edə və sonra həmin funksiyaları bir düstur daxilində birləşdirə bilərsiniz.

MƏTN funksiyasında siz aylar və illər üçün müxtəlif kodlardan istifadə edə bilərsiniz, məsələn:

• "mmm" - qısaldılmış ay adları, yanvar - dekabr kimi.
• "mmmm" - tam ay adları, yanvar - dekabr kimi.
• "yy" - 2-rəqəmli illər
• "yyyy" - 4-rəqəmli illər

Çıxışı daha yaxşı oxunaqlı etmək üçün kodları vergül, defis və ya hər hansı digər simvolla ayıra bilərsiniz, aşağıdakı Tarix-Ay və İl düsturlarında olduğu kimi:

=TEXT(B2, "mmmm") & ", " & TEXT(B2, "yyyy")

Vəya

=TEXT(B2, "mmm") & "-" & TEXT(B2, "yy")

B2 burada olan xanadır tarix.

Misal 3. Tarixi il kimi göstərin

Əgər tarixlərin iş dəftərinizdə necə saxlanmasının əhəmiyyəti yoxdursa, siz bunu edə bilərsiniz. Excel-i yalnız illəri göstərmək üçün əldə edin ut orijinal tarixləri dəyişdirmək. Başqa sözlə, ola bilərsinizxanalarda tam tarixlər saxlanılır, ancaq illər göstərilir.

Bu halda heç bir düstur tələb olunmur. Siz sadəcə Ctrl + 1 düymələrini basaraq Hüceyrələri Formatla dialoq qutusunu açın, Nömrə nişanında Xüsusi kateqoriyasını seçin və Type qutusu:

• yy - 2 rəqəmli illəri 00 - 99 kimi göstərmək üçün.
• yyyy - 4 rəqəmli illəri 1900 - 9999 kimi göstərmək üçün .

Xahiş edirik unutmayın ki, bu metod orijinal tarixi dəyişmir , yalnız iş vərəqinizdə tarixin göstərilmə tərzini dəyişir. Düsturlarınızda belə xanalara istinad etsəniz, Microsoft Excel il hesablamalarından daha çox tarix hesablamalarını yerinə yetirəcək.

Tarix formatının dəyişdirilməsi ilə bağlı ətraflı məlumatı bu təlimatda tapa bilərsiniz: Excel-də tarix formatını necə dəyişdirmək olar.

Excel-də doğum tarixindən yaşı necə hesablamaq olar

Excel-də yaş formasının doğum tarixini hesablamaq üçün bir neçə üsul var - DATEDIF, YEARFRAC və ya INT funksiyasından TODAY() ilə birlikdə istifadə etməklə. BUGÜN funksiyası yaşı hesablamaq üçün tarixi təqdim edərək, düsturunuzun həmişə düzgün yaşı qaytarmasını təmin edir.

Doğum tarixindən yaşı illərlə hesablayın

İnsanın yaşını hesablamaq üçün ənənəvi üsul illərlə cari tarixdən doğum tarixini çıxarmaqdır. Bu yanaşma gündəlik həyatda yaxşı işləyir, lakin analoji Excel yaş hesablama düsturu tamamilə doğru deyil:

Burada DOB doğum tarixidir.

Düsturun birinci hissəsi (TODAY()-B2) fərq gündür və illərin sayını almaq üçün onu 365-ə bölürsən. Əksər hallarda, bu tənliyin nəticəsi onluq ədəddir və siz onu ən yaxın tam ədədə yuvarlaqlaşdıran INT funksiyasına sahibsiniz.

Doğum tarixinin B2 xanasında olduğunu fərz etsək, tam formula aşağıdakı kimi olur. :

=INT((TODAY()-B2)/365)

Yuxarıda qeyd edildiyi kimi, bu yaş hesablama düsturu həmişə qüsursuz deyil və bunun səbəbi budur. Hər 4-cü il 366 gündən ibarət sıçrayış ilidir, halbuki düstur günlərin sayını 365-ə bölür. Beləliklə, əgər kimsə fevralın 29-da doğulubsa və bu gün 28 fevraldırsa, bu yaş düsturu insanı bir gün qocaldacaq.

365 əvəzinə 365,25-ə bölmək də qüsursuz deyil, məsələn, hələ sıçrayış ilini yaşamamış uşağın yaşını hesablayarkən.

Yuxarıda göstərilənləri nəzərə alsaq, siz istərdiniz normal həyat üçün yaşı hesablamağın bu üsulunu daha yaxşı yadda saxlayın və Excel-də doğum tarixindən yaşı hesablamaq üçün aşağıdakı düsturlardan birini istifadə edin.

Yuxarıdakı düsturların ətraflı izahı Excel-də yaşı necə hesablamaq olar bölməsində verilmişdir. Və aşağıdakı skrinshot real həyatda yaş hesablama düsturunu nümayiş etdirir:

=DATEDIF(B2, TODAY(), "y")

Dəqiq yaş hesablanmasıdoğum tarixi (illər, aylar və günlərlə)

Dəqiq yaşı illər, aylar və günlərlə hesablamaq üçün son arqumentdə aşağıdakı vahidlərlə üç DATEDIF funksiyasını yazın:

• Y - tam illərin sayını hesablamaq üçün.
• YM - illəri nəzərə almadan aylar arasındakı fərqi almaq üçün.
• MD - illər və ayları nəzərə almadan günlər arasındakı fərqi almaq üçün .

Sonra isə 3 DATEDIF funksiyasını bir düsturda birləşdirin, hər bir funksiyanın qaytardığı rəqəmləri vergüllə ayırın və hər bir rəqəmin nə demək olduğunu müəyyən edin.

Tarixi fərz edin. doğuş B2 hüceyrəsindədir, tam formula aşağıdakı kimidir:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

Bu yaş düsturu, məsələn, həkimə xəstələrin dəqiq yaşını göstərmək üçün çox faydalı ola bilər və ya bütün işçilərin dəqiq yaşını bilmək üçün kadr zabiti:

Müəyyən bir tarixdə və ya müəyyən bir ildə yaşın hesablanması kimi daha çox düstur nümunələri üçün aşağıdakıları yoxlayın. dərslik: Excel-də yaşı necə hesablamaq olar.

İlin gün nömrəsini necə əldə etmək olar (1-365)

Bu nümunə bir ildə müəyyən bir günün sayını 1 ilə 365 arasında (uzun illərdə 1-366) necə əldə edə biləcəyinizi nümayiş etdirir. 1 yanvar 1-ci gün hesab olunur.

Bunun üçün YEAR funksiyasını TARİX ilə birlikdə bu şəkildə istifadə edin:

=A2-DATE(YEAR(A2), 1, 0)

A2 tarixi olan xanadır.

İndi isə düsturun əslində nə etdiyini görək. The YEAR funksiyası A2 xanasındakı tarixin ilini alır və onu müəyyən tarixi təmsil edən ardıcıl nömrəni qaytaran TARİX(il, ay, gün) funksiyasına ötürür.

Beləliklə, bizim düsturumuzda year orijinal tarixdən (A2) çıxarılıb, month 1 (yanvar) və day 0-dır. Əslində, sıfır gün Excel-i əvvəlki ilin 31 dekabr tarixinə qayıtmağa məcbur edir. , çünki biz istəyirik ki, 1 yanvar 1-ci gün kimi qəbul edilsin. Və sonra, TARİX düsturunun qaytardığı seriya nömrəsini orijinal tarixdən (bu həm də Excel-də seriya nömrəsi kimi saxlanılır) çıxarırsınız və fərq axtardığınız ilin günüdür. Məsələn, 5 yanvar 2015-ci il 42009, 31 dekabr 2014-cü il isə 42004 kimi saxlanılır, buna görə də 42009 - 42004 = 5.

Əgər 0-cı gün anlayışı sizə uyğun gəlmirsə, aşağıdakılardan istifadə edə bilərsiniz. əvəzinə düstur:

=A2-DATE(YEAR(A2), 1, 1)+1

İldə qalan günlərin sayını necə hesablamaq olar

İldə qalan günlərin sayını hesablamaq üçün biz istifadə edəcəyik TARİX və YEAR funksiyaları yenidən işləyir. Düstur yuxarıdakı 3-cü Nümunə ilə eyni yanaşmaya əsaslanır, ona görə də onun məntiqini başa düşməkdə çətin ki, çətinlik çəkəsiniz:

=DATE(YEAR(A2),12,31)-A2

Əgər siz cari tarixə əsasən ilin sonuna neçə gün qaldığını bilmək istəyirsinizsə, Excel TODAY() funksiyasından aşağıdakı kimi istifadə edirsiniz:

=DATE(2015, 12, 31)-TODAY()

2015-ci ilin cari il olduğu halda .

HesablanırExcel-də sıçrayış illəri

Bildiyiniz kimi, demək olar ki, hər 4-cü ildə 29 fevralda əlavə bir gün olur və sıçrayış ili adlanır. Microsoft Excel vərəqlərində müəyyən bir tarixin sıçrayış ilinə və ya ümumi ilə aid olduğunu müxtəlif yollarla müəyyən edə bilərsiniz. Mən sadəcə bir neçə düstur nümayiş etdirəcəyəm, məncə, onları başa düşmək asandır.

Formula 1. Fevralın 29 gün olub-olmadığını yoxlayın

Bu, çox açıq bir sınaqdır. Fevral ayı sıçrayış ilində 29 gün olduğundan, biz verilmiş ilin 2-ci ayında günlərin sayını hesablayırıq və onu 29 rəqəmi ilə müqayisə edirik. Məsələn:

=DAY(DATE(2015,3,1)-1)=29

Bu düsturda TARİX(2015,3,1) funksiyası 2015-ci ilin mart ayının 1-ci gününü qaytarır, ondan 1 çıxırıq. DAY funksiyası bu tarixdən gün nömrəsini çıxarır və biz həmin rəqəmi 29 ilə müqayisə edirik. Rəqəmlər üst-üstə düşürsə, düstur DOĞRU, əks halda YANLIŞ qaytarır.

Əgər Excel iş vərəqinizdə artıq tarixlərin siyahısı varsa və hansının sıçrayış illəri olduğunu bilmək istəyirsinizsə, ondan bir il çıxarmaq üçün YEAR funksiyasını formulaya daxil edin. tarix:

=DAY(DATE(YEAR(A2),3,1)-1)=29

A2 tarixi olan xanadır.

Düsturla qaytarılan nəticələr aşağıdakı kimidir:

Alternativ olaraq, Fevral ayının son gününü qaytarmaq üçün EOMONTH funksiyasından istifadə edə və həmin rəqəmi 29 ilə müqayisə edə bilərsiniz:

=DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29

Düsulu daha istifadəçi üçün daha asan etmək üçün IF funksiyasından istifadə edin və ona sahib olunDOĞRU və YANLIŞ əvəzinə "Artı il" və "Ümumi ili" qaytarın:

=IF(DAY(DATE(YEAR(A2),3,1)-1)=29, "Leap year", "Common year")

=IF(DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29, "Leap year", "Common year")

Formula 2 İlin 366 günü olub-olmadığını yoxlayın

Bu, heç bir izahat tələb etməyən başqa bir aşkar testdir. Gələn ilin 1-Yanvarını qaytarmaq üçün bir TARİX funksiyasından, bu ilin 1-Yanvarını əldə etmək üçün başqa bir TARİX funksiyasından istifadə edirik, birincidən sonuncunu çıxarırıq və fərqin 366-ya bərabər olub olmadığını yoxlayırıq:

=DATE(2016,1,1) - DATE(2015,1,1)=366

Bəzi xanaya daxil edilmiş tarixə əsasən ili hesablamaq üçün siz Excel YEAR funksiyasından əvvəlki nümunədə etdiyimiz kimi istifadə edirsiniz:

=DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366

Burada A2 tarixi ehtiva edən xanadır.

Və təbii olaraq yuxarıdakı TARİX/İL düsturunu ƏGƏR funksiyasına əlavə edə bilərsiniz ki, o, TRUE və FALSE-in Boolean dəyərlərindən daha mənalı bir şey qaytarsın:

=IF(DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366, "Leap year", "Non-leap year")

Daha əvvəl qeyd edildiyi kimi, Excel-də sıçrayış illərini hesablamaq üçün yeganə mümkün yollar bunlar deyil. Başqa həll yolları ilə maraqlanırsınızsa, Microsoft tərəfindən təklif olunan metodu yoxlaya bilərsiniz. Həmişə olduğu kimi, Microsoft oğlanları asan yollar axtarmırlar, elə deyilmi?

Ümid edirik ki, bu məqalə Excel-də il hesablamalarını anlamağa kömək etdi. Oxuduğunuz üçün sizə təşəkkür edirəm və gələn həftə görüşməyi səbirsizliklə gözləyirəm.