Tutorial honek Excel URTE funtzioaren sintaxia eta erabilerak azaltzen ditu eta formula-adibideak eskaintzen ditu urtetik datatik ateratzeko, data hilabetera eta urtera bihurtzeko, jaiotze-datatik adina kalkulatzeko eta zehazteko. urte bisurteak.

Azken argitalpen batzuetan, Excel-en datak eta orduak kalkulatzeko modu desberdinak aztertu ditugu eta hainbat funtzio erabilgarria ikasi ditugu, hala nola WEEKDAY, WEEKNUM, MONTH eta DAY. Gaur, denbora-unitate handiago batean zentratuko gara eta zure Excel lan-orrietan urteak kalkulatzeari buruz hitz egingo dugu.

Tutorial honetan, hauxe ikasiko duzu:

URTE funtzioa Excel-en

Excel-en URTE funtzioak data jakin bati dagokion lau zifrako urtea itzultzen du 1900tik 9999ra bitarteko zenbaki oso gisa.

Excel URTE funtzioaren sintaxia bezain erraza da. honako hau izan daiteke:

Non serie_zenbakia aurkitu nahi duzun urteko data baliozko bat den.

Excel URTE formula

Excel-en URTE formula bat egiteko, hainbat modutara eman dezakezu iturburu-data.

DATA funtzioa erabiliz

Excel-en data bat emateko modurik fidagarriena DATA funtzioa erabiltzea da.

Adibidez, formula honek 2015eko apirilaren 28ko urtea itzultzen du:

=YEAR(DATE(2015, 4, 28))

Asaterako. data adierazten duen serie-zenbakia

Barne Excel sisteman, datak serie-zenbaki gisa gordetzen dira 1900eko urtarrilaren 1etik hasita, 1 zenbaki gisa gordetzen dena.Excel-en datak nola gordetzen diren jakiteko, ikusi Excel data-formatua.

2015eko apirilaren 28a 42122 gisa gordetzen da, beraz, zenbaki hau zuzenean sartu dezakezu formulan:

=YEAR(42122)

Onargarria bada ere, metodo hau ez da gomendatzen, dataren zenbakiak sistema desberdinetan alda daitezkeelako.

Gelula-erreferentzia gisa

Zelula batzuetan data baliozko bat duzula suposatuz, besterik gabe, zelula horri erreferentzia egin dezakezu. Adibidez:

=YEAR(A1)

Beste formularen baten ondorioz

Adibidez, GAUR() funtzioa erabil dezakezu uneko datatik urtea ateratzeko:

=YEAR(TODAY())

Testu gisa

Kasu sinple batean, URTEA formulak testu gisa sartutako datak ere uler ditzake, honela:

=YEAR("28-Apr-2015")

Metodo hau erabiltzean, egiaztatu bi aldiz data idazten duzula Excelek ulertzen duen formatuan. Gainera, gogoratu, mesedez, Microsoft-ek ez duela emaitza zuzenak bermatzen data bat testu-balio gisa ematen denean.

Ondoko pantaila-argazkiak goiko URTE formula guztiak martxan erakusten ditu, denak 2015. urtea espero zenezakeen bezala itzuliz :)

Nola bihurtu data urtera Excel-en

Data informazioa Excel-en lan egiten duzunean, zure lan-orriek normalean data osoa erakusten dute, hilabetea, eguna eta urtea barne. . Hala ere, mugarri nagusietarako eta gertaera garrantzitsuetarako (adibidez, produktuen aurkezpena edo aktiboen erosketak, adibidez), baliteke urtea soilik ikusi nahi izatea, berriro sartu edo aldatu gabe.jatorrizko datuak. Jarraian, 3 modu azkar aurkituko dituzu horretarako.

Adibidea 1. Atera urte bat datatik URTE funtzioa erabiliz

Izan ere, dagoeneko badakizu Excel-en URTE funtzioa nola erabiltzen data bat urte bihurtzeko. Goiko pantaila-argazkiak formula mordoa erakusten ditu, eta beheko pantaila-argazkian adibide batzuk ikus ditzakezu. Kontuan izan URTE funtzioak ezin hobeto ulertzen dituela datak formatu posible guztietan:

Adibidea 2. Bihurtu data hilabete eta urte Excel-en

Data jakin bat bihurtzeko urtera eta hilabetera, TESTU funtzioa erabil dezakezu unitate bakoitza banan-banan ateratzeko eta, ondoren, funtzio horiek formula batean kateatu.

TESTU funtzioan, hilabete eta urteetarako kode desberdinak erabil ditzakezu, hala nola:

• "mmm" - hilabeteen izenak laburtuak, urtarrila - abendua.
• "mmmm" - hilabete osoko izenak, urtarrila - abendua bezala.
• "yy" - 2 zifrako urteak
• "yyyy" - 4 zifrako urteak

Irteera hobeto irakurtzeko, kodeak koma, marratxoa edo beste edozein karaktererekin bereiz ditzakezu. honako Datatik hilabetera eta urtera formuletan bezala:

=TEXT(B2, "mmmm") & ", " & TEXT(B2, "yyyy")

Edo

=TEXT(B2, "mmm") & "-" & TEXT(B2, "yy")

Non B2 duen gelaxka bat den. data bat.

Adibidea 3. Bistaratu data bat urte gisa

Ez badu axola zure lan-liburuan datak nola gordetzen diren, dezakezu lortu Excel-ek urteak bakarrik erakusteko jatorrizko datak aldatuz. Beste era batera esanda, izan dezakezugelaxketan gordetako data osoak, baina bistaratzen diren urteak soilik.

Kasu honetan, ez da formularik behar. Ireki besterik ez duzu Formatu gelaxkak elkarrizketa-koadroa Ctrl + 1 sakatuz, hautatu Pertsonalizatua kategoria Zenbakia fitxan eta sartu beheko kodeetako bat Idatzi koadroa:

• yy - 2 zifrako urteak bistaratzeko, 00 - 99 gisa.
• yyyy - 4 digituko urteak bistaratzeko, 1900 - 9999 gisa .

Gogoratu metodo honek ez duela jatorrizko data aldatzen , data zure lan-orrian bistaratzeko modua baino ez duela aldatzen. Zure formuletan horrelako gelaxkak aipatzen badituzu, Microsoft Excel-ek data kalkuluak egingo ditu urteen kalkuluak baino.

Data formatua aldatzeari buruzko xehetasun gehiago aurki ditzakezu tutorial honetan: Nola aldatu data-formatua Excel-en.

Nola kalkulatu adina jaiotze-datatik Excel-en

Adinaren jaiotze-data kalkulatzeko hainbat modu daude Excel-en: DATEDIF, YEARFRAC edo INT funtzioa erabiliz TODAY()rekin batera. GAUR funtzioak adina kalkulatzeko data ematen du, zure formulak beti adin zuzena itzuliko duela ziurtatuz.

Kalkulatu adina jaiotze-datatik urtetan

Pertsona baten adina kalkulatzeko modu tradizionala. urtetan jaiotze-data uneko datatik kentzea da. Planteamendu honek ondo funtzionatzen du eguneroko bizitzan, baina Excel adina kalkulatzeko formula ez da guztiz egia:

Non DOB jaioteguna den.

Formularen lehen zatiak (GAUR()-B2) kalkulatzen du. aldea egunak dira, eta 365ez zatitzen duzu urte kopurua lortzeko. Kasu gehienetan, ekuazio honen emaitza zenbaki hamartar bat da, eta INT funtzioak osorik hurbilenera biribiltzen du.

Jaiotze data B2 gelaxkan dagoela suposatuz, formula osoa honela doa. :

=INT((TODAY()-B2)/365)

Goian esan bezala, adina kalkulatzeko formula hau ez da beti akatsik gabekoa, eta hona hemen zergatik. 4. urtero 366 egun dituen bisurte bat da, formulak, aldiz, egun kopurua 365ez zatitzen du. Beraz, norbait otsailaren 29an jaio bazen eta gaur otsailaren 28a bada, adinaren formula honek pertsona bat egun bat zahartuko du.

365en ordez 365,25ez zatitzea ere ez da ezinhobea, adibidez, oraindik bisurterik bizi ez duen ume baten adina kalkulatzerakoan.

Aurrekoa kontuan hartuta, litzateke hobe gorde adina kalkulatzeko modu hau bizitza arrunterako, eta erabili ondorengo formula hauetako bat jaiotze-datatik adina kalkulatzeko Excel-en.

Goiko formulen azalpen zehatza Nola adina kalkulatu Excel-en eskaintzen da. Eta hurrengo pantaila-argazkiak bizitza errealeko adina kalkulatzeko formula bat martxan erakusten du:

=DATEDIF(B2, TODAY(), "y")

Adin zehatza kalkulatzea.jaioteguna (urte, hilabete eta egunetan)

Adin zehatza urte, hilabete eta egunetan kalkulatzeko, idatzi hiru DATEDIF funtzio unitate hauekin azken argumentuan:

• Y - urte osoen kopurua kalkulatzeko.
• YM - hilabeteen arteko aldea lortzeko, urteak alde batera utzita.
• MD - egunen arteko aldea lortzeko, urteak eta hilabeteak alde batera utzita. .

Eta gero, kateatu 3 DATEDIF funtzioak formula bakarrean, bereizi funtzio bakoitzak itzultzen dituen zenbakiak komaz eta zehaztu zer esan nahi duen zenbaki bakoitzak.

Data suposatuz. jaiotza B2 gelaxkan dago, formula osoa honela doa:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

Adinaren formula hau oso erabilgarria izan daiteke, esate baterako, mediku bati pazienteen adin zehatza erakusteko, edo langile guztien adin zehatza jakiteko:

Formula adibide gehiago lortzeko, esate baterako, data jakin batean edo urte jakin batean adina kalkulatzea, begiratu honako hau. tutoriala: Nola kalkulatu adina Excel-en.

Nola lortu urteko egun-zenbakia (1-365)

Adibide honek erakusten du nola lor dezakezun urte bateko egun jakin baten zenbakia, 1 eta 365 artean (1-366 bisurteetan) urtarrilaren 1a 1. eguntzat hartuta.

Horretarako, erabili URTE funtzioa DATArekin batera modu honetan:

=A2-DATE(YEAR(A2), 1, 0)

Non A2 data duen gelaxka bat den.

Eta orain, ikus dezagun formulak benetan zer egiten duen. The URTE funtzioak A2 gelaxkako dataren urtea berreskuratzen du eta DATE(urtea, hilabetea, eguna) funtziora pasatzen du, eta horrek data jakin bat adierazten duen zenbaki sekuentziala itzultzen du.

Beraz, gure formulan, year jatorrizko datatik (A2) ateratzen da, month 1 da (urtarrila) eta day 0 da. Izan ere, zero egun batek Excel aurreko urteko abenduaren 31 itzultzera behartzen du. , urtarrilaren 1a 1. egun bezala tratatzea nahi dugulako. Eta gero, DATE formulak itzultzen duen serie zenbakia kentzen duzu jatorrizko datatik (Excel-en serie-zenbaki gisa gordetzen dena) eta aldea bilatzen ari zaren urteko eguna da. Adibidez, 2015eko urtarrilaren 5a 42009 gisa gordetzen da eta 2014ko abenduaren 31koa 42004 da, beraz, 42009 - 42004 = 5.

0 egunaren kontzeptua egokia iruditzen ez bazaizu, honako hau erabil dezakezu formula horren ordez:

=A2-DATE(YEAR(A2), 1, 1)+1

Nola kalkulatu urtean geratzen diren egunak

Urtean geratzen diren egunak kalkulatzeko, erabiliko dugu. DATE eta YEAR funtzioak berriro. Formula goiko 3. adibidearen ikuspegi berdinean oinarritzen da, beraz, nekez izango duzu bere logika ulertzeko zailtasunik:

=DATE(YEAR(A2),12,31)-A2

Bada uneko datan oinarrituta urtea amaitzeko zenbat egun falta diren jakin nahi baduzu, Excel GAUR() funtzioa erabiltzen duzu, honela:

=DATE(2015, 12, 31)-TODAY()

Non den 2015 uneko urtea. .

KalkulatzenExcel-en urte bisurteak

Dakizuenez, ia 4. urte bakoitzak egun gehigarri bat du otsailaren 29an eta bisurte deitzen zaio. Microsoft Excel orrietan, data jakin bat bisurte batekoa edo urte arrunt batekoa den zehaztu dezakezu hainbat modutan. Formula pare bat erakutsiko ditut, nire ustez ulertzeko errazenak direnak.

Formula 1. Egiaztatu otsailak 29 egun dituen ala ez

Oso agerikoa den proba da. Otsailak bisurteetan 29 egun dituenez, urte jakin bateko 2. hilabeteko egun kopurua kalkulatzen dugu eta 29 zenbakiarekin alderatzen dugu. Adibidez:

=DAY(DATE(2015,3,1)-1)=29

Formula honetan, DATE(2015,3,1) funtzioak 2015eko martxoaren 1a itzultzen du, eta hortik 1 kentzen dugu. EGUNA funtzioak data honetako egunaren zenbakia ateratzen du, eta zenbaki hori 29arekin alderatzen dugu. Zenbakiak bat datoz, formulak EGIA itzultzen du, GEZURRA bestela.

Dagoeneko zure Excel lan-orrian daten zerrenda bat baduzu eta biurteak diren jakin nahi baduzu, sartu URTE funtzioa formulan urte bat ateratzeko. data bat:

=DAY(DATE(YEAR(A2),3,1)-1)=29

Non A2 data duen gelaxka bat den.

Formulak itzultzen dituen emaitzak hauek dira:

Bestela, EOMONTH funtzioa erabil dezakezu otsaileko azken eguna itzultzeko, eta zenbaki hori 29rekin alderatu:

=DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29

Formula erabilerrazagoa izan dadin. , erabili IF funtzioa eta edukiitzuli, esan, "Bisurte urtea" eta "Urte arrunta" EGIA eta GEZURRA ordez:

=IF(DAY(DATE(YEAR(A2),3,1)-1)=29, "Leap year", "Common year")

=IF(DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29, "Leap year", "Common year")

2. Formula Egiaztatu urteak 366 egun dituen ala ez

Hau da ia azalpenik behar ez duen beste proba ageriko bat. DATE funtzio bat erabiltzen dugu hurrengo urteko urtarrila itzultzeko, beste DATE funtzio bat aurtengo urtarrila lortzeko, bigarrena kendu eta lehenengotik aldea 366 berdina den egiaztatu:

=DATE(2016,1,1) - DATE(2015,1,1)=366

Urte bat gelaxka batean sartutako data batean oinarrituta kalkulatzeko, Excel URTEA funtzioa erabiltzen duzu aurreko adibidean egin genuen modu berean:

=DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366

Non A2 data duen gelaxka bat den.

Eta, jakina, goiko DATA / URTE formula sartu dezakezu IF funtzioan, TRUE eta FALSE balio boolearrak baino zerbait esanguratsuagoa itzultzeko:

=IF(DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366, "Leap year", "Non-leap year")

Esan bezala, hauek ez dira Excel-en bisurteak kalkulatzeko modu posible bakarrak. Beste irtenbide batzuk ezagutzeko jakin-mina baduzu, Microsoft-ek iradokitako metodoa egiaztatu dezakezu. Ohi bezala, Microsoft-eko mutilak ez dira bide errazak bilatzen, ezta?

Zorionez, artikulu honek Excel-en urteko kalkuluak asmatzen lagundu dizu. Eskerrak ematen dizkizut irakurtzeagatik eta datorren astean ikustea espero dut.