Ky tutorial shpjegon sintaksën dhe përdorimet e funksionit Excel YEAR dhe ofron shembuj formulash për nxjerrjen e vitit nga data, konvertimin e datës në muaj dhe vit, llogaritjen e moshës nga data e lindjes dhe përcaktimin vite të brishta.

Në disa postime të fundit, ne kemi eksploruar mënyra të ndryshme për të llogaritur datat dhe orët në Excel dhe kemi mësuar një sërë funksionesh të dobishme si WEEKDAY, WEEKNUM, MONTH dhe DAY. Sot, ne do të fokusohemi në një njësi më të madhe kohore dhe do të flasim për llogaritjen e viteve në fletët tuaja të punës në Excel.

Në këtë tutorial, do të mësoni:

Funksioni YEAR në Excel

Funksioni YEAR në Excel kthen një vit katërshifror që korrespondon me një datë të caktuar si një numër i plotë nga 1900 në 9999.

Sintaksa e funksionit Excel YEAR është po aq e thjeshtë sa ajo mund të jetë:

Ku numri_serial është çdo datë e vlefshme e vitit që dëshironi të gjeni.

Formula Excel YEAR

Për të bërë një formulë YEAR në Excel, mund të jepni datën e burimit në disa mënyra.

Duke përdorur funksionin DATE

mënyra më e besueshme për të dhënë një datë në Excel është përdorimi i funksionit DATE.

Për shembull, formula e mëposhtme kthen vitin për 28 Prill 2015:

=YEAR(DATE(2015, 4, 28))

Si një numër serial që përfaqëson datën

Në sistemin e brendshëm Excel, datat ruhen si numra serialë duke filluar nga 1 janari 1900, i cili ruhet si numër 1. Për më shumëinformacione se si ruhen datat në Excel, ju lutemi shikoni formatin e datës Excel.

Dita 28 e prillit 2015 ruhet si 42122, kështu që mund ta futni këtë numër direkt në formulën:

=YEAR(42122)

Megjithëse e pranueshme, kjo metodë nuk rekomandohet sepse numërimi i datave mund të ndryshojë në sisteme të ndryshme.

Si referencë qelize

Duke supozuar se keni një datë të vlefshme në një qelizë, ju thjesht mund t'i referoheni asaj qelize. Për shembull:

=YEAR(A1)

Si rezultat i disa formulave të tjera

Për shembull, mund të përdorni funksionin TODAY() për të nxjerrë vitin nga data aktuale:

=YEAR(TODAY())

Si tekst

Në një rast të thjeshtë, formula YEAR mund të kuptojë edhe datat e futura si tekst, si kjo:

=YEAR("28-Apr-2015")

Kur përdorni këtë metodë, ju lutemi kontrolloni dy herë që të vendosni datën në formatin që Excel kupton. Gjithashtu, mbani mend se Microsoft nuk garanton rezultate të sakta kur një datë jepet si një vlerë teksti.

Pamja e mëposhtme tregon të gjitha formulat e mësipërme YEAR në veprim, të gjitha kthehen në vitin 2015 siç mund të prisni :)

Si të konvertohet data në vit në Excel

Kur punoni me informacionin e datës në Excel, fletët tuaja të punës zakonisht shfaqin data të plota, duke përfshirë muajin, ditën dhe vitin . Megjithatë, për momentet kryesore dhe ngjarjet e rëndësishme si lançimi i produkteve ose blerja e aseteve, mund të dëshironi të shikoni vetëm vitin pa hyrë ose modifikuar sërishtë dhëna origjinale. Më poshtë, do të gjeni 3 mënyra të shpejta për ta bërë këtë.

Shembulli 1. Nxjerrja e një viti nga data duke përdorur funksionin YEAR

Në fakt, ju tashmë dini se si të përdorni funksionin YEAR në Excel për të kthyer një datë në një vit. Pamja e mësipërme tregon një sërë formulash dhe mund të shihni disa shembuj të tjerë në pamjen e mëposhtme të ekranit. Vini re se funksioni YEAR kupton në mënyrë të përsosur datat në të gjitha formatet e mundshme:

Shembulli 2. Konvertoni datën në muaj dhe vit në Excel

Për të kthyer një datë të caktuar për vitin dhe muajin, mund të përdorni funksionin TEXT për të nxjerrë secilën njësi individualisht dhe më pas t'i bashkoni ato funksione brenda një formule.

Në funksionin TEXT, mund të përdorni kode të ndryshme për muaj dhe vite, si p.sh.

• "mmmm" - emrat e shkurtuar të muajve, si janar - dhjetor.
• "mmmm" - emrat e muajve të plotë, si janar - dhjetor.
• "vv" - Vitet 2-shifrore
• "vvvv" - vjet 4-shifror

Për ta bërë rezultatin më të lexueshëm, mund t'i ndani kodet me presje, vizë ndarëse ose ndonjë karakter tjetër, si në formulat e mëposhtme Data në muaj dhe Viti :

=TEXT(B2, "mmmm") & ", " & TEXT(B2, "yyyy")

Ose

=TEXT(B2, "mmm") & "-" & TEXT(B2, "yy")

Ku B2 është një qelizë që përmban një datë.

Shembulli 3. Shfaqni një datë si vit

Nëse nuk ka vërtet rëndësi se si ruhen datat në librin tuaj të punës, mund të merrni Excel për të treguar vetëm vitet me të duke ndryshuar datat origjinale. Me fjalë të tjera, ju mund të kenidatat e plota ruhen në qeliza, por shfaqen vetëm vitet.

Në këtë rast, nuk nevojitet asnjë formulë. Thjesht hapni dialogun Formatoni qelizat duke shtypur Ctrl + 1 , zgjidhni kategorinë Custom në skedën Numër dhe futni një nga kodet e mëposhtme në Shkruani kutinë:

• vv - për të shfaqur vitet 2-shifrore, si 00 - 99.
• vvvv - për të shfaqur vitet 4-shifrore, si 1900 - 9999 .

Ju lutemi mbani mend se kjo metodë nuk e ndryshon datën origjinale , ajo ndryshon vetëm mënyrën se si data shfaqet në fletën tuaj të punës. Nëse u referoheni qelizave të tilla në formulat tuaja, Microsoft Excel do të kryejë llogaritjet e datës dhe jo llogaritjet e vitit.

Mund të gjeni më shumë detaje rreth ndryshimit të formatit të datës në këtë tutorial: Si të ndryshoni formatin e datës në Excel.

Si të llogarisni moshën nga data e lindjes në Excel

Ka disa mënyra për të llogaritur moshën nga data e lindjes në Excel - duke përdorur funksionin DATEDIF, YEARFRAC ose INT në kombinim me TODAY(). Funksioni TODAY jep datën për të llogaritur moshën, duke siguruar që formula juaj do të kthejë gjithmonë moshën e saktë.

Llogaritni moshën nga data e lindjes në vite

Mënyra tradicionale për të llogaritur moshën e një personi në vite është zbritja e datës së lindjes nga data aktuale. Kjo qasje funksionon mirë në jetën e përditshme, por një formulë analoge e llogaritjes së moshës në Excel nuk është plotësisht e vërtetë:

Ku DOB është data e lindjes.

Pjesa e parë e formulës (TODAY()-B2) llogarit diferenca është ditë, dhe ju e pjestoni atë me 365 për të marrë numrin e viteve. Në shumicën e rasteve, rezultati i këtij ekuacioni është një numër dhjetor dhe ju keni funksionin INT ta rrumbullakosni atë në numrin më të afërt të plotë.

Duke supozuar se data e lindjes është në qelizën B2, formula e plotë shkon si më poshtë :

=INT((TODAY()-B2)/365)

Siç u përmend më lart, kjo formulë e llogaritjes së moshës nuk është gjithmonë e përsosur, dhe ja pse. Çdo vit i katërt është një vit i brishtë që përmban 366 ditë, ndërsa formula e ndan numrin e ditëve me 365. Pra, nëse dikush ka lindur më 29 shkurt dhe sot është 28 shkurt, kjo formulë moshe do ta bëjë njeriun një ditë më të vjetër.

Pjestimi me 365,25 në vend të 365 nuk është as i përsosur, për shembull, kur llogaritet mosha e një fëmije që nuk ka jetuar ende një vit të brishtë.

Duke pasur parasysh sa më sipër, do të ruajeni më mirë këtë mënyrë të llogaritjes së moshës për jetën normale dhe përdorni një nga formulat e mëposhtme për të llogaritur moshën nga data e lindjes në Excel.

Shpjegimi i detajuar i formulave të mësipërme jepet në Si të llogarisim moshën në Excel. Dhe pamja e mëposhtme e ekranit tregon një formulë të llogaritjes së moshës në jetën reale në veprim:

=DATEDIF(B2, TODAY(), "y")

Llogaritja e moshës së saktë ngadata e lindjes (në vite, muaj dhe ditë)

Për të llogaritur moshën e saktë në vite, muaj dhe ditë, shkruani tre funksione DATEDIF me njësitë e mëposhtme në argumentin e fundit:

• Y - për të llogaritur numrin e viteve të plota.
• YM - për të marrë diferencën midis muajve, duke injoruar vitet.
• MD - për të marrë diferencën midis ditëve, duke injoruar vitet dhe muajt .

Dhe më pas, lidhni 3 funksionet DATEDIF në një formulë të vetme, ndani numrat e kthyer nga secili funksion me presje dhe përcaktoni se çfarë do të thotë secili numër.

Duke supozuar datën e lindja është në qelizën B2, formula e plotë shkon si më poshtë:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

Kjo formulë moshe mund të jetë shumë e dobishme, të themi, që një mjek të tregojë moshën e saktë të pacientëve, ose për një oficer personeli për të ditur moshën e saktë të të gjithë punonjësve:

Për më shumë shembuj të formulës si llogaritja e moshës në një datë të caktuar ose në një vit të caktuar, ju lutemi shikoni sa vijon tutorial: Si të llogarisni moshën në Excel.

Si të merrni numrin e ditës së vitit (1-365)

Ky shembull tregon se si mund të merrni numrin e një dite të caktuar në një vit, midis 1 dhe 365 (1-366 në vitin e brishtë) me 1 janar të konsideruar dita 1.

Për këtë, përdorni funksionin YEAR së bashku me DATE në këtë mënyrë:

=A2-DATE(YEAR(A2), 1, 0)

Ku A2 është një qelizë që përmban datën.

Dhe tani, le të shohim se çfarë bën në të vërtetë formula. TëFunksioni YEAR merr vitin e datës në qelizën A2 dhe ia kalon funksionit DATA(viti, muaji, dita) , i cili kthen numrin vijues që përfaqëson një datë të caktuar.

Pra, në formulën tonë, year nxirret nga data origjinale (A2), month është 1 (janar) dhe day është 0. Në fakt, një ditë zero detyron Excel të kthejë 31 dhjetor të vitit të kaluar , sepse duam që 1 janari të trajtohet si dita e 1-rë. Dhe pastaj, ju zbritni numrin serial të kthyer nga formula DATE nga data origjinale (e cila ruhet gjithashtu si numër serial në Excel) dhe ndryshimi është dita e vitit që kërkoni. Për shembull, 5 janari 2015 ruhet si 42009 dhe 31 dhjetori 2014 është 42004, pra 42009 - 42004 = 5.

Nëse koncepti i ditës 0 nuk ju duket i drejtë, mund të përdorni sa vijon në vend të kësaj formule:

=A2-DATE(YEAR(A2), 1, 1)+1

Si të llogarisim numrin e ditëve të mbetura në vit

Për të llogaritur numrin e ditëve të mbetura në vit, ne do të përdorim DATE dhe YEAR funksionojnë përsëri. Formula bazohet në të njëjtën qasje si shembulli 3 më sipër, kështu që nuk ka gjasa të keni ndonjë vështirësi në kuptimin e logjikës së saj:

=DATE(YEAR(A2),12,31)-A2

Nëse ju dëshironi të dini se sa ditë kanë mbetur deri në fund të vitit bazuar në datën aktuale, ju përdorni funksionin Excel TODAY(), si më poshtë:

=DATE(2015, 12, 31)-TODAY()

Ku 2015 është viti aktual .

Llogaritjavite të brishtë në Excel

Siç e dini, pothuajse çdo vit i katërt ka një ditë shtesë më 29 shkurt dhe quhet vit i brishtë. Në fletët e Microsoft Excel, mund të përcaktoni nëse një datë e caktuar i përket një viti të brishtë apo një viti të zakonshëm në mënyra të ndryshme. Unë do të demonstroj vetëm disa formula, të cilat për mendimin tim janë më të lehta për t'u kuptuar.

Formula 1. Kontrolloni nëse shkurti ka 29 ditë

Ky është një test shumë i qartë. Meqenëse shkurti ka 29 ditë në vitin e brishtë, ne llogarisim numrin e ditëve në muajin 2 të një viti të caktuar dhe e krahasojmë atë me numrin 29. Për shembull:

=DAY(DATE(2015,3,1)-1)=29

Në këtë formulë, Funksioni DATE(2015,3,1) kthen ditën e 1 marsit të vitit 2015, nga e cila zbresim 1. Funksioni DAY nxjerr numrin e ditës nga kjo datë dhe ne e krahasojmë atë numër me 29. Nëse numrat përputhen, formula kthen TRUE, FALSE përndryshe.

Nëse tashmë keni një listë datash në fletën tuaj të punës në Excel dhe dëshironi të dini se cilat janë vitet e brishtë, atëherë inkorporoni funksionin YEAR në formulë për të nxjerrë një vit nga një datë:

=DAY(DATE(YEAR(A2),3,1)-1)=29

Ku A2 është një qelizë që përmban datën.

Rezultatet e kthyera nga formula janë si më poshtë:

Përndryshe, mund të përdorni funksionin EOMONTH për të kthyer ditën e fundit të shkurtit dhe ta krahasoni atë numër me 29:

=DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29

Për ta bërë formulën më të përshtatshme për përdoruesit , përdorni funksionin IF dhe keni atëktheni, le të themi, "viti i brishtë" dhe "viti i zakonshëm" në vend të TRUE dhe FALSE:

=IF(DAY(DATE(YEAR(A2),3,1)-1)=29, "Leap year", "Common year")

=IF(DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29, "Leap year", "Common year")

Formula 2 Kontrolloni nëse viti ka 366 ditë

Ky është një tjetër test i dukshëm që vështirë se kërkon ndonjë shpjegim. Ne përdorim një funksion DATE për të kthyer 1-Jan të vitit të ardhshëm, një funksion tjetër DATE për të marrë 1-Jan të këtij viti, zbresim këtë të fundit nga i pari dhe kontrollojmë nëse diferenca është e barabartë me 366:

=DATE(2016,1,1) - DATE(2015,1,1)=366

Për të llogaritur një vit bazuar në një datë të futur në një qelizë, ju përdorni funksionin Excel YEAR saktësisht në të njëjtën mënyrë si ne në shembullin e mëparshëm:

=DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366

Aty ku A2 është një qelizë që përmban datën.

Dhe natyrisht, ju mund të bashkoni formulën e mësipërme DATE / YEAR në funksionin IF që ajo të kthejë diçka më kuptimplote se vlerat Boolean të TRUE dhe FALSE:

=IF(DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366, "Leap year", "Non-leap year")

Siç është përmendur tashmë, këto nuk janë mënyrat e vetme të mundshme për të llogaritur vitet e brishtë në Excel. Nëse jeni kurioz të dini zgjidhje të tjera, mund të kontrolloni metodën e sugjeruar nga Microsoft. Si zakonisht, djemtë e Microsoft nuk po kërkojnë mënyra të thjeshta, apo jo?

Shpresojmë, ky artikull ju ka ndihmuar të kuptoni llogaritjet e vitit në Excel. Ju falënderoj që lexoni dhe mezi pres t'ju shoh javën tjetër.