આ ટ્યુટોરીયલ એક્સેલ YEAR ફંક્શનના સિન્ટેક્સ અને ઉપયોગો સમજાવે છે અને તારીખમાંથી વર્ષ કાઢવા, તારીખને મહિનો અને વર્ષમાં કન્વર્ટ કરવા, જન્મ તારીખથી ઉંમરની ગણતરી કરવા અને નિર્ધારિત કરવા માટે ફોર્મ્યુલા ઉદાહરણો પ્રદાન કરે છે લીપ વર્ષ.

તાજેતરની કેટલીક પોસ્ટ્સમાં, અમે એક્સેલમાં તારીખો અને સમયની ગણતરી કરવાની વિવિધ રીતો શોધી કાઢી છે અને WEEKDAY, WEEKNUM, MONTH અને DAY જેવા વિવિધ ઉપયોગી કાર્યો શીખ્યા છે. આજે, અમે એક મોટા સમયના એકમ પર ધ્યાન કેન્દ્રિત કરવા જઈ રહ્યા છીએ અને તમારી એક્સેલ વર્કશીટ્સમાં વર્ષોની ગણતરી કરવા વિશે વાત કરીશું.

આ ટ્યુટોરીયલમાં, તમે શીખી શકશો:

YEAR ફંક્શન Excel માં

Excel માં YEAR ફંક્શન 1900 થી 9999 સુધીની પૂર્ણાંક તરીકે આપેલ તારીખને અનુરૂપ ચાર-અંકનું વર્ષ આપે છે.

Excel YEAR ફંક્શનનું સિન્ટેક્સ તેટલું જ સરળ છે. સંભવતઃ આ હોઈ શકે છે:

જ્યાં serial_number એ વર્ષના કોઈપણ માન્ય તારીખ છે જે તમે શોધવા માંગો છો.

Excel YEAR ફોર્મ્યુલા

Excel માં YEAR ફોર્મ્યુલા બનાવવા માટે, તમે સ્ત્રોત તારીખ ઘણી રીતે આપી શકો છો.

DATE ફંક્શનનો ઉપયોગ કરીને

The એક્સેલમાં તારીખ સપ્લાય કરવાની સૌથી વિશ્વસનીય રીત DATE ફંક્શનનો ઉપયોગ કરી રહી છે.

ઉદાહરણ તરીકે, નીચેનું સૂત્ર 28 એપ્રિલ, 2015 માટેનું વર્ષ આપે છે:

=YEAR(DATE(2015, 4, 28))

જેમ તારીખનું પ્રતિનિધિત્વ કરતો સીરીયલ નંબર

આંતરિક એક્સેલ સિસ્ટમમાં, તારીખો 1 જાન્યુઆરી 1900 થી શરૂ થતા સીરીયલ નંબર તરીકે સંગ્રહિત થાય છે, જે નંબર 1 તરીકે સંગ્રહિત થાય છે. વધુ માટેએક્સેલમાં તારીખો કેવી રીતે સંગ્રહિત થાય છે તેની માહિતી, કૃપા કરીને એક્સેલ તારીખ ફોર્મેટ જુઓ.

એપ્રિલ, 2015 નો 28 દિવસ 42122 તરીકે સંગ્રહિત થાય છે, જેથી તમે આ નંબર સીધા જ ફોર્મ્યુલામાં દાખલ કરી શકો:

=YEAR(42122)

સ્વીકાર્ય હોવા છતાં, આ પદ્ધતિની ભલામણ કરવામાં આવતી નથી કારણ કે તારીખની સંખ્યા વિવિધ સિસ્ટમોમાં બદલાઈ શકે છે.

સેલ સંદર્ભ તરીકે

ધારી રહ્યા છીએ કે તમારી પાસે અમુક સેલમાં માન્ય તારીખ છે, તમે ફક્ત તે કોષનો સંદર્ભ લઈ શકો છો. ઉદાહરણ તરીકે:

=YEAR(A1)

કોઈ અન્ય ફોર્મ્યુલાના પરિણામે

ઉદાહરણ તરીકે, તમે વર્તમાન તારીખમાંથી વર્ષ કાઢવા માટે TODAY() ફંક્શનનો ઉપયોગ કરી શકો છો:

=YEAR(TODAY())

ટેક્સ્ટ તરીકે

સાદા કિસ્સામાં, YEAR ફોર્મ્યુલા ટેક્સ્ટ તરીકે દાખલ કરેલી તારીખોને પણ સમજી શકે છે, જેમ કે:

=YEAR("28-Apr-2015")

આ પદ્ધતિનો ઉપયોગ કરતી વખતે, કૃપા કરીને બે વાર તપાસો કે તમે એક્સેલ સમજે છે તે ફોર્મેટમાં તારીખ દાખલ કરો છો. ઉપરાંત, કૃપા કરીને યાદ રાખો કે જ્યારે ટેક્સ્ટ મૂલ્ય તરીકે તારીખ પૂરી પાડવામાં આવે ત્યારે માઇક્રોસોફ્ટ સાચા પરિણામોની બાંયધરી આપતું નથી.

નીચેનો સ્ક્રીનશૉટ ઉપરોક્ત તમામ YEAR ફોર્મ્યુલાને કાર્યમાં દર્શાવે છે, જે તમે અપેક્ષા રાખી શકો છો તે બધા 2015 પરત કરે છે :)

એક્સેલમાં તારીખને વર્ષમાં કેવી રીતે રૂપાંતરિત કરવી

જ્યારે તમે Excel માં તારીખ માહિતી સાથે કામ કરો છો, ત્યારે તમારી કાર્યપત્રકો સામાન્ય રીતે મહિનો, દિવસ અને વર્ષ સહિત સંપૂર્ણ તારીખો દર્શાવે છે . જો કે, મુખ્ય લક્ષ્યો અને મહત્વની ઘટનાઓ જેમ કે પ્રોડક્ટ લોંચ અથવા એસેટ એક્વિઝિશન માટે, તમે પુનઃપ્રવેશ કર્યા વિના અથવા સંશોધિત કર્યા વિના માત્ર વર્ષ જ જોવા માગી શકો છો.મૂળ ડેટા. નીચે, તમને આ કરવા માટેની 3 ઝડપી રીતો મળશે.

ઉદાહરણ 1. YEAR ફંક્શનનો ઉપયોગ કરીને તારીખમાંથી એક વર્ષ કાઢો

હકીકતમાં, તમે Excel માં YEAR ફંક્શનનો ઉપયોગ કેવી રીતે કરવો તે પહેલાથી જ જાણો છો તારીખને વર્ષમાં રૂપાંતરિત કરવા. ઉપરનો સ્ક્રીનશોટ સૂત્રોનો સમૂહ દર્શાવે છે, અને તમે નીચેના સ્ક્રીનશોટમાં થોડા વધુ ઉદાહરણો જોઈ શકો છો. નોંધ લો કે YEAR ફંક્શન તમામ સંભવિત ફોર્મેટમાં તારીખોને સંપૂર્ણ રીતે સમજે છે:

ઉદાહરણ 2. એક્સેલમાં તારીખને મહિને અને વર્ષમાં કન્વર્ટ કરો

આપેલ તારીખને કન્વર્ટ કરવા માટે વર્ષ અને મહિના સુધી, તમે દરેક એકમને વ્યક્તિગત રીતે કાઢવા માટે TEXT ફંક્શનનો ઉપયોગ કરી શકો છો અને પછી તે ફંક્શનને એક ફોર્મ્યુલામાં જોડી શકો છો.

TEXT ફંક્શનમાં, તમે મહિનાઓ અને વર્ષો માટે વિવિધ કોડનો ઉપયોગ કરી શકો છો, જેમ કે:

• "mmmm" - સંક્ષિપ્ત મહિનાના નામ, જાન્યુઆરી - ડિસેમ્બર તરીકે.
• "mmmm" - સંપૂર્ણ મહિનાના નામ, જાન્યુઆરી - ડિસેમ્બર તરીકે.
• "yy" - 2-અંકનાં વર્ષો
• "yyyy" - 4-અંકનાં વર્ષો

આઉટપુટને વધુ સારી રીતે વાંચવા યોગ્ય બનાવવા માટે, તમે કોડને અલ્પવિરામ, હાઇફન અથવા અન્ય કોઈપણ અક્ષરથી અલગ કરી શકો છો, નીચેના તારીખથી મહિનો અને વર્ષ સૂત્રોની જેમ:

=TEXT(B2, "mmmm") & ", " & TEXT(B2, "yyyy")

અથવા

=TEXT(B2, "mmm") & "-" & TEXT(B2, "yy")

જ્યાં B2 એ કોષ ધરાવે છે તારીખ.

ઉદાહરણ 3. એક વર્ષ તરીકે તારીખ દર્શાવો

જો તમારી વર્કબુકમાં તારીખો કેવી રીતે સંગ્રહિત કરવામાં આવે છે તે ખરેખર વાંધો નથી, તો તમે માત્ર વર્ષો બતાવવા માટે એક્સેલ મેળવો મૂળ તારીખો બદલવી. બીજા શબ્દોમાં કહીએ તો, તમારી પાસે હોઈ શકે છેકોષોમાં સંગ્રહિત સંપૂર્ણ તારીખો, પરંતુ ફક્ત વર્ષો જ પ્રદર્શિત થાય છે.

આ કિસ્સામાં, કોઈ ફોર્મ્યુલાની જરૂર નથી. તમે Ctrl + 1 દબાવીને માત્ર કોષોને ફોર્મેટ કરો સંવાદ ખોલો, નંબર ટેબ પર કસ્ટમ શ્રેણી પસંદ કરો અને <માં નીચેના કોડમાંથી એક દાખલ કરો. 1>ટાઈપ કરો બોક્સ:

• yy - 2-અંકના વર્ષ દર્શાવવા માટે, 00 - 99 તરીકે.
• yyyy - 4-અંકના વર્ષો દર્શાવવા માટે, 1900 - 9999 તરીકે .

કૃપા કરીને યાદ રાખો કે આ પદ્ધતિ મૂળ તારીખને બદલતી નથી , તે ફક્ત તમારી કાર્યપત્રકમાં તારીખ દર્શાવવાની રીતને બદલે છે. જો તમે તમારા સૂત્રોમાં આવા કોષોનો સંદર્ભ લો છો, તો Microsoft Excel વર્ષની ગણતરીને બદલે તારીખની ગણતરી કરશે.

તમે આ ટ્યુટોરીયલમાં તારીખનું ફોર્મેટ બદલવા વિશે વધુ વિગતો મેળવી શકો છો: Excel માં તારીખનું ફોર્મેટ કેવી રીતે બદલવું.

એક્સેલમાં જન્મ તારીખથી ઉંમરની ગણતરી કેવી રીતે કરવી

એક્સેલમાં જન્મતારીખની ઉંમરની ગણતરી કરવાની ઘણી રીતો છે - TODAY() સાથે સંયોજનમાં DATEDIF, YEARFRAC અથવા INT ફંક્શનનો ઉપયોગ કરીને. TODAY ફંક્શન એ સુનિશ્ચિત કરે છે કે તમારું સૂત્ર હંમેશા સાચી ઉંમર આપશે તેની ખાતરી કરીને ઉંમરની ગણતરી કરવાની તારીખ પૂરી પાડે છે.

જન્મ તારીખથી ઉંમરની ગણતરી વર્ષોમાં કરો

વ્યક્તિની ઉંમરની ગણતરી કરવાની પરંપરાગત રીત વર્ષોમાં વર્તમાન તારીખમાંથી જન્મ તારીખ બાદ કરવી છે. આ અભિગમ રોજિંદા જીવનમાં બરાબર કામ કરે છે, પરંતુ એક્સેલની ઉંમરની ગણતરી માટેનું એક સમાન સૂત્ર સંપૂર્ણ રીતે સાચું નથી:

જ્યાં DOB જન્મ તારીખ છે.

સૂત્રનો પ્રથમ ભાગ (TODAY()-B2) ગણતરી કરે છે તફાવત એ દિવસો છે, અને તમે વર્ષોની સંખ્યા મેળવવા માટે તેને 365 વડે ભાગો છો. મોટા ભાગના કિસ્સાઓમાં, આ સમીકરણનું પરિણામ દશાંશ સંખ્યા હોય છે, અને તમારી પાસે INT ફંક્શન તેને નજીકના પૂર્ણાંક સુધી ગોળ કરે છે.

જન્મ તારીખ કોષ B2 માં છે એમ ધારી રહ્યા છીએ, સંપૂર્ણ સૂત્ર નીચે મુજબ છે :

=INT((TODAY()-B2)/365)

ઉપર સૂચવ્યા મુજબ, આ વય ગણતરી સૂત્ર હંમેશા દોષરહિત નથી, અને તેનું કારણ અહીં છે. દર ચોથું વર્ષ એ લીપ વર્ષ છે જેમાં 366 દિવસનો સમાવેશ થાય છે, જ્યારે સૂત્ર દિવસોની સંખ્યાને 365 વડે વિભાજિત કરે છે. તેથી, જો કોઈ વ્યક્તિનો જન્મ 29 ફેબ્રુઆરીએ થયો હોય અને આજે 28 ફેબ્રુઆરી છે, તો આ વય સૂત્ર વ્યક્તિને એક દિવસ મોટો બનાવશે.

365 ને બદલે 365.25 વડે ભાગાકાર કરવો પણ દોષરહિત નથી, ઉદાહરણ તરીકે, બાળકની ઉંમરની ગણતરી કરતી વખતે જે હજુ સુધી લીપ વર્ષ સુધી જીવ્યું નથી.

ઉપર આપેલ, તમે સામાન્ય જીવન માટે ઉંમરની ગણતરી કરવાની આ રીતને વધુ સારી રીતે સાચવો, અને Excel માં જન્મ તારીખથી ઉંમરની ગણતરી કરવા માટે નીચેનામાંથી એક ફોર્મ્યુલાનો ઉપયોગ કરો.

ઉપરોક્ત સૂત્રોની વિગતવાર સમજૂતી Excel માં ઉંમરની ગણતરી કેવી રીતે કરવી તેમાં આપવામાં આવી છે. અને નીચેનો સ્ક્રીનશોટ વાસ્તવિક જીવનની ઉંમરની ગણતરીના સૂત્રને કાર્યમાં દર્શાવે છે:

=DATEDIF(B2, TODAY(), "y")

થી ચોક્કસ ઉંમરની ગણતરીજન્મ તારીખ (વર્ષ, મહિનો અને દિવસોમાં)

વર્ષો, મહિનાઓ અને દિવસોમાં ચોક્કસ ઉંમરની ગણતરી કરવા માટે, છેલ્લી દલીલમાં નીચેના એકમો સાથે ત્રણ DATEDIF ફંક્શન્સ લખો:

• Y - પૂર્ણ વર્ષોની સંખ્યાની ગણતરી કરવા માટે.
• YM - મહિનાઓ વચ્ચેનો તફાવત મેળવવા માટે, વર્ષોને અવગણીને.
• MD - વર્ષો અને મહિનાઓને અવગણીને દિવસો વચ્ચેનો તફાવત મેળવવા માટે .

અને પછી, એક જ સૂત્રમાં 3 DATEDIF ફંક્શનને જોડો, દરેક ફંક્શન દ્વારા પરત કરવામાં આવેલી સંખ્યાઓને અલ્પવિરામથી અલગ કરો અને દરેક સંખ્યાનો અર્થ શું છે તે વ્યાખ્યાયિત કરો.

ની તારીખ ધારી રહ્યા છીએ જન્મ કોષ B2 માં છે, સંપૂર્ણ સૂત્ર નીચે મુજબ છે:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

આ વય સૂત્ર ખૂબ જ કામમાં આવી શકે છે, જેમ કે, ડૉક્ટર દર્દીઓની ચોક્કસ ઉંમર દર્શાવવા માટે, અથવા તમામ કર્મચારીઓની ચોક્કસ ઉંમર જાણવા માટે કર્મચારી અધિકારી:

વિશિષ્ટ તારીખે અથવા ચોક્કસ વર્ષમાં ઉંમરની ગણતરી કરવા જેવા વધુ ફોર્મ્યુલા ઉદાહરણો માટે, કૃપા કરીને નીચેનાને તપાસો ટ્યુટોરીયલ: Excel માં ઉંમરની ગણતરી કેવી રીતે કરવી.

વર્ષનો દિવસ નંબર કેવી રીતે મેળવવો (1-365)

આ ઉદાહરણ દર્શાવે છે કે તમે એક વર્ષમાં ચોક્કસ દિવસની સંખ્યા કેવી રીતે મેળવી શકો છો, 1 અને 365 (લીપ વર્ષમાં 1-366) જાન્યુઆરી 1 સાથે દિવસ 1 ગણવામાં આવે છે.

આ માટે, DATE સાથે YEAR ફંક્શનનો આ રીતે ઉપયોગ કરો:

=A2-DATE(YEAR(A2), 1, 0)

જ્યાં A2 એ તારીખ ધરાવતો કોષ છે.

અને હવે, ચાલો જોઈએ કે ફોર્મ્યુલા ખરેખર શું કરે છે. આ YEAR ફંક્શન સેલ A2 માં તારીખના વર્ષને પુનઃપ્રાપ્ત કરે છે, અને તેને DATE(વર્ષ, મહિનો, દિવસ) ફંક્શનમાં પસાર કરે છે, જે ચોક્કસ તારીખનું પ્રતિનિધિત્વ કરતી ક્રમિક સંખ્યા પરત કરે છે.

તેથી, અમારા સૂત્રમાં, મૂળ તારીખ (A2) માંથી year કાઢવામાં આવે છે, month 1 (જાન્યુઆરી) અને day 0 છે. વાસ્તવમાં, એક શૂન્ય દિવસ એક્સેલને પાછલા વર્ષની 31 ડિસેમ્બર પરત કરવા દબાણ કરે છે. , કારણ કે અમે ઇચ્છીએ છીએ કે 1 જાન્યુઆરીને 1 લી દિવસ તરીકે ગણવામાં આવે. અને પછી, તમે મૂળ તારીખ (જે Excel માં સીરીયલ નંબર તરીકે પણ સંગ્રહિત છે) માંથી DATE ફોર્મ્યુલા દ્વારા પરત કરવામાં આવેલ સીરીયલ નંબર બાદ કરો અને તફાવત એ વર્ષનો દિવસ છે જે તમે શોધી રહ્યા છો. ઉદાહરણ તરીકે, 5 જાન્યુઆરી, 2015 એ 42009 તરીકે સંગ્રહિત છે અને 31 ડિસેમ્બર, 2014 એ 42004 છે, તેથી 42009 - 42004 = 5.

જો દિવસ 0 ની કલ્પના તમને યોગ્ય લાગતી નથી, તો તમે નીચેનાનો ઉપયોગ કરી શકો છો તેના બદલે ફોર્મ્યુલા:

=A2-DATE(YEAR(A2), 1, 1)+1

વર્ષમાં બાકી રહેલા દિવસોની સંખ્યાની ગણતરી કેવી રીતે કરવી

વર્ષમાં બાકી રહેલા દિવસોની ગણતરી કરવા માટે, અમે ઉપયોગ કરવા જઈ રહ્યા છીએ DATE અને YEAR ફરીથી કાર્ય કરે છે. ફોર્મ્યુલા ઉપરના ઉદાહરણ 3 જેવા જ અભિગમ પર આધારિત છે, તેથી તમને તેના તર્કને સમજવામાં કોઈ મુશ્કેલી થવાની શક્યતા નથી:

=DATE(YEAR(A2),12,31)-A2

જો તમે વર્તમાન તારીખના આધારે વર્ષના અંત સુધી કેટલા દિવસો બાકી છે તે જાણવા માગો છો, તો તમે Excel TODAY() ફંક્શનનો ઉપયોગ નીચે મુજબ કરો છો:

=DATE(2015, 12, 31)-TODAY()

જ્યાં 2015 ચાલુ વર્ષ છે .

ગણતરીએક્સેલમાં લીપ વર્ષ

જેમ તમે જાણો છો, લગભગ દર ચોથા વર્ષે 29 ફેબ્રુઆરીએ એક વધારાનો દિવસ હોય છે અને તેને લીપ વર્ષ કહેવામાં આવે છે. માઈક્રોસોફ્ટ એક્સેલ શીટ્સમાં, તમે વિવિધ રીતે નક્કી કરી શકો છો કે કોઈ ચોક્કસ તારીખ લીપ વર્ષની છે કે સામાન્ય વર્ષની છે. હું માત્ર કેટલાક સૂત્રો દર્શાવવા જઈ રહ્યો છું, જે મારા મતે સમજવા માટે સૌથી સરળ છે.

ફોર્મ્યુલા 1. તપાસો કે ફેબ્રુઆરીમાં 29 દિવસ છે કે કેમ

આ એકદમ સ્પષ્ટ કસોટી છે. લીપ વર્ષમાં ફેબ્રુઆરીમાં 29 દિવસ હોવાથી, અમે આપેલ વર્ષના મહિના 2 માં દિવસોની સંખ્યાની ગણતરી કરીએ છીએ અને તેની સંખ્યા 29 સાથે સરખામણી કરીએ છીએ. ઉદાહરણ તરીકે:

=DAY(DATE(2015,3,1)-1)=29

આ સૂત્રમાં, DATE(2015,3,1) ફંક્શન વર્ષ 2015 માં માર્ચનો 1 લી દિવસ પરત કરે છે, જેમાંથી આપણે 1 બાદ કરીએ છીએ. DAY ફંક્શન આ તારીખથી દિવસની સંખ્યા કાઢે છે, અને અમે તે સંખ્યાને 29 સાથે સરખાવીએ છીએ. જો સંખ્યાઓ મેળ ખાય છે, ફોર્મ્યુલા સાચું આપે છે, અન્યથા ખોટું.

જો તમારી એક્સેલ વર્કશીટમાં તમારી પાસે પહેલેથી જ તારીખોની સૂચિ છે અને તમે જાણવા માગો છો કે કયા લીપ વર્ષ છે, તો પછી એક વર્ષ કાઢવા માટે ફોર્મ્યુલામાં YEAR ફંક્શનનો સમાવેશ કરો. તારીખ:

=DAY(DATE(YEAR(A2),3,1)-1)=29

જ્યાં A2 એ તારીખ ધરાવતો કોષ છે.

સૂત્ર દ્વારા આપવામાં આવેલા પરિણામો નીચે મુજબ છે:

વૈકલ્પિક રીતે, તમે ફેબ્રુઆરીમાં છેલ્લો દિવસ પરત કરવા માટે EOMONTH ફંક્શનનો ઉપયોગ કરી શકો છો અને તે સંખ્યાને 29 સાથે સરખાવી શકો છો:

=DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29

ફોર્મ્યુલાને વધુ વપરાશકર્તા-મૈત્રીપૂર્ણ બનાવવા માટે , IF ફંક્શનનો ઉપયોગ કરો અને તેને રાખોપરત કરો, કહો, સાચું અને ખોટું ના બદલે "લીપ વર્ષ" અને "સામાન્ય વર્ષ":

=IF(DAY(DATE(YEAR(A2),3,1)-1)=29, "Leap year", "Common year")

=IF(DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29, "Leap year", "Common year")

ફોર્મ્યુલા 2 તપાસો કે વર્ષમાં 366 દિવસ છે કે કેમ

આ બીજી સ્પષ્ટ કસોટી છે જેને ભાગ્યે જ કોઈ સમજૂતીની જરૂર હોય છે. અમે એક DATE ફંક્શનનો ઉપયોગ આવતા વર્ષની 1-જાન્યુરી પરત કરવા માટે કરીએ છીએ, આ વર્ષની 1-જાન્યુઆરી મેળવવા માટે અન્ય DATE ફંક્શનનો ઉપયોગ કરીએ છીએ, પહેલામાંથી બાદમાં બાદ કરીએ છીએ અને તપાસો કે તફાવત 366:

=DATE(2016,1,1) - DATE(2015,1,1)=366 <ની બરાબર છે કે નહીં. 3>

કેટલાક કોષમાં દાખલ કરેલ તારીખના આધારે વર્ષની ગણતરી કરવા માટે, તમે એક્સેલ YEAR ફંક્શનનો બરાબર એ જ રીતે ઉપયોગ કરો છો જે રીતે આપણે અગાઉના ઉદાહરણમાં કર્યો હતો:

=DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366

જ્યાં A2 એ તારીખ ધરાવતો કોષ છે.

અને સ્વાભાવિક રીતે, તમે TRUE અને FALSE ના બુલિયન મૂલ્યો કરતાં કંઈક વધુ અર્થપૂર્ણ પરત કરવા માટે IF ફંક્શનમાં ઉપરોક્ત DATE/YEAR સૂત્રને બંધ કરી શકો છો:

=IF(DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366, "Leap year", "Non-leap year")

પહેલેથી જ ઉલ્લેખ કર્યો છે તેમ, Excel માં લીપ વર્ષની ગણતરી કરવાની આ એકમાત્ર સંભવિત રીતો નથી. જો તમે અન્ય ઉકેલો જાણવા માટે ઉત્સુક છો, તો તમે Microsoft દ્વારા સૂચવેલ પદ્ધતિ ચકાસી શકો છો. હંમેશની જેમ, માઈક્રોસોફ્ટ લોકો સરળ રીતો શોધી રહ્યા નથી, શું તેઓ છે?

આશા છે કે, આ લેખે તમને Excel માં વર્ષની ગણતરીઓ શોધવામાં મદદ કરી છે. હું વાંચવા બદલ તમારો આભાર માનું છું અને આવતા અઠવાડિયે તમને મળવાની રાહ જોઉં છું.