Dizze tutorial ferklearret de syntaksis en gebrûk fan 'e Excel YEAR-funksje en jout formulefoarbylden om jier fan datum te ekstrahearjen, datum om te konvertearjen nei moanne en jier, leeftyd te berekkenjen fanôf de bertedatum en bepale skrikkeljierren.

Yn in pear resinte berjochten hawwe wy ferskate manieren ûndersocht om datums en tiden yn Excel te berekkenjen en in ferskaat oan nuttige funksjes leard lykas WEEKDAY, WEEKNUM, MONTH en DAY. Hjoed sille wy ús rjochtsje op in gruttere tiidienheid en prate oer it berekkenjen fan jierren yn jo Excel-wurkblêden.

Yn dizze tutorial sille jo leare:

YEAR-funksje yn Excel

De funksje JIER yn Excel jout in jiertal fan fjouwer sifers dat oerienkomt mei in opjûne datum werom as in hiel getal fan 1900 oant 9999.

De syntaksis fan 'e Excel YEAR-funksje is sa ienfâldich as it koe mooglik wêze:

Wêr't searjenûmer elke jildige datum fan it jier is dat jo fine wolle.

Excel JAAR-formule

Om in JIER-formule yn Excel te meitsjen, kinne jo de boarnedatum op ferskate wizen oanjaan.

Mei help fan de DATE funksje

De De meast betroubere manier om in datum yn Excel oan te jaan is mei de funksje DATE.

De folgjende formule jout bygelyks it jier werom foar 28 april 2015:

=YEAR(DATE(2015, 4, 28))

As in searjenûmer dat de datum foarstelt

Yn it ynterne Excel-systeem wurde datums opslein as searjenûmers dy't begjinne mei 1 jannewaris 1900, dat wurdt opslein as nûmer 1. Foar mearynformaasje oer hoe't datums wurde opslein yn Excel, sjoch asjebleaft Excel datumformaat.

De 28e dei fan april, 2015 wurdt opslein as 42122, dus jo kinne dit nûmer direkt yn 'e formule ynfiere:

=YEAR(42122)

Hoewol akseptabel, wurdt dizze metoade net oanrikkemandearre, om't datumnûmering kin ferskille tusken ferskate systemen.

As selferwizing

As jo ​​​​oannimme dat jo in jildige datum hawwe yn guon sel, jo kinne gewoan ferwize nei dy sel. Bygelyks:

=YEAR(A1)

As gefolch fan in oare formule

Jo kinne bygelyks de funksje TODAY() brûke om it jier út de hjoeddeiske datum te heljen:

=YEAR(TODAY())

As tekst

Yn in ienfâldich gefal kin de YEAR-formule sels datums begripe dy't as tekst ynfierd binne, lykas dit:

=YEAR("28-Apr-2015")

As jo ​​dizze metoade brûke, kontrolearje dan dûbel dat jo de datum ynfiere yn it formaat dat Excel begrypt. Unthâld ek dat Microsoft gjin goede resultaten garandearret as in datum as tekstwearde wurdt levere.

De folgjende skermôfbylding toant alle boppesteande YEAR-formules yn aksje, allegear weromkomme 2015 lykas jo miskien ferwachtsje :)

Hoe kinne jo datum nei jier konvertearje yn Excel

As jo ​​wurkje mei datumynformaasje yn Excel, werjaan jo wurkblêden normaal folsleine datums, ynklusyf moanne, dei en jier . Foar grutte mylpealen en wichtige barrens lykas produktlansearrings of oanwinsten fan aktiva wolle jo miskien allinich it jier besjen sûnder it opnij yn te fieren of te feroarjenorizjinele gegevens. Hjirûnder fine jo 3 rappe manieren om dit te dwaan.

Foarbyld 1. Meitsje in jier fan datum út mei de funksje YEAR

Yn feite witte jo al hoe't jo de YEAR-funksje brûke yn Excel om in datum te konvertearjen nei in jier. De skermprint hjirboppe toant in boskje formules, en jo kinne in pear mear foarbylden sjen yn 'e skermprint hjirûnder. Tink derom dat de YEAR-funksje datums perfekt begrypt yn alle mooglike formaten:

Foarbyld 2. Konvertearje datum nei moanne en jier yn Excel

Om in opjûne datum te konvertearjen nei jier en moanne kinne jo de TEKST-funksje brûke om elke ienheid yndividueel út te pakken, en dan dy funksjes yn ien formule gear te setten.

Yn de TEKST-funksje kinne jo ferskate koades brûke foar moannen en jierren, lykas:

• "mmm" - ôfkoarte moannen nammen, as Jan - Des.
• "mmmm" - folsleine moanne nammen, as jannewaris - Desimber.
• "yy" - 2-siferjierren
• "yyyy" - 4-sifersjierren

Om de útfier better lêsber te meitsjen, kinne jo de koades skieden mei in komma, keppelteken of in oar karakter, lykas yn de folgjende Datum oant Moanne en Jier formules:

=TEXT(B2, "mmmm") & ", " & TEXT(B2, "yyyy")

Of

=TEXT(B2, "mmm") & "-" & TEXT(B2, "yy")

Dêr't B2 in sel is mei in datum.

Foarbyld 3. Toan in datum as in jier

As it net echt útmakket hoe't de datums yn jo wurkboek bewarre wurde, kinne jo Excel krije om allinich de jierren mei te sjen ut feroarjen fan de oarspronklike datums. Mei oare wurden, jo kinne hawwefolsleine datums opslein yn sellen, mar allinich de jierren werjûn.

Yn dit gefal is gjin formule nedich. Jo iepenje gewoan it dialoochfinster Sellen opmaak troch op Ctrl + 1 te drukken, selektearje de kategory Aanpaste op it ljepblêd Nûmer en fier ien fan de ûndersteande koades yn de Typ -fak:

• yy - om 2-sifers jierren te werjaan, as 00 - 99.
• yyyy - om 4-sifers jierren wer te jaan, as 1900 - 9999 .

Tink derom dat dizze metoade de oarspronklike datum net feroaret , it feroaret allinich de manier wêrop de datum yn jo wurkblêd werjûn wurdt. As jo ​​​​nei sokke sellen yn jo formules ferwize, sil Microsoft Excel datumberekkeningen útfiere ynstee fan jierberekkeningen.

Jo kinne mear details fine oer it feroarjen fan de datumopmaak yn dizze tutorial: Hoe kinne jo datumformaat feroarje yn Excel.

Hoe kinne jo leeftyd fan bertedatum berekkenje yn Excel

D'r binne ferskate manieren om leeftyd te berekkenjen fan bertedatum yn Excel - mei DATEDIF, YEARFRAC of INT-funksje yn kombinaasje mei TODAY(). De TODAY-funksje leveret de datum om de leeftyd op te berekkenjen, en soarget derfoar dat jo formule altyd de juste leeftyd werombringt.

Berekkenje leeftyd fan bertedatum yn jierren

De tradisjonele manier om de leeftyd fan in persoan te berekkenjen yn jierren is om de bertedatum fan 'e hjoeddeistige datum ôf te lûken. Dizze oanpak wurket goed yn it deistich libben, mar in analoge formule foar berekkening fan Excel-leeftyd is net perfekt wier:

Dêr't DOB de bertedatum is.

It earste diel fan de formule (TODAY()-B2) berekkent de ferskil is dagen, en jo diele it troch 365 te krijen it oantal jierren. Yn 'e measte gefallen is it resultaat fan dizze fergeliking in desimaal getal, en jo hawwe de INT-funksje omleech nei it tichtstbyste heule getal.

As oannommen dat de bertedatum yn sel B2 stiet, giet de folsleine formule as folget :

=INT((TODAY()-B2)/365)

Lykas hjirboppe neamde, is dizze leeftydsberekkeningsformule net altyd feilloos, en hjir is wêrom. Elk 4e jier is in skrikkeljier dat 366 dagen befettet, wylst de formule it oantal dagen dielt troch 365. Dus, as immen berne is op 29 febrewaris en hjoed is 28 febrewaris, sil dizze leeftydsformule in persoan ien dei âlder meitsje.

Diel troch 365,25 ynstee fan 365 is ek net ûnberikber, bygelyks by it berekkenjen fan de leeftyd fan in bern dat noch gjin skrikkeljier trochmakke hat.

Sjoen it boppesteande soene jo Bewarje dizze manier fan berekkenjen fan leeftyd foar normaal libben better, en brûk ien fan 'e folgjende formules om leeftyd fan bertedatum te berekkenjen yn Excel.

De detaillearre útlis fan de boppesteande formules wurdt jûn yn Hoe leeftyd berekkenje yn Excel. En it folgjende skermôfbylding toant in echte leeftydsberekkeningsformule yn aksje:

=DATEDIF(B2, TODAY(), "y")

De krekte leeftyd berekkenje fanôfbertedatum (yn jierren, moanne en dagen)

Om in krekte leeftyd yn jierren, moannen en dagen te berekkenjen, skriuw trije DATEDIF-funksjes mei de folgjende ienheden yn it lêste argumint:

• Y - om it oantal folsleine jierren te berekkenjen.
• YM - om it ferskil tusken de moannen te krijen, jierren te negearjen.
• MD - om it ferskil tusken de dagen te krijen, jierren en moannen te negearjen .

En dan, ferbine de 3 DATEDIF-funksjes yn ien formule, skied de sifers weromjûn troch elke funksje mei komma's, en definiearje wat elk getal betsjut.

Ungeande fan de datum fan berte is yn sel B2, giet de folsleine formule as folget:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

Dizze leeftydsformule kin tige handich wêze, bygelyks foar in dokter om de krekte leeftyd fan pasjinten te sjen, of foar in personielsoffisier om de krekte leeftyd fan alle meiwurkers te witten:

Foar mear formulefoarbylden lykas it berekkenjen fan leeftyd op in bepaalde datum of yn in bepaald jier, kontrolearje asjebleaft it folgjende tutorial: Hoe leeftyd te berekkenjen yn Excel.

Hoe kinne jo it deinûmer fan it jier krije (1-365)

Dit foarbyld lit sjen hoe't jo it nûmer fan in bepaalde dei yn in jier krije kinne, tusken 1 en 365 (1-366 yn in skrikkeljier) mei 1 jannewaris beskôge as dei 1.

Gebrûk hjirfoar de funksje YEAR tegearre mei DATE op dizze manier:

=A2-DATE(YEAR(A2), 1, 0)

Wêr't A2 in sel is mei de datum.

En no, litte wy sjen wat de formule eins docht. DeDe funksje YEAR hellet it jier fan 'e datum op yn sel A2, en jout it troch oan de funksje DATE(jier, moanne, dei) , dy't it sekwinsjele nûmer weromjout dat in bepaalde datum foarstelt.

Dus, yn ús formule, wurdt year ekstrahearre út de oarspronklike datum (A2), month is 1 (jannewaris) en day is 0. Eins twingt in nul dei Excel om 31 desimber fan it foarige jier werom te jaan , want wy wolle dat 1 jannewaris behannele wurdt as de 1e dei. En dan subtrahearje jo it searjenûmer weromjûn troch de DATE-formule fan 'e orizjinele datum (dy't ek wurdt opslein as searjenûmer yn Excel) en it ferskil is de dei fan it jier wêr't jo nei sykje. Bygelyks, 5 jannewaris 2015 wurdt bewarre as 42009 en 31 desimber 2014 is 42004, dus 42009 - 42004 = 5.

As it konsept fan dei 0 jo net goed liket, kinne jo de folgjende brûke formule ynstee:

=A2-DATE(YEAR(A2), 1, 1)+1

Hoe kinne jo it oantal oerbleaune dagen yn it jier berekkenje

Om it oantal oerbleaune dagen yn it jier te berekkenjen, sille wy de DATE en YEAR funksjonearje wer. De formule is basearre op deselde oanpak as foarbyld 3 hjirboppe, sadat jo wierskynlik gjin swierrichheden hawwe mei it begripen fan de logika:

=DATE(YEAR(A2),12,31)-A2

As jo wolle witte hoefolle dagen der oerbliuwe oant it ein fan it jier basearre op de aktuele datum, brûke jo de Excel TODAY() funksje, as folget:

=DATE(2015, 12, 31)-TODAY()

Wêr 2015 it aktuele jier is .

Berekkenjeskrikkeljierren yn Excel

Sa't jo witte, hat hast elk 4e jier in ekstra dei op 29 febrewaris en wurdt in skrikkeljier neamd. Yn Microsoft Excel-blêden kinne jo op ferskate manieren bepale oft in bepaalde datum ta in skrikkeljier of in gewoan jier heart. Ik sil mar in pear formules demonstrearje, dy't neffens my it maklikst te begripen binne.

Formule 1. Kontrolearje oft febrewaris 29 dagen hat

Dit is in heul dúdlike test. Sûnt febrewaris 29 dagen hat yn in skrikkeljier, berekkenje wy it oantal dagen yn moanne 2 fan in opjûn jier en fergelykje it mei nûmer 29. Bygelyks:

=DAY(DATE(2015,3,1)-1)=29

Yn dizze formule is de DATE(2015;3,1)-funksje jout de 1e dei fan maart yn it jier 2015 werom, wêrfan wy 1 ôflûke. De DAY-funksje ekstrahearret it deinûmer fan dizze datum, en wy fergelykje dat nûmer mei 29. As de nûmers oerienkomme, de formule jout TRUE, FALSE oars.

As jo ​​al in list mei datums yn jo Excel-wurkblêd hawwe en jo wolle witte hokker skrikkeljierren binne, ferfetsje dan de YEAR-funksje yn 'e formule om in jier út te heljen in datum:

=DAY(DATE(YEAR(A2),3,1)-1)=29

Dêr't A2 in sel is mei de datum.

De resultaten weromjûn troch de formule binne as folget:

As alternatyf kinne jo de EOMONTH-funksje brûke om de lêste dei yn febrewaris werom te jaan en dat nûmer te fergelykjen mei 29:

=DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29

Om de formule brûkerfreonliker te meitsjen , brûke de IF-funksje en hawwe itwerom, sis, "Schrikkeljier" en "Algemien jier" ynstee fan TRUE en FALSE:

=IF(DAY(DATE(YEAR(A2),3,1)-1)=29, "Leap year", "Common year")

=IF(DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29, "Leap year", "Common year")

Formule 2 Kontrolearje oft it jier 366 dagen hat

Dit is in oare foar de hân lizzende test dy't amper útlis fereasket. Wy brûke ien DATE-funksje om 1-jannewaris fan it folgjende jier werom te jaan, in oare DATE-funksje om 1-jan fan dit jier te krijen, de lêste ôflûke fan de eardere en kontrolearje oft it ferskil lyk is oan 366:

=DATE(2016,1,1) - DATE(2015,1,1)=366

Om in jier te berekkenjen op basis fan in datum ynfierd yn guon sel, brûke jo de Excel YEAR-funksje krekt op deselde manier as yn it foarige foarbyld:

=DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366

Wêr't A2 in sel is dy't de datum befettet.

En fansels kinne jo de boppesteande DATUM / JAAR-formule yn 'e IF-funksje omfetsje om it wat betsjuttingsvoller werom te jaan dan de Booleaanske wearden fan TRUE en FALSE:

=IF(DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366, "Leap year", "Non-leap year")

As al neamd binne dit net de ienige mooglike manieren om skrikkeljierren yn Excel te berekkenjen. As jo ​​​​nijsgjirrich binne om oare oplossingen te kennen, kinne jo de troch Microsoft foarstelde metoade kontrolearje. Lykas gewoanlik sykje Microsoft-jonges net nei maklike manieren, binne se?

Hooplik hat dit artikel jo holpen om jierberekkeningen yn Excel út te finen. Ik tankje jo foar it lêzen en sjoch út nei jo nije wike te sjen.