يشرح هذا البرنامج التعليمي بناء الجملة واستخدامات دالة Excel YEAR ويقدم أمثلة صيغة لاستخراج السنة من التاريخ ، وتحويل التاريخ إلى الشهر والسنة ، وحساب العمر من تاريخ الميلاد و تحديد السنوات الكبيسة.

في عدد قليل من المنشورات الأخيرة ، اكتشفنا طرقًا مختلفة لحساب التواريخ والأوقات في Excel وتعلمنا مجموعة متنوعة من الوظائف المفيدة مثل WEEKDAY و WEEKNUM و MONTH و DAY. اليوم ، سنركز على وحدة زمنية أكبر ونتحدث عن حساب السنوات في أوراق عمل Excel الخاصة بك.

في هذا البرنامج التعليمي ، ستتعلم:

دالة YEAR في Excel

ترجع الدالة YEAR في Excel سنة مكونة من أربعة أرقام مطابقة لتاريخ معين كعدد صحيح من 1900 إلى 9999.

إن بناء جملة دالة Excel YEAR بسيطة بقدر ما يمكن أن يكون:

حيث serial_number هو أي تاريخ صالح من السنة التي تريد العثور عليها.

صيغة Excel YEAR

لإنشاء صيغة YEAR في Excel ، يمكنك توفير تاريخ المصدر بعدة طرق.

استخدام وظيفة DATE

الطريقة الأكثر موثوقية لتوفير تاريخ في Excel هي استخدام الدالة DATE.

على سبيل المثال ، ترجع الصيغة التالية السنة في 28 أبريل 2015:

=YEAR(DATE(2015, 4, 28))

As رقم تسلسلي يمثل التاريخ

في نظام Excel الداخلي ، يتم تخزين التواريخ كأرقام تسلسلية تبدأ من 1 يناير 1900 ، ويتم تخزينها كرقم 1. لمزيد من المعلوماتمعلومات حول كيفية تخزين التواريخ في Excel ، يرجى الاطلاع على تنسيق تاريخ Excel.

يتم تخزين اليوم 28 من أبريل 2015 كـ 42122 ، لذا يمكنك إدخال هذا الرقم مباشرة في الصيغة:

=YEAR(42122)

على الرغم من قبولها ، لا يُنصح بهذه الطريقة لأن ترقيم التاريخ قد يختلف عبر أنظمة مختلفة.

كمرجع خلية

بافتراض أن لديك تاريخًا صالحًا في بعض الخلايا ، يمكنك ببساطة الرجوع إلى تلك الخلية. على سبيل المثال:

=YEAR(A1)

كنتيجة لبعض الصيغة الأخرى

على سبيل المثال ، يمكنك استخدام الدالة TODAY () لاستخراج السنة من التاريخ الحالي:

=YEAR(TODAY())

كنص

في حالة بسيطة ، يمكن أن تفهم صيغة YEAR التواريخ التي تم إدخالها كنص ، مثل هذا:

=YEAR("28-Apr-2015")

عند استخدام هذه الطريقة ، يرجى التحقق جيدًا من إدخال التاريخ بالتنسيق الذي يفهمه Excel. أيضًا ، يرجى تذكر أن Microsoft لا تضمن النتائج الصحيحة عندما يتم تقديم التاريخ كقيمة نصية.

توضح لقطة الشاشة التالية جميع صيغ YEAR أعلاه في العمل ، وكلها تعود لعام 2015 كما قد تتوقع:)

كيفية تحويل التاريخ إلى سنة في Excel

عندما تعمل مع معلومات التاريخ في Excel ، تعرض أوراق العمل الخاصة بك عادةً التواريخ الكاملة ، بما في ذلك الشهر واليوم والسنة . ومع ذلك ، بالنسبة للمعالم الرئيسية والأحداث المهمة مثل إطلاق المنتجات أو عمليات الاستحواذ على الأصول ، قد ترغب في عرض العام فقط دون إعادة إدخال أو تعديلالبيانات الأصلية. أدناه ، ستجد 3 طرق سريعة للقيام بذلك.

مثال 1. استخراج سنة من التاريخ باستخدام وظيفة YEAR

في الواقع ، أنت تعرف بالفعل كيفية استخدام وظيفة YEAR في Excel لتحويل تاريخ إلى عام. توضح لقطة الشاشة أعلاه مجموعة من الصيغ ، ويمكنك رؤية بعض الأمثلة الأخرى في لقطة الشاشة أدناه. لاحظ أن الدالة YEAR تتفهم تمامًا التواريخ بجميع التنسيقات الممكنة:

مثال 2. تحويل التاريخ إلى شهر وسنة في Excel

لتحويل تاريخ معين إلى السنة والشهر ، يمكنك استخدام الدالة TEXT لاستخراج كل وحدة على حدة ، ثم ربط هذه الوظائف في صيغة واحدة.

في دالة TEXT ، يمكنك استخدام رموز مختلفة للأشهر والسنوات ، مثل:

• "mmm" - أسماء الشهور المختصرة ، مثل كانون الثاني (يناير) - كانون الأول (ديسمبر)
• "mmmm" - أسماء الأشهر الكاملة ، مثل كانون الثاني (يناير) - كانون الأول (ديسمبر).
• "yy" - السنوات المكونة من رقمين
• "yyyy" - السنوات المكونة من 4 أرقام

لجعل الإخراج قابلاً للقراءة بشكل أفضل ، يمكنك فصل الرموز بفاصلة أو واصلة أو أي حرف آخر ، كما في المعادلات التالية التاريخ إلى الشهر والسنة :

=TEXT(B2, "mmmm") & ", " & TEXT(B2, "yyyy")

أو

=TEXT(B2, "mmm") & "-" & TEXT(B2, "yy")

حيث B2 هي خلية تحتوي تاريخ.

مثال 3. عرض تاريخ كسنة

إذا لم يكن الأمر مهمًا حقًا في كيفية تخزين التواريخ في المصنف ، فيمكنك احصل على برنامج Excel لإظهار السنوات بدونه فقط ليرة لبنانية تغيير التواريخ الأصلية. بمعنى آخر ، يمكنك الحصول علىالتواريخ الكاملة المخزنة في الخلايا ، ولكن يتم عرض السنوات فقط.

في هذه الحالة ، ليست هناك حاجة إلى صيغة. ما عليك سوى فتح مربع الحوار تنسيق الخلايا بالضغط على Ctrl + 1 ، وتحديد فئة مخصص في علامة التبويب رقم ، وأدخل أحد الرموز أدناه في اكتب المربع:

• yy - لعرض السنوات المكونة من رقمين ، مثل 00 - 99.
• yyyy - لعرض السنوات المكونة من 4 أرقام ، مثل 1900-9999 .

الرجاء تذكر أن هذه الطريقة لا تغير التاريخ الأصلي ، إنها تغير فقط طريقة عرض التاريخ في ورقة العمل الخاصة بك. إذا أشرت إلى هذه الخلايا في الصيغ الخاصة بك ، فسيقوم Microsoft Excel بإجراء حسابات التاريخ بدلاً من حسابات السنة.

يمكنك العثور على مزيد من التفاصيل حول تغيير تنسيق التاريخ في هذا البرنامج التعليمي: كيفية تغيير تنسيق التاريخ في Excel.

كيفية حساب العمر من تاريخ الميلاد في Excel

هناك عدة طرق لحساب نموذج العمر وتاريخ الميلاد في Excel - باستخدام DATEDIF أو YEARFRAC أو INT بالاشتراك مع TODAY (). توفر وظيفة TODAY التاريخ لحساب العمر ، مما يضمن أن الصيغة الخاصة بك سترجع دائمًا العمر الصحيح.

احسب العمر من تاريخ الميلاد بالسنوات

الطريقة التقليدية لحساب عمر الشخص بالسنوات هو طرح تاريخ الميلاد من التاريخ الحالي. يعمل هذا النهج بشكل جيد في الحياة اليومية ، ولكن معادلة حساب العمر في Excel ليست صحيحة تمامًا:

حيث DOB هو تاريخ الميلاد.

يحسب الجزء الأول من الصيغة (TODAY () - B2) الفرق هو الأيام ، وتقسمه على 365 للحصول على عدد السنوات. في معظم الحالات ، تكون نتيجة هذه المعادلة رقمًا عشريًا ، ويكون لديك دالة INT تقريبها إلى أقرب عدد صحيح.

بافتراض أن تاريخ الميلاد موجود في الخلية B2 ، فإن الصيغة الكاملة هي كما يلي :

=INT((TODAY()-B2)/365)

كما هو مذكور أعلاه ، صيغة حساب العمر هذه ليست دائمًا خالية من العيوب ، وإليك السبب. كل عام رابع هو سنة كبيسة تحتوي على 366 يومًا ، في حين أن الصيغة تقسم عدد الأيام على 365. لذلك ، إذا ولد شخص ما في 29 فبراير واليوم 28 فبراير ، فإن معادلة العمر هذه ستجعل الشخص أكبر يومًا بيوم.

القسمة على 365.25 بدلاً من 365 لا تشوبها شائبة أيضًا ، على سبيل المثال ، عند حساب عمر الطفل الذي لم يعيش بعد سنة كبيسة.

بالنظر إلى ما سبق ، من الأفضل حفظ طريقة حساب العمر للحياة الطبيعية ، واستخدام إحدى الصيغ التالية لحساب العمر من تاريخ الميلاد في Excel.

يتم توفير الشرح التفصيلي للصيغ أعلاه في كيفية حساب العمر في Excel. وتوضح لقطة الشاشة التالية معادلة حساب العمر الواقعي قيد التنفيذ:

=DATEDIF(B2, TODAY(), "y")

حساب العمر بالضبط منتاريخ الميلاد (بالسنوات والشهر والأيام)

لحساب العمر الدقيق بالسنوات والشهور والأيام ، اكتب ثلاث دالات DATEDIF بالوحدات التالية في الوسيطة الأخيرة:

• Y - لحساب عدد السنوات الكاملة.
• YM - للحصول على الفرق بين الأشهر ، وتجاهل السنوات.
• MD - للحصول على الفرق بين الأيام ، وتجاهل السنوات والأشهر .

وبعد ذلك ، قم بتوصيل دالات DATEDIF الثلاث في صيغة واحدة ، وافصل الأرقام التي ترجعها كل دالة بفاصلات ، وحدد معنى كل رقم.

بافتراض تاريخ الولادة في الخلية B2 ، الصيغة الكاملة هي كما يلي:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

قد تكون صيغة العمر هذه مفيدة جدًا ، على سبيل المثال ، للطبيب لعرض العمر الدقيق للمرضى ، أو ضابط شؤون الموظفين لمعرفة العمر الدقيق لجميع الموظفين:

لمزيد من أمثلة الصيغ مثل حساب العمر في تاريخ معين أو في عام معين ، يرجى مراجعة ما يلي البرنامج التعليمي: كيفية حساب العمر في Excel.

كيفية الحصول على رقم اليوم من السنة (1-365)

يوضح هذا المثال كيف يمكنك الحصول على رقم يوم معين في السنة ، بين 1 و 365 (1-366 في السنوات الكبيسة) مع اعتبار 1 كانون الثاني (يناير) اليوم الأول.

لهذا ، استخدم الدالة YEAR مع DATE بهذه الطريقة:

=A2-DATE(YEAR(A2), 1, 0)

حيث A2 هي خلية تحتوي على التاريخ.

والآن ، دعنا نرى ما تفعله الصيغة بالفعل. التسترد الدالة YEAR سنة التاريخ في الخلية A2 ، وتمررها إلى الدالة DATE (السنة والشهر واليوم) ، والتي تُرجع الرقم التسلسلي الذي يمثل تاريخًا معينًا.

لذلك ، في صيغتنا ، يتم استخراج year من التاريخ الأصلي (A2) ، و month هو 1 (يناير) و day هو 0. في الواقع ، يفرض يوم الصفر على Excel إعادة 31 ديسمبر من العام السابق ، لأننا نريد أن يتم التعامل مع الأول من كانون الثاني (يناير) باعتباره اليوم الأول. وبعد ذلك ، تقوم بطرح الرقم التسلسلي الذي تم إرجاعه بواسطة صيغة DATE من التاريخ الأصلي (والذي يتم تخزينه أيضًا كرقم تسلسلي في Excel) والفرق هو يوم السنة الذي تبحث عنه. على سبيل المثال ، يتم تخزين 5 كانون الثاني (يناير) 2015 كـ 42009 و 31 كانون الأول (ديسمبر) 2014 هو 42004 ، لذلك 42009 - 42004 = 5.

إذا كان مفهوم اليوم 0 لا يبدو مناسبًا لك ، فيمكنك استخدام ما يلي الصيغة بدلاً من ذلك:

=A2-DATE(YEAR(A2), 1, 1)+1

كيفية حساب عدد الأيام المتبقية في السنة

لحساب عدد الأيام المتبقية في السنة ، سنستخدم يعمل DATE و YEAR مرة أخرى. تعتمد المعادلة على نفس الطريقة المستخدمة في المثال 3 أعلاه ، لذلك من غير المحتمل أن تواجه أي صعوبات في فهم منطقها:

=DATE(YEAR(A2),12,31)-A2

إذا كنت تريد معرفة عدد الأيام المتبقية حتى نهاية العام بناءً على التاريخ الحالي ، يمكنك استخدام وظيفة Excel TODAY () ، على النحو التالي:

=DATE(2015, 12, 31)-TODAY()

أين عام 2015 هو العام الحالي .

حسابالسنوات الكبيسة في Excel

كما تعلم ، كل سنة رابعة تقريبًا بها يوم إضافي في 29 فبراير وتسمى السنة الكبيسة. في أوراق Microsoft Excel ، يمكنك تحديد ما إذا كان تاريخ معين ينتمي إلى سنة كبيسة أو سنة مشتركة بعدة طرق. سأقوم بشرح صيغتين فقط ، والتي برأيي أسهل في الفهم.

الصيغة 1. تحقق مما إذا كان فبراير يحتوي على 29 يومًا

هذا اختبار واضح جدًا. منذ فبراير 29 يومًا في السنوات الكبيسة ، نحسب عدد الأيام في الشهر 2 من سنة معينة ونقارنها بالرقم 29. على سبيل المثال:

=DAY(DATE(2015,3,1)-1)=29

في هذه الصيغة ، تُرجع الدالة DATE (2015،3،1) اليوم الأول من شهر مارس في عام 2015 ، والذي نطرح منه 1. تستخرج الدالة DAY رقم اليوم من هذا التاريخ ، ونقارن هذا الرقم بـ 29. إذا كانت الأرقام متطابقة ، تُرجع الصيغة TRUE ، أو FALSE بخلاف ذلك.

إذا كان لديك بالفعل قائمة بالتواريخ في ورقة عمل Excel الخاصة بك وتريد معرفة التواريخ التي هي سنوات كبيسة ، فقم بدمج الدالة YEAR في الصيغة لاستخراج سنة منها تاريخ:

=DAY(DATE(YEAR(A2),3,1)-1)=29

حيث A2 هي خلية تحتوي على التاريخ.

النتائج التي تم إرجاعها بواسطة الصيغة هي كما يلي:

بدلاً من ذلك ، يمكنك استخدام الدالة EOMONTH لإرجاع اليوم الأخير في فبراير ، ومقارنة هذا الرقم بـ 29:

=DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29

لجعل الصيغة أكثر سهولة في الاستخدام ، استخدم وظيفة IF واحصل عليهاإرجاع ، على سبيل المثال ، "Leap year" و "Common year" بدلاً من TRUE و FALSE:

=IF(DAY(DATE(YEAR(A2),3,1)-1)=29, "Leap year", "Common year")

=IF(DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29, "Leap year", "Common year")

Formula 2 . تحقق مما إذا كان العام يحتوي على 366 يومًا

هذا اختبار واضح آخر لا يتطلب أي تفسير. نستخدم دالة DATE واحدة لإرجاع 1 يناير من العام التالي ، ودالة DATE أخرى للحصول على 1 يناير من هذا العام ، وطرح الأخيرة من الأولى وتحقق مما إذا كان الفرق يساوي 366:

=DATE(2016,1,1) - DATE(2015,1,1)=366

لحساب سنة بناءً على تاريخ تم إدخاله في خلية ما ، يمكنك استخدام وظيفة Excel YEAR تمامًا كما فعلنا في المثال السابق:

=DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366

عندما تكون A2 خلية تحتوي على التاريخ.

وبطبيعة الحال ، يمكنك إرفاق صيغة DATE / YEAR أعلاه في دالة IF لإرجاع شيء أكثر أهمية من القيم المنطقية لـ TRUE و FALSE:

=IF(DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366, "Leap year", "Non-leap year")

كما ذكرنا سابقًا ، هذه ليست الطرق الوحيدة الممكنة لحساب السنوات الكبيسة في Excel. إذا كنت مهتمًا بمعرفة حلول أخرى ، فيمكنك التحقق من الطريقة التي تقترحها Microsoft. كالعادة ، لا يبحث شباب Microsoft عن طرق سهلة ، أليس كذلك؟

نأمل أن تكون هذه المقالة قد ساعدتك في معرفة حسابات السنة في Excel. أشكرك على القراءة وأتطلع إلى رؤيتك الأسبوع المقبل.