Në këtë tutorial, ne do të shikojmë se si të përdorim funksionet IFERROR dhe VLOOKUP së bashku për të kapur dhe trajtuar gabime të ndryshme. Përveç kësaj, do të mësoni se si të bëni vlookups sekuencialë në Excel duke futur funksione të shumta IFERROR njëri mbi tjetrin.

Excel VLOOKUP dhe IFERROR - këto dy funksione mund të jenë mjaft të vështira për t'u kuptuar veçmas, e lëre më kur kombinohen. Në këtë artikull, do të gjeni disa shembuj të thjeshtë për t'u ndjekur që trajtojnë përdorimet e zakonshme dhe ilustrojnë qartë logjikën e formulave.

Nëse nuk keni shumë përvojë me funksionet IFERROR dhe VLOOKUP, mund të jetë një ide e mirë për të rishikuar fillimisht bazat e tyre duke ndjekur lidhjet e mësipërme.

Formula IFERROR VLOOKUP për të trajtuar #N/A dhe gabime të tjera

Kur Excel Vlookup nuk arrin të gjejë një vlerë kërkimi, ajo hedh një gabim #N/A, si ky:

Në varësi të nevojave të biznesit tuaj, ju mund të dëshironi ta maskoni gabimin me tekstin tuaj, zero , ose një qelizë bosh.

Shembulli 1. IFERROR me formulën VLOOKUP për të zëvendësuar gabimet me tekstin tuaj

Nëse dëshironi të zëvendësoni shënimin standard të gabimit me tekstin tuaj të personalizuar, mbështillni Formula VLOOKUP në IFERROR dhe shkruani çdo tekst që dëshironi në argumentin e dytë ( value_if_error ), për shembull "Nuk u gjet":

Me vlerën e kërkimit në B2 në tabelën kryesore dhe gamën e kërkimit A2:B4 në kërkimintabela, formula merr formën e mëposhtme:

=IFERROR(VLOOKUP(B2,'Lookup table'!$A$2:$B$5, 2, FALSE), "Not found")

Pastroja më poshtë tregon formulën tonë Excel IFERROR VLOOKUP në veprim:

rezultati duket shumë më i kuptueshëm dhe shumë më pak frikësues, apo jo?

Në mënyrë të ngjashme, ju mund të përdorni INDEX MATCH së bashku me IFERROR:

=IFERROR(INDEX('Lookup table'!$B$2:$B$5,MATCH(B2,'Lookup table'!$A$2:$A$5,0)), "Not found")

IFERROR Formula INDEX MATCH është veçanërisht e dobishme kur dëshironi të tërheqni vlera nga një kolonë që shtrihet në të majtë të kolonës së kërkimit (kërkim majtas) dhe të ktheni tekstin tuaj kur nuk gjendet asgjë.

Shembulli 2. IFERROR me VLOOKUP për të kthyer bosh ose 0 nëse nuk gjendet asgjë

Nëse nuk dëshironi të shfaqni asgjë kur vlera e kërkimit nuk gjendet, lëreni IFERROR të shfaqë një varg bosh (""):

Në shembullin tonë, formula shkon si më poshtë:

=IFERROR(VLOOKUP(B2,'Lookup table'!$A$2:$B$5, 2, FALSE), "")

Siç mund ta shihni, nuk kthen asgjë kur vlera e kërkimit nuk është në listën e kërkimit.

Nëse dëshironi të zëvendësoni gabimin me vlerën zero , vendosni 0 në a-në e fundit rgument:

=IFERROR(VLOOKUP(B2,'Lookup table'!$A$2:$B$5, 2, FALSE), 0)

Kujdes! Funksioni IFERROR i Excel kap të gjitha llojet e gabimeve, jo vetëm #N/A. A është e mirë apo e keqe? Gjithçka varet nga qëllimi juaj. Nëse dëshironi të maskoni të gjitha gabimet e mundshme, IFERROR Vlookup është mënyra për të shkuar. Por mund të jetë një teknikë jo e mençur në shumë situata.

Për shembull, nëse keni krijuar një varg të emërtuar për të dhënat e tabelës suaj dhe e keni shkruar gabim atë emër nëFormula Vlookup, IFERROR do të kapë një #EMRI? gabim dhe zëvendësojeni me "Nuk u gjet" ose ndonjë tekst tjetër që jepni. Si rezultat, mund të mos e dini kurrë se formula juaj po jep rezultate të gabuara, nëse nuk e dalloni vetë gabimin. Në një rast të tillë, një qasje më e arsyeshme do të ishte bllokimi i vetëm gabimeve #N/A. Për këtë, përdorni formulën IFNA Vlookup në Excel 2013 dhe më të lartë, IF ISNA VLOOKUP në të gjitha versionet e Excel.

Përfundimi është: jini shumë të kujdesshëm kur zgjidhni një shoqërues për formulën tuaj VLOOKUP :)

Nest IFERROR brenda VLOOKUP për të gjetur gjithmonë diçka

Imagjinoni situatën e mëposhtme: kërkoni një vlerë specifike në një listë dhe nuk e gjeni. Çfarë zgjedhjesh keni? Ose merrni një gabim N/A ose tregoni mesazhin tuaj. Në fakt, ekziston një opsion i tretë - nëse vlookupi juaj kryesor pengohet, atëherë kërkoni diçka tjetër që është padyshim atje!

Duke marrë shembullin tonë më tej, le të krijojmë një lloj pulti për përdoruesit tanë që do t'u tregojë atyre një shtesë numri i një zyre të caktuar. Diçka si kjo:

Pra, si ta tërhiqni shtesën nga kolona B bazuar në numrin e zyrës në D2? Me këtë formulë të rregullt Vlookup:

=VLOOKUP($D$2,$A$2:$B$7,2,FALSE)

Dhe do të funksionojë mirë për sa kohë që përdoruesit tuaj të fusin një numër të vlefshëm në D2. Por, çka nëse një përdorues fut një numër që nuk ekziston? Në këtë rast le të thërrasin zyrën qendrore! Për këtë, ju futni formulën e mësipërme në vlera argumenti i IFERROR dhe vendosni një tjetër Vlookup në argumentin value_if_error .

Formula e plotë është pak e gjatë, por funksionon në mënyrë perfekte:

=IFERROR(VLOOKUP("office "&$D$2,$A$2:$B$7,2,FALSE),VLOOKUP("central office",$A$2:$B$7,2,FALSE))

Nëse gjendet numri i zyrës, përdoruesi merr numrin përkatës të shtesës:

Nëse numri i zyrës nuk gjendet, zgjerimi i zyrës qendrore shfaqet:

Për ta bërë formulën pak më kompakte, mund të përdorni një qasje tjetër:

Së pari, kontrolloni nëse numri në D2 është i pranishëm në kolonën e kërkimit (ju lutemi vini re se kemi vendosur col_index_num në 1 që formula të kërkojë dhe të kthejë vlerën nga kolona A): VLOOKUP(D2,$A$2:$B$7,1,FALSE)

Nëse numri i specifikuar i zyrës nuk gjendet, atëherë ne kërkojmë vargun "zyra qendrore", i cili është padyshim në listën e kërkimit. Për këtë, ju mbështillni VLOOKUP-in e parë në IFERROR dhe futni të gjithë këtë kombinim brenda një funksioni tjetër VLOOKUP:

=VLOOKUP(IFERROR(VLOOKUP(D2,$A$2:$B$7,1,FALSE),"central office"),$A$2:$B$7,2)

Epo, një formulë paksa e ndryshme, i njëjti rezultat:

Por cila është arsyeja për të kërkuar "zyrën qendrore", mund të më pyesni. Pse të mos jepni numrin shtesë direkt në IFERROR? Sepse zgjatja mund të ndryshojë në një moment në të ardhmen. Nëse kjo ndodh, do t'ju duhet t'i përditësoni të dhënat tuaja vetëm një herë në tabelën burimore, pa u shqetësuar për përditësimin e secilës prej formulave tuaja VLOOKUP.

Si të bëni VLOOKUP të njëpasnjëshme në Excel

Në situatat kur ju duhet tëkryeni të ashtuquajturat Vlookups sekuenciale ose zinxhiruara në Excel në varësi të faktit nëse një kërkim i mëparshëm pati sukses apo dështoi, vendosni dy ose më shumë funksione IFERROR për të ekzekutuar Vlookup-et tuaja një nga një:

The formula funksionon me logjikën e mëposhtme:

Nëse VLOOKUP-i i parë nuk gjen asgjë, IFERROR-i i parë bllokon një gabim dhe ekzekuton një tjetër VLOOKUP. Nëse VLOOKUP-i i dytë dështon, IFERROR i dytë kap një gabim dhe ekzekuton VLOOKUP-in e tretë, e kështu me radhë. Nëse të gjitha Vlookup-et pengohen, IFERROR-i i fundit kthen mesazhin tuaj.

Kjo formulë IFERROR e ndërlidhur është veçanërisht e dobishme kur duhet të Vlookup-i nëpër shumë fletë siç tregohet në shembullin e mëposhtëm.

0>Le të themi, ju keni tre lista të dhënash homogjene në tre fletë pune të ndryshme (numrat e zyrës në këtë shembull) dhe dëshironi të merrni një shtesë për një numër të caktuar.

Duke supozuar se vlera e kërkimit është në qelizën A2 në fletën aktuale dhe diapazoni i kërkimit është A2:B5 në 3 fletë pune të ndryshme (Veri, Jug dhe Perëndim), formula e mëposhtme funksionon mirë:

=IFERROR(VLOOKUP(A2,North!$A$2:$B$5,2,FALSE), IFERROR(VLOOKUP(A2,South!$A$2:$B$5,2,FALSE), IFERROR(VLOOKUP(A2,West!$A$2:$B$5,2,FALSE),"Not found")))

Pra, "të lidhura me zinxhirë Formula Vlookups" kërkon në tre fletë të ndryshme sipas renditjes që i kemi futur në formulë dhe sjell përputhjen e parë që gjen:

Kështu e përdorni IFERROR me VLOOKUP në Excel. Ju falënderoj që lexoni dhe shpresoj t'ju shohnë blogun tonë javën tjetër!

Shkarkime të disponueshme

Shembuj të formulave të Excel IFERROR VLOOKUP