Opplæringen forklarer hva ISNUMBER i Excel er og gir eksempler på grunnleggende og avansert bruk.

Konseptet med ISNUMBER-funksjonen i Excel er veldig enkelt - det sjekker bare om en gitt verdi er et tall eller ikke. Et viktig poeng her er at den praktiske bruken av funksjonen går langt utover dets grunnleggende konsept, spesielt når den kombineres med andre funksjoner innenfor større formler.

Excel ISNUMBER-funksjonen

ISNUMBER-funksjonen i Excel sjekker om en celle inneholder en numerisk verdi eller ikke. Den tilhører gruppen av IS-funksjoner.

Funksjonen er tilgjengelig i alle versjoner av Excel for Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 og lavere.

ISNUMBER-syntaksen krever bare ett argument:

=ISNUMBER(value)

Hvor verdi er verdien du vil teste. Vanligvis er det representert av en cellereferanse, men du kan også angi en reell verdi eller legge en annen funksjon i ISNUMBER for å sjekke resultatet.

Hvis verdi er numerisk, returnerer funksjonen TRUE . For alt annet (tekstverdier, feil, tomrom) returnerer ISNUMBER FALSE.

La oss som et eksempel teste verdier i cellene A2 til A6, og vi vil finne ut at de tre første verdiene er tall og de to siste er tekst:

2 ting du bør vite om ISNUMBER-funksjonen i Excel

Det er et par interessante punkter å merke seg her:

• Iintern Excel-representasjon, datoer og tider er numeriske verdier, så ISNUMBER-formelen returnerer TRUE for dem (se B3 og B4 i skjermbildet ovenfor).
• For tall lagret som tekst, returnerer ISNUMBER-funksjonen FALSE (se dette eksemplet).

Excel ISNUMBER-formeleksempler

Eksemplene nedenfor viser noen få vanlige og et par ikke-trivielle bruksområder av ISNUMBER i Excel.

Sjekk om en verdi er tall

Når du har en haug med verdier i regnearket ditt og du vil vite hvilke som er tall, er ISNUMBER den riktige funksjonen å bruke .

I dette eksemplet er den første verdien i A2, så vi bruker formelen nedenfor for å sjekke den, og drar deretter ned formelen til så mange celler som nødvendig:

=ISNUMBER(A2)

Vær oppmerksom på at selv om alle verdiene ser ut som tall, har ISNUMBER-formelen returnert FALSE for cellene A4 og A5, noe som betyr at disse verdiene er numeriske strenger , dvs. tall formatert som tekst. Det kan være forskjellige årsaker til dette, for eksempel innledende nuller, foranstående apostrof osv. Uansett årsak gjenkjenner ikke Excel slike verdier som tall. Så hvis verdiene dine ikke beregner riktig, er det første du må sjekke om de virkelig er tall i form av Excel, og deretter konvertere tekst til tall om nødvendig.

Excel ISNUMBER SEARCH formel

Bortsett fra å identifisere tall, ExcelISNUMBER-funksjonen kan også sjekke om en celle inneholder spesifikk tekst som en del av innholdet. For dette, bruk ISNUMBER sammen med SEARCH-funksjonen.

I den generiske formen ser formelen slik ut:

Hvor delstreng er teksten du vil finne.

Som et eksempel, la oss sjekke om strengen i A3 inneholder en bestemt farge, si rød:

=ISNUMBER(SEARCH("red", A3))

Denne formelen fungerer bra for en enkelt celle. Men fordi prøvetabellen vår (se nedenfor) inneholder tre forskjellige farger, vil det være bortkastet tid å skrive en separat formel for hver av dem. I stedet vil vi referere til cellen som inneholder fargen av interesse (B2).

=ISNUMBER(SEARCH(B$2, $A3))

For at formelen skal kopieres korrekt nedover og til høyre, pass på å låse følgende koordinater med $-tegnet:

• I delstreng -referansen, lås raden (B$2) slik at de kopierte formlene alltid velger delstrengene i rad 2. Kolonnereferansen er relativ fordi vi vil at den skal justeres for hver kolonne, dvs. når formelen kopieres til C3, vil delstrengreferansen endres til C$2.
• I kildecelle -referansen låser du kolonnen ($A3) ) slik at alle formlene sjekker verdiene i kolonne A.

Skjermbildet nedenfor viser resultatet:

ISNUMBER FINN - skiller mellom store og små bokstaver formel

Ettersom SEARCH-funksjonen er uavhengig av store og små bokstaver , er det ovennevnteformelen skiller ikke store og små bokstaver. Hvis du leter etter en formel som skiller mellom store og små bokstaver, bruk FINN-funksjonen i stedet for SØK.

For vårt eksempeldatasett , vil formelen ha denne formen:

=ISNUMBER(FIND(B$2, $A3))

Hvordan denne formelen fungerer

Formelens logikk er ganske åpenbar og enkel å følge:

• SØK/FINN-funksjonen ser etter understrengen i den angitte cellen. Hvis delstrengen blir funnet, returneres posisjonen til det første tegnet. Hvis delstrengen ikke blir funnet, produserer funksjonen en #VERDI! feil.
• ISNUMBER-funksjonen tar den derfra og behandler numeriske posisjoner. Så hvis delstrengen blir funnet og dens posisjon returneres som et tall, gir ISNUMBER ut TRUE. Hvis delstrengen ikke blir funnet og en #VALUE! feil oppstår, ISNUMBER gir usann.

HVIS ISNUMBER-formel

Hvis du har som mål å få en formel som gir noe annet enn SANN eller USANN, bruk ISNUMBER sammen med HVIS-funksjonen.

Eksempel 1. Celle inneholder hvilken tekst

For å ta forrige eksempel videre, anta at du vil merke fargen på hvert element med "x" som vist i tabellen nedenfor.

For å få dette gjort, pakk ganske enkelt ISNUMBER SEARCH-formelen inn i IF-setningen:

=IF(ISNUMBER(SEARCH(B$2, $A3)), "x", "")

Hvis ISNUMBER returnerer TRUE, gir HVIS-funksjonen "x" (eller en annen verdi du oppgir til verdien_hvis_sann argument). Hvis ISNUMBER returnerer FALSE, sender HVIS-funksjonen ut en tom streng ("").

Eksempel 2. Det første tegnet i en celle er tall eller tekst

Tenk deg at du jobber med en liste over alfanumeriske strenger og du vil vite om det første tegnet til en streng er et tall eller en bokstav.

For å bygge en slik formel trenger vi 4 forskjellige funksjoner:

• VENSTRE-funksjonen trekker ut det første tegnet fra starten av en streng, for eksempel i celle A2:

  LEFT(A2, 1)

• Fordi LEFT tilhører kategorien tekstfunksjoner, resultatet er alltid en tekststreng, selv om den bare inneholder tall. Derfor, før vi sjekker det utpakkede tegnet, må vi prøve å konvertere det til et tall. For dette, bruk enten VERDI-funksjonen eller dobbel unær operator:

  VALUE(LEFT(A2, 1)) eller (--LEFT(A2, 1))

• ISNUMBER-funksjonen bestemmer om det utpakkede tegnet er numerisk eller ikke:

  ISNUMBER(VALUE(LEFT(A2, 1)))

• Basert på ISNUMBER-resultatet (TRUE eller FALSE), returnerer HVIS-funksjonen henholdsvis "Tall" eller "Letter".

Forutsatt at vi tester en streng i A2, den komplette formelen har denne formen:

=IF(ISNUMBER(VALUE(LEFT(A2, 1))), "Number", "Letter")

eller

=IF(ISNUMBER(--LEFT(A2, 1)), "Number", "Letter")

ISNUMBER-funksjonen er også nyttig for trekker ut tall fra en streng. Her er et eksempel: Få tall fra en hvilken som helst posisjon i en streng.

Sjekk om en verdi ikke er tall

Selv om Microsoft Excel har en spesiell funksjon, ISNONTEXT, for å bestemmeom en celles verdi ikke er tekst, mangler en analog funksjon for tall.

En enkel løsning er å bruke ISNUMBER i kombinasjon med NOT som returnerer det motsatte av en logisk verdi. Med andre ord, når ISNUMBER returnerer TRUE, NOT konverterer det til FALSE, og omvendt.

For å se det i aksjon, vennligst observer resultatene av følgende formel:

=NOT(ISNUMBER(A2))

En annen tilnærming er å bruke IF- og ISNUMBER-funksjonene sammen:

=IF(ISNUMBER(A2), "", "Not number")

Hvis A2 er numerisk, returnerer formelen ingenting (en tom streng). Hvis A2 ikke er numerisk, sier formelen det på forhånd: "Ikke tall".

Hvis du vil utføre noen beregninger med tall, sett inn en ligning eller en annen formel i verdi_hvis_sann -argumentet i stedet for en tom streng. For eksempel vil formelen nedenfor multiplisere tall med 10 og gi "Ikke tall" for ikke-numeriske verdier:

=IF(ISNUMBER(A2), A2*10, "Not number")

Sjekk om et område inneholder et tall

I situasjon når du vil teste hele området for tall, bruk ISNUMBER-funksjonen i kombinasjon med SUMPRODUKT slik:

For å finne ut om området A2:A5 for eksempel inneholder en numerisk verdi, vil formlene gå som følger:

=SUMPRODUCT(--ISNUMBER(A2:A5))>0

=SUMPRODUCT(ISNUMBER(A2:A5)*1)>0

Hvis du vil skrive ut "Ja" og "Nei" i stedet for TRUE og FALSE, bruk IF-setningen som en"wrapper" for formlene ovenfor. For eksempel:

=IF(SUMPRODUCT(--ISNUMBER(A2:A5))>0, "Yes", "No")

Hvordan denne formelen fungerer

I hjertet av formelen evaluerer ISNUMBER-funksjonen hver celle i spesifisert område, si B2:B5, og returnerer TRUE for tall, FALSE for alt annet. Siden området inneholder 4 celler, har matrisen 4 elementer:

{TRUE;FALSE;FALSE;FALSE}

Multiplikasjonsoperasjonen eller den doble unære (--) tvinger SANN og USANN til henholdsvis 1-er og 0-er:

{1;0;0;0}

SUMPRODUCT-funksjonen legger sammen elementene i matrisen. Hvis resultatet er større enn null, betyr det at det er minst ett tall i området. Så du bruker ">0" for å få et endelig resultat av SANN eller USANN.

ISNUMBER i betinget formatering for å fremheve celler som inneholder bestemt tekst

Hvis du ønsker å utheve celler eller hele rader som inneholder spesifikk tekst, lag en betinget formateringsregel basert på ISNUMBER SEARCH (uavhengig av store og små bokstaver) eller ISNUMBER FIND (skiller mellom store og små bokstaver).

For dette eksemplet skal vi fremheve rader basert på verdien i kolonne A. Mer presist vil vi fremheve elementene som inneholder ordet "rød". Slik gjør du det:

1. Velg alle dataradene (A2:C6 i dette eksemplet) eller bare kolonnen der du vil markere celler.
2. På Hjem , i Stiler -gruppen, klikk Ny regel > Bruk en formel for å bestemme hvilke celler som skal formateres .
3. Iboksen Format verdier der denne formelen er sann , skriv inn formelen nedenfor (vær oppmerksom på at kolonnekoordinaten er låst med $-tegnet):

   =ISNUMBER(SEARCH("red", $A2))

4. Klikk på Format -knappen og velg formatet du ønsker.
5. Klikk OK to ganger.

Hvis du har liten erfaring med Excel-betinget formatering, kan du finne de detaljerte trinnene med skjermbilder i denne opplæringen: Hvordan lage en formelbasert betinget formateringsregel.

Som et resultat er alle elementene i den røde fargen uthevet:

I stedet for å "hardkode" fargen i den betingede formateringsregelen, kan du skrive den inn i en forhåndsdefinert celle, si E2, og referere til den cellen i formelen din (vær oppmerksom på den absolutte cellereferansen $E$2). I tillegg må du sjekke om inndatacellen ikke er tom:

=AND(ISNUMBER(SEARCH($E$2, $A2)), $E$2"")

Som et resultat vil du få en mer fleksibel regel som fremhever rader basert på inndataene dine i E2:

Slik bruker du ISNUMBER-funksjonen i Excel. Jeg takker for at du leser og håper å se deg på bloggen vår neste uke!

Tilgjengelige nedlastinger

Excel ISNUMBER-formeleksempler