Tutorial akan mengajar anda formula yang paling berkesan kepada purata nombor, peratusan dan masa dalam Excel dan mengelakkan ralat.

Dalam Microsoft Excel, terdapat segelintir formula berbeza untuk mengira purata. Tutorial ini memfokuskan pada yang paling popular - fungsi AVERAGE.

Fungsi AVERAGE dalam Excel

Fungsi AVERAGE dalam Excel digunakan untuk mencari min aritmetik bagi nombor yang ditentukan . Sintaks adalah seperti berikut:

AVERAGE(nombor1, [nombor2], …)

Di mana nombor1, nombor2 , dsb. ialah nilai angka yang anda ingin dapatkan purata. Ia boleh dibekalkan dalam bentuk nilai angka, tatasusunan, rujukan sel atau julat. Hujah pertama diperlukan, yang berikutnya adalah pilihan. Dalam satu formula, anda boleh memasukkan sehingga 255 argumen.

AVERAGE tersedia dalam semua versi Excel 365 walaupun Excel 2007.

Fungsi AVERAGE - 6 perkara yang perlu diketahui

Untuk sebahagian besar, menggunakan fungsi AVERAGE dalam Excel adalah mudah. Walau bagaimanapun, terdapat beberapa nuansa yang perlu anda ketahui.

1. Sel dengan nilai sifar disertakan dalam purata.
2. Sel kosong diabaikan.
3. Sel yang mengandungi rentetan teks dan nilai logik TRUE dan FALSE diabaikan. Jika anda ingin memasukkan nilai Boolean dan perwakilan teks nombor dalam pengiraan, gunakan fungsi AVERAGEA.
4. Nilai BooleanPenyelesaian kepada semua masalah ini disediakan di sini: Formula Excel tidak mengira.

   Begitulah anda menggunakan fungsi AVERAGE dalam Excel untuk mencari min aritmetik. Saya mengucapkan terima kasih kerana membaca dan berharap dapat berjumpa anda di blog kami minggu hadapan!

   Amalkan buku kerja untuk muat turun

   Formula PURATA dalam Excel - contoh (fail .xlsx)

   ditaip terus dalam formula dikira. Sebagai contoh, formula AVERAGE(TRUE, FALSE) mengembalikan 0.5, iaitu purata 1 dan 0.
5. Jika argumen yang ditentukan tidak mengandungi satu nilai angka yang sah, #DIV/0! ralat berlaku.
6. Argumen yang nilai ralat menyebabkan formula AVERAGE mengembalikan ralat. Untuk mengelakkan perkara ini, sila lihat cara purata mengabaikan ralat.

Nota. Apabila menggunakan fungsi AVERAGE dalam helaian Excel anda, sila ingat perbezaan antara sel dengan nilai sifar dan sel kosong - 0's dikira, tetapi sel kosong tidak. Ini mungkin mengelirukan terutamanya jika pilihan " Tunjukkan sifar dalam sel yang mempunyai nilai sifar " dinyahtandai dalam lembaran kerja yang diberikan. Anda boleh menemui pilihan ini di bawah Pilihan Excel > Terperinci > Pilihan paparan untuk lembaran kerja ini .

Formula PURATA Excel

Untuk membina formula asas Excel untuk purata, anda hanya perlu membekalkan nilai sumber. Ini boleh dilakukan dalam beberapa cara yang berbeza.

Untuk mengira purata nombor tertentu, anda boleh menaipnya terus dalam formula. Sebagai contoh, untuk purata nombor 1,2,3 dan 4, formulanya ialah:

=AVERAGE(1,2,3,4)

Untuk purata lajur dalam Excel, bekalkan keseluruhan- rujukan lajur:

=AVERAGE(A:A)

Untuk purata baris , gunakan rujukan seluruh baris:

=AVERAGE(1:1)

Untuk purata julat sel , nyatakanjulat itu dalam formula anda:

=AVERAGE(A1:C20)

Untuk mengembalikan min sel bukan bersebelahan , setiap rujukan sel hendaklah dibekalkan secara individu:

=AVERAGE(A1, C1, D1)

Untuk purata berbilang julat , gunakan beberapa rujukan julat dalam satu formula:

=AVERAGE(A1:A20, C1:D10)

Dan secara semulajadi, tiada apa yang menghalang anda daripada memasukkan nilai, sel dan julat rujukan dalam formula yang sama seperti yang diperlukan oleh logik perniagaan anda. Contohnya:

=AVERAGE(B3:B5, D7:D9, E11, 100)

Dan berikut ialah senario kehidupan sebenar. Dalam set data di bawah, kami menggunakan 3 formula berbeza untuk mengira purata - dalam keseluruhan julat, dalam setiap baris dan dalam setiap lajur:

Cara menggunakan fungsi AVERAGE dalam Excel - contoh

Selain daripada nombor, Excel AVERAGE boleh mencari min aritmetik bagi nilai angka lain seperti peratusan dan masa, seperti yang ditunjukkan dalam contoh berikut.

Kira peratusan purata dalam Excel

Untuk mendapatkan purata peratusan, anda menggunakan formula Excel biasa untuk purata. Perkara utama ialah menetapkan format Peratusan untuk sel formula.

Contohnya, untuk mengira purata peratusan dalam sel C2 hingga C11, formulanya ialah:

=AVERAGE(C2:C11)

Dapatkan purata masa dalam Excel

Mengira unit masa yang berbeza secara manual, akan menjadi sangat menyakitkan... Nasib baik, fungsi Excel AVERAGE mengatasi masa dengan sempurna. Untuk purata masa dipaparkan dengan betul, cuma ingat untuk menggunakan format masa yang sesuai pada formulasel.

Contohnya, untuk mencari purata masa dalam set data di bawah, formulanya ialah:

=AVERAGE(B3:B13)

Purata Excel tanpa sifar

Excel Fungsi AVERAGE melangkau sel kosong, teks dan nilai logik, tetapi bukan sifar. Dalam imej di bawah, perhatikan bahawa purata dalam sel E4, E5 dan E6 adalah sama seperti dalam E3 sebagai sel kosong dan nilai tidak sah dalam lajur C diabaikan dan hanya nombor dalam lajur B dan D diproses. Walau bagaimanapun, nilai sifar dalam C7 termasuk dalam purata dalam E7, kerana ia adalah nilai angka yang sah.

Untuk mengecualikan sifar, gunakan fungsi AVERAGEIF atau AVERAGEIFS sebaliknya. Contohnya:

=AVERAGEIF(B3:D3, "0")

Purata nilai N atas atau bawah

Untuk mendapatkan purata nilai 3, 5, 10 atau n teratas dalam julat, gunakan AVERAGE dalam kombinasi dengan fungsi LARGE:

AVERAGE(LARGE( julat , {1,2,3, …, n}))

Contohnya, untuk mendapatkan purata 3 nombor terbesar dalam B3:B11, formulanya ialah:

=AVERAGE(LARGE(B3:B11, {1,2,3}))

Untuk mengira min nilai 3, 5, 10 atau n bawah dalam julat, gunakan AVERAGE bersama-sama dengan fungsi SMALL:

AVERAGE(SMALL( julat , {1,2,3, …, n}))

Sebagai contoh, untuk purata 3 nombor terendah dalam julat, formulanya adalah seperti berikut:

=AVERAGE(SMALL (B3:B11, {1,2,3}))

Dan berikut ialah hasilnya:

Cara formula ini berfungsi :

Biasanya, fungsi LARGE menentukan nilai terbesar ke-N dalam tatasusunan tertentu. Untuk mendapatkan nilai n teratas, tatasusunanpemalar seperti {1,2,3} digunakan untuk hujah kedua.

Dalam kes kami, LARGE mengembalikan 3 nilai tertinggi dalam julat, iaitu 94, 93 dan 90. AVERAGE mengambilnya dari sana dan mengeluarkan min.

Gabungan AVERAGE SMALL berfungsi dengan cara yang sama.

Formula PURATA JIKA dalam Excel

Untuk mengira purata dengan syarat, anda boleh memanfaatkan AVERAGEIF atau AVERAGEIFS dalam Excel 2007 - 365. Dalam versi terdahulu, anda boleh membina formula AVERAGE IF anda sendiri.

PURATA IF dengan satu syarat

Untuk purata nombor yang memenuhi syarat tertentu, gunakan formula generik ini:

PURATA(JIKA( julat_kriteria = kriteria , julat_purata ))

Dalam Excel 2019 dan lebih rendah, ini hanya berfungsi sebagai formula tatasusunan, bermakna anda perlu menekan kekunci Ctrl + Shift + Enter untuk melengkapkannya dengan betul. Dalam Excel 365 dan 2021, formula biasa akan berfungsi dengan baik.

Sebagai contoh, mari cari purata skor Matematik dalam jadual di bawah. Untuk ini, hanya gunakan "Math" untuk kriteria:

=AVERAGE(IF(C3:C11="Math", B3:B11))

Atau anda boleh memasukkan keadaan dalam beberapa sel dan merujuk sel tersebut (F2 dalam kes kami):

=AVERAGE(IF(C3:C11=F2, B3:B11))))

Cara formula ini berfungsi

Ujian logik fungsi IF membandingkan setiap subjek dalam C3:C11 dengan sasaran satu dalam F2. Hasil perbandingan ialah tatasusunan nilai TRUE dan FALSE, dengan TRUE mewakili padanan:

{FALSE;FALSE;FALSE;TRUE;TRUE;FALSE;FALSE;TRUE;FALSE}

Untuk argumen value_ if_true , kamimembekalkan julat markah (B3:B11), jadi jika ujian logik adalah BENAR, skor yang sepadan dikembalikan. Oleh kerana argumen value_ if_false ditinggalkan, FALSE muncul apabila syarat tidak dipenuhi:

{FALSE;FALSE;FALSE;74;67;FALSE;FALSE;59;FALSE}

Tatasusunan ini disalurkan kepada fungsi AVERAGE, yang mengira min aritmetik daripada nombor yang mengabaikan nilai FALSE.

PURATA JIKA dengan berbilang kriteria

Untuk purata nombor dengan beberapa kriteria, formula generik ialah:

PURATA(JIKA(( kriteria_julat1 = kriteria1 ) * ( kriteria_julat2 = kriteria2 ), purata_julat ))

Contohnya, kepada purata markah Matematik dalam kelas A, anda boleh menggunakan formula ini:

=AVERAGE(IF((C3:C11="Math") * (D3:D11="A"), B3:B11))

Dengan rujukan sel untuk kriteria, ini berfungsi dengan baik:

=AVERAGE(IF((C3:C11=G2) * (D3:D11=G3), B3:B11))

Dalam Excel 2019 dan lebih rendah, kedua-dua perkara di atas mestilah formula tatasusunan, jadi ingat untuk menekan Ctrl + Shift + Enter untuk mendapatkan hasil yang tepat. Dalam Excel 365 dan 2021, kunci Enter biasa akan berfungsi dengan baik kerana sokongan terbina untuk tatasusunan dinamik.

Hasil yang sama boleh dicapai dengan bantuan pernyataan IF bersarang:

=AVERAGE(IF(C3:C11=G2, IF(D3:D11=G3, B3:B11)))

Formula mana yang hendak digunakan hanyalah soal pilihan peribadi anda.

Cara formula ini berfungsi

Dalam ujian logik IF, dua operasi perbandingan dilakukan - pertama, anda menyemak senarai subjek dalam C3:C11 berbanding nilai dalam G2, dan kemudian anda membandingkan kelas dalam D3:D11 dengannilai dalam G3. Dua tatasusunan nilai TRUE dan FALSE didarabkan dan operasi pendaraban berfungsi seperti operator AND. Dalam mana-mana operasi aritmetik, TRUE bersamaan dengan 1 dan FALSE bersamaan dengan 0. Darab dengan 0 sentiasa memberikan sifar, jadi tatasusunan yang terhasil mempunyai 1 hanya apabila kedua-dua keadaan adalah BENAR. Tatasusunan ini dinilai dalam ujian logik fungsi IF, yang mengembalikan markah yang sepadan dengan 1's (TRUE):

{FALSE;FALSE;FALSE;74;67;FALSE;FALSE;FALSE;FALSE}

Tatasusunan akhir ini disampaikan kepada AVERAGE.

Cara untuk membundarkan purata dalam Excel

Sekiranya anda ingin membundarkan hanya purata yang dipaparkan tanpa mengubah nilai asas, gunakan Penurunan Perpuluhan perintah pada reben atau kotak dialog Format Sel seperti yang dijelaskan dalam Cara untuk membundarkan purata dalam Excel.

Untuk membundarkan nilai yang dikira itu sendiri, gabungkan AVERAGE dengan salah satu fungsi pembundaran Excel.

Untuk mengikut peraturan matematik am untuk pembundaran, sarang AVERAGE dalam fungsi ROUND. Dalam hujah ke-2 ( num_digit ), tentukan bilangan digit untuk membundarkan purata kepada.

Contohnya, untuk membundarkan purata kepada integer terdekat , gunakan formula ini:

=ROUND(AVERAGE(B3:B11), 0)

Untuk membundarkan purata kepada satu tempat perpuluhan , gunakan 1 untuk argumen num_digits :

=ROUND(AVERAGE(B3:B11), 1)

Untuk membundarkan purata kepada dua tempat perpuluhan , gunakan 2 untuk argumen num_digits :

=ROUND(AVERAGE(B3:B11), 2)

Dan seterusnya pada.

Untukmembundar ke atas, gunakan fungsi ROUNDUP:

=ROUNDUP(AVERAGE(B3:B11), 1)

Untuk membundar ke bawah, ROUNDDOWN ialah fungsi untuk digunakan:

=ROUNDDOWN(AVERAGE(B3:B11), 1)

Membetulkan #DIV/0 ralat dalam Excel AVERAGE

Jika julat sel yang anda cuba kira tidak mempunyai nilai berangka, formula AVERAGE akan mengembalikan ralat bahagi dengan sifar (#DIV/0!). Untuk membetulkannya, anda boleh mendapatkan jumlah nilai berangka dengan fungsi COUNT dan jika kiraan lebih besar daripada 0, maka purata; sebaliknya - kembalikan rentetan kosong.

IF(COUNT( julat )>0, PURATA( julat ), "")

Contohnya, untuk mengelakkan # Ralat DIV/0 dengan purata dalam set data di bawah, gunakan formula ini:

=IF(COUNT(B6:B16)>0, AVERAGE(B6:B16), "")

Purata dan abaikan ralat

Apabila cuba purata julat sel yang mempunyai sebarang ralat, hasilnya akan menjadi ralat. Untuk mengelakkan perkara ini daripada berlaku, gunakan salah satu daripada penyelesaian berikut.

PURATA dan IFERROR

Sebelum membuat purata, tapis ralat dengan bantuan fungsi IFERROR:

AVERAGE(IFERROR( julat ,""))

Dalam semua versi kecuali Excel 365 dan 2021 yang tatasusunan dikendalikan secara asli, tekan kekunci Ctrl + Shift + Enter bersama-sama untuk menjadikannya formula tatasusunan.

Contohnya, untuk purata julat sel di bawah tanpa ralat, formulanya ialah:

=AVERAGE(IFERROR(B3:B13, ""))

Fungsi AGREGAT

Satu lagi cara mudah untuk purata mengabaikan ralat ialah menggunakan fungsi AGREGAT. Untuk mengkonfigurasi AGREGATE untuk tujuan ini, anda menetapkan function_num argumen kepada 1 (fungsi AVERAGE) dan argumen options kepada 6 (abaikan nilai ralat).

Contohnya:

=AGGREGATE(1, 6, B3:B13)

Seperti yang anda boleh lihat dalam tangkapan skrin, kedua-dua fungsi berfungsi dengan baik:

Excel AVERAGE tidak berfungsi

Jika anda menghadapi masalah dengan formula AVERAGE dalam Excel, penyelesaian masalah kami petua akan membantu anda menyelesaikannya dengan cepat.

Nombor yang diformatkan sebagai teks

Jika julat yang anda cuba purata tidak mempunyai nilai angka tunggal, ralat #DIV/0 berlaku. Ini sering berlaku apabila nombor diformatkan sebagai teks. Untuk membetulkan ralat, cuma tukar teks kepada nombor.

Segitiga hijau kecil di penjuru kiri sebelah atas sel ialah petunjuk yang jelas bagi kes ini:

Nilai ralat dalam sel yang dirujuk

Jika formula AVERAGE merujuk kepada sel yang mengandungi beberapa ralat, sebut #VALUE!, formula akan menghasilkan ralat yang sama. Untuk menyelesaikan masalah ini, gunakan gabungan AVERAGE bersama-sama dengan IFERROR atau fungsi AGGREGATE seperti yang diterangkan dalam contoh ini. Atau gantikan ralat nilai dalam data sumber dengan beberapa teks jika berkenaan.

Formula PURATA muncul dalam sel dan bukannya hasil

Jika sel anda memaparkan formula dan bukannya formula jawab, maka kemungkinan besar mod Tunjukkan Formula dihidupkan dalam lembaran kerja anda. Sebab lain boleh jadi formula yang dimasukkan sebagai teks, dengan ruang depan atau apostrof sebelum tanda sama.