Iako se broj riječi i znakova u Google tablicama koristi u rijetkim slučajevima, to je još uvijek funkcija koju neki od nas očekuju vidjeti upravo u izborniku. Ali za razliku od Google dokumenata, za Google tablice to radi funkcija LEN.

Iako postoji mnogo različitih načina za brojanje znakova u proračunskim tablicama, današnji blog će pokriti funkciju LEN kao glavna svrha u tablicama je – pa, brojanje :) Međutim, rijetko se ikada koristi samostalno. U nastavku ćete naučiti kako pravilno koristiti LEN Google tablica i pronaći najtraženije formule za izračunavanje znakova u proračunskim tablicama.

Funkcija LEN Google tablica – upotreba i sintaksa

The Glavna i jedina svrha funkcije LEN u Google tablicama je dobivanje duljine niza. Toliko je jednostavan da čak zahtijeva samo 1 argument:

• može uzeti ili sam tekst u dvostrukim navodnicima:

  =LEN("Yggdrasil")

• ili referenca na ćeliju s tekstom od interesa:

  =LEN(A2)

Da vidimo postoje li neke osobitosti u korištenju funkcije u proračunskim tablicama.

Znak brojanje u Google tablicama

Počet ću s najjednostavnijom operacijom: izvršite brojanje znakova u Google tablicama na najčešći način – upućivanjem na ćeliju s tekstom pomoću funkcije LEN.

I unesite formulu u B2 i kopirajte je niz cijeli stupac kako biste izbrojali znakove u svakom retku:

=LEN(A2)

Napomena. Funkcija LENizračunava sve znakove: slova, brojke, razmake, interpunkcijske znakove itd.

Možda mislite da biste na sličan način mogli napraviti broj znakova za cijeli raspon ćelija, ovako: LEN(A2:A6) . Ali, kao koliko god bizarno bilo, ne radi jednostavno na ovaj način.

Da biste zbrojili znakove u nekoliko ćelija, trebali biste svoj LEN zamotati u SUMPRODUCT – funkciju koja zbraja brojeve iz unesenih raspona. U mom slučaju, raspon vraća funkcija LEN:

=SUMPRODUCT(LEN(A2:A6))

Naravno, umjesto toga možete uključiti funkciju SUM. Ali SUM u Google tablicama ne obrađuje nizove iz drugih funkcija. Da bi funkcioniralo, morat ćete dodati još jednu funkciju – ArrayFormula:

=ArrayFormula(SUM(LEN(A2:A6)))

Kako brojati znakove bez razmaka u Google tablicama

Kao što sam gore napomenuo, Google tablice Funkcija LEN broji svaki znak koji vidi uključujući razmake.

Ali što ako postoje dodatni razmaci dodani greškom i ne želite ih uzeti u obzir za rezultat?

Za slučajeve kao što su ovo, postoji funkcija TRIM u Google tablicama. Provjerava ima li teksta na početku, na kraju i ponovljenih razmaka između. Kada je TRIM uparen s LEN-om, potonji ne broji sve te neparne razmake.

Evo primjera. Dodao sam razmake na različitim pozicijama u stupcu A. Kao što vidite, kada je sam, Google Sheets LEN ih sve broji:

=LEN(A2)

Ali čim integrirate TRIM, sve dodatno prostori suignorirano:

=LEN(TRIM(A2))

Možete ići dalje i učiniti da vaša formula zanemari čak i one pojedinačne razmake između riječi. Pomoći će vam funkcija SUBSTITUTE. Iako mu je glavna svrha zamijeniti jedan znak drugim, postoji trik za potpuno smanjenje razmaka:

• text_to_search je raspon s kojim radite: stupac A, ili A2 da budemo točni.
• search_for trebao bi biti znak razmaka u dvostrukim navodnicima: " "
• replace_with treba sadržavati prazne dvostruke navodnike. Ako namjeravate ignorirati razmake, trebate ih zamijeniti doslovno ničim (prazan niz): ""
• occurence_number obično se koristi za određivanje instance zamijeniti. Ali budući da opisujem kako brojati znakove bez razmaka, predlažem da izostavite ovaj argument jer nije obavezan.

Sada pokušajte sastaviti sve ovo u Google tablice LEN i vidjet ćete da razmak se ne uzima u obzir:

=LEN(SUBSTITUTE(A2, " ", ""))

Google tablice: broji određene znakove

Isti tandem Google tablica LEN i SUBSTITUTE koristi se kad god trebate brojati određene znakove , slova ili brojke.

U svojim primjerima, saznat ću broj pojavljivanja slova 's'. I ovaj put ću započeti sa već pripremljenom formulom:

=LEN(A2)-LEN(SUBSTITUTE(A2, "s", ""))

Razložimo je na dijelove da bismo razumjeli kakoradi:

1. SUBSTITUTE(A2, "s", "") traži slovo 's' u A2 i zamjenjuje sva pojavljivanja s "ništa" ili praznim nizom ( "").
2. LEN(SUBSTITUTE(A2, "s", "") izračunava broj svih znakova osim 's' u A2.
3. LEN(A2) broji sve znakove u A2.
4. Na kraju, oduzimate jedan od drugog.

Razlika rezultata pokazuje koliko 's' ima u ćeliji:

Napomena. Možda se pitate zašto B1 kaže da postoji samo 1 's' u A2 dok možete vidjeti 3?

Stvar je u tome što funkcija SUBSTITUTE razlikuje velika i mala slova. Zamolio sam ga da uzme sve instance 's' malim slovima i tako je i učinio.

Da bi ignorirao velika i mala slova teksta i obrađivao slova i malim i velikim slovima, morat ćete pozvati još jednu funkciju Google tablica za pomoć: LOWER.

Savjet. Pogledajte druge načine za promjenu veličine teksta u Google tablicama.

Jednostavan je kao Google tablice LEN i TRIM jer sve što zahtijeva je tekst:

=LOWER(text)

I sve što radi je pretvara cijeli tekstualni niz u int o mala slova. Ovaj trik je upravo ono što vam je potrebno da Google tablice broje određene znakove bez obzira na veličinu teksta:

=LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "s", ""))

Savjet. I kao i prije, da biste prebrojali ukupan broj određenih znakova u rasponu, zamotajte svoj LEN u SUMPRODUCT:

=SUMPRODUCT(LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "s", "")))

Broj riječi u Google tablicama

Kada tamo su više riječi u ćelijama, vjerojatno ćete morati imati njihov broj umjestoduljina niza Google tablica.

I iako postoji više načina za to, danas ću spomenuti kako Google tablice LEN obavljaju posao.

Sjetite se formule koju sam koristio za brojanje određenih znakova u Google tablice? Dapače, i ovdje će dobro doći. Jer neću doslovno brojati riječi. Umjesto toga, brojat ću razmake između riječi i zatim jednostavno dodati 1. Pogledajte:

=LEN(A2)-LEN(SUBSTITUTE((A2), " ", ""))+1

1. LEN(A2) broji broj svih znakova u ćeliji.
2. LEN(SUBSTITUTE((A2)," ","")) uklanja sve razmake iz tekstualnog niza i broji preostale znakove.
3. Zatim oduzmete jedan od drugog, a razlika koju dobijete je broj razmaka u ćeliji.
4. Budući da riječi uvijek premašuju razmake u rečenici za jedan, dodajete 1 na kraju.

Google tablice: brojite određene riječi

Na kraju, želio bih podijeliti formulu Google tablica koju možete koristiti za brojanje određenih riječi.

Ovdje imam pjesmu lažne kornjače iz Alicinih avantura u zemlji čudesa:

Želim znati koliko se puta riječ 'će' pojavljuje u svakom retku. Vjerujem da se nećete iznenaditi ako vam kažem da se formula koju trebam sastoji od istih funkcija kao i prije: Google tablice LEN, SUBSTITUTE i LOWER:

=(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "will", "")))/LEN("will")

Formula može izgleda zastrašujuće, ali uvjeravam vas da je lako razumjeti, stoga strpite se sa mnom :)

1. Budući da velika i mala slova u tekstu nisubitno mi je, koristim LOWER(A2) da sve pretvorim u mala slova.
2. Onda ide ZAMJENA(LOWER(A2), "će",""))) – rješava se svih pojavljivanja 'will' zamjenjujući ih praznim nizovima ("").
3. Nakon toga, oduzimam broj znakova bez riječi 'will' od ukupne duljine niza . Broj koji dobijem broji sve znakove u svim pojavljivanjima 'will' u svakom retku.

   Dakle, ako se 'will' pojavi jednom, broj je 4 jer riječ ima 4 slova. Ako se pojavi dva puta, broj je 8, i tako dalje.

4. Na kraju, dijelim ovaj broj s duljinom jedne riječi 'will'.

Savjet. I opet, ako biste radije dobili ukupan broj svih pojavljivanja riječi 'will', samo priložite cijelu formulu SUMPRODUCT:

=SUMPRODUCT((LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "will", "")))/LEN("will"))

Kao što vidite , svi ti slučajevi brojanja znakova rješavaju se istim obrascima istih funkcija za Google tablice: LEN, SUBSTITUTE, LOWER i SUMPRODUCT.

Ako vas neke formule i dalje zbunjuju ili ako niste znate kako sve primijeniti na svoj zadatak, nemojte se sramiti i pitajte u odjeljku s komentarima u nastavku!