Sadržaj
Udžbenik objašnjava kako brojati riječi u programu Excel pomoću funkcije LEN u kombinaciji s drugim funkcijama programa Excel i nudi formule koje razlikuju velika i mala slova za brojanje ukupnih ili određenih riječi/teksta u ćeliji ili rasponu .
Microsoft Excel ima pregršt korisnih funkcija koje mogu brojati gotovo sve: funkcija COUNT za brojanje ćelija s brojevima, COUNTA za brojanje ćelija koje nisu prazne, COUNTIF i COUNTIFS za uvjetno brojanje ćelija i LEN za izračunavanje duljine tekstualnog niza.
Nažalost, Excel ne nudi nikakav ugrađeni alat za brojanje broja riječi. Srećom, kombiniranjem serval funkcija možete napraviti složenije formule za postizanje gotovo bilo kojeg zadatka. I koristit ćemo ovaj pristup za prebrojavanje riječi u Excelu.
Kako prebrojati ukupan broj riječi u ćeliji
Da prebrojite riječi u ćeliji, upotrijebite sljedeća kombinacija funkcija LEN, SUBSTITUTE i TRIM:
LEN(TRIM( cell))-LEN(SUBSTITUTE( cell," ",""))+1Gdje je ćelija adresa ćelije u kojoj želite brojati riječi.
Na primjer, za brojanje riječi u ćeliji A2 upotrijebite ovu formulu:
=LEN(TRIM(A2))-LEN(SUBSTITUTE(A2," ",""))+1
A zatim možete kopirati formulu kako biste brojali riječi u drugim ćelijama stupca A:
Kako funkcionira ova formula za brojanje riječi
Prvo koristite funkciju SUBSTITUTE kako biste uklonili sve razmake u ćeliji tako da ih zamijenite praznim tekstomstring ("") za funkciju LEN koja vraća duljinu niza bez razmaka:
LEN(SUBSTITUTE(A2," ",""))
Nakon toga oduzimate duljinu niza bez razmaka od ukupne duljine niza, i dodajte 1 konačnom broju riječi, jer je broj riječi u ćeliji jednak broju razmaka plus 1.
Osim toga, koristite funkciju TRIM za uklanjanje dodatnih razmaka u ćeliji, ako ih ima. Ponekad radni list može sadržavati mnogo nevidljivih razmaka, na primjer dva ili više razmaka između riječi ili znakova razmaka koji su slučajno upisani na početku ili kraju teksta (tj. razmaci na početku i na kraju). A svi ti dodatni razmaci mogu vam poremetiti broj riječi. Kako bismo se zaštitili od toga, prije izračunavanja ukupne duljine niza koristimo funkciju TRIM za uklanjanje svih suvišnih razmaka osim pojedinačnih razmaka između riječi.
Poboljšana formula koja ispravno obrađuje prazne ćelije
Gornja formula za brojanje riječi u Excelu mogla bi se nazvati savršenom da nema jednog nedostatka - vraća 1 za prazne ćelije. Da biste to popravili, možete dodati naredbu IF za provjeru praznih ćelija:
=IF(A2="", 0, LEN(TRIM(A2))-LEN(SUBSTITUTE(A2," ",""))+1)
Kao što možete vidjeti na gornjoj snimci zaslona, formula vraća nula za prazne ćelije i točan broj riječi za ćelije koje nisu prazne.
Kako brojati određene riječi u ćeliji
Za brojanje koliko se puta pojavljuje određena riječ, tekst ili podniz u ćeliji upotrijebite sljedećeformula:
=(LEN( cell )-LEN(SUBSTITUTE( cell , word ,"")))/LEN( word )
Na primjer, izračunajmo broj pojavljivanja " mjesec " u ćeliji A2:
=(LEN(A2)-LEN(SUBSTITUTE(A2, "moon","")))/LEN("moon")
Umjesto unosa riječi koja se broji izravno u formulu, možete je upisati u neku ćeliju i referencirati tu ćeliju u svojoj formuli. Kao rezultat, dobit ćete svestraniju formulu za brojanje riječi u Excelu.
Savjet. Ako planirate kopirati svoju formulu u više ćelija, svakako popravite referencu na ćeliju koja sadrži riječ za brojanje znakom $. Na primjer:
=(LEN(A2)-LEN(SUBSTITUTE(A2, $B$1,"")))/LEN($B$1)
Kako ova formula broji pojavljivanja određenog teksta u ćeliji
- Funkcija SUBSTITUTE uklanja navedene riječ iz izvornog teksta.
U ovom primjeru uklanjamo unos riječi u ćeliju B1 iz izvornog teksta koji se nalazi u A2:
SUBSTITUTE(A2, $B$1,"")
U ovom primjeru, LEN(SUBSTITUTE(A2, $B$1,"")) vraća duljinu teksta u ćeliji A2 nakon uklanjanja svih znakova sadržanih u svim pojavljivanjima riječi " mjesec ".
(LEN(A2)-LEN(SUBSTITUTE(A2, $B$1,"")))
Rezultat ovog operacija je broj znakova sadržanih u svim pojavljivanjima ciljne riječi, što je 12 u ovom primjeru (3 pojavljivanja riječi " mjesec ", po 4 znaka).
Osim brojanja određenih riječi u ćeliji, ovu formulu možete koristiti za brojanje pojavljivanja bilo kojeg tekst (podniz). Na primjer, možete izbrojati koliko se puta tekst " odaberi " pojavljuje u ćeliji A2:
Formula koja razlikuje velika i mala slova za brojanje određenih riječi u ćelija
Kao što vjerojatno znate, Excel SUBSTITUTE je funkcija koja razlikuje velika i mala slova, pa je stoga formula za brojanje riječi temeljena na SUBSTITUTE prema zadanim postavkama osjetljiva na velika i mala slova:
Formula koja ne razlikuje velika i mala slova za brojanje određenih riječi u ćeliji
Ako trebate brojati pojavljivanja i velikih i malih slova u datoj riječi, upotrijebite funkciju UPPER ili LOWER unutar SUBSTITUTE za pretvaranje izvornog teksta i tekst koji želite računati na ista velika i mala slova.
=(LEN( cell )-LEN(SUBSTITUTE(UPPER( cell ),UPPER( text ),"")))/LEN( tekst )Ili
=(LEN( cell )-LEN(SUBSTITUTE(LOWER( cell ),LOWER( tekst ),"")))/LEN( tekst )Na primjer, za brojanje broja pojavljivanja riječi u B1 unutar ćelije A2 ignorirajući velika i mala slova, koristite ovu formulu:
=(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2),LOWER($B$1),"")))/LEN($B$1)
Kao što je prikazano u nastavkusnimak zaslona, formula vraća isti broj riječi bez obzira na to je li riječ upisana VELIKIM SLOVIMA (ćelija B1), malim slovima (ćelija D1) ili velikim slovima (ćelija C1):
Izbrojite ukupan broj riječi u rasponu
Da biste saznali koliko riječi sadrži određeni raspon, uzmite formulu koja broji ukupan broj riječi u ćeliji i ugradite je unutar funkcije SUMPRODUCT ili SUM:
=SUMPRODUCT(LEN(TRIM( raspon ))-LEN(ZAMJENA( raspon ," ",""))+1)Ili
=SUM(LEN (TRIM( range ))-LEN(SUBSTITUTE( range ," ",""))+1)SUMPRODUCT jedna je od nekoliko Excel funkcija koje mogu rukovati nizovima, a formulu dovršavate na uobičajeni način pritiskom na tipku Enter.
Da bi funkcija SUM izračunala nizove, trebala bi se koristiti u formuli polja koja se dovršava pritiskom na Ctrl+Shift+Enter umjesto uobičajeni potez Enter.
Na primjer, za brojanje svih riječi u rasponu A2:A4, upotrijebite jednu od sljedećih formula:
=SUMPRODUCT(LEN(TRIM(A2:A4))-LEN(SUBSTITUTE(A2:A4," ",""))+1)
=SUM(LEN(TRIM(A2:A4))-LEN(SUBSTITUTE(A2:A4," ",""))+1)
Prebrojite određene riječi u ra nge
Ako želite izbrojati koliko se puta određena riječ ili tekst pojavljuje unutar raspona ćelija, upotrijebite sličan pristup - uzmite formulu za brojanje određenih riječi u ćeliji i kombinirajte je sa SUM ili Funkcija SUMPRODUCT:
=SUMPRODUCT((LEN( raspon )-LEN(ZAMJENA( raspon , riječ ,"")/LEN( riječ ))Ili
=SUM((LEN( raspon )-LEN(ZAMJENA( raspon , riječ ,"")))/LEN( riječ ))Ne zaboravite pritisnuti Ctrl+Shift+Enter kako biste ispravno dovršili formulu polja SUM.
Na primjer, za brojanje svih pojavljivanja riječi unesene u ćeliju C1 unutar raspona A2:A4, koristite ovu formulu:
=SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE(A2:A4, C1,"")))/LEN(C1))
Kao što zapamtite, SUBSTITUTE je funkcija osjetljiva na velika i mala slova i stoga gornja formula razlikuje tekst napisan velikim i malim slovima:
Da biste napravili formulu neosjetljivo na velika i mala slova , koristite funkciju UPPER ili LOWER:
=SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE((UPPER(A2:A4)),UPPER(C1),"")))/LEN(C1))
Ili
=SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE((LOWER(A2:A4)),LOWER(C1),"")))/LEN(C1))
Ovako se broje riječi u Excelu. Da biste bolje razumjeli i vjerojatno izvršili obrnuti inženjering formula, dobrodošli ste preuzeti oglednu radnu knjigu Excel Count Words.
Ako nijedna od formula o kojima se govori u ovom vodiču nije riješila vaš zadatak, pogledajte sljedeći popis resursi koji pokazuju druga rješenja za brojanje ćelija, teksta i pojedinačnih znakova u Excelu.
