El tutorial explica cómo buscar duplicados en Excel. Aprenderá algunas fórmulas para identificar valores duplicados o encontrar filas duplicadas con o sin las primeras ocurrencias. También aprenderá cómo contar instancias de cada registro duplicado individualmente y encontrar el número total de duplicados en una columna, cómo filtrar duplicados y más.

Al trabajar con una hoja de cálculo de Excel de gran tamaño o al consolidar varias hojas de cálculo pequeñas en una más grande, es posible que encuentre muchas filas duplicadas en ella. En uno de nuestros tutoriales anteriores, analizamos varias formas de comparar dos tablas o columnas en busca de duplicados.

Y hoy, me gustaría compartir algunos métodos rápidos y eficaces para identificar duplicados en una sola lista. Estas soluciones funcionan en todas las versiones de Excel 365, Excel 2021, Excel 2019, Excel 2016, Excel 2013 e inferiores.

Cómo identificar duplicados en Excel

La forma más sencilla de detectar duplicados en Excel es utilizando la función COUNTIF. Dependiendo de si desea encontrar valores duplicados con o sin primera ocurrencia, va a haber una ligera variación en la fórmula como se muestra en los siguientes ejemplos.

Cómo encontrar registros duplicados, incluidas las primeras ocurrencias

Supongamos que tiene una lista de elementos en la columna A que desea comprobar si hay duplicados. Pueden ser facturas, Id. de productos, nombres o cualquier otro dato.

He aquí una fórmula para encontrar duplicados en Excel incluyendo las primeras ocurrencias (donde A2 es la celda superior):

=COUNTIF(A:A, A2)>1

Introduce la fórmula anterior en B2, luego selecciona B2 y arrastra el manejador de relleno para copiar la fórmula a otras celdas:

Como puede ver en la captura de pantalla anterior, la fórmula devuelve TRUE para valores duplicados y FALSE para valores únicos.

Nota: Si necesita encontrar duplicados en un archivo rango de celdas en lugar de en toda una columna, recuerde bloquear ese rango con el signo $. Por ejemplo, para buscar duplicados en las celdas A2:A8, utilice esta fórmula:

=COUNTIF( $A$2:$A$8 , A2)>1

Para que una fórmula duplicada devuelva algo más significativo que los valores booleanos de TRUE y FALSE, enciérrela en la función IF y escriba las etiquetas que desee para los valores duplicados y únicos:

=IF(COUNTIF($A$2:$A$8, $A2)>1, "Duplicado", "Único")

En caso de que desee una fórmula de Excel que sólo encuentre duplicados, sustituya "Único" por una cadena vacía ("") de la siguiente manera:

=IF(COUNTIF($A$2:$A$8, $A2)>1, "Duplicado", "")

La fórmula devolverá "Duplicados" para los registros duplicados, y una celda en blanco para los registros únicos:

Cómo buscar duplicados en Excel sin 1ª ocurrencia

En caso de que quiera filtrar o eliminar duplicados después de encontrarlos, utilizar la fórmula anterior no es seguro porque marca todos los registros idénticos como duplicados. Y si quiere mantener los valores únicos en su lista, entonces no puede eliminar todos los registros duplicados, sólo necesita eliminar la 2ª instancia y todas las subsiguientes.

Así pues, modifiquemos nuestra fórmula duplicada de Excel utilizando referencias de celda absolutas y relativas cuando proceda:

=IF(COUNTIF($A$2:$A2, $A2)>1, "Duplicado", "")

Como puede ver en la siguiente captura de pantalla, esta fórmula no identifica la primera aparición de " Manzanas "como duplicado:

Cómo encontrar duplicados con distinción entre mayúsculas y minúsculas en Excel

En situaciones en las que necesite identificar duplicados exactos, incluida la caja de texto, utilice esta fórmula de matriz genérica (que se introduce pulsando Ctrl + Mayús + Intro ):

En el núcleo de la fórmula, se utiliza la función EXACT para comparar exactamente la celda de destino con cada celda del rango especificado. El resultado de esta operación es una matriz de TRUE (coincidencia) y FALSE (no coincidencia), que se convierte en una matriz de 1 y 0 mediante el operador unario (--). A continuación, la función SUM suma los números y, si la suma es mayor que 1, la función IF informa de un valor de"Duplicado".

Para nuestro conjunto de datos de muestra, la fórmula es la siguiente:

=IF(SUM((--EXACT($A$2:$A$8,A2)))<=1,"", "Duplicado")

Como se muestra en la siguiente captura de pantalla, trata las minúsculas y las mayúsculas como caracteres diferentes (APPLES no se identifica como duplicado):

Sugerencia: si utilizas hojas de cálculo de Google, el siguiente artículo puede resultarte útil: Cómo encontrar y eliminar duplicados en las hojas de cálculo de Google.

Cómo encontrar filas duplicadas en Excel

Si su objetivo es deduplicar una tabla que consta de varias columnas, entonces necesita una fórmula que pueda comprobar cada columna e identificar únicamente duplicado absoluto de filas es decir, filas que tienen valores completamente iguales en todas las columnas.

Consideremos el siguiente ejemplo. Supongamos que tenemos números de pedido en la columna A, fechas en la columna B y artículos pedidos en la columna C, y queremos encontrar filas duplicadas con el mismo número de pedido, fecha y artículo. Para ello, vamos a crear una fórmula de duplicados basada en la función COUNTIFS que permite comprobar varios criterios a la vez:

A búsqueda de filas duplicadas con 1ª ocurrencia utiliza esta fórmula:

=IF(COUNTIFS($A$2:$A$8,$A2,$B$2:$B$8,$B2,$C$2:$C$8,$C2)>1, "Fila duplicada", "")

La siguiente captura de pantalla demuestra que la fórmula realmente localiza sólo las filas que tienen valores idénticos en las 3 columnas. Por ejemplo, la fila 8 tiene el mismo número de pedido y fecha que las filas 2 y 5, pero un elemento diferente en la columna C, por lo que no se marca como fila duplicada:

Mostrar filas duplicadas sin 1ª ocurrencia Si no es así, haz un pequeño ajuste en la fórmula anterior:

=IF(COUNTIFS($A$2:$A2,$A2,$B$2:$B2,$B2,$B$2:$B2,$B2,$C$2:$C2,$C2,)>1, "Fila duplicada", "")

Cómo contar duplicados en Excel

Si quieres saber el número exacto de registros idénticos que hay en tu hoja de Excel, utiliza una de las siguientes fórmulas para contar duplicados.

Contar individualmente las instancias de cada registro duplicado

Cuando se tiene una columna con valores duplicados, a menudo se necesita saber cuántos duplicados hay para cada uno de esos valores.

Para averiguar cuántas veces aparece tal o cual entrada en la hoja de cálculo de Excel, utilice una sencilla fórmula COUNTIF, donde A2 es el primer elemento de la lista y A8 es el último:

=COUNTIF($A$2:$A$8, $A2)

Como se muestra en la siguiente captura de pantalla, la fórmula cuenta las apariciones de cada elemento: " Manzanas "aparece 3 veces, " Plátanos verdes " - 2 veces, " Plátanos " y " Naranjas "sólo una vez.

Si desea identificar la 1ª, 2ª, 3ª, etc. ocurrencias de cada elemento, utilice la siguiente fórmula:

=COUNTIF($A$2:$A2, $A2)

De forma similar, puede contar los ocurrencias de filas duplicadas La única diferencia es que tendrá que utilizar la función COUNTIFS en lugar de COUNTIF. Por ejemplo:

=COUNTIFS($A$2:$A$8, $A2, $B$2:$B$8, $B2)

Una vez contados los valores duplicados, puede ocultar los valores únicos y ver sólo los duplicados, o viceversa. Para ello, aplique el autofiltro de Excel como se muestra en el siguiente ejemplo: Cómo filtrar duplicados en Excel.

Contar el número total de duplicados en una(s) columna(s)

La forma más sencilla de contar duplicados en una columna es emplear cualquiera de las fórmulas que utilizamos para identificar duplicados en Excel (con o sin primera ocurrencia). Y entonces puedes contar los valores duplicados utilizando la siguiente fórmula COUNTIF:

=COUNTIF(rango, "duplicado")

¿Dónde? duplicado " es la etiqueta que utilizó en la fórmula que localiza duplicados.

En este ejemplo, nuestra fórmula duplicada adopta la siguiente forma:

=COUNTIF(B2:B8, "duplicado")

Otra forma de contar valores duplicados en Excel utilizando una fórmula de matriz más compleja. Una ventaja de este enfoque es que no requiere una columna de ayuda:

=FILAS($A$2:$A$8)-SUMA(IF( COUNTIF($A$2:$A$8,$A$2:$A$8)=1,1,0))

Como se trata de una fórmula de matriz, recuerde pulsar Ctrl + Mayús + Intro para completarla. Además, tenga en cuenta que esta fórmula cuenta todos los registros duplicados, incluidas las primeras ocurrencias :

Para encontrar el número total de filas duplicadas Por ejemplo, para contar filas duplicadas basándose en las columnas A y B, introduzca la siguiente fórmula en su hoja de Excel:

=ROWS($A$2:$A$8)-SUMA(IF( COUNTIFS($A$2:$A$8,$A$2:$A$8, $B$2:$B$8,$B$2:$B$8)=1,1,0))

Cómo filtrar duplicados en Excel

Para facilitar el análisis de los datos, puede que desee filtrarlos para que sólo se muestren los duplicados. En otras situaciones, puede que necesite lo contrario: ocultar los duplicados y ver los registros únicos. A continuación encontrará soluciones para ambos casos.

Cómo mostrar y ocultar duplicados en Excel

Si desea ver todos los duplicados de un vistazo, utilice una de las fórmulas para buscar duplicados en Excel que mejor se adapte a sus necesidades. A continuación, seleccione su tabla, cambie a la función Datos y haga clic en el botón Filtro También puede hacer clic en Ordenar y filtrar > Filtro en el Inicio en la pestaña Edición de grupo.

Sugerencia: para que el filtrado se active automáticamente, convierta sus datos en una tabla de Excel totalmente funcional. Sólo tiene que seleccionar todos los datos y pulsar la combinación de teclas Ctrl + T.

A continuación, haz clic en la flecha en la cabecera del Duplicar y marque la casilla " Fila duplicada a mostrar duplicados Si desea filtrar, por ejemplo. ocultar duplicados seleccione " Único " para ver sólo los registros únicos:

Y ahora, puede ordenar los duplicados por la columna clave para agruparlos y facilitar su análisis. En este ejemplo, podemos ordenar las filas duplicadas por la columna Número de pedido columna:

Cómo filtrar los duplicados por sus apariciones

Si desea mostrar la segunda, tercera o enésima aparición de valores duplicados, utilice la fórmula para contar instancias duplicadas de la que hemos hablado antes:

=COUNTIF($A$2:$A2, $A2)

A continuación, aplique el filtrado a la tabla y seleccione sólo las ocurrencias que desea ver. Por ejemplo, puede filtrar las segundas ocurrencias como en la siguiente captura de pantalla:

Para visualizar todos los registros duplicados, es decir incidencias superiores a 1 haga clic en la flecha de filtro situada en la cabecera de la ventana Ocurrencias (la columna con la fórmula) y, a continuación, haga clic en Filtros numéricos > Mayor que .

Seleccione " es mayor que " en la primera casilla, escriba 1 en la casilla de al lado y pulse el botón OK botón:

Del mismo modo, puede mostrar el segundo, el tercer y todos los duplicados posteriores. Para ello, escriba el número deseado en la casilla situada junto a " es mayor que ".

Resaltar, seleccionar, borrar, eliminar, copiar o mover duplicados

Después de filtrar los duplicados como se ha demostrado anteriormente, tiene varias opciones para tratarlos.

Cómo seleccionar duplicados en Excel

Para seleccionar duplicados, incluidos los encabezados de columna Para filtrarlas, haz clic en cualquier celda filtrada para seleccionarla y, a continuación, pulsa Ctrl + A .

Para seleccionar registros duplicados sin cabeceras de columna seleccione la primera celda (superior izquierda) y pulse Ctrl + Mayús + Fin para ampliar la selección hasta la última celda.

Sugerencia: en la mayoría de los casos, los métodos abreviados anteriores funcionan correctamente y sólo seleccionan las filas filtradas (visibles). En algunos casos excepcionales, sobre todo en libros muy grandes, pueden seleccionarse tanto las celdas visibles como las invisibles. Para solucionarlo, utilice primero uno de los métodos abreviados anteriores y, a continuación, pulse Alt + ; para seleccionar sólo las celdas visibles ignorando las filas ocultas.

Cómo borrar o eliminar duplicados en Excel

A eliminar duplicados en Excel selecciónelos, haga clic con el botón derecho y, a continuación, haga clic en Contenido claro (o haga clic en el botón Claro botón> Contenido claro en el Inicio en la pestaña Edición de Esto borrará sólo el contenido de la celda y el resultado serán celdas vacías. Seleccionando las celdas duplicadas filtradas y pulsando la tecla Borrar tendrá el mismo efecto.

A eliminar todas las filas duplicadas Para filtrar los duplicados, seleccione las filas arrastrando el ratón por los encabezados de fila, haga clic con el botón derecho en la selección y elija Borrar fila del menú contextual.

Cómo resaltar duplicados en Excel

Para resaltar los valores duplicados, seleccione los duplicados filtrados, haga clic en el botón Color de relleno botón en el Inicio en la pestaña Fuente y seleccione el color que desee.

Otra forma de resaltar los duplicados en Excel es utilizar una regla de formato condicional incorporada para duplicados, o crear una regla personalizada especialmente adaptada a su hoja. Los usuarios experimentados de Excel no tendrán ningún problema para crear una regla de este tipo basada en las fórmulas que hemos utilizado para comprobar los duplicados en Excel. Si todavía no se siente muy cómodo con las fórmulas o reglas de Excel, encontrará la detalladapasos de este tutorial: Cómo resaltar duplicados en Excel.

Cómo copiar o mover duplicados a otra hoja

A copia duplicados, selecciónalos, pulsa Ctrl + C , luego abre otra hoja (una nueva o una existente), selecciona la celda superior izquierda del rango donde quieres copiar los duplicados, y pulsa Ctrl + V para pegarlos.

A mover duplicados a otra hoja, realice los mismos pasos con la única diferencia de que pulsará Ctrl + X (cortar) en lugar de Ctrl + C (copiar).

Duplicate Remover - forma rápida y eficaz de localizar duplicados en Excel

Ahora que ya sabe cómo utilizar fórmulas duplicadas en Excel, permítame mostrarle otra forma rápida, eficaz y sin fórmulas: Duplicate Remover for Excel.

Esta herramienta todo en uno puede buscar valores duplicados o únicos en una sola columna o comparar dos columnas. Puede encontrar, seleccionar y resaltar registros duplicados o filas duplicadas enteras, eliminar los duplicados encontrados, copiarlos o moverlos a otra hoja. Creo que un ejemplo de uso práctico vale más que muchas palabras, así que vamos a ello.

Cómo encontrar filas duplicadas en Excel en 2 pasos rápidos

Para probar las capacidades de nuestro complemento Duplicate Remover, he creado una tabla con unos cientos de filas que tiene el siguiente aspecto:

Como ves, la tabla tiene unas cuantas columnas. Las 3 primeras columnas contienen la información más relevante, por lo que vamos a buscar filas duplicadas basándonos únicamente en los datos de las columnas A - C. Para encontrar registros duplicados en estas columnas, sólo tienes que hacer lo siguiente:

1. Seleccione cualquier celda de la tabla y haga clic en el botón Tabla Dedupe Después de instalar Ultimate Suite para Excel, lo encontrará en la barra de herramientas de Excel. Datos de Ablebits en la pestaña Deduplicación grupo.

   

2. El complemento inteligente recogerá toda la tabla y le pedirá que especifique las dos cosas siguientes:
   • Seleccione columnas para comprobar si hay duplicados (en este ejemplo, son los Nº de pedido Fecha de pedido y Artículo columnas).
   • Elija una acción a realizar sobre los duplicados Dado que nuestro objetivo es identificar filas duplicadas, he seleccionado la opción Añadir una columna de estado

     

   Además de añadir una columna de estado, tiene a su disposición una serie de opciones:

   • Eliminar duplicados
   • Colorear (resaltar) duplicados
   • Seleccionar duplicados
   • Copiar duplicados a una nueva hoja de cálculo
   • Mover duplicados a una nueva hoja de cálculo

   Haga clic en el botón OK y espere unos segundos. ¡Listo!

Como puede ver en la siguiente captura de pantalla, se han localizado todas las filas que tienen valores idénticos en las 3 primeras columnas (las primeras apariciones no se identifican como duplicados).

Si desea más opciones para deduplicar sus hojas de cálculo, utilice la función Asistente para eliminar duplicados que puede encontrar duplicados con o sin primera aparición, así como valores únicos. A continuación se detallan los pasos a seguir.

Asistente para eliminar duplicados: más opciones para buscar duplicados en Excel

Dependiendo de la hoja en particular con la que esté trabajando, puede que quiera o no tratar las primeras instancias de registros idénticos como duplicados. Una posible solución es utilizar una fórmula diferente para cada escenario, tal y como comentamos en Cómo identificar duplicados en Excel. Si está buscando un método rápido, preciso y sin fórmulas, pruebe el método Asistente para eliminar duplicados :

1. Seleccione cualquier celda de la tabla y haga clic en el botón Eliminador de duplicados en el botón Datos de Ablebits El asistente se ejecutará y se seleccionará toda la tabla.

   

2. En el siguiente paso, se le presentan las 4 opciones para comprobar duplicados en su hoja Excel:
   • Duplicados sin 1ª aparición
   • Duplicados con 1ª aparición
   • Valores únicos
   • Valores únicos y 1er duplicado

   Para este ejemplo, vamos a optar por la segunda opción, es decir Duplicados + 1ª ocurrencia :

   

3. Ahora, seleccione las columnas en las que desea comprobar los duplicados. Como en el ejemplo anterior, estamos seleccionando las 3 primeras columnas:

   

4. Por último, elija la acción que desee realizar con los duplicados. Al igual que ocurre con la herramienta Tabla Deduplicada, el asistente de Eliminación de Duplicados puede identificar , seleccione , destacar , borrar , copia o mover duplicados.

   Dado que el objetivo de este tutorial es mostrar distintas formas de identificar duplicados en Excel, marquemos la opción correspondiente y hagamos clic en Acabado :

   

El asistente de eliminación de duplicados sólo tarda una fracción de segundo en comprobar cientos de filas y ofrecer el siguiente resultado:

Sin fórmulas, sin estrés, sin errores: siempre resultados rápidos e impecables :)

Si estás interesado en probar estas herramientas para encontrar duplicados en tus hojas de Excel, te invitamos a descargar una versión de evaluación a continuación. Tu opinión en los comentarios será muy apreciada.

Descargas disponibles

Identificar duplicados - ejemplos de fórmulas (archivo .xlsx)

Ultimate Suite - versión de prueba (archivo .exe)