У навчальному посібнику пояснюється, як шукати дублікати в Excel. Ви вивчите кілька формул для виявлення значень, що повторюються, або пошуку рядків, що повторюються, з першими входженнями або без них. Ви також дізнаєтеся, як підрахувати екземпляри кожного запису, що повторюється, окремо і знайти загальну кількість дублікатів у стовпці, як відфільтрувати дублікати та багато іншого.

Працюючи з великою таблицею Excel або об'єднуючи кілька маленьких таблиць в одну велику, ви можете виявити в ній багато рядків, що повторюються. В одному з наших попередніх уроків ми розглядали різні способи порівняння двох таблиць або стовпців на наявність дублікатів.

І сьогодні я хотів би поділитися кількома швидкими та ефективними методами виявлення дублікатів в одному списку. Ці рішення працюють у всіх версіях Excel 365, Excel 2021, Excel 2019, Excel 2016, Excel 2013 і нижче.

Як виявити дублікати в Excel

Найпростіший спосіб виявлення дублікатів в Excel - це використання функції СУММЕСЛИ. Залежно від того, чи хочете ви знайти дублікати значень з першими входженнями або без них, формула буде дещо відрізнятися, як показано в наступних прикладах.

Як знайти дублікати записів, включаючи 1-е входження

Припустимо, у вас є список елементів в колонці А, які ви хочете перевірити на наявність дублікатів. Це можуть бути рахунки-фактури, ідентифікатори товарів, назви або будь-які інші дані.

Ось формула для пошуку дублікатів в Excel, включаючи перші входження (де A2 - верхня комірка):

=COUNTIF(A:A, A2)>1

Введіть наведену вище формулу в клітинку B2, потім виберіть B2 і перетягніть маркер заповнення, щоб скопіювати формулу в інші клітинки:

Як видно на скріншоті вище, формула повертає значення TRUE для значень, що повторюються, та FALSE для унікальних значень.

Примітка: якщо вам потрібно знайти дублікати в діапазон комірок а не в цілому стовпчику, не забудьте заблокувати цей діапазон знаком $. Наприклад, для пошуку дублікатів в комірках A2:A8 використовуйте цю формулу:

=COUNTIF( $A$2:$A$8 , A2)>1

Щоб дублююча формула повертала щось більш значуще, ніж булеві значення TRUE і FALSE, помістіть її у функцію IF і введіть будь-які мітки для повторюваних і унікальних значень:

=IF(COUNTIF($A$2:$A$8, $A2)>1, "Дублікат", "Унікальний")

Якщо ви хочете, щоб формула Excel знаходила тільки дублікати, замініть "Унікальний" на порожній рядок (""), наприклад, таким чином:

=IF(COUNTIF($A$2:$A$8, $A2)>1, "Дублікат", "")

Формула поверне "Duplicates" для записів, що повторюються, і порожню комірку для унікальних записів:

Як шукати дублікати в Excel без 1-го входження

У разі, якщо ви плануєте фільтрувати або видаляти дублікати після їх знаходження, використовувати наведену вище формулу небезпечно, оскільки вона позначає всі однакові записи як дублікати. А якщо ви хочете зберегти унікальні значення в своєму списку, то не можна видаляти всі дублікати, потрібно видаляти тільки 2-й і всі наступні екземпляри.

Отже, давайте модифікуємо нашу дублюючу формулу Excel, використовуючи абсолютні та відносні посилання на клітинки, де це доречно:

=IF(COUNTIF($A$2:$A2, $A2)>1, "Дублікат", "")

Як видно на наступному скріншоті, ця формула не ідентифікує перше входження " Яблука "як дублікат:

Як знайти дублікати з урахуванням регістру в Excel

У ситуаціях, коли потрібно виявити точні дублікати, включаючи регістр тексту, використовуйте цю загальну формулу масиву (вводиться натисканням клавіш Ctrl + Shift + Enter):

В основі формули лежить функція ТОЧНО для точного порівняння цільової комірки з кожною коміркою вказаного діапазону. Результатом цієї операції є масив значень ІСТИНА (збіг) і БРЕХНЯ (не збіг), який унарним оператором (--) примусово перетворюється в масив 1 і 0. Після цього функція СУММЕСЛИ підсумовує числа, і якщо сума більше 1, то функція ЯКЩО видає повідомлення про те, що"Дублікат".

Для нашого прикладу формула виглядає наступним чином:

=IF(SUM((--EXACT($A$2:$A$8,A2)))<=1,"", "Дублікат")

Як показано на скріншоті нижче, він розглядає малі та великі літери як різні символи (APPLES не ідентифікується як дублікат):

Порада: Якщо ви користуєтеся таблицями Google, вам може бути корисною наступна стаття: Як знайти та видалити дублікати в таблицях Google.

Як знайти повторювані рядки в Excel

Якщо ваша мета - вивести таблицю, що складається з декількох стовпців, то вам потрібна формула, яка може перевірити кожен стовпець і визначити тільки абсолютні дублікати рядків тобто рядки, які мають абсолютно однакові значення в усіх стовпчиках.

Розглянемо наступний приклад. Припустимо, у вас є номери замовлень в колонці А, дати в колонці В і замовлені позиції в колонці С, і ви хочете знайти дублікати рядків з однаковими номерами замовлень, датами і позиціями. Для цього створимо дублюючу формулу на основі функції СУММЕСЛИ, яка дозволяє перевіряти кілька критеріїв одночасно:

До пошук повторюваних рядків з 1-м входженням використовуйте цю формулу:

=IF(COUNTIFS($A$2:$A$8,$A2,$B$2:$B$8,$B2,$C$2:$C$8,$C2)>1, "Дублюючий рядок", "")

На наступному скріншоті видно, що формула дійсно знаходить тільки ті рядки, які мають однакові значення у всіх 3 колонках. Наприклад, рядок 8 має той самий порядковий номер та дату, що і рядки 2 та 5, але інший елемент у колонці С, і тому він не позначений як дубльований рядок:

Показати повторювані рядки без 1-го входження вносять невеликі корективи у наведену вище формулу:

=IF(COUNTIFS($A$2:$A2,$A2,$B$2:$B2,$B2,$B$2:$B2,$B2,$C$2:$C2,$C2,)>1, "Дублюючий рядок", "")

Як порахувати дублікати в Excel

Якщо ви хочете знати точну кількість однакових записів у вашому аркуші Excel, скористайтеся однією з наведених нижче формул для підрахунку дублікатів.

Підрахувати екземпляри кожного запису-дубліката окремо

Якщо у вас є стовпець з повторюваними значеннями, вам часто може знадобитися дізнатися, скільки дублікатів є для кожного з цих значень.

Щоб дізнатися, скільки разів зустрічається той чи інший запис у вашому аркуші Excel, скористайтеся простою формулою СЧЕТЕСЛИ, де А2 - перший, а А8 - останній елемент списку:

=COUNTIF($A$2:$A$8, $A2)

Як показано на наступному скріншоті, формула підраховує входження кожного елемента: " Яблука " відбувається 3 рази, " Зелені банани " - 2 рази, " Банани " і " Апельсини "тільки один раз.

Якщо потрібно визначити 1-е, 2-е, 3-е і т.д. входження кожного елемента, використовуйте наступну формулу:

=COUNTIF($A$2:$A2, $A2)

Аналогічним чином можна порахувати випадки дубльовані рядки Різниця лише в тому, що замість COUNTIFS потрібно буде використовувати функцію COUNTIFS. Наприклад:

=COUNTIFS($A$2:$A$8, $A2, $B$2:$B$8, $B2)

Після підрахунку значень, що повторюються, можна приховати унікальні значення і переглянути тільки дублікати, або навпаки. Для цього слід застосувати автофільтр Excel, як показано в наступному прикладі: Як відфільтрувати дублікати в Excel.

Підрахувати загальну кількість повторів у стовпчику (стовпчиках)

Найпростіший спосіб підрахувати дублікати в стовпці - застосувати будь-яку з формул, які ми використовували для виявлення дублікатів в Excel (з першими входженнями або без них). А потім ви можете підрахувати повторювані значення за допомогою наступної формули COUNTIF:

=COUNTIF(range, "duplicate")

Де " дублікат " - це мітка, яку ви використовували у формулі, що визначає місцезнаходження дублікатів.

У цьому прикладі наша дублююча формула набуває наступного вигляду:

=COUNTIF(B2:B8, "duplicate")

Інший спосіб підрахунку повторюваних значень в Excel - за допомогою більш складної формули масиву. Перевагою такого підходу є те, що він не вимагає допоміжного стовпця:

=ROWS($A$2:$A$8)-SUM(IF( COUNTIF($A$2:$A$8,$A$2:$A$8)=1,1,0))

Оскільки це формула масиву, не забудьте натиснути Ctrl + Shift + Enter для її заповнення. Також, будь ласка, майте на увазі, що ця формула враховує всі записи, що повторюються, у тому числі вперше виявлено :

Щоб знайти загальна кількість рядків, що повторюються вставити функцію COUNTIFS замість COUNTIF у наведену вище формулу і вказати всі стовпці, які потрібно перевірити на наявність дублікатів. Наприклад, щоб підрахувати повторювані рядки на основі стовпців A і B, введіть наступну формулу на аркуші Excel:

=ROWS($A$2:$A$8)-SUM(IF( COUNTIFS($A$2:$A$8,$A$2:$A$8, $B$2:$B$8,$B$2:$B$8)=1,1,0))

Як відфільтрувати дублікати в Excel

Для полегшення аналізу даних ви можете відфільтрувати дані, щоб відобразити лише дублікати. В інших ситуаціях вам може знадобитися протилежне - приховати дублікати та переглянути унікальні записи. Нижче ви знайдете рішення для обох сценаріїв.

Як показати і приховати дублікати в Excel

Якщо ви хочете побачити всі дублікати відразу, скористайтеся однією з формул для пошуку дублікатів в Excel, яка краще відповідає вашим потребам. Потім виберіть вашу таблицю, перейдіть на вкладку Дані і натисніть на вкладку Фільтр Крім того, ви можете натиснути кнопку Сортування та фільтрація > Фільтр на Головна сторінка у вкладці Редагування група.

Порада: щоб фільтрація вмикалася автоматично, конвертуйте дані в повнофункціональну таблицю Excel. Просто виділіть всі дані і натисніть комбінацію клавіш Ctrl + T.

Після цього натисніть стрілку у заголовку Дублікат і встановіть прапорець у колонці " Дубльований рядок " box to показати дублікати Якщо ви хочете відфільтрувати, тобто приховати дублікати виберіть " Унікальний " для перегляду тільки унікальних записів:

А тепер ви можете відсортувати дублікати за ключовим стовпцем, щоб згрупувати їх для більш зручного аналізу. У цьому прикладі ми можемо відсортувати дублікати рядків за стовпцем Номер замовлення колонка:

Як відфільтрувати дублікати за входженнями

Якщо ви хочете показати 2-е, 3-е або N-е входження значень, що повторюються, використовуйте формулу для підрахунку повторень, яку ми обговорювали раніше:

=COUNTIF($A$2:$A2, $A2)

Потім застосуйте фільтрацію до Вашої таблиці і виберіть тільки ті випадки, які Ви хочете переглянути. Наприклад, Ви можете відфільтрувати 2 випадки, як показано на наступному скріншоті:

Для відображення всіх записів, що повторюються, тобто випадків більше 1 натисніть на стрілку фільтра в заголовку вікна Події (стовпчик з формулою), а потім натисніть Числові фільтри > Більше, ніж .

Виберіть " більше, ніж " в першому полі, введіть 1 в полі поруч з ним і натисніть кнопку ГАРАЗД. кнопку:

Аналогічним чином можна показати 2-е, 3-е і всі наступні повторення. Просто введіть необхідну кількість в поле напроти " більше, ніж ".

Виділення, вибір, очищення, видалення, копіювання або переміщення дублікатів

Після того, як ви відфільтрували дублікати, як показано вище, у вас є кілька варіантів, як з ними працювати.

Як виділити дублікати в Excel

Виділити дублікати, включаючи заголовки колонок , відфільтруйте їх, клацніть по будь-якій відфільтрованій комірці, щоб виділити її, а потім натисніть Ctrl + A .

Щоб виділити записи, що повторюються без заголовків стовпців виберіть першу (верхню ліву) комірку і натисніть клавіші Ctrl + Shift + End, щоб розширити виділення до останньої комірки.

Порада. У більшості випадків наведені вище комбінації клавіш працюють нормально і виділяють тільки відфільтровані (видимі) рядки. У деяких рідкісних випадках, в основному на дуже великих книгах, можуть виділятися як видимі, так і невидимі комірки. Щоб виправити це, спочатку скористайтеся однією з наведених вище комбінацій клавіш, а потім натисніть клавіші Alt + ; для того, щоб виділити тільки видимі комірки ігноруючи приховані рядки.

Як очистити або видалити дублікати в Excel

До очистити дублікати в Excel виберіть їх, клацніть правою кнопкою миші, а потім натисніть Чіткий вміст (або натисніть кнопку Чисто кнопку>; Чіткий вміст на Головна сторінка у вкладці Редагування При цьому буде видалено тільки вміст комірок, і в результаті ви отримаєте порожні комірки. Виділивши відфільтровані повторювані комірки і натиснувши клавішу Видалити матиме такий самий ефект.

До видалити цілі рядки, що повторюються відфільтрувати дублікати, виділити рядки, провівши мишею по заголовках рядків, клацнути правою кнопкою миші по виділеному, а потім вибрати Видалити рядок з контекстного меню.

Як виділити дублікати в Excel

Для виділення значень, що повторюються, виділіть відфільтровані дублі, натисніть кнопку Колір заливки кнопка на Головна сторінка у вкладці Шрифт а потім виберіть колір на свій розсуд.

Інший спосіб виділення дублікатів в Excel - це використання вбудованого правила умовного форматування для дублікатів або створення власного правила, спеціально адаптованого для вашого аркуша. Досвідчені користувачі Excel без проблем створять таке правило на основі формул, які ми використовували для перевірки дублікатів в Excel. Якщо ви ще не дуже добре орієнтуєтеся в формулах або правилах Excel, ви знайдете детальну інструкціюкроки в цьому посібнику: Як виділити дублікати в Excel.

Як скопіювати або перенести дублікати на інший аркуш

До копія дублікати, виділити їх, натиснути Ctrl + C , потім відкрити інший аркуш (новий або існуючий), виділити ліву верхню комірку діапазону, куди потрібно скопіювати дублікати, і натиснути Ctrl + V , щоб вставити їх.

До переїзд дублікати на інший аркуш, виконайте ті ж дії з тією лише різницею, що замість Ctrl + X (вирізати) натисніть Ctrl + C (копіювати).

Duplicate Remover - швидкий і ефективний спосіб знайти дублікати в Excel

Тепер, коли ви знаєте, як використовувати дублікати формул в Excel, дозвольте продемонструвати вам ще один швидкий, ефективний і вільний від формул спосіб - Duplicate Remover for Excel.

Цей універсальний інструмент може шукати повторювані або унікальні значення в одному стовпці або порівнювати два стовпці. Він може знаходити, виділяти і виділяти повторювані записи або цілі повторювані рядки, видаляти знайдені дублі, копіювати або переміщати їх на інший аркуш. Думаю, приклад практичного використання вартий багатьох слів, тому давайте перейдемо до нього.

Як знайти повторювані рядки в Excel за 2 швидких кроки

Щоб протестувати можливості нашого доповнення Duplicate Remover, я створив таблицю з кількома сотнями рядків, яка виглядає наступним чином:

Як бачите, таблиця має декілька стовпців. Перші 3 стовпці містять найбільш релевантну інформацію, тому ми будемо шукати повторювані рядки, спираючись виключно на дані стовпців A - C. Щоб знайти записи, що повторюються в цих стовпцях, достатньо виконати наступне:

1. Виділіть будь-яку комірку в таблиці і натисніть кнопку Таблиця дедукції Після встановлення нашого Ultimate Suite для Excel ви знайдете його на стрічці Excel. Дані про абіти у вкладці Dedupe група.

   

2. Розумне доповнення підхопить всю таблицю і попросить вас вказати наступні дві речі:
   • Виберіть пункт стовпці для перевірки на наявність дублікатів (в даному прикладі це Наказ №., Дата замовлення і Пункт колонки).
   • Оберіть дії, що вчиняються над дублікатами Оскільки нашою метою є виявлення рядків, що повторюються, я вибрав Додати колонку статусу

     

   Крім додавання колонки статусу, вам доступний ряд інших опцій:

   • Видалення дублікатів
   • Розфарбувати (виділити) дублікати
   • Вибрати дублікати
   • Копіювати дублікати на новий аркуш
   • Переміщення дублікатів на новий аркуш

   Натисніть на кнопку ГАРАЗД. і зачекайте кілька секунд. Готово!

Як видно на скріншоті нижче, всі рядки, які мають однакові значення в перших 3 стовпчиках, були знайдені (перші входження не ідентифіковані як дублікати).

Якщо ви хочете отримати більше можливостей для виведення робочих аркушів, скористайтеся кнопкою Майстер видалення дублікатів який може знаходити дублікати з першими входженнями або без них, а також унікальні значення. Детальні кроки наведені нижче.

Майстер видалення дублікатів - більше можливостей для пошуку дублікатів в Excel

Залежно від конкретного аркуша, з яким ви працюєте, ви можете або не можете розглядати перші екземпляри ідентичних записів як дублікати. Одним з можливих рішень є використання різних формул для кожного сценарію, як ми обговорювали в розділі Як визначити дублікати в Excel. Якщо ви шукаєте швидкий, точний і безформульний метод, спробуйте скористатися функцією Майстер видалення дублікатів :

1. Виділіть будь-яку комірку в таблиці і натисніть кнопку Duplicate Remover на кнопці Дані про абіти Запуститься майстер, і вся таблиця буде виділена.

   

2. На наступному кроці Вам буде запропоновано 4 варіанти перевірки дублікатів у Вашому аркуші Excel:
   • Дублікати без 1-го входження
   • Дублікати з 1-м входженням
   • Унікальні цінності
   • Унікальні значення та 1-е повторення

   Для цього прикладу підемо за другим варіантом, тобто Дублікати + 1-е входження :

   

3. Тепер виділяємо колонки, в яких потрібно перевірити дублікати. Як і в попередньому прикладі, вибираємо перші 3 колонки:

   

4. Нарешті, виберіть дію, яку ви хочете виконати над дублікатами. Як і у випадку з інструментом Вилучення таблиці, майстер видалення дублікатів може ідентифікувати , вибрати , родзинка , видалити , копія або переїзд дублікати.

   Оскільки метою даного уроку є демонстрація різних способів виявлення дублікатів в Excel, давайте відзначимо відповідну опцію і натиснемо кнопку Фініш :

   

Майстру Duplicate Remover знадобиться лише частка секунди, щоб перевірити сотні рядків і видати наступний результат:

Ніяких формул, ніякого стресу, ніяких помилок - завжди швидкий і бездоганний результат :)

Якщо вам цікаво спробувати ці інструменти для пошуку дублікатів у ваших таблицях Excel, ви можете завантажити ознайомчу версію нижче. Будемо дуже вдячні за ваші відгуки в коментарях!

Доступні для завантаження

Виявлення дублікатів - приклади формул (файл .xlsx)

Ultimate Suite - пробна версія (файл .exe)