Učebnica vysvetľuje, ako vyhľadávať duplikáty v programe Excel. Naučíte sa niekoľko vzorcov na identifikáciu duplicitných hodnôt alebo na vyhľadávanie duplicitných riadkov s prvým výskytom alebo bez neho. Dozviete sa tiež, ako spočítať prípady každého duplicitného záznamu jednotlivo a zistiť celkový počet duplikátov v stĺpci, ako odfiltrovať duplikáty a ďalšie informácie.

Pri práci s veľkým pracovným hárkom programu Excel alebo pri konsolidácii niekoľkých malých tabuliek do väčšieho hárka môžete v ňom nájsť veľa duplicitných riadkov. V jednom z našich predchádzajúcich návodov sme sa zaoberali rôznymi spôsobmi porovnania dvoch tabuliek alebo stĺpcov na duplicity.

A dnes by som sa chcel podeliť o niekoľko rýchlych a účinných metód na identifikáciu duplicít v jednom zozname. Tieto riešenia fungujú vo všetkých verziách Excel 365, Excel 2021, Excel 2019, Excel 2016, Excel 2013 a nižších.

Ako identifikovať duplikáty v programe Excel

Najjednoduchším spôsobom, ako v programe Excel zistiť duplicity, je použitie funkcie COUNTIF. V závislosti od toho, či chcete nájsť duplicitné hodnoty s prvým výskytom alebo bez neho, bude vzorec mierne odlišný, ako je uvedené v nasledujúcich príkladoch.

Ako nájsť duplicitné záznamy vrátane 1. výskytu

Predpokladajme, že v stĺpci A máte zoznam položiek, ktoré chcete skontrolovať na duplicity. Môžu to byť faktúry, identifikátory produktov, názvy alebo akékoľvek iné údaje.

Tu je vzorec na vyhľadávanie duplikátov v programe Excel vrátane prvých výskytov (kde A2 je najvyššia bunka):

=COUNTIF(A:A, A2)>1

Zadajte vyššie uvedený vzorec do bunky B2, potom vyberte B2 a potiahnutím rukoväte výplne skopírujte vzorec do ďalších buniek:

Ako môžete vidieť na obrázku vyššie, vzorec vracia TRUE pre duplicitné hodnoty a FALSE pre jedinečné hodnoty.

Poznámka: Ak potrebujete nájsť duplikáty v rozsah buniek a nie v celom stĺpci, nezabudnite tento rozsah uzamknúť znakom $. Ak chcete napríklad vyhľadať duplikáty v bunkách A2:A8, použite tento vzorec:

=COUNTIF( $A$2:$A$8 , A2)>1

Ak chcete, aby duplicitný vzorec vrátil niečo zmysluplnejšie ako logické hodnoty TRUE a FALSE, uzavrite ho do funkcie IF a zadajte ľubovoľné označenia pre duplicitné a jedinečné hodnoty:

=IF(COUNTIF($A$2:$A$8, $A2)>1, "Duplicate", "Unique")

V prípade, že chcete, aby vzorec Excelu našiel iba duplikáty, nahraďte "Unique" prázdnym reťazcom ("") takto:

=IF(COUNTIF($A$2:$A$8, $A2)>1, "Duplicate", "")

Vzorec vráti "Duplicates" pre duplicitné záznamy a prázdnu bunku pre jedinečné záznamy:

Ako vyhľadávať duplikáty v programe Excel bez 1. výskytu

V prípade, že po nájdení duplikátov plánujete ich filtrovanie alebo odstránenie, použitie uvedeného vzorca nie je bezpečné, pretože označí všetky rovnaké záznamy ako duplikáty. A ak chcete v zozname zachovať jedinečné hodnoty, potom nemôžete odstrániť všetky duplicitné záznamy, musíte odstrániť iba 2. a všetky nasledujúce prípady.

Upravme teda náš duplicitný vzorec programu Excel tak, že v prípade potreby použijeme absolútne a relatívne odkazy na bunky:

=IF(COUNTIF($A$2:$A2, $A2)>1, "Duplicate", "")

Ako vidíte na nasledujúcom obrázku, tento vzorec neidentifikuje prvý výskyt " Jablká " ako duplikát:

Ako nájsť duplikáty v programe Excel s rozlišovaním veľkých a malých písmen

V situáciách, keď potrebujete identifikovať presné duplikáty vrátane prípadu textu, použite tento všeobecný vzorec poľa (zadáva sa stlačením klávesovej skratky Ctrl + Shift + Enter ):

Jadrom vzorca je funkcia EXACT, ktorá presne porovná cieľovú bunku s každou bunkou v zadanom rozsahu. Výsledkom tejto operácie je pole TRUE (zhoda) a FALSE (nezhoda), ktoré sa pomocou unárneho operátora (--) zmení na pole 1 a 0. Potom funkcia SUM sčíta čísla, a ak je súčet väčší ako 1, funkcia IF oznámi"Duplikát".

Pre náš vzorový súbor údajov platí tento vzorec:

=IF(SUM((--EXACT($A$2:$A$8,A2)))<=1,"", "Duplicitné")

Ako je znázornené na nasledujúcom obrázku, malé a veľké písmená sa považujú za rôzne znaky (APPLES sa neidentifikuje ako duplikát):

Tip. Ak používate tabuľky Google, môže vám pomôcť nasledujúci článok: Ako nájsť a odstrániť duplikáty v tabuľkách Google.

Ako nájsť duplicitné riadky v programe Excel

Ak je vaším cieľom oddeliť tabuľku pozostávajúcu z viacerých stĺpcov, potom potrebujete vzorec, ktorý dokáže skontrolovať každý stĺpec a identifikovať iba absolútne duplicitné riadky t. j. riadky, ktoré majú úplne rovnaké hodnoty vo všetkých stĺpcoch.

Uvažujme o nasledujúcom príklade. Predpokladajme, že máte čísla objednávok v stĺpci A, dátumy v stĺpci B a objednané položky v stĺpci C a chcete nájsť duplicitné riadky s rovnakým číslom objednávky, dátumom a položkou. Na tento účel vytvoríme vzorec pre duplicity založený na funkcii COUNTIFS, ktorá umožňuje kontrolovať viacero kritérií naraz:

Na vyhľadávanie duplicitných riadkov s 1. výskytom , použite tento vzorec:

=IF(COUNTIFS($A$2:$A$8,$A2,$B$2:$B$8,$B2,$C$2:$C$8,$C2)>1, "Duplicitný riadok", "")

Nasledujúci obrázok ukazuje, že vzorec skutočne vyhľadáva len riadky, ktoré majú rovnaké hodnoty vo všetkých 3 stĺpcoch. Napríklad riadok 8 má rovnaké číslo objednávky a dátum ako riadky 2 a 5, ale inú položku v stĺpci C, a preto nie je označený ako duplicitný riadok:

Ukázať duplicitné riadky bez 1. výskytu , vykonajte malú úpravu uvedeného vzorca:

=IF(COUNTIFS($A$2:$A2,$A2,$B$2:$B2,$B2,$B$2:$B2,$B2,$C$2:$C2,$C2,)>1, "Duplicitný riadok", "")

Ako počítať duplikáty v programe Excel

Ak chcete zistiť presný počet rovnakých záznamov v hárku programu Excel, použite na spočítanie duplikátov jeden z nasledujúcich vzorcov.

Počítanie prípadov každého duplicitného záznamu jednotlivo

Ak máte stĺpec s duplicitnými hodnotami, často potrebujete vedieť, koľko duplicít je pre každú z týchto hodnôt.

Ak chcete zistiť, koľkokrát sa vo vašom hárku programu Excel vyskytuje tá alebo oná položka, použite jednoduchý vzorec COUNTIF, kde A2 je prvá a A8 posledná položka zoznamu:

=COUNTIF($A$2:$A$8, $A2)

Ako je znázornené na nasledujúcom obrázku, vzorec počíta výskyty jednotlivých položiek: " Jablká " sa vyskytuje 3-krát, " Zelené banány " - 2 krát, " Banány " a " Pomaranče " len raz.

Ak chcete určiť 1., 2., 3. atď. výskyt každej položky, použite nasledujúci vzorec:

=COUNTIF($A$2:$A2, $A2)

Podobným spôsobom môžete počítať výskytov duplicitné riadky Jediný rozdiel je v tom, že namiesto funkcie COUNTIFS budete musieť použiť funkciu COUNTIF. Napríklad:

=COUNTIFS($A$2:$A$8, $A2, $B$2:$B$8, $B2)

Po spočítaní duplicitných hodnôt môžete skryť jedinečné hodnoty a zobraziť len duplicitné hodnoty alebo naopak. Ak to chcete urobiť, použite automatický filter programu Excel, ako je ukázané v nasledujúcom príklade: Ako odfiltrovať duplicity v programe Excel.

Spočítať celkový počet duplikátov v stĺpci(-och)

Najjednoduchší spôsob, ako spočítať duplikáty v stĺpci, je použiť niektorý zo vzorcov, ktoré sme použili na identifikáciu duplikátov v programe Excel (s prvým výskytom alebo bez neho). A potom môžete spočítať duplicitné hodnoty pomocou nasledujúceho vzorca COUNTIF:

=COUNTIF(range, "duplicate")

Kde " duplikát " je označenie, ktoré ste použili vo vzorci na vyhľadávanie duplikátov.

V tomto príklade má náš duplicitný vzorec nasledujúci tvar:

=COUNTIF(B2:B8, "duplicate")

Iný spôsob počítania duplicitných hodnôt v programe Excel pomocou zložitejšieho vzorca poľa. Výhodou tohto prístupu je, že nevyžaduje pomocný stĺpec:

=ROWS($A$2:$A$8)-SUM(IF( COUNTIF($A$2:$A$8,$A$2:$A$8)=1,1,0))

Pretože ide o vzorec poľa, nezabudnite na jeho dokončenie stlačiť klávesovú skratku Ctrl + Shift + Enter. Majte tiež na pamäti, že tento vzorec počíta všetky duplicitné záznamy, vrátane prvých výskytov :

Ak chcete nájsť celkový počet duplicitných riadkov , vložte do vyššie uvedeného vzorca namiesto funkcie COUNTIFS funkciu COUNTIF a zadajte všetky stĺpce, ktoré chcete skontrolovať na duplicity. Ak chcete napríklad spočítať duplicitné riadky na základe stĺpcov A a B, zadajte do hárka programu Excel nasledujúci vzorec:

=ROWS($A$2:$A$8)-SUM(IF( COUNTIFS($A$2:$A$8,$A$2:$A$8, $B$2:$B$8,$B$2:$B$8)=1,1,0))

Ako filtrovať duplikáty v programe Excel

Pre jednoduchšiu analýzu údajov môžete chcieť údaje filtrovať tak, aby sa zobrazovali len duplikáty. V iných situáciách môžete potrebovať opak - skryť duplikáty a zobraziť jedinečné záznamy. Nižšie nájdete riešenia pre oba scenáre.

Ako zobraziť a skryť duplikáty v programe Excel

Ak chcete vidieť všetky duplikáty na prvý pohľad, použite jeden zo vzorcov na vyhľadávanie duplikátov v programe Excel, ktorý lepšie vyhovuje vašim potrebám. Potom vyberte tabuľku, prepnite na Údaje a kliknite na kartu Filter prípadne môžete kliknúť na tlačidlo Triedenie & amp; Filter > Filter na Domov na karte Úprava stránky skupina.

Tip. Ak chcete mať filtrovanie zapnuté automaticky, preveďte svoje údaje na plne funkčnú tabuľku programu Excel. Stačí vybrať všetky údaje a stlačiť klávesovú skratku Ctrl + T.

Potom kliknite na šípku v záhlaví Duplikát stĺpec a začiarknite políčko " Duplicitný riadok " na zobraziť duplikáty Ak chcete odfiltrovať, t. j. skryť duplikáty , vyberte " Jedinečné " na zobrazenie iba jedinečných záznamov:

A teraz môžete duplikáty zoradiť podľa kľúčového stĺpca, aby ste ich mohli zoskupiť na jednoduchšiu analýzu. V tomto príklade môžeme duplicitné riadky zoradiť podľa Objednávacie číslo stĺpec:

Ako filtrovať duplikáty podľa ich výskytu

Ak chcete zobraziť 2., 3. alebo N-tý výskyt duplicitných hodnôt, použite vzorec na počítanie duplicitných prípadov, o ktorom sme hovorili skôr:

=COUNTIF($A$2:$A2, $A2)

Potom na tabuľku použite filtrovanie a vyberte len výskyt(y), ktoré chcete zobraziť. Môžete napríklad filtrovať 2. výskyt ako na nasledujúcej snímke:

Zobrazenie všetkých duplicitných záznamov, t. j. počet výskytov väčší ako 1 , kliknite na šípku filtra v záhlaví Výskyt (stĺpec so vzorcom) a potom kliknite na tlačidlo Číselné filtre > Väčší ako .

Vyberte " je väčšia ako " v prvom políčku, do vedľajšieho políčka napíšte 1 a kliknite na tlačidlo OK tlačidlo:

Podobným spôsobom môžete zobraziť 2., 3. a všetky nasledujúce duplicitné výskyty. Stačí zadať požadované číslo do políčka vedľa " je väčšia ako ".

Zvýraznenie, výber, vymazanie, odstránenie, kopírovanie alebo presun duplikátov

Po vyfiltrovaní duplikátov, ako je uvedené vyššie, máte rôzne možnosti, ako sa s nimi vysporiadať.

Ako vybrať duplikáty v programe Excel

Výber duplikátov, vrátane záhlaví stĺpcov , filtrujte ich, kliknite na ktorúkoľvek filtrovanú bunku, aby ste ju vybrali, a potom stlačte klávesovú skratku Ctrl + A .

Výber duplicitných záznamov bez záhlaví stĺpcov , vyberte prvú (ľavú hornú) bunku a stlačením kombinácie kláves Ctrl + Shift + End rozšírte výber na poslednú bunku.

Tip: Vo väčšine prípadov uvedené skratky fungujú dobre a vyberajú len filtrované (viditeľné) riadky. V niektorých zriedkavých prípadoch, väčšinou pri veľmi veľkých zošitoch, sa môžu vybrať viditeľné aj neviditeľné bunky. Ak to chcete napraviť, použite najprv jednu z uvedených skratiek a potom stlačte Alt + ;, aby ste vybrať len viditeľné bunky , pričom sa ignorujú skryté riadky.

Ako vymazať alebo odstrániť duplikáty v programe Excel

Na vymazanie duplikátov v programe Excel , vyberte ich, kliknite pravým tlačidlom myši a potom kliknite na položku Jasný obsah (alebo kliknite na Jasné tlačidlo> Jasný obsah na Domov na karte Úprava stránky Tým sa odstráni iba obsah buniek a výsledkom budú prázdne bunky. Výberom vyfiltrovaných duplicitných buniek a stlačením tlačidla Odstrániť bude mať rovnaký účinok.

Na odstrániť celé duplicitné riadky , odfiltrujte duplikáty, vyberte riadky potiahnutím myši cez záhlavie riadkov, kliknite na výber pravým tlačidlom myši a potom vyberte Odstrániť riadok z kontextového menu.

Ako zvýrazniť duplikáty v programe Excel

Ak chcete zvýrazniť duplicitné hodnoty, vyberte filtrované duplikáty, kliknite na Farba výplne tlačidlo na Domov na karte Písmo a potom vyberte požadovanú farbu.

Ďalším spôsobom, ako zvýrazniť duplicity v programe Excel, je použitie zabudovaného pravidla podmieneného formátovania pre duplicity alebo vytvorenie vlastného pravidla špeciálne prispôsobeného pre váš hárok. Skúsení používatelia programu Excel nebudú mať problém s vytvorením takéhoto pravidla na základe vzorcov, ktoré sme použili na kontrolu duplicít v programe Excel. Ak si so vzorcami alebo pravidlami programu Excel ešte veľmi nerozumiete, nájdete podrobnýkroky v tomto návode: Ako zvýrazniť duplikáty v programe Excel.

Ako skopírovať alebo presunúť duplikáty do iného hárka

Na kopírovať duplikáty, vyberte ich, stlačte klávesovú skratku Ctrl + C , potom otvorte iný hárok (nový alebo existujúci), vyberte ľavú hornú bunku rozsahu, do ktorého chcete skopírovať duplikáty, a stlačte klávesovú skratku Ctrl + V, aby ste ich vložili.

Na presunúť duplikovať na iný hárok, vykonajte rovnaké kroky s jediným rozdielom, že namiesto Ctrl + C (kopírovať) stlačíte Ctrl + X (vyrezať).

Odstránenie duplikátov - rýchly a efektívny spôsob vyhľadávania duplikátov v programe Excel

Teraz, keď už viete, ako používať duplicitné vzorce v programe Excel, vám ukážem ďalší rýchly, efektívny a bezvzorcový spôsob - Duplicate Remover for Excel.

Tento univerzálny nástroj dokáže vyhľadať duplicitné alebo jedinečné hodnoty v jednom stĺpci alebo porovnať dva stĺpce. Dokáže nájsť, vybrať a zvýrazniť duplicitné záznamy alebo celé duplicitné riadky, odstrániť nájdené duplicity, skopírovať ich alebo presunúť na iný hárok. Myslím, že príklad praktického použitia je hodný mnohých slov, takže poďme naň.

Ako nájsť duplicitné riadky v programe Excel v 2 rýchlych krokoch

Na otestovanie možností nášho doplnku Duplicate Remover som vytvoril tabuľku s niekoľkými stovkami riadkov, ktorá vyzerá takto:

Ako vidíte, tabuľka má niekoľko stĺpcov. Prvé 3 stĺpce obsahujú najdôležitejšie informácie, takže budeme hľadať duplicitné riadky výlučne na základe údajov v stĺpcoch A - C. Ak chcete nájsť duplicitné záznamy v týchto stĺpcoch, stačí vykonať nasledujúce kroky:

1. Vyberte ľubovoľnú bunku v tabuľke a kliknite na tlačidlo Tabuľka Dedupe Po nainštalovaní nášho balíka Ultimate Suite pre Excel ho nájdete na páse Údaje Ablebits na karte Dedupe skupina.

   

2. Inteligentný doplnok vyberie celú tabuľku a požiada vás o zadanie nasledujúcich dvoch vecí:
   • Vyberte stĺpce na kontrolu duplicít (v tomto príklade sú to Objednávacie číslo, Dátum objednávky a Položka stĺpcov).
   • Vyberte si akcia, ktorá sa má vykonať na duplikátoch Keďže naším cieľom je identifikovať duplicitné riadky, vybral som Pridanie stĺpca stavu

     

   Okrem pridania stavového stĺpca máte k dispozícii celý rad ďalších možností:

   • Odstránenie duplikátov
   • Farebné (zvýraznenie) duplikátov
   • Výber duplikátov
   • Kopírovanie duplikátov do nového pracovného hárka
   • Presun duplikátov do nového pracovného hárka

   Kliknite na tlačidlo OK a počkajte niekoľko sekúnd. Hotovo!

Ako vidíte na nasledujúcom obrázku, všetky riadky, ktoré majú rovnaké hodnoty v prvých 3 stĺpcoch, boli lokalizované (prvé výskyty nie sú identifikované ako duplicity).

Ak chcete mať viac možností oddeľovania pracovných hárkov, použite príkaz Sprievodca odstránením duplikátov ktorá dokáže nájsť duplicity s prvým výskytom alebo bez neho, ako aj jedinečné hodnoty. Podrobný postup je uvedený nižšie.

Sprievodca odstránením duplikátov - viac možností na vyhľadávanie duplikátov v programe Excel

V závislosti od konkrétneho hárku, s ktorým pracujete, môžete, ale nemusíte chcieť považovať prvé prípady rovnakých záznamov za duplikáty. Jedným z možných riešení je použitie iného vzorca pre každý scenár, ako sme uviedli v časti Ako identifikovať duplikáty v programe Excel. Ak hľadáte rýchlu, presnú a bezvzorcovú metódu, vyskúšajte Sprievodca odstránením duplikátov :

1. Vyberte ľubovoľnú bunku v tabuľke a kliknite na tlačidlo Odstránenie duplikátov tlačidlo na Údaje Ablebits karta. Sprievodca sa spustí a vyberie sa celá tabuľka.

   

2. V ďalšom kroku sa zobrazia 4 možnosti kontroly duplicít v hárku programu Excel:
   • Duplikáty bez 1. výskytu
   • Duplikáty s 1. výskytom
   • Jedinečné hodnoty
   • Jedinečné hodnoty a 1. duplicitný výskyt

   Pre tento príklad vyberieme druhú možnosť, t. j. Duplikáty + 1. výskyt :

   

3. Teraz vyberte stĺpce, v ktorých chcete skontrolovať duplicity. Podobne ako v predchádzajúcom príklade vyberáme prvé 3 stĺpce:

   

4. Nakoniec vyberte akciu, ktorú chcete vykonať s duplikátmi. Podobne ako v prípade nástroja Deduplikovaná tabuľka môže sprievodca Odstránenie duplikátov identifikovať , vybrať , zvýraznenie , vymazať , kopírovať alebo presunúť duplikáty.

   Keďže cieľom tohto návodu je demonštrovať rôzne spôsoby identifikácie duplicít v programe Excel, začiarknime príslušnú možnosť a kliknite na tlačidlo Dokončenie :

   

Sprievodcovi odstránením duplikátov trvá len zlomok sekundy, kým skontroluje stovky riadkov a poskytne nasledujúci výsledok:

Žiadne vzorce, žiadny stres, žiadne chyby - vždy rýchle a dokonalé výsledky :)

Ak máte záujem vyskúšať tieto nástroje na vyhľadávanie duplicít v hárkoch programu Excel, môžete si stiahnuť nižšie uvedenú hodnotiacu verziu. Budeme vďační za vašu spätnú väzbu v komentároch!

Dostupné súbory na stiahnutie

Identifikácia duplikátov - príklady vzorcov (.xlsx súbor)

Ultimate Suite - skúšobná verzia (.exe súbor)