Tutorial ini menjelaskan cara mencari duplikat di Excel. Anda akan mempelajari beberapa rumus untuk mengidentifikasi nilai duplikat atau menemukan baris duplikat dengan atau tanpa kemunculan pertama. Anda juga akan belajar cara menghitung contoh setiap rekaman duplikat satu per satu dan menemukan jumlah total duplikat dalam kolom, cara memfilter duplikat, dan banyak lagi.

Saat bekerja dengan lembar kerja Excel yang besar atau menggabungkan beberapa lembar kerja kecil menjadi lebih besar, Anda mungkin menemukan banyak baris duplikat di dalamnya. Di salah satu tutorial kami sebelumnya, kami membahas berbagai cara untuk membandingkan dua tabel atau kolom untuk duplikat.

Dan hari ini, saya ingin berbagi beberapa metode cepat dan efektif untuk mengidentifikasi duplikat dalam satu daftar. Solusi ini berfungsi di semua versi Excel 365, Excel 2021, Excel 2019, Excel 2016, Excel 2013 dan yang lebih rendah.

Cara mengidentifikasi duplikat di Excel

Cara termudah untuk mendeteksi duplikat di Excel menggunakan fungsi COUNTIF. Bergantung pada apakah Anda ingin menemukan nilai duplikat dengan atau tanpa kemunculan pertama, akan ada sedikit variasi dalam rumus seperti yang ditunjukkan pada contoh berikut.

Cara menemukan catatan duplikat termasuk kejadian pertama

Misalkan Anda memiliki daftar item di kolom A yang ingin Anda periksa duplikatnya. Ini bisa berupa faktur, Id produk, nama atau data lainnya.

Berikut rumus untuk menemukan duplikat di Excel termasuk kejadian pertama (di mana A2 adalah sel paling atas):

=COUNTIF(A:A, A2)>1

Masukkan rumus di atas di B2, lalu pilih B2 dan seret gagang isian untuk menyalin rumus ke sel lain:

Seperti yang Anda lihat pada gambar di atas, rumus mengembalikan TRUE untuk nilai duplikat dan FALSE untuk nilai unik.

Catatan. Jika Anda perlu menemukan duplikat dalam sebuah rentang sel daripada di seluruh kolom, ingatlah untuk mengunci rentang itu dengan tanda $. Misalnya, untuk mencari duplikat di sel A2: A8, gunakan rumus ini:

=COUNTIF( $A$2:$A$8 , A2)>1

Agar rumus duplikat mengembalikan sesuatu yang lebih bermakna daripada nilai Boolean TRUE dan FALSE, lampirkan dalam fungsi IF dan ketik label apa pun yang Anda inginkan untuk nilai duplikat dan unik:

=IF(COUNTIF($A$2:$A$8, $A2)>1, "Duplikat", "Unik")

Jika, Anda menginginkan rumus Excel untuk menemukan duplikat saja, ganti "Unique" dengan string kosong ("") seperti ini:

=IF(COUNTIF($A$2:$A$8, $A2)>1, "Duplikat", "")

Rumus akan mengembalikan "Duplikat" untuk catatan duplikat, dan sel kosong untuk catatan unik:

Cara mencari duplikat di Excel tanpa kejadian pertama

Jika Anda berencana untuk memfilter atau menghapus duplikat setelah menemukannya, menggunakan rumus di atas tidak aman karena menandai semua rekaman yang identik sebagai duplikat. Dan jika Anda ingin menyimpan nilai unik dalam daftar Anda, maka Anda tidak dapat menghapus semua rekaman duplikat, Anda hanya perlu menghapus rekaman ke-2 dan semua contoh berikutnya.

Jadi, mari kita modifikasi rumus duplikat Excel kita dengan menggunakan referensi sel absolut dan relatif jika sesuai:

=IF(COUNTIF($A$2:$A2, $A2)>1, "Duplikat", "")

Seperti yang bisa Anda lihat pada screenshot berikut, rumus ini tidak mengidentifikasi kemunculan pertama " Apel " sebagai duplikat:

Bagaimana menemukan duplikat peka huruf besar-kecil di Excel

Dalam situasi ketika Anda perlu mengidentifikasi duplikat yang tepat termasuk kasus teks, gunakan rumus array generik ini (dimasukkan dengan menekan Ctrl + Shift + Enter ):

Di jantung rumus, Anda menggunakan fungsi EXACT untuk membandingkan sel target dengan setiap sel dalam rentang yang ditentukan dengan tepat. Hasil dari operasi ini adalah larik TRUE (cocok) dan FALSE (tidak cocok), yang dipaksa menjadi larik 1 dan 0 oleh operator unary (--). Setelah itu, fungsi SUM menjumlahkan angka-angka tersebut, dan jika jumlahnya lebih besar dari 1, fungsi IF melaporkan"Duplikat".

Untuk set data sampel kami, rumusnya adalah sebagai berikut:

=IF(SUM((--EXACT($A$2:$A$8,A2)))<=1,"", "Duplicate")

Seperti yang ditunjukkan pada gambar di bawah ini, ia memperlakukan huruf kecil dan huruf besar sebagai karakter yang berbeda (APPLES tidak diidentifikasi sebagai duplikat):

Jika Anda menggunakan spreadsheet Google, artikel berikut mungkin bermanfaat: Cara menemukan dan menghapus duplikat di Google Sheets.

Bagaimana menemukan baris duplikat di Excel

Jika tujuan Anda adalah untuk menyimpulkan tabel yang terdiri dari beberapa kolom, maka Anda memerlukan formula yang bisa memeriksa setiap kolom dan mengidentifikasi hanya baris duplikat absolut yaitu baris-baris yang memiliki nilai yang benar-benar sama di semua kolom.

Misalkan, Anda memiliki nomor pesanan di kolom A, tanggal di kolom B, dan item yang dipesan di kolom C, dan Anda ingin menemukan baris duplikat dengan nomor pesanan, tanggal, dan item yang sama. Untuk ini, kami akan membuat rumus duplikat berdasarkan fungsi COUNTIFS yang memungkinkan pengecekan beberapa kriteria sekaligus:

Untuk mencari baris duplikat dengan kejadian pertama , gunakan rumus ini:

=IF(COUNTIFS($A$2:$A$8,$A2,$B$2:$B$8,$B2,$C$2:$C$8,$C2)>1, "Duplicate row", "")

Tangkapan layar berikut menunjukkan bahwa rumus benar-benar hanya menemukan baris yang memiliki nilai identik di semua 3 kolom. Misalnya, baris 8 memiliki nomor pesanan dan tanggal yang sama dengan baris 2 dan 5, tetapi item yang berbeda di kolom C, dan oleh karena itu tidak ditandai sebagai baris duplikat:

Untuk menunjukkan baris duplikat tanpa kejadian pertama , lakukan sedikit penyesuaian pada rumus di atas:

=IF(COUNTIFS($A$2:$A2,$A2,$B$2:$B2,$B2,$B$2:$B2,$B2,$C$2:$C2,$C2,)>1, "Duplicate row", "")

Cara menghitung duplikat di Excel

Jika Anda ingin mengetahui jumlah pasti dari rekaman identik di lembar Excel Anda, gunakan salah satu rumus berikut untuk menghitung duplikat.

Hitung contoh dari setiap catatan duplikat secara individual

Bila Anda memiliki kolom dengan nilai duplikat, Anda mungkin sering perlu mengetahui berapa banyak duplikat yang ada untuk masing-masing nilai tersebut.

Untuk mengetahui berapa kali entri ini atau itu muncul di lembar kerja Excel Anda, gunakan rumus COUNTIF sederhana, di mana A2 adalah yang pertama dan A8 adalah item terakhir dari daftar:

=COUNTIF($A$2:$A$8, $A2)

Seperti yang ditunjukkan dalam tangkapan layar berikut ini, rumus menghitung kemunculan setiap item: " Apel " terjadi 3 kali, " Pisang hijau " - 2 kali, " Pisang " dan " Jeruk " hanya sekali.

Jika Anda ingin mengidentifikasi kemunculan ke-1, ke-2, ke-3, dst. dari setiap item, gunakan rumus berikut ini:

=COUNTIF($A$2:$A2, $A2)

Dengan cara yang sama, Anda bisa menghitung kejadian baris yang diduplikasi Satu-satunya perbedaan adalah bahwa Anda perlu menggunakan fungsi COUNTIFS, bukan COUNTIF. Sebagai contoh:

=COUNTIFS($A$2:$A$8, $A2, $B$2:$B$8, $B2)

Setelah nilai duplikat dihitung, Anda dapat menyembunyikan nilai unik dan hanya melihat duplikat, atau sebaliknya. Untuk melakukan ini, terapkan filter otomatis Excel seperti yang ditunjukkan dalam contoh berikut: Cara memfilter duplikat di Excel.

Menghitung jumlah total duplikat dalam kolom

Cara termudah untuk menghitung duplikat dalam kolom adalah dengan menggunakan salah satu rumus yang kami gunakan untuk mengidentifikasi duplikat di Excel (dengan atau tanpa kejadian pertama). Dan kemudian Anda dapat menghitung nilai duplikat dengan menggunakan rumus COUNTIF berikut:

=COUNTIF(range, "duplikat")

Di mana " duplikat " adalah label yang Anda gunakan dalam rumus yang menemukan duplikat.

Dalam contoh ini, rumus duplikat kita mengambil bentuk berikut:

=COUNTIF(B2:B8, "duplikat")

Cara lain untuk menghitung nilai duplikat di Excel dengan menggunakan rumus array yang lebih kompleks. Keuntungan dari pendekatan ini adalah tidak memerlukan kolom pembantu:

=ROWS($A$2:$A$8)-SUM(IF( COUNTIF($A$2:$A$8,$A$2:$A$8)=1,1,0))

Karena ini adalah rumus array, ingatlah untuk menekan Ctrl + Shift + Enter untuk menyelesaikannya. Selain itu, harap diingat bahwa rumus ini menghitung semua record duplikat, termasuk kejadian pertama :

Untuk menemukan jumlah total baris duplikat , sematkan fungsi COUNTIFS alih-alih COUNTIF dalam rumus di atas, dan tentukan semua kolom yang ingin Anda periksa duplikatnya. Misalnya, untuk menghitung baris duplikat berdasarkan kolom A dan B, masukkan rumus berikut di lembar Excel Anda:

=ROWS($A$2:$A$8)-SUM(IF( COUNTIFS($A$2:$A$8,$A$2:$A$8, $B$2:$B$8,$B$2:$B$8)=1,1,0))

Cara memfilter duplikat di Excel

Untuk analisis data yang lebih mudah, Anda mungkin ingin memfilter data Anda untuk hanya menampilkan duplikat. Dalam situasi lain, Anda mungkin perlu sebaliknya - menyembunyikan duplikat dan melihat catatan unik. Di bawah ini Anda akan menemukan solusi untuk kedua skenario tersebut.

Cara menampilkan dan menyembunyikan duplikat di Excel

Jika Anda ingin melihat semua duplikat secara sekilas, gunakan salah satu rumus untuk menemukan duplikat di Excel yang lebih sesuai dengan kebutuhan Anda. Data tab, dan klik tab Filter Atau, Anda dapat mengklik Urutkan &; Saring > Filter pada Rumah tab di Penyuntingan kelompok.

Tip. Agar pemfilteran diaktifkan secara otomatis, ubah data Anda ke tabel Excel yang berfungsi penuh. Cukup pilih semua data dan tekan pintasan Ctrl + T.

Setelah itu, klik tanda panah di header dari Duplikat dan periksa kolom " Baris duplikat " kotak ke tampilkan duplikat Jika Anda ingin menyaring, yaitu. sembunyikan duplikat , pilih " Unik " untuk hanya melihat catatan unik:

Dan sekarang, Anda bisa mengurutkan duplikat berdasarkan kolom kunci untuk mengelompokkannya agar lebih mudah dianalisis. Dalam contoh ini, kita bisa mengurutkan baris duplikat berdasarkan kolom Nomor pesanan kolom:

Cara memfilter duplikat berdasarkan kemunculannya

Jika Anda ingin menampilkan kejadian ke-2, ke-3, atau ke-N dari nilai duplikat, gunakan rumus untuk menghitung contoh duplikat yang kita bahas sebelumnya:

=COUNTIF($A$2:$A2, $A2)

Kemudian terapkan pemfilteran ke tabel Anda dan pilih hanya kejadian yang ingin Anda lihat. Misalnya, Anda dapat memfilter kejadian ke-2 seperti pada tangkapan layar berikut:

Untuk menampilkan semua rekaman duplikat, yaitu kejadian lebih besar dari 1 , klik tanda panah filter di header dari Kejadian kolom (kolom dengan formula), lalu klik Filter Angka > Lebih besar dari .

Pilih " lebih besar dari " di kotak pertama, ketik 1 di kotak di sebelahnya, dan klik tombol OK tombol:

Dengan cara yang sama, Anda bisa menampilkan kejadian duplikat ke-2, ke-3 dan semua duplikat berikutnya. Cukup ketik nomor yang diperlukan dalam kotak di samping " lebih besar dari ".

Sorot, pilih, hapus, hapus, salin, atau pindahkan duplikat

Setelah Anda memfilter duplikat seperti yang ditunjukkan di atas, Anda memiliki berbagai pilihan untuk menanganinya.

Cara memilih duplikat di Excel

Untuk memilih duplikat, termasuk tajuk kolom , saring mereka, klik pada sel yang difilter untuk memilihnya, lalu tekan Ctrl + A .

Untuk memilih catatan duplikat tanpa tajuk kolom , pilih sel pertama (kiri atas), dan tekan Ctrl + Shift + End untuk memperpanjang pilihan ke sel terakhir.

Dalam kebanyakan kasus, pintasan di atas berfungsi dengan baik dan hanya memilih baris yang difilter (terlihat). Dalam beberapa kasus yang jarang terjadi, sebagian besar pada buku kerja yang sangat besar, baik sel yang terlihat maupun yang tidak terlihat mungkin dipilih. Untuk memperbaikinya, gunakan salah satu pintasan di atas terlebih dahulu, lalu tekan Alt + ; untuk pilih hanya sel yang terlihat , mengabaikan baris tersembunyi.

Cara menghapus atau menghapus duplikat di Excel

Untuk hapus duplikat di Excel , pilih mereka, klik kanan, lalu klik Isi yang Jelas (atau klik tombol Bersih tombol> Isi yang Jelas pada Rumah tab, di tab Penyuntingan Ini akan menghapus isi sel saja, dan Anda akan memiliki sel kosong sebagai hasilnya. Memilih sel duplikat yang difilter dan menekan tombol Hapus akan memiliki efek yang sama.

Untuk hapus seluruh baris duplikat , saring duplikat, pilih baris dengan menyeret mouse melintasi judul baris, klik kanan pilihan, lalu pilih Hapus Baris dari menu konteks.

Cara menyorot duplikat di Excel

Untuk menyoroti nilai duplikat, pilih duplikat yang difilter, klik tombol Isi warna tombol pada Rumah tab, di tab Font kelompok, kemudian pilih warna yang Anda pilih.

Cara lain untuk menyorot duplikat di Excel adalah menggunakan aturan pemformatan bersyarat bawaan untuk duplikat, atau membuat aturan khusus yang dirancang khusus untuk lembar Anda. Pengguna Excel yang berpengalaman tidak akan mengalami masalah dalam membuat aturan seperti itu berdasarkan rumus yang kami gunakan untuk memeriksa duplikat di Excel. Jika Anda belum terlalu nyaman dengan rumus atau aturan Excel, Anda akan menemukan detailnyalangkah-langkah dalam tutorial ini: Cara menyorot duplikat di Excel.

Cara menyalin atau memindahkan duplikat ke lembar lain

Untuk salinan lalu buka lembar lain (yang baru atau yang sudah ada), pilih sel kiri atas dari rentang tempat Anda ingin menyalin duplikat, dan tekan Ctrl + V untuk menempelkannya.

Untuk bergerak duplikat ke sheet lain, lakukan langkah yang sama dengan satu-satunya perbedaan, yaitu Anda menekan Ctrl + X (cut), bukan Ctrl + C (copy).

Duplicate Remover - cara cepat dan efisien untuk menemukan duplikat di Excel

Sekarang setelah Anda tahu cara menggunakan rumus duplikat di Excel, izinkan saya mendemonstrasikan kepada Anda cara lain yang cepat, efisien, dan bebas rumus - Duplicate Remover for Excel.

Alat all-in-one ini dapat mencari nilai duplikat atau unik dalam satu kolom atau membandingkan dua kolom. Ini dapat menemukan, memilih dan menyorot catatan duplikat atau seluruh baris duplikat, menghapus duplikat yang ditemukan, menyalin atau memindahkannya ke lembar lain. Saya pikir contoh penggunaan praktis bernilai banyak kata, jadi mari kita mulai.

Cara menemukan baris duplikat di Excel dalam 2 langkah cepat

Untuk menguji kemampuan add-in Duplicate Remover kami, saya telah membuat tabel dengan beberapa ratus baris yang terlihat seperti berikut:

Seperti yang Anda lihat, tabel memiliki beberapa kolom. 3 kolom pertama berisi informasi yang paling relevan, jadi kita akan mencari baris duplikat hanya berdasarkan data di kolom A - C. Untuk menemukan record duplikat di kolom-kolom ini, cukup lakukan hal berikut:

1. Pilih sel mana pun di dalam tabel Anda dan klik tombol Tabel Dedupe Setelah menginstal Ultimate Suite for Excel kami, Anda akan menemukannya di menu Data Ablebits tab, di tab Dedupe kelompok.

   

2. Smart add-in akan mengambil seluruh tabel dan meminta Anda untuk menentukan dua hal berikut ini:
   • Pilih kolom untuk memeriksa duplikat (dalam contoh ini, ini adalah Pesanan no., Tanggal pemesanan dan Barang kolom).
   • Pilihlah tindakan untuk dilakukan pada duplikat Karena tujuan kita adalah untuk mengidentifikasi baris duplikat, saya telah memilih Tambahkan kolom status

     

   Selain menambahkan kolom status, serangkaian opsi lain tersedia bagi Anda:

   • Hapus duplikat
   • Warna (sorot) duplikat
   • Pilih duplikat
   • Salin duplikat ke lembar kerja baru
   • Pindahkan duplikat ke lembar kerja baru

   Klik OK dan tunggu beberapa detik. Selesai!

Seperti yang dapat Anda lihat pada tangkapan layar di bawah ini, semua baris yang memiliki nilai identik dalam 3 kolom pertama telah ditemukan (kejadian pertama tidak diidentifikasi sebagai duplikat).

Jika Anda ingin lebih banyak opsi untuk memotong lembar kerja Anda, gunakan Wisaya Penghapus Duplikat yang dapat menemukan duplikat dengan atau tanpa kemunculan pertama serta nilai unik. Langkah-langkah terperinci mengikuti di bawah ini.

Wisaya Penghilang Duplikat - lebih banyak opsi untuk mencari duplikat di Excel

Tergantung pada lembar tertentu yang Anda kerjakan, Anda mungkin atau mungkin tidak ingin memperlakukan contoh pertama dari catatan yang identik sebagai duplikat. Salah satu solusi yang mungkin adalah menggunakan rumus yang berbeda untuk setiap skenario, seperti yang kita bahas di Cara mengidentifikasi duplikat di Excel. Jika Anda mencari metode yang cepat, akurat, dan bebas rumus, coba metode Wisaya Penghapus Duplikat :

1. Pilih sel mana pun di dalam tabel Anda dan klik tombol Penghapus Duplikat tombol pada Data Ablebits Wizard akan berjalan dan seluruh tabel akan dipilih.

   

2. Pada langkah berikutnya, Anda disajikan dengan 4 opsi untuk memeriksa duplikat di lembar Excel Anda:
   • Duplikat tanpa kejadian pertama
   • Duplikat dengan kejadian pertama
   • Nilai-nilai unik
   • Nilai-nilai unik dan kejadian duplikat pertama

   Untuk contoh ini, mari kita gunakan opsi kedua, yaitu Duplikat + kejadian pertama :

   

3. Sekarang, pilih kolom di mana Anda ingin memeriksa duplikat. Seperti pada contoh sebelumnya, kita memilih 3 kolom pertama:

   

4. Terakhir, pilih tindakan yang ingin Anda lakukan pada duplikat. Seperti halnya dengan alat Tabel Dedupe, wizard Duplicate Remover dapat mengidentifikasi , pilih , sorot , hapus , salinan atau bergerak duplikat.

   Karena tujuan tutorial ini adalah untuk mendemonstrasikan berbagai cara untuk mengidentifikasi duplikat di Excel, mari kita periksa opsi yang sesuai dan klik Selesai :

   

Hanya membutuhkan waktu sepersekian detik untuk wizard Duplicate Remover untuk memeriksa ratusan baris, dan memberikan hasil berikut:

Tanpa rumus, tanpa stres, tanpa kesalahan - selalu cepat dan hasil yang sempurna :)

Jika Anda tertarik untuk mencoba alat ini untuk menemukan duplikat di lembar Excel Anda, Anda dipersilakan untuk mengunduh versi evaluasi di bawah ini. Umpan balik Anda dalam komentar akan sangat dihargai!

Unduhan yang tersedia

Identifikasi Duplikat - contoh rumus (file .xlsx)

Ultimate Suite - versi percobaan (file .exe)