Bu eğitimde Excel'de yinelemelerin nasıl aranacağı açıklanmaktadır. Yinelenen değerleri tanımlamak veya ilk oluşumu olan veya olmayan yinelenen satırları bulmak için birkaç formül öğreneceksiniz. Ayrıca, her yinelenen kaydın örneklerini ayrı ayrı nasıl sayacağınızı ve bir sütundaki toplam yinelenen sayısını nasıl bulacağınızı, yinelenenleri nasıl filtreleyeceğinizi ve daha fazlasını öğreneceksiniz.

Büyük bir Excel çalışma sayfasıyla çalışırken veya birkaç küçük elektronik tabloyu daha büyük bir tabloda birleştirirken, içinde çok sayıda yinelenen satır bulabilirsiniz. Önceki eğitimlerimizden birinde, iki tabloyu veya sütunu yinelemeler için karşılaştırmanın çeşitli yollarını tartışmıştık.

Ve bugün, tek bir listedeki yinelemeleri belirlemek için birkaç hızlı ve etkili yöntemi paylaşmak istiyorum. Bu çözümler Excel 365, Excel 2021, Excel 2019, Excel 2016, Excel 2013 ve daha düşük sürümlerin tümünde çalışır.

Excel'de yinelemeler nasıl belirlenir

Excel'de yinelenen değerleri saptamanın en kolay yolu EĞERSAY işlevini kullanmaktır. Yinelenen değerleri ilk oluşlarıyla mı yoksa ilk oluşları olmadan mı bulmak istediğinize bağlı olarak, aşağıdaki örneklerde gösterildiği gibi formülde küçük bir değişiklik olacaktır.

İlk oluşumlar dahil olmak üzere yinelenen kayıtlar nasıl bulunur?

A sütununda yinelenenleri kontrol etmek istediğiniz bir öğe listeniz olduğunu varsayalım. Bunlar faturalar, ürün kimlikleri, adlar veya başka herhangi bir veri olabilir.

İşte ilk oluşumlar dahil olmak üzere Excel'de yinelenenleri bulmak için bir formül (A2'nin en üstteki hücre olduğu yerde):

=COUNTIF(A:A, A2)>1

Yukarıdaki formülü B2'ye girin, ardından B2'yi seçin ve formülü diğer hücrelere kopyalamak için doldurma tutamacını sürükleyin:

Yukarıdaki ekran görüntüsünde görebileceğiniz gibi, formül yinelenen değerler için DOĞRU, benzersiz değerler için YANLIŞ döndürür.

Not: Bir dosyada yinelenenleri bulmanız gerekiyorsa hücre aralığı yerine, bu aralığı $ işaretiyle kilitlemeyi unutmayın. Örneğin, A2:A8 hücrelerindeki yinelemeleri aramak için şu formülü kullanın:

=COUNTIF( $A$2:$A$8 , A2)>1

Yinelenen bir formülün DOĞRU ve YANLIŞ Boole değerlerinden daha anlamlı bir şey döndürmesi için, bunu EĞER işlevi içine alın ve yinelenen ve benzersiz değerler için istediğiniz etiketleri yazın:

=IF(COUNTIF($A$2:$A$8, $A2)>1, "Duplicate", "Unique")

Bir Excel formülünün yalnızca yinelenenleri bulmasını istiyorsanız, "Benzersiz" ifadesini aşağıdaki gibi boş bir dizeyle ("") değiştirin:

=IF(COUNTIF($A$2:$A$8, $A2)>1, "Duplicate", "")

Formül, yinelenen kayıtlar için "Yinelenenler" ve benzersiz kayıtlar için boş bir hücre döndürür:

Excel'de 1. tekrarlar olmadan kopyalar nasıl aranır

Yinelenen kayıtları bulduktan sonra filtrelemeyi veya kaldırmayı planlıyorsanız, yukarıdaki formülü kullanmak güvenli değildir çünkü tüm aynı kayıtları yinelenen olarak işaretler. Ve benzersiz değerleri listenizde tutmak istiyorsanız, tüm yinelenen kayıtları silemezsiniz, yalnızca 2. ve sonraki tüm örnekleri silmeniz gerekir.

Öyleyse, uygun yerlerde mutlak ve göreli hücre referanslarını kullanarak Excel yinelenen formülümüzü değiştirelim:

=IF(COUNTIF($A$2:$A2, $A2)>1, "Duplicate", "")

Aşağıdaki ekran görüntüsünde de görebileceğiniz gibi, bu formül " Elmalar " ifadesinin kopyasıdır:

Excel'de büyük/küçük harfe duyarlı yinelemeler nasıl bulunur?

Metin durumu da dahil olmak üzere tam kopyaları belirlemeniz gereken durumlarda, bu genel dizi formülünü kullanın (Ctrl + Shift + Enter tuşlarına basılarak girilir):

Formülün merkezinde, hedef hücreyi belirtilen aralıktaki her hücreyle tam olarak karşılaştırmak için EXACT işlevini kullanırsınız. Bu işlemin sonucu bir dizi TRUE (eşleşme) ve FALSE (eşleşme değil) olup, bu dizi unary operatörü (--) tarafından bir dizi 1 ve 0'a zorlanır. Bundan sonra, SUM işlevi sayıları toplar ve toplam 1'den büyükse, IF işlevi bir"Kopya".

Örnek veri setimiz için formül aşağıdaki gibidir:

=IF(SUM((--EXACT($A$2:$A$8,A2)))<=1,"", "Duplicate")

Aşağıdaki ekran görüntüsünde gösterildiği gibi, küçük ve büyük harfleri farklı karakterler olarak ele alır (APPLES bir kopya olarak tanımlanmaz):

İpucu: Google elektronik tablolarını kullanıyorsanız, aşağıdaki makale yararlı olabilir: Google E-Tablolar'da yinelemeler nasıl bulunur ve kaldırılır.

Excel'de yinelenen satırlar nasıl bulunur

Amacınız birkaç sütundan oluşan bir tabloyu tekilleştirmekse, her sütunu kontrol edebilecek ve yalnızca mutlak yinelenen satırlar yani tüm sütunlarda tamamen eşit değerlere sahip satırlar.

Aşağıdaki örneği ele alalım: A sütununda sipariş numaralarınız, B sütununda tarihleriniz ve C sütununda sipariş edilen öğeleriniz olduğunu ve aynı sipariş numarası, tarih ve öğeye sahip yinelenen satırları bulmak istediğinizi varsayalım. Bunun için, bir seferde birden çok ölçütün kontrol edilmesine olanak tanıyan COUNTIFS işlevini temel alan bir yinelenen formül oluşturacağız:

için 1'inci oluşlarla yinelenen satırları arayın bu formülü kullanın:

=IF(COUNTIFS($A$2:$A$8,$A2,$B$2:$B$8,$B2,$C$2:$C$8,$C2)>1, "Duplicate row", "")

Aşağıdaki ekran görüntüsü, formülün gerçekten yalnızca 3 sütunda da aynı değerlere sahip satırları bulduğunu göstermektedir. Örneğin, 8. satır 2. ve 5. satırlarla aynı sipariş numarası ve tarihe sahiptir, ancak C sütununda farklı bir öğe vardır ve bu nedenle yinelenen satır olarak işaretlenmez:

Göstermek için ilk oluşumu olmayan yinelenen satırlar yukarıdaki formülde küçük bir ayarlama yapın:

=IF(COUNTIFS($A$2:$A2,$A2,$B$2:$B2,$B2,$B$2:$B2,$B2,$C$2:$C2,$C2,)>1, "Duplicate row", "")

Excel'de yinelemeler nasıl sayılır

Excel sayfanızdaki aynı kayıtların tam sayısını bilmek istiyorsanız, yinelenenleri saymak için aşağıdaki formüllerden birini kullanın.

Her bir yinelenen kaydın örneklerini ayrı ayrı sayın

Yinelenen değerlere sahip bir sütununuz olduğunda, genellikle bu değerlerin her biri için kaç tane yinelenen olduğunu bilmeniz gerekebilir.

Excel çalışma sayfanızda şu veya bu girdinin kaç kez geçtiğini bulmak için, A2'nin listenin ilk ve A8'in son öğesi olduğu basit bir EĞERSAY formülü kullanın:

=COUNTIF($A$2:$A$8, $A2)

Aşağıdaki ekran görüntüsünde gösterildiği gibi, formül her bir öğenin oluşumlarını sayar: " Elmalar " 3 kez, " Yeşil muzlar " - 2 kez, " Muzlar " ve " Portakallar " sadece bir kez.

Her bir öğenin 1., 2., 3., vb. oluşumlarını tanımlamak istiyorsanız, aşağıdaki formülü kullanın:

=COUNTIF($A$2:$A2, $A2)

Benzer bir şekilde oluşumları yinelenen satırlar Tek fark, COUNTIF yerine COUNTIFS işlevini kullanmanız gerekecek olmasıdır. Örneğin:

=COUNTIFS($A$2:$A$8, $A2, $B$2:$B$8, $B2)

Yinelenen değerler sayıldıktan sonra, benzersiz değerleri gizleyebilir ve yalnızca yinelenenleri görüntüleyebilir veya tam tersini yapabilirsiniz. Bunu yapmak için, aşağıdaki örnekte gösterildiği gibi Excel'in otomatik filtresini uygulayın: Excel'de yinelenenleri filtreleme.

Sütun(lar)daki toplam yinelenen sayısını sayma

Bir sütundaki yinelemeleri saymanın en kolay yolu, Excel'de yinelemeleri belirlemek için kullandığımız formüllerden herhangi birini kullanmaktır (ilk oluşları olsun ya da olmasın). Ardından aşağıdaki EĞERSAY formülünü kullanarak yinelenen değerleri sayabilirsiniz:

=COUNTIF(range, "duplicate")

Nerede " çoğaltmak " yinelenenleri bulan formülde kullandığınız etikettir.

Bu örnekte, yinelenen formülümüz aşağıdaki şekli alır:

=COUNTIF(B2:B8, "duplicate")

Excel'de yinelenen değerleri saymanın bir başka yolu da daha karmaşık bir dizi formülü kullanmaktır. Bu yaklaşımın bir avantajı, yardımcı sütun gerektirmemesidir:

=ROWS($A$2:$A$8)-SUM(IF( COUNTIF($A$2:$A$8,$A$2:$A$8)=1,1,0))

Bu bir dizi formülü olduğundan, tamamlamak için Ctrl + Shift + Enter tuşlarına basmayı unutmayın. Ayrıca, bu formülün tüm yinelenen kayıtları saydığını lütfen unutmayın, ilk oluşumlar dahil :

Bulmak için toplam yinelenen satır sayısı Yukarıdaki formülde COUNTIF yerine COUNTIFS işlevini yerleştirin ve yinelenenleri denetlemek istediğiniz tüm sütunları belirtin. Örneğin, A ve B sütunlarını temel alarak yinelenen satırları saymak için Excel sayfanıza aşağıdaki formülü girin:

=ROWS($A$2:$A$8)-SUM(IF( COUNTIFS($A$2:$A$8,$A$2:$A$8, $B$2:$B$8,$B$2:$B$8)=1,1,0))

Excel'de yinelenenleri filtreleme

Daha kolay veri analizi için, verilerinizi yalnızca kopyaları görüntüleyecek şekilde filtrelemek isteyebilirsiniz. Diğer durumlarda, tam tersine ihtiyacınız olabilir - kopyaları gizleyin ve benzersiz kayıtları görüntüleyin. Aşağıda her iki senaryo için de çözümler bulacaksınız.

Excel'de yinelenenleri gösterme ve gizleme

Tüm kopyaları bir bakışta görmek istiyorsanız, Excel'de kopyaları bulmak için ihtiyaçlarınıza daha uygun olan formüllerden birini kullanın. Ardından tablonuzu seçin ve Veri sekmesine tıklayın ve Filtre düğmesine tıklayabilirsiniz. Alternatif olarak Sırala ve Filtrele > Filtre üzerinde Ev sekmesinde Düzenleme Grup.

İpucu: Filtrelemenin otomatik olarak etkinleştirilmesi için verilerinizi tam işlevli bir Excel tablosuna dönüştürün. Tüm verileri seçin ve Ctrl + T kısayoluna basın.

Bundan sonra, oka tıklayın başlığında Yinelenen sütununu işaretleyin ve " Yinelenen satır " kutusuna kopyaları göster Filtrelemek istiyorsanız, örn. kopyaları gizle seçiniz " Eşsiz " öğesine tıklayarak yalnızca benzersiz kayıtları görüntüleyebilirsiniz:

Ve şimdi, daha kolay analiz için gruplandırmak üzere yinelenenleri anahtar sütuna göre sıralayabilirsiniz. Bu örnekte, yinelenen satırları Sipariş numarası sütun:

Yinelenenleri oluşumlarına göre filtreleme

Yinelenen değerlerin 2., 3. veya N. oluşumlarını göstermek istiyorsanız, daha önce tartıştığımız yinelenen örnekleri saymak için formülü kullanın:

=COUNTIF($A$2:$A2, $A2)

Ardından tablonuza filtreleme uygulayın ve yalnızca görüntülemek istediğiniz oluşum(lar)ı seçin. Örneğin, aşağıdaki ekran görüntüsünde olduğu gibi 2. oluşumları filtreleyebilirsiniz:

Tüm yinelenen kayıtları görüntülemek için, örn. 1'den büyük oluşumlar 'nin başlığındaki filtre okuna tıklayın. Oluşumlar sütununu (formülün bulunduğu sütun) seçin ve ardından Sayı Filtreleri > Daha Büyük .

Seçiniz " 'den büyüktür. " öğesini ilk kutuya yazın, yanındaki kutuya 1 yazın ve TAMAM. Düğme:

Benzer şekilde, 2., 3. ve sonraki tüm yinelenen oluşumları gösterebilirsiniz. Sadece " 'den büyüktür. ".

Kopyaları vurgulayın, seçin, temizleyin, silin, kopyalayın veya taşıyın

Yukarıda gösterildiği gibi kopyaları filtreledikten sonra, bunlarla başa çıkmak için çeşitli seçenekleriniz vardır.

Excel'de yinelenenler nasıl seçilir

Çiftleri seçmek için, sütun başlıkları dahil 'ye basın, filtreleyin, seçmek için filtrelenmiş herhangi bir hücreye tıklayın ve ardından Ctrl + A tuşlarına basın.

Yinelenen kayıtları seçmek için sütun başlıkları olmadan 'ye basın, ilk (sol üst) hücreyi seçin ve seçimi son hücreye kadar genişletmek için Ctrl + Shift + End tuşlarına basın.

İpucu: Çoğu durumda, yukarıdaki kısayollar iyi çalışır ve yalnızca filtrelenmiş (görünür) satırları seçer. Bazı nadir durumlarda, çoğunlukla çok büyük çalışma kitaplarında, hem görünür hem de görünmez hücreler seçilebilir. Bunu düzeltmek için, önce yukarıdaki kısayollardan birini kullanın ve ardından Alt + ; tuşlarına basarak yalnızca görünür hücreleri seçin gizli satırları göz ardı ederek.

Excel'de yinelemeler nasıl temizlenir veya kaldırılır

için Excel'de yinelenenleri temizleme 'ye tıklayın, seçin, sağ tıklayın ve ardından Temiz İçindekiler (veya Temiz düğme> Temiz İçindekiler üzerinde Ev sekmesinde Düzenleme Bu işlem yalnızca hücre içeriğini siler ve sonuç olarak boş hücreler elde edersiniz. Filtrelenmiş yinelenen hücreleri seçip Silme tuşu da aynı etkiye sahip olacaktır.

için yinelenen satırların tamamını kaldırın , yinelenenleri filtreleyin, fareyi satır başlıkları boyunca sürükleyerek satırları seçin, seçime sağ tıklayın ve ardından Satır Sil bağlam menüsünden.

Excel'de yinelemeler nasıl vurgulanır

Yinelenen değerleri vurgulamak için, filtrelenmiş yinelenen değerleri seçin ve Dolgu rengi düğme üzerinde Ev sekmesinde Yazı Tipi grubunu seçin ve ardından istediğiniz rengi seçin.

Excel'de kopyaları vurgulamanın bir başka yolu da kopyalar için yerleşik bir koşullu biçimlendirme kuralı kullanmak veya sayfanıza özel bir kural oluşturmaktır. Deneyimli Excel kullanıcıları, Excel'de kopyaları kontrol etmek için kullandığımız formüllere dayalı olarak böyle bir kural oluştururken sorun yaşamayacaklardır. Excel formülleri veya kuralları konusunda henüz çok rahat değilseniz, ayrıntılıBu eğitimdeki adımlar: Excel'de kopyalar nasıl vurgulanır.

Kopyaları başka bir sayfaya kopyalama veya taşıma

için kopya kopyaları seçin, Ctrl + C tuşlarına basın, ardından başka bir sayfa açın (yeni veya mevcut bir sayfa), kopyaları kopyalamak istediğiniz aralığın sol üst hücresini seçin ve yapıştırmak için Ctrl + V tuşlarına basın.

için hareket et başka bir sayfaya çoğaltmak için, Ctrl + C (kopyala) yerine Ctrl + X (kes) tuşlarına basmanız dışında tek farkla aynı adımları uygulayın.

Duplicate Remover - Excel'de kopyaları bulmanın hızlı ve etkili yolu

Artık Excel'de yinelenen formülleri nasıl kullanacağınızı bildiğinize göre, size başka bir hızlı, verimli ve formülsüz yol göstereyim - Excel için Duplicate Remover.

Bu hepsi bir arada araç, tek bir sütunda yinelenen veya benzersiz değerleri arayabilir veya iki sütunu karşılaştırabilir. Yinelenen kayıtları veya tüm yinelenen satırları bulabilir, seçebilir ve vurgulayabilir, bulunan kopyaları kaldırabilir, kopyalayabilir veya başka bir sayfaya taşıyabilir. Pratik kullanım örneğinin birçok kelimeye bedel olduğunu düşünüyorum, bu yüzden başlayalım.

Excel'de yinelenen satırlar 2 hızlı adımda nasıl bulunur?

Duplicate Remover eklentimizin yeteneklerini test etmek için, aşağıdaki gibi görünen birkaç yüz satırlı bir tablo oluşturdum:

Gördüğünüz gibi, tabloda birkaç sütun var. İlk 3 sütun en alakalı bilgileri içeriyor, bu nedenle yalnızca A - C sütunlarındaki verilere dayalı olarak yinelenen satırları arayacağız:

1. Tablonuzdaki herhangi bir hücreyi seçin ve Dedupe Tablosu Excel için Ultimate Suite'imizi yükledikten sonra, Excel şeridindeki Ablebits Verileri sekmesinde Dedupe Grup.

   

2. Akıllı eklenti tüm tabloyu alır ve sizden aşağıdaki iki şeyi belirtmenizi ister:
   • Seçiniz çiftleri kontrol etmek için sütunlar (bu örnekte, bunlar Sipariş no, Sipariş tarihi ve Öğe sütunlar).
   • Bir seçim yapın kopyalar üzerinde gerçekleştirilecek eylem Amacımız yinelenen satırları belirlemek olduğu için Durum sütunu ekleme

     

   Bir durum sütunu eklemenin yanı sıra, bir dizi başka seçenek de mevcuttur:

   • Yinelenenleri sil
   • Yinelenenleri renklendirme (vurgulama)
   • Çiftleri seçin
   • Yinelenenleri yeni bir çalışma sayfasına kopyalama
   • Yinelenenleri yeni bir çalışma sayfasına taşıma

   Tıklayınız TAMAM. düğmesine basın ve birkaç saniye bekleyin. Bitti!

Aşağıdaki ekran görüntüsünde görebileceğiniz gibi, ilk 3 sütunda aynı değerlere sahip olan tüm satırlar bulunmuştur (ilk oluşumlar yinelenen olarak tanımlanmaz).

Çalışma sayfalarınızı tekilleştirmek için daha fazla seçenek istiyorsanız Duplicate Remover sihirbazı benzersiz değerlerin yanı sıra ilk geçişleri olan veya olmayan yinelemeleri de bulabilir. Ayrıntılı adımlar aşağıda verilmiştir.

Yinelenen Kaldırma sihirbazı - Excel'de yinelenenleri aramak için daha fazla seçenek

Çalıştığınız belirli bir sayfaya bağlı olarak, aynı kayıtların ilk örneklerini yineleme olarak ele almak isteyebilir veya istemeyebilirsiniz. Olası bir çözüm, Excel'de yinelemeleri belirleme bölümünde tartıştığımız gibi, her senaryo için farklı bir formül kullanmaktır. Hızlı, doğru ve formülsüz bir yöntem arıyorsanız Duplicate Remover sihirbazı :

1. Tablonuzdaki herhangi bir hücreyi seçin ve Duplicate Remover üzerindeki Ablebits Verileri Sihirbaz çalışacak ve tablonun tamamı seçilecektir.

   

2. Bir sonraki adımda, Excel sayfanızdaki kopyaları kontrol etmek için 4 seçenek sunulur:
   • İlk oluşumu olmayan kopyalar
   • 1. kez tekrar eden kopyalar
   • Benzersiz değerler
   • Benzersiz değerler ve 1. yinelenen oluşumlar

   Bu örnek için ikinci seçeneği seçelim, yani Mükerrerler + 1. oluşumlar :

   

3. Şimdi, kopyaları kontrol etmek istediğiniz sütunları seçin. Önceki örnekte olduğu gibi, ilk 3 sütunu seçiyoruz:

   

4. Son olarak, kopyalar üzerinde gerçekleştirmek istediğiniz bir eylem seçin. Tekilleştirme Tablosu aracında olduğu gibi, Yinelenen Kaldırma sihirbazı şunları yapabilir tanımlamak , seçin , vurgulamak , silme , kopya veya hareket et kopyalar.

   Bu eğitimin amacı Excel'de kopyaları belirlemenin farklı yollarını göstermek olduğundan, ilgili seçeneği işaretleyelim ve Bitirmek :

   

Duplicate Remover sihirbazının yüzlerce satırı kontrol etmesi ve aşağıdaki sonucu vermesi yalnızca bir saniye sürer:

Formül yok, stres yok, hata yok - her zaman hızlı ve kusursuz sonuçlar :)

Excel sayfalarınızdaki kopyaları bulmak için bu araçları denemek istiyorsanız, aşağıdaki değerlendirme sürümünü indirebilirsiniz. Yorumlardaki geri bildirimleriniz çok takdir edilecektir!

Mevcut indirmeler

Yinelemeleri Belirleme - formül örnekleri (.xlsx dosyası)

Ultimate Suite - deneme sürümü (.exe dosyası)