Το σεμινάριο εξηγεί τη σύνταξη και τις βασικές χρήσεις της συνάρτησης CHOOSE και παρέχει μερικά μη τετριμμένα παραδείγματα που δείχνουν πώς να χρησιμοποιήσετε έναν τύπο CHOOSE στο Excel.

Η CHOOSE είναι μία από εκείνες τις συναρτήσεις του Excel που μπορεί να μη φαίνονται χρήσιμες από μόνες τους, αλλά σε συνδυασμό με άλλες συναρτήσεις δίνουν μια σειρά από φοβερά οφέλη. Στο πιο βασικό επίπεδο, χρησιμοποιείτε τη συνάρτηση CHOOSE για να λάβετε μια τιμή από μια λίστα καθορίζοντας τη θέση αυτής της τιμής. Πιο κάτω σε αυτό το σεμινάριο, θα βρείτε αρκετές προηγμένες χρήσεις που σίγουρα αξίζει να εξερευνήσετε.

Συνάρτηση CHOOSE του Excel - σύνταξη και βασικές χρήσεις

Η συνάρτηση CHOOSE στο Excel έχει σχεδιαστεί για να επιστρέφει μια τιμή από τη λίστα με βάση μια καθορισμένη θέση.

Η λειτουργία είναι διαθέσιμη στο Excel 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 και Excel 2007.

Η σύνταξη της συνάρτησης CHOOSE έχει ως εξής:

Πού:

Index_num (υποχρεωτικό) - η θέση της τιμής που θα επιστραφεί. Μπορεί να είναι οποιοσδήποτε αριθμός μεταξύ 1 και 254, μια αναφορά κελιού ή ένας άλλος τύπος.

Value1, value2, ... - μια λίστα με έως και 254 τιμές από τις οποίες μπορείτε να επιλέξετε. Η τιμή Value1 είναι υποχρεωτική, οι άλλες τιμές είναι προαιρετικές. Αυτές μπορεί να είναι αριθμοί, τιμές κειμένου, αναφορές κελιών, τύποι ή καθορισμένα ονόματα.

Ακολουθεί ένα παράδειγμα τύπου CHOOSE στην απλούστερη μορφή του:

=CHOOSE(3, "Mike", "Sally", "Amy", "Neal")

Ο τύπος επιστρέφει "Amy" επειδή index_num είναι 3 και η "Amy" είναι η 3η τιμή στη λίστα:

Συνάρτηση CHOOSE του Excel - 3 πράγματα που πρέπει να θυμάστε!

Η CHOOSE είναι μια πολύ απλή συνάρτηση και δύσκολα θα αντιμετωπίσετε δυσκολίες στην εφαρμογή της στα φύλλα εργασίας σας. Εάν το αποτέλεσμα που επιστρέφει ο τύπος CHOOSE είναι απροσδόκητο ή δεν είναι το αποτέλεσμα που αναζητούσατε, αυτό μπορεί να οφείλεται στους ακόλουθους λόγους:

1. Ο αριθμός των τιμών που μπορείτε να επιλέξετε περιορίζεται σε 254.
2. Εάν index_num είναι μικρότερη από 1 ή μεγαλύτερη από τον αριθμό των τιμών στη λίστα, επιστρέφεται το σφάλμα #VALUE!
3. Εάν η index_num όρισμα είναι κλάσμα, περικόπτεται στον μικρότερο ακέραιο αριθμό.

Πώς να χρησιμοποιήσετε τη συνάρτηση CHOOSE στο Excel - παραδείγματα τύπων

Τα παρακάτω παραδείγματα δείχνουν πώς η CHOOSE μπορεί να επεκτείνει τις δυνατότητες άλλων συναρτήσεων του Excel και να παρέχει εναλλακτικές λύσεις σε ορισμένες κοινές εργασίες, ακόμη και σε αυτές που θεωρούνται ανέφικτες από πολλούς.

Excel CHOOSE αντί για ένθετα IFs

Μια από τις πιο συχνές εργασίες στο Excel είναι η επιστροφή διαφορετικών τιμών με βάση μια καθορισμένη συνθήκη. Στις περισσότερες περιπτώσεις, αυτό μπορεί να γίνει με τη χρήση μιας κλασικής ένθετης εντολής IF. Αλλά η συνάρτηση CHOOSE μπορεί να αποτελέσει μια γρήγορη και εύκολα κατανοητή εναλλακτική λύση.

Παράδειγμα 1. Επιστροφή διαφορετικών τιμών με βάση τη συνθήκη

Ας υποθέσουμε ότι έχετε μια στήλη με βαθμολογίες μαθητών και θέλετε να επισημάνετε τις βαθμολογίες με βάση τις ακόλουθες συνθήκες:

Ένας τρόπος για να το κάνετε αυτό είναι να φωλιάσετε μερικές φόρμουλες IF η μία μέσα στην άλλη:

=IF(B2>=151, "Εξαιρετική", IF(B2>=101, "Καλή", IF(B2>=51, "Ικανοποιητική", "Κακή")))

Ένας άλλος τρόπος είναι να επιλέξετε μια ετικέτα που αντιστοιχεί στην κατάσταση:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent")

Πώς λειτουργεί αυτή η φόρμουλα:

Στο index_num όρισμα, αξιολογείτε κάθε συνθήκη και επιστρέφετε TRUE αν ικανοποιείται η συνθήκη, FALSE διαφορετικά. Για παράδειγμα, η τιμή στο κελί B2 ικανοποιεί τις τρεις πρώτες συνθήκες, οπότε λαμβάνουμε αυτό το ενδιάμεσο αποτέλεσμα:

=CHOOSE(TRUE + TRUE + TRUE + FALSE, "Poor", "Satisfactory", "Good", "Excellent")

Δεδομένου ότι στους περισσότερους τύπους του Excel το TRUE ισούται με 1 και το FALSE με 0, ο τύπος μας υφίσταται αυτόν τον μετασχηματισμό:

=CHOOSE(1 + 1 + 1 + 1 + 0, "Κακή", "Ικανοποιητική", "Καλή", "Εξαιρετική")

Μετά την εκτέλεση της πράξης πρόσθεσης, έχουμε:

=CHOOSE(3, "Κακή", "Ικανοποιητική", "Καλή", "Εξαιρετική")

Ως αποτέλεσμα, επιστρέφεται η 3η τιμή της λίστας, η οποία είναι "Good".

Συμβουλές:

• Για να κάνετε τον τύπο πιο ευέλικτο, μπορείτε να χρησιμοποιήσετε αναφορές κελιών αντί για σκληρά κωδικοποιημένες ετικέτες, για παράδειγμα:

  =CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), $E$1, $E$2, $E$3, $E$4)

• Εάν καμία από τις συνθήκες σας δεν είναι ΑΛΗΘΗΣ, η index_num θα οριστεί σε 0 και θα αναγκάσει τον τύπο σας να επιστρέψει το σφάλμα #VALUE! Για να το αποφύγετε αυτό, απλά τυλίξτε το CHOOSE στη συνάρτηση IFERROR ως εξής:

  =IFERROR(CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent"), "")

Παράδειγμα 2. Εκτέλεση διαφορετικών υπολογισμών ανάλογα με την κατάσταση

Με παρόμοιο τρόπο, μπορείτε να χρησιμοποιήσετε τη συνάρτηση CHOOSE του Excel για να εκτελέσετε έναν υπολογισμό σε μια σειρά πιθανών υπολογισμών/τύπων χωρίς να εμφωλεύσετε πολλαπλές δηλώσεις IF η μία μέσα στην άλλη.

Για παράδειγμα, ας υπολογίσουμε την προμήθεια κάθε πωλητή ανάλογα με τις πωλήσεις του:

Με το ποσό των πωλήσεων στο Β2, ο τύπος παίρνει την ακόλουθη μορφή:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*5%, B2*7%, B2*10%)

Αντί να κωδικοποιήσετε τα ποσοστά στον τύπο, μπορείτε να ανατρέξετε στο αντίστοιχο κελί στον πίνακα αναφοράς σας, αν υπάρχει. Απλά θυμηθείτε να καθορίσετε τις αναφορές χρησιμοποιώντας το σύμβολο $.

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*$E$2, B2*$E$3, B2*$E$4)

Τύπος του Excel CHOOSE για τη δημιουργία τυχαίων δεδομένων

Όπως πιθανώς γνωρίζετε, το Microsoft Excel διαθέτει μια ειδική συνάρτηση για τη δημιουργία τυχαίων ακεραίων αριθμών μεταξύ του κάτω και του πάνω αριθμού που έχετε καθορίσει - τη συνάρτηση RANDBETWEEN. Τοποθετήστε την στο index_num του όρου CHOOSE, και ο τύπος σας θα δημιουργήσει σχεδόν οποιαδήποτε τυχαία δεδομένα θέλετε.

Για παράδειγμα, αυτός ο τύπος μπορεί να παράγει μια λίστα με τυχαία αποτελέσματα εξετάσεων:

=CHOOSE(RANDBETWEEN(1,4), "Κακή", "Ικανοποιητική", "Καλή", "Εξαιρετική")

Η λογική του τύπου είναι προφανής: το RANDBETWEEN παράγει τυχαίους αριθμούς από το 1 έως το 4 και το CHOOSE επιστρέφει μια αντίστοιχη τιμή από τον προκαθορισμένο κατάλογο των τεσσάρων τιμών.

Σημείωση. Η RANDBETWEEN είναι μια ασταθής συνάρτηση και υπολογίζει εκ νέου με κάθε αλλαγή που κάνετε στο φύλλο εργασίας. Ως αποτέλεσμα, η λίστα των τυχαίων τιμών σας θα αλλάξει επίσης. Για να αποτρέψετε αυτό το ενδεχόμενο, μπορείτε να αντικαταστήσετε τους τύπους με τις τιμές τους χρησιμοποιώντας την εντολή Ειδική επικόλληση χαρακτηριστικό.

ΕΠΙΛΕΞΤΕ τύπο για να κάνετε ένα αριστερό Vlookup

Αν έχετε εκτελέσει ποτέ κάθετη αναζήτηση στο Excel, γνωρίζετε ότι η συνάρτηση VLOOKUP μπορεί να κάνει αναζήτηση μόνο στην αριστερότερη στήλη. Σε περιπτώσεις που πρέπει να επιστρέψετε μια τιμή στα αριστερά της στήλης αναζήτησης, μπορείτε είτε να χρησιμοποιήσετε το συνδυασμό INDEX / MATCH είτε να ξεγελάσετε την VLOOKUP με την ενσωμάτωση της συνάρτησης CHOOSE σε αυτήν. Ακούστε πώς:

Ας υποθέσουμε ότι έχετε μια λίστα με βαθμολογίες στη στήλη Α, ονόματα μαθητών στη στήλη Β και θέλετε να ανακτήσετε τη βαθμολογία ενός συγκεκριμένου μαθητή. Δεδομένου ότι η στήλη επιστροφής βρίσκεται στα αριστερά της στήλης αναζήτησης, ένας κανονικός τύπος Vlookup επιστρέφει το σφάλμα #N/A:

Για να το διορθώσετε αυτό, βάλτε τη συνάρτηση CHOOSE να ανταλλάξει τις θέσεις των στηλών, λέγοντας στο Excel ότι η στήλη 1 είναι το Β και η στήλη 2 είναι το Α:

=CHOOSE({1,2}, B2:B5, A2:A5)

Επειδή παρέχουμε έναν πίνακα {1,2} στην εντολή index_num όρισμα, η συνάρτηση CHOOSE δέχεται εύρος τιμών στο πεδίο αξία επιχειρήματα (κανονικά, δεν το κάνει).

Τώρα, ενσωματώστε τον παραπάνω τύπο στο table_array επιχείρημα του VLOOKUP:

=VLOOKUP(E1,CHOOSE({1,2}, B2:B5, A2:A5),2,FALSE)

Και ορίστε - μια αναζήτηση προς τα αριστερά εκτελείται χωρίς πρόβλημα!

ΕΠΙΛΕΞΤΕ φόρμουλα για επιστροφή την επόμενη εργάσιμη ημέρα

Αν δεν είστε σίγουροι αν θα πρέπει να πάτε αύριο στη δουλειά ή αν μπορείτε να μείνετε στο σπίτι και να απολαύσετε το καλά κερδισμένο Σαββατοκύριακο, η συνάρτηση CHOOSE του Excel μπορεί να βρει πότε είναι η επόμενη εργάσιμη ημέρα.

Υποθέτοντας ότι οι εργάσιμες ημέρες σας είναι από Δευτέρα έως Παρασκευή, ο τύπος έχει ως εξής:

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,1,1,3,2)

Δύσκολο με την πρώτη ματιά, με μια πιο προσεκτική ματιά η λογική του τύπου είναι εύκολο να ακολουθηθεί:

WEEKDAY(TODAY()) επιστρέφει έναν αύξοντα αριθμό που αντιστοιχεί στη σημερινή ημερομηνία και κυμαίνεται από 1 (Κυριακή) έως 7 (Σάββατο). Αυτός ο αριθμός πηγαίνει στο index_num επιχείρημα του τύπου CHOOSE.

Αξία1 - value7 (1,1,1,1,1,1,3,2) καθορίζουν πόσες ημέρες θα προστεθούν στην τρέχουσα ημερομηνία. Αν σήμερα είναι Κυριακή - Πέμπτη (index_num 1 - 5), προσθέτετε 1 για να επιστρέψετε την επόμενη ημέρα. Αν σήμερα είναι Παρασκευή (index_num 6), προσθέτετε 3 για να επιστρέψετε την επόμενη Δευτέρα. Αν σήμερα είναι Σάββατο (index_num 7), προσθέτετε 2 για να επιστρέψετε πάλι την επόμενη Δευτέρα. Ναι, είναι τόσο απλό :)

ΕΠΙΛΕΞΤΕ τύπο για να επιστρέψετε ένα προσαρμοσμένο όνομα ημέρας/μήνα από την ημερομηνία

Σε περιπτώσεις που θέλετε να λάβετε το όνομα μιας ημέρας με την τυπική μορφή, όπως το πλήρες όνομα (Δευτέρα, Τρίτη κ.λπ.) ή το σύντομο όνομα (Δευτέρα, Τρίτη κ.λπ.), μπορείτε να χρησιμοποιήσετε τη συνάρτηση TEXT, όπως εξηγείται σε αυτό το παράδειγμα: Λήψη ημέρας εβδομάδας από ημερομηνία στο Excel.

Αν θέλετε να επιστρέψετε μια ημέρα της εβδομάδας ή ένα όνομα μήνα σε προσαρμοσμένη μορφή, χρησιμοποιήστε τη λειτουργία ΕΠΙΛΟΓΗ με τον ακόλουθο τρόπο.

Για να πάρετε μια ημέρα της εβδομάδας:

=CHOOSE(WEEKDAY(A2),"Su","Mo","Tu","We","Th","Fr","Sa")

Για να πάρετε ένα μήνα:

=CHOOSE(MONTH(A2), "Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

Όπου A2 είναι το κελί που περιέχει την αρχική ημερομηνία.

Ελπίζω αυτό το σεμινάριο να σας έδωσε μερικές ιδέες για το πώς μπορείτε να χρησιμοποιήσετε τη συνάρτηση CHOOSE στο Excel για να βελτιώσετε τα μοντέλα δεδομένων σας. Σας ευχαριστώ για την ανάγνωση και ελπίζω να σας δω στο blog μας την επόμενη εβδομάδα!

Κατεβάστε το βιβλίο ασκήσεων

Παραδείγματα της συνάρτησης CHOOSE του Excel