Гэты падручнік паказвае, як стварыць формулу Excel для працэнтнага павелічэння або памяншэння і выкарыстоўваць яе з дадатнымі і адмоўнымі лікамі.

У Microsoft Excel ёсць 6 розных функцый для вылічэння дысперсія. Аднак ні адзін з іх не падыходзіць для разліку працэнтнай розніцы паміж дзвюма клеткамі. Убудаваныя функцыі прызначаныя для вызначэння дысперсіі ў класічным разуменні, гэта значыць таго, наколькі далёка набор значэнняў адхілены ад іх сярэдняга. Працэнтная дысперсія - гэта нешта іншае. У гэтым артыкуле вы знойдзеце правільную формулу для разліку працэнтных змяненняў у Excel.

Што такое працэнтныя змены?

Працэнтныя змены, таксама працэнтная дысперсія або розніца , гэта прапарцыянальнае змяненне паміж двума значэннямі, першапачатковым значэннем і новым значэннем.

Формула адсоткавага змянення вылічае, наколькі нешта змяняецца паміж двума перыядамі ў працэнтах. Напрыклад, вы можаце падлічыць розніцу паміж продажамі ў гэтым і мінулым годзе, паміж прагнозам і назіранай тэмпературай, паміж запланаваным коштам і рэальным.

Напрыклад, у студзені вы зарабілі $1000, а ў лютым $1200 , такім чынам, розніца складае павелічэнне прыбытку на 200 долараў. Але колькі гэта ў працэнтах? Каб высветліць гэта, вы выкарыстоўваеце формулу працэнтнай змены.

Формула працэнтнай змены Excel

Ёсць дзве асноўныя формулы, каб знайсці працэнтную розніцу паміж двумалічбы.

Класічная формула працэнтнай дысперсіі

Вось звычайна выкарыстоўваная формула для разліку працэнтнай змены:

У матэматыцы вы звычайна выконваеце 3 крокі, каб вылічыць працэнтную дысперсію паміж любымі двума лікавымі значэннямі:

1. Адняць новае значэнне ад старога.
2. Падзяліце розніцу на стары лік.
3. Памножце вынік на 100.

У Excel вы прапускаеце апошні крок на прымяненне фармату Працэнт .

Формула працэнтнага змянення Excel

А вось больш простая формула працэнтнага змянення ў Excel, якая вяртае той самы вынік.

Як разлічыць працэнтнае змяненне ў Excel

Каб знайсці працэнтную розніцу паміж двума лікамі ў Excel, вы можаце выкарыстоўваць любой з прыведзеных вышэй формул. Дапусцім, у вас ёсць разліковы аб'ём продажаў у слупку B і фактычны аб'ём продажаў у слупку C. Мяркуючы, што разліковы лік з'яўляецца "базавым" значэннем, а фактычны з'яўляецца "новым" значэннем, формулы прымаюць такую ​​форму:

=(C3-B3)/B3

або

=ABS((C3-B3)/B3)

Прыведзеныя вышэй формулы параўноўваюць лічбы ў радку 3. Каб вылічыць працэнт змены ва ўсім слупку, вам трэба зрабіць вось што:

1. Увядзіце формулу працэнтнай рознасці ў любую пустую ячэйку ў радку 3, скажам, у D3 або E3.
2. Калі ячэйка з формулай выбрана, націсніце кнопку Стыль працэнтаў на устужка або націсніце спалучэнне клавіш Ctrl + Shift + %. Гэта прывядзе да пераўтварэння вернутага дзесятковага ліку ў працэнты.
3. Перацягніце формулу ўніз праз столькі радкоў, колькі неабходна.

Пасля капіравання формулы вы атрымаеце слупок працэнтнай змены з вашых дадзеных.

Як працуе формула працэнтных змяненняў Excel

Пры выкананні вылічэнняў уручную вы б узялі старое (арыгінальнае) значэнне і новае значэнне, знайдзіце розніцу паміж імі і падзяліць яго на зыходнае значэнне. Каб атрымаць вынік у працэнтах, трэба памножыць яго на 100.

Напрыклад, калі першапачатковае значэнне роўна 120, а новае — 150, працэнтную розніцу можна вылічыць наступным чынам:

=(150-120)/120

=30/120

=0.25

0.25*100 = 25%

Прымяненне лічбавага фармату Працэнт у Excel аўтаматычна адлюстроўвае дзесятковы лік у выглядзе працэнтаў , таму частка *100 апускаецца.

Формула Excel для працэнтнага павелічэння/памяншэння

Паколькі працэнтнае павелічэнне або памяншэнне з'яўляецца толькі прыватным выпадкам адсоткавай дысперсіі, ён разлічваецца па той жа формуле:

Або

Напрыклад, каб вылічыць працэнтнае павелічэнне паміж двума значэннямі (B2 і C2), формула:

=(C2-B2)/B2

Або

=C2/B2-1

Формула для разліку працэнтнага зніжэння цалкам такая ж.

Працэнт Excelзмяніць абсалютнае значэнне

Па змаўчанні формула працэнтнай дысперсіі ў Excel вяртае станоўчае значэнне для працэнтнага павелічэння і адмоўнае для працэнтнага памяншэння. Каб атрымаць працэнтнае змяненне ў выглядзе абсалютнага значэння без уліку яго знака, занясіце формулу ў функцыю ABS так:

У нашым выпадку формула прымае наступны выгляд:

=ABS((C3-B3)/B3)

Гэта таксама будзе нармальна працаваць:

=ABS(C3/B3-1)

Разлічыць працэнт скідкі

Гэты прыклад паказвае яшчэ адно практычнае прымяненне формулы працэнтнай змены Excel - вызначэнне працэнта скідкі. Такім чынам, дамы, калі вы ідзяце па крамах, памятайце пра гэта:

discount % = (discounted price - regular price) / regular price

discount % = discounted price / regular price - 1

Працэнт зніжкі адлюстроўваецца як адмоўнае значэнне, таму што новая цана са зніжкай меншая за пачатковая цана. Каб вывесці вынік у выглядзе дадатнага ліку , укладзіце формулы ў функцыю ABS, як мы рабілі ў папярэднім прыкладзе:

=ABS((C2-B2)/B2)

Вылічыць значэнне пасля змены ў працэнтах

Каб атрымаць значэнне пасля працэнтнага павелічэння або памяншэння, агульная формула:

Выкажам здагадку, што ў вас ёсць арыгінал значэнні ў слупку B і розніца ў працэнтах у слупку C. Каб вылічыць новае значэнне пасля змены ў працэнтах, скапіруйце формулу ў D2:

=B2*(1+C2)

Спачатку вы знаходзіце агульны працэнт што трэба памножыць напершапачатковае значэнне. Для гэтага проста дадайце працэнт да 1 (1+C2). Затым вы памнажаеце агульны працэнт на зыходныя лічбы, каб атрымаць жаданы вынік.

Як бачыце, гэтае рашэнне добра працуе як для павелічэння, так і для памяншэння адсотка:

Да павялічыць або паменшыць увесь слупок на пэўны адсотак , вы можаце падаць працэнтнае значэнне непасрэдна ў формуле. Скажам, каб павялічыць усе значэнні ў слупку B на 5%, увядзіце наступную формулу ў C2, а затым перацягніце яе ўніз праз астатнія радкі:

=B2*(1+5%)

Тут вы проста памнажаеце зыходнае значэнне на 105%, што дае значэнне на 5% вышэй.

Для зручнасці вы можаце ўвесці працэнтнае значэнне ў загадзя вызначаную ячэйку (F2) і звярнуцца да гэтай ячэйкі. Хітрасць заключаецца ў блакіроўцы спасылкі на ячэйку знакам $, таму формула правільна капіюецца:

=B2*(1+$F$2)

Перавага гэтага падыходу заключаецца ў тым, што каб павялічыць слупок яшчэ на адзін працэнт, вам трэба толькі змяніць значэнне ў адной ячэйцы. Паколькі ўсе формулы звязаны з гэтай ячэйкай, яны будуць пералічаны аўтаматычна.

Разлік працэнтнай дысперсіі з адмоўнымі значэннямі

Калі некаторыя з вашых значэнняў прадстаўлены адмоўнымі лікамі, традыцыйная формула працэнтнай рознасці будзе працаваць няправільна. Агульнапрынятае рашэнне - зрабіць назоўнік дадатным лікам з дапамогай функцыі ABS.

Вось агульная формула Excel дляпрацэнтнае змяненне з адмоўнымі лікамі:

Са старым значэннем у B2 і новым значэннем у C2 рэальная формула выглядае наступным чынам:

=(C2-B2)/ABS(B2)

Заўвага. Нягледзячы на ​​тое, што гэта карэкціроўка ABS тэхнічна правільная, формула можа даць памылковыя вынікі ў выпадку, калі першапачатковае значэнне адмоўнае, а новае значэнне дадатнае, і наадварот.

Працэнт змены Excel, дзяленне на нуль, памылка (#DIV/0)

Калі ваш набор даных утрымлівае нулявыя значэнні, вы, хутчэй за ўсё, сутыкнецеся з памылкай дзялення на нуль (#DIV/0!) пры разліку працэнтных змяненняў у Excel, таму што вы не можаце падзяліць лік на нуль у матэматыцы. Функцыя IFERROR можа дапамагчы пераадолець гэтую праблему. У залежнасці ад вашых чаканняў адносна канчатковага выніку, выкарыстоўвайце адно з наступных рашэнняў.

Рашэнне 1: калі старое значэнне роўна нулю, вярніце 0

Калі старое значэнне роўна нулю, працэнтнае змяненне будзе 0% незалежна ад таго, роўнае новае значэнне нулю ці не.

=IFERROR((C2-B2)/B2, 0)

або

=IFERROR(C2/B2-1, 0)

Рашэнне 2: калі старое значэнне роўна нулю, вярнуць 100%

Гэта рашэнне рэалізуе іншы падыход, мяркуючы, што новае значэнне вырасла на 100%, пачынаючы з нуля:

=IFERROR((C2-B2)/B2, 1)

=IFERROR(C2/B2-1, 1)

У гэтым выпадку працэнтная розніца будзе роўная 100%, калі старое значэнне роўна нулю (радок 5) або абодва значэнні роўныя нулю (радок 9).

Гледзячы на ​​вылучаныя запісы ніжэй, становіцца відавочным што ні формулаperfect:

Каб атрымаць лепшыя вынікі, вы можаце аб'яднаць дзве формулы ў адну, выкарыстоўваючы ўкладзены аператар IF:

=IF(C20, IFERROR((C2-B2)/B2, 1), IFERROR((C2-B2)/B2, 0))

Гэтая палепшаная формула верне:

• Працэнт змяняецца на 0%, калі і старое, і новае значэнні роўны нулю.
• Працэнт змяняецца на 100%, калі старое значэнне роўна нулю, а новае значэнне не роўна нулю.

Вось як разлічыць павелічэнне або памяншэнне ў працэнтах у Excel. Каб атрымаць практычны вопыт, вы можаце загрузіць наш узор рабочай кнігі ніжэй. Я дзякую вам за чытанне і спадзяюся ўбачыць вас у нашым блогу на наступным тыдні!

Практычны сшытак для спампоўкі

Формула Excel для працэнтнага павелічэння/памяншэння - прыклады (.xlsx файл)