Mục lục
Trong một số bài viết gần đây, chúng ta đã thảo luận về các hàm Văn bản khác nhau - những hàm được sử dụng để thao tác với chuỗi văn bản. Hôm nay, trọng tâm của chúng ta là hàm RIGHT, được thiết kế để trả về một số ký tự xác định từ phía ngoài cùng bên phải của chuỗi. Giống như các hàm Văn bản Excel khác, RIGHT rất đơn giản và dễ hiểu, tuy nhiên, nó có một vài cách sử dụng không rõ ràng có thể hữu ích trong công việc của bạn.
Cú pháp hàm Excel RIGHT
Hàm RIGHT trong Excel trả về số lượng ký tự được chỉ định từ cuối chuỗi văn bản.
Cú pháp của hàm RIGHT như sau:
RIGHT(text, [num_chars])Ở đâu :
- Văn bản (bắt buộc) - chuỗi văn bản mà bạn muốn trích xuất các ký tự.
- Num_chars (tùy chọn) - số ký tự cần trích xuất, bắt đầu từ ký tự ngoài cùng bên phải.
- Nếu num_chars bị bỏ qua, 1 ký tự cuối cùng của chuỗi sẽ được trả về (mặc định).
- Nếu num_chars lớn hơn tổng số các ký tự trong chuỗi, tất cả các ký tự được trả về.
- Nếu num_chars là số âm, công thức Right sẽ trả về lỗi #VALUE! lỗi.
Ví dụ: để trích xuất 3 ký tự cuối cùng từ chuỗi trong ô A2, hãy sử dụng công thức sau:
=RIGHT(A2, 3)
Kết quả có thể giống như sau: 
Lưu ý quan trọng! Hàm RIGHT của Excel luôn trả về một văn bản chuỗi , ngay cả khi giá trị ban đầu là một số. Để buộc một công thức Right xuất ra một số, hãy sử dụng nó kết hợp với hàm VALUE như minh họa trong ví dụ này.
Cách sử dụng hàm RIGHT trong Excel - ví dụ về công thức
Trong thực tế bảng tính, hàm RIGHT của Excel hiếm khi được sử dụng riêng. Trong hầu hết các trường hợp, bạn sẽ sử dụng nó cùng với các hàm Excel khác như một phần của các công thức phức tạp hơn.
Cách lấy chuỗi con đứng sau một ký tự nhất định
Trong trường hợp bạn muốn trích xuất một chuỗi con theo sau một ký tự cụ thể, hãy sử dụng hàm TÌM KIẾM hoặc TÌM để xác định vị trí của ký tự đó, trừ vị trí khỏi tổng độ dài chuỗi do hàm LEN trả về và kéo nhiều ký tự đó từ phía ngoài cùng bên phải của chuỗi ban đầu.
RIGHT( string , LEN( string ) - SEARCH( character , string ))Giả sử, ô A2 gồm phần họ và tên cách nhau bởi khoảng trắng, bạn nhắm kéo phần họ sang ô khác. Chỉ cần lấy công thức chung ở trên và bạn đặt A2 thay cho chuỗi và " " (dấu cách) theo tốc độ của ký tự:
=RIGHT(A2,LEN(A2)-SEARCH(" ",A2))
Công thức sẽ cho kết quả như sau: 
Theo cách tương tự, bạn có thể nhận được một chuỗi con theo sau bất kỳ ký tự nào khác, ví dụ: dấu phẩy, dấu chấm phẩy, dấu gạch nối, v.v. Ví dụ: để trích xuất một chuỗi con xuất hiện sau dấu gạch nối,sử dụng công thức này:
=RIGHT(A2,LEN(A2)-SEARCH("-",A2))
Kết quả sẽ giống như sau: 
Cách trích xuất một chuỗi con sau lần xuất hiện cuối cùng của dấu phân cách
Khi nào xử lý các chuỗi phức tạp chứa nhiều lần xuất hiện của cùng một dấu phân cách, bạn có thể thường xuyên cần truy xuất văn bản ở bên phải của lần xuất hiện cuối cùng của dấu phân cách. Để dễ hiểu hơn, hãy xem dữ liệu nguồn sau đây và kết quả mong muốn: 
Như bạn có thể thấy trong ảnh chụp màn hình ở trên, Cột A chứa danh sách các lỗi. Mục tiêu của bạn là kéo mô tả lỗi xuất hiện sau dấu hai chấm cuối cùng trong mỗi chuỗi. Một điều phức tạp nữa là các chuỗi ban đầu có thể chứa các số lượng khác nhau của các trường hợp dấu phân cách, ví dụ: A3 chứa 3 dấu hai chấm trong khi A5 chỉ có một.
Chìa khóa để tìm giải pháp là xác định vị trí của dấu phân cách cuối cùng trong chuỗi nguồn (lần xuất hiện cuối cùng của dấu hai chấm trong ví dụ này). Để làm điều này, bạn sẽ cần sử dụng một số hàm khác nhau:
- Lấy số lượng dấu phân cách trong chuỗi gốc. Đây là một phần dễ dàng:
- Đầu tiên, bạn tính tổng độ dài của chuỗi bằng cách sử dụng hàm LEN: LEN(A2)
- Thứ hai, bạn tính độ dài của chuỗi mà không có dấu phân cách bằng cách sử dụng Hàm SUBSTITUTE thay thế tất cả các lần xuất hiện của dấu hai chấm bằng không có gì: LEN(SUBSTITUTE(A2,":",""))
- Cuối cùng, bạn trừ đi độ dài của chuỗi ban đầukhông có dấu phân cách từ tổng độ dài chuỗi: LEN(A2)-LEN(SUBSTITUTE(A2,":",""))
Để đảm bảo công thức hoạt động đúng, bạn có thể nhập công thức vào ô ô riêng biệt và kết quả sẽ là 2, là số lượng dấu hai chấm trong ô A2.
- Thay thế dấu phân cách cuối cùng bằng một số ký tự duy nhất. Để trích xuất văn bản xuất hiện sau dấu phân cách cuối cùng trong chuỗi, chúng ta cần "đánh dấu" lần xuất hiện cuối cùng của dấu phân cách theo một cách nào đó. Đối với điều này, hãy thay thế lần xuất hiện cuối cùng của dấu hai chấm bằng một ký tự không xuất hiện ở bất kỳ đâu trong chuỗi gốc, chẳng hạn như bằng dấu thăng (#).
Nếu bạn đã quen với cú pháp của hàm SUBSTITUTE trong Excel, bạn có thể nhớ rằng hàm này có đối số tùy chọn thứ 4 (instance_num) cho phép chỉ thay thế một lần xuất hiện cụ thể của ký tự đã chỉ định. Và vì chúng ta đã tính toán số lượng dấu phân cách trong chuỗi, nên chỉ cần cung cấp hàm trên trong đối số thứ tư của một hàm SUBSTITUTE khác:
=SUBSTITUTE(A2,":","#",LEN(A2)-LEN(SUBSTITUTE(A2,":","")))Nếu bạn đặt công thức này trong một ô riêng biệt , nó sẽ trả về chuỗi này: ERROR:432#Connection timed out
- Lấy vị trí của dấu phân cách cuối cùng trong chuỗi. Tùy thuộc vào ký tự bạn đã thay thế dấu phân cách cuối cùng bằng ký tự nào, hãy sử dụng TÌM KIẾM không phân biệt chữ hoa chữ thường hoặc TÌM phân biệt chữ hoa chữ thường để xác định vị trí của ký tự đó trong chuỗi. Chúng tôi đã thay thế dấu hai chấm cuối cùngbằng dấu #, vì vậy chúng tôi sử dụng công thức sau để tìm ra vị trí của nó:
=SEARCH("#", SUBSTITUTE(A2,":","#",LEN(A2)-LEN(SUBSTITUTE(A2,":",""))))Trong ví dụ này, công thức trả về 10, là vị trí của # trong chuỗi được thay thế.
- Trả về một chuỗi con ở bên phải dấu phân cách cuối cùng. Bây giờ bạn đã biết vị trí của dấu phân cách cuối cùng trong một chuỗi, tất cả những gì bạn phải làm là lấy tổng độ dài chuỗi trừ đi con số đó và sử dụng hàm RIGHT để trả về nhiều ký tự đó từ cuối chuỗi ban đầu:
=RIGHT(A2,LEN(A2)-SEARCH("$",SUBSTITUTE(A2,":","$",LEN(A2)-LEN(SUBSTITUTE(A2,":","")))))
Như minh họa trong ảnh chụp màn hình bên dưới, công thức hoạt động hoàn hảo: 
Nếu bạn đang làm việc với một tập dữ liệu lớn trong đó các ô khác nhau có thể chứa các dấu phân cách khác nhau, bạn có thể muốn để đưa công thức trên vào hàm IFERROR để ngăn các lỗi có thể xảy ra:
=IFERROR(RIGHT(A2,LEN(A2)-SEARCH("$",SUBSTITUTE(A2,":","$",LEN(A2)-LEN(SUBSTITUTE(A2,":",""))))), A2)
Trong trường hợp một chuỗi nhất định không chứa một lần xuất hiện của dấu phân cách đã chỉ định, thì chuỗi gốc sẽ được trả về, như ở hàng 6 trong ảnh chụp màn hình bên dưới: 
Cách xóa N ký tự đầu tiên khỏi một chuỗi
Ngoài việc trích xuất một chuỗi con từ cuối chuỗi, hàm RIGHT của Excel rất hữu ích trong trường hợp bạn muốn xóa một số ký tự nhất định khỏi đầu chuỗi.
Trong tập dữ liệu được sử dụng ở phần trước Ví dụ quan trọng, bạn có thể muốn xóa từ "ERROR" xuất hiện ở đầu mỗi chuỗi và chỉ để lại số lỗi và mô tả. Để có được nóxong, hãy trừ đi số ký tự cần xóa khỏi tổng độ dài chuỗi và cung cấp số đó cho đối số num_chars của hàm Excel RIGHT:
RIGHT( string , LEN ( string )- number_of_chars_to_remove )Trong ví dụ này, chúng tôi xóa 6 ký tự đầu tiên (5 chữ cái và dấu hai chấm) khỏi chuỗi văn bản trong A2, vì vậy công thức của chúng tôi sẽ như sau sau:
=RIGHT(A2, LEN(A2)-6) 
Hàm RIGHT trong Excel có thể trả về một số không?
Như đã đề cập ở phần đầu của hướng dẫn này, hàm RIGHT trong Excel luôn trả về một chuỗi văn bản chẵn nếu giá trị ban đầu là một số. Nhưng nếu bạn làm việc với tập dữ liệu số và muốn đầu ra cũng là số thì sao? Một cách giải quyết dễ dàng là lồng một công thức Right trong hàm VALUE, được thiết kế đặc biệt để chuyển đổi một chuỗi đại diện cho một số thành một số.
Ví dụ: để kéo 5 ký tự cuối cùng (mã zip) khỏi chuỗi trong A2 và chuyển đổi các ký tự được trích xuất thành một số, hãy sử dụng công thức sau:
=VALUE(RIGHT(A2, 5))
Ảnh chụp màn hình bên dưới hiển thị kết quả - vui lòng lưu ý các số được căn phải trong cột B, trái ngược với bên trái -dòng văn bản được căn chỉnh trong cột A: 
Tại sao hàm RIGHT không hoạt động với ngày?
Vì hàm RIGHT trong Excel được thiết kế để hoạt động với chuỗi văn bản trong khi ngày được biểu thị bằng số trong hệ thống Excel nội bộ, một công thức đúng không thể truy xuất một cá nhânmột phần của ngày như ngày, tháng hoặc năm. Nếu bạn cố gắng làm điều này, tất cả những gì bạn sẽ nhận được là một vài chữ số cuối của số đại diện cho một ngày.
Giả sử, bạn có ngày 18-Jan-2017 trong ô A1. Nếu bạn cố trích xuất năm bằng công thức RIGHT(A1,4), kết quả sẽ là 2753, là 4 chữ số cuối của số 42753 đại diện cho ngày 18 tháng 1 năm 2017 trong hệ thống Excel. 
"Vậy, làm cách nào để truy xuất một phần nhất định của một ngày?", Bạn có thể hỏi tôi. Bằng cách sử dụng một trong các hàm sau:
- Hàm DAY để trích xuất một ngày: =DAY(A1)
- Hàm MONTH để lấy một tháng: =MONTH(A1)
- Hàm NĂM để lấy một năm: =YEAR(A1)
Ảnh chụp màn hình sau hiển thị kết quả: 
Nếu ngày của bạn được biểu thị bằng chuỗi văn bản , điều này thường xảy ra khi bạn xuất dữ liệu từ một nguồn bên ngoài, không có gì ngăn cản bạn sử dụng hàm RIGHT để lấy một vài ký tự cuối cùng trong chuỗi đại diện cho một phần nhất định của ngày: 
Excel RIGHT hàm không hoạt động - nguyên nhân và giải pháp
Nếu một công thức Right không hoạt động ngay trong trang tính của bạn, rất có thể là do một trong những lý do sau:
- Có một hoặc nhiều dấu cách trong dữ liệu gốc. Để nhanh chóng xóa khoảng trắng thừa trong các ô, hãy sử dụng hàm TRIM của Excel hoặc phần bổ trợ Trình dọn dẹp ô.
- Đối số num_chars là nhỏ hơn 0 . Củatất nhiên, bạn sẽ khó có thể cố ý đặt một số âm trong công thức của mình, nhưng nếu đối số num_chars được tính toán bởi một hàm Excel khác hoặc sự kết hợp của các hàm khác nhau và công thức Right của bạn trả về lỗi #VALUE! lỗi, hãy đảm bảo kiểm tra (các) hàm lồng nhau để tìm lỗi.
- Giá trị ban đầu là ngày . Nếu bạn đã theo dõi kỹ hướng dẫn này, thì bạn đã biết tại sao hàm RIGHT không thể hoạt động với ngày tháng. Nếu ai đó đã bỏ qua phần trước, bạn có thể tìm thấy đầy đủ chi tiết trong Tại sao hàm RIGHT của Excel không hoạt động với ngày tháng.
Đây là cách bạn sử dụng hàm RIGHT trong Excel. Để xem kỹ hơn các công thức được thảo luận trong hướng dẫn này, rất hoan nghênh bạn tải xuống sổ làm việc mẫu của chúng tôi bên dưới. Tôi cảm ơn bạn đã đọc và hy vọng sẽ gặp bạn trên blog của chúng tôi vào tuần tới.
Các bản tải xuống hiện có
Hàm Excel RIGHT - ví dụ (tệp .xlsx)
